git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([MeshLink], [0.1])
   5 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AM_SILENT_RULES([yes])
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AM_PROG_CC_C_O
  18 AM_PROG_AR
  19 AC_PROG_CC_C99
  20 AC_PROG_CXX
  21 AC_PROG_CPP
  22 AC_PROG_INSTALL
  23 AC_PROG_LN_S
  24 AC_PROG_LIBTOOL
  25 AX_PTHREAD
  26
  27 dnl Check and set OS
  28
  29 AC_CANONICAL_HOST
  30
  31 case $host_os in
  32   *linux*)
  33     linux=true
  34     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  35   ;;
  36   *mingw*)
  37     mingw=true
  38     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  39     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  40   ;;
  41 esac
  42
  43 AM_CONDITIONAL(LINUX, test "$linux" = true)
  44 AM_CONDITIONAL(MINGW, test "$mingw" = true)
  45
  46 AC_CACHE_SAVE
  47
  48 if test -d /sw/include ; then
  49   CPPFLAGS="$CPPFLAGS -I/sw/include"
  50 fi
  51 if test -d /sw/lib ; then
  52   LIBS="$LIBS -L/sw/lib"
  53 fi
  54
  55 dnl Compiler hardening flags
  56 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
  57
  58 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
  59 AS_IF([test "x$enable_hardening" != "xno"],
  60   [CPPFLAGS="$CPPFLAGS -W -pedantic"
  61    AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
  62    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
  63      [AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])]
  64    )
  65    case $host_os in
  66      *mingw*)
  67        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
  68        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
  69        ;;
  70      *)
  71        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
  72        AX_CHECK_COMPILE_FLAG([-fPIC], [CPPFLAGS="$CPPFLAGS -fPIC"])
  73        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
  74        ;;
  75    esac
  76    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
  77    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
  78   ]
  79 );
  80
  81 dnl Allow building without Catta
  82 AC_ARG_ENABLE([catta], AS_HELP_STRING([--disable-catta], [disable linking with the Catta library]))
  83 AS_IF([test "x$enable_catta" != "xno"],
  84   AC_DEFINE(HAVE_CATTA, 1, [Link with Catta])
  85   AC_CONFIG_SUBDIRS([catta])
  86 )
  87 AM_CONDITIONAL(CATTA, test "x$enable_catta" != "xno")
  88
  89 dnl UTCP debug flags
  90 AC_ARG_ENABLE([utcp_debug], AS_HELP_STRING([--enable-utcp-debug], [compile utcp with debug output]))
  91 AS_IF([test "x$enable_utcp_debug" = "xyes"],
  92   [AX_CHECK_COMPILE_FLAG([-DUTCP_DEBUG], [CPPFLAGS="$CPPFLAGS -DUTCP_DEBUG"])
  93   ]
  94 );
  95
  96 dnl Install test binaries
  97 AC_ARG_ENABLE([install_tests],
  98   [AS_HELP_STRING([--enable-install-tests], [include test binaries in installation])],
  99   [AS_IF([test "x$enable_install_tests" = "xyes"], [install_tests=true], [install_tests=false])],
 100   [install_tests=false]
 101 )
 102
 103 AM_CONDITIONAL(INSTALL_TESTS, test "$install_tests" = true)
 104
 105 dnl Checks for header files.
 106 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 107
 108 AC_CHECK_HEADERS([syslog.h sys/file.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 109
 110 dnl Checks for typedefs, structures, and compiler characteristics.
 111 MeshLink_ATTRIBUTE(__malloc__)
 112 MeshLink_ATTRIBUTE(__warn_unused_result__)
 113
 114 AC_CHECK_TYPES([socklen_t, struct addrinfo, struct sockaddr_in6], , ,
 115   [#include "$srcdir/src/have.h"]
 116 )
 117
 118 AC_CHECK_TYPES([struct sockaddr_storage], ,AC_MSG_ERROR([System must support struct sockaddr_storage.]),
 119   [#include "$srcdir/src/have.h"]
 120 )
 121
 122 dnl Checks for library functions.
 123 AC_TYPE_SIGNAL
 124 AC_CHECK_FUNCS([asprintf fchmod fork gettimeofday random select strdup usleep],
 125   [], [], [#include "$srcdir/src/have.h"]
 126 )
 127
 128 dnl Support for SunOS
 129
 130 AC_CHECK_FUNC(socket, [], [
 131   AC_CHECK_LIB(socket, connect)
 132 ])
 133 AC_CHECK_FUNC(gethostbyname, [], [
 134   AC_CHECK_LIB(nsl, gethostbyname)
 135 ])
 136
 137 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 138   [], [], [#include "$srcdir/src/have.h"]
 139 )
 140
 141 AC_CACHE_SAVE
 142
 143 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile test/Makefile examples/Makefile])
 144
 145 AC_OUTPUT