git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.69)
   4 AC_INIT([MeshLink], [0.1])
   5 DX_PS_FEATURE(OFF)
   6 DX_INIT_DOXYGEN([MeshLink], [$(top_srcdir)/Doxyfile])
   7 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AM_SILENT_RULES([yes])
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_USE_SYSTEM_EXTENSIONS
  16 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  17 AC_DEFINE([_POSIX_C_SOURCE], 200809L, [Enable POSIX features])
  18 AC_DEFINE([_DARWIN_C_SOURCE], 1, [Enable Darwin features])
  19
  20 dnl Checks for programs.
  21 AM_PROG_CC_C_O
  22 AM_PROG_AR
  23 AC_PROG_CC
  24 AC_PROG_CC_C99
  25 AC_PROG_CXX
  26 AC_PROG_CPP
  27 AC_PROG_INSTALL
  28 AC_PROG_LN_S
  29 LT_INIT
  30 AX_PTHREAD
  31
  32 dnl Check and set OS
  33
  34 AC_CANONICAL_HOST
  35
  36 case $host_os in
  37   *linux*)
  38     linux=true
  39     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  40   ;;
  41   *mingw*)
  42     mingw=true
  43     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  44     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  45   ;;
  46   *darwin* | *ios*)
  47     LIBS="$LIBS -framework Foundation -framework SystemConfiguration"
  48   ;;
  49 esac
  50
  51 AM_CONDITIONAL(LINUX, test "$linux" = true)
  52 AM_CONDITIONAL(MINGW, test "$mingw" = true)
  53
  54 AC_CACHE_SAVE
  55
  56 if test -d /sw/include ; then
  57   CPPFLAGS="$CPPFLAGS -I/sw/include"
  58 fi
  59 if test -d /sw/lib ; then
  60   LIBS="$LIBS -L/sw/lib"
  61 fi
  62
  63 AX_CHECK_COMPILE_FLAG([-std=c11], [CFLAGS="$CFLAGS -std=c11"])
  64
  65 dnl Compiler hardening flags
  66 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
  67
  68 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
  69 AS_IF([test "x$enable_hardening" != "xno"],
  70   [CPPFLAGS="$CPPFLAGS -Wall -W -pedantic"
  71    AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
  72    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
  73      [AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])]
  74    )
  75    case $host_os in
  76      *mingw*)
  77        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
  78        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
  79        ;;
  80      *)
  81        AX_CHECK_COMPILE_FLAG([-fPIC], [CPPFLAGS="$CPPFLAGS -fPIC"])
  82        ;;
  83    esac
  84    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
  85    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
  86    AX_CHECK_COMPILE_FLAG([-Wextra -pedantic -Wreturn-type -Wold-style-definition -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wshadow -Wbad-function-cast -Wwrite-strings -fdiagnostics-show-option -fstrict-aliasing -Wmissing-noreturn], [CPPFLAGS="$CPPFLAGS -Wextra -pedantic -Wreturn-type -Wold-style-definition -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wshadow -Wbad-function-cast -Wwrite-strings -fdiagnostics-show-option -fstrict-aliasing -Wmissing-noreturn"])
  87   ]
  88 );
  89
  90 dnl UTCP debug flags
  91 AC_ARG_ENABLE([utcp_debug], AS_HELP_STRING([--enable-utcp-debug], [compile utcp with debug output]))
  92 AS_IF([test "x$enable_utcp_debug" = "xyes"],
  93   [AX_CHECK_COMPILE_FLAG([-DUTCP_DEBUG], [CPPFLAGS="$CPPFLAGS -DUTCP_DEBUG"])
  94   ]
  95 );
  96
  97 dnl Blackbox test suite
  98 PKG_CHECK_MODULES([CMOCKA], [cmocka >= 1.1.0], [cmocka=true], [cmocka=false])
  99 PKG_CHECK_MODULES([LXC], [lxc >= 2.0.0], [lxc=true], [lxc=false])
 100 AM_CONDITIONAL(BLACKBOX_TESTS, test "$cmocka" = true -a "$lxc" = true)
 101
 102
 103 dnl Additional example code
 104 PKG_CHECK_MODULES([NCURSES], [ncurses >= 5], [curses=true], [curses=false])
 105 AC_ARG_ENABLE([monitor_code],
 106         [AS_HELP_STRING([--enable-monitor-code], [Add monitor example code to the build])],
 107   [AS_IF([test "x$enable_monitor_code" = "xyes"], [monitor_code=true], [monitor_code=false])],
 108   [monitor_code=false]
 109 )
 110 AM_CONDITIONAL(MONITOR, test "$monitor_code" = true)
 111
 112 dnl Install test binaries
 113 AC_ARG_ENABLE([install_tests],
 114   [AS_HELP_STRING([--enable-install-tests], [include test binaries in installation])],
 115   [AS_IF([test "x$enable_install_tests" = "xyes"], [install_tests=true], [install_tests=false])],
 116   [install_tests=false]
 117 )
 118
 119 AM_CONDITIONAL(INSTALL_TESTS, test "$install_tests" = true)
 120
 121 dnl Checks for header files.
 122 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 123
 124 AC_CHECK_HEADERS([syslog.h sys/file.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h curses.h ifaddrs.h stdatomic.h])
 125
 126 dnl Checks for typedefs, structures, and compiler characteristics.
 127 MeshLink_ATTRIBUTE(__malloc__)
 128 MeshLink_ATTRIBUTE(__warn_unused_result__)
 129
 130 dnl Checks for library functions.
 131 AC_CHECK_FUNCS([asprintf fchmod fork gettimeofday random pselect select setns strdup usleep getifaddrs freeifaddrs],
 132   [], [], [#include "$srcdir/src/have.h"]
 133 )
 134
 135 dnl Support for SunOS
 136
 137 AC_CHECK_FUNC(socket, [], [
 138   AC_CHECK_LIB(socket, connect)
 139 ])
 140
 141 AC_CACHE_SAVE
 142
 143 AC_CONFIG_FILES([
 144          Makefile
 145          src/Makefile
 146          test/Makefile
 147          test/blackbox/Makefile
 148          test/blackbox/run_blackbox_tests/Makefile
 149          test/blackbox/test_case_channel_conn_01/Makefile
 150          test/blackbox/test_case_channel_conn_02/Makefile
 151          test/blackbox/test_case_channel_conn_03/Makefile
 152          test/blackbox/test_case_channel_conn_04/Makefile
 153          test/blackbox/test_case_channel_conn_05/Makefile
 154          test/blackbox/test_case_channel_conn_06/Makefile
 155          test/blackbox/test_case_channel_conn_07/Makefile
 156          test/blackbox/test_case_channel_conn_08/Makefile
 157          test/blackbox/test_case_meta_conn_01/Makefile
 158          test/blackbox/test_case_meta_conn_02/Makefile
 159          test/blackbox/test_case_meta_conn_03/Makefile
 160          test/blackbox/test_case_meta_conn_04/Makefile
 161          test/blackbox/test_case_meta_conn_05/Makefile
 162          test/blackbox/test_cases_submesh01/Makefile
 163          test/blackbox/test_cases_submesh02/Makefile
 164          test/blackbox/test_cases_submesh03/Makefile
 165          test/blackbox/test_cases_submesh04/Makefile
 166          examples/Makefile
 167 ])
 168
 169 AC_OUTPUT