git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([MeshLink], [0.1])
   5 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_CONFIG_SUBDIRS([catta])
   9 AM_SILENT_RULES([yes])
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AM_PROG_CC_C_O
  19 AM_PROG_AR
  20 AC_PROG_CC_C99
  21 AC_PROG_CXX
  22 AC_PROG_CPP
  23 AC_PROG_INSTALL
  24 AC_PROG_LN_S
  25 AC_PROG_LIBTOOL
  26
  27 dnl Check and set OS
  28
  29 AC_CANONICAL_HOST
  30
  31 case $host_os in
  32   *linux*)
  33     linux=true
  34     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  35   ;;
  36   *mingw*)
  37     mingw=true
  38     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  39     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  40   ;;
  41 esac
  42
  43 AM_CONDITIONAL(LINUX, test "$linux" = true)
  44 AM_CONDITIONAL(MINGW, test "$mingw" = true)
  45
  46 AC_CACHE_SAVE
  47
  48 if test -d /sw/include ; then
  49   CPPFLAGS="$CPPFLAGS -I/sw/include"
  50 fi
  51 if test -d /sw/lib ; then
  52   LIBS="$LIBS -L/sw/lib"
  53 fi
  54
  55 dnl Compiler hardening flags
  56 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
  57
  58 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
  59 AS_IF([test "x$enable_hardening" != "xno"],
  60   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
  61    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
  62    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
  63    case $host_os in
  64      *mingw*)
  65        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
  66        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
  67        ;;
  68      *)
  69        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
  70        AX_CHECK_COMPILE_FLAG([-fPIC], [CPPFLAGS="$CPPFLAGS -fPIC"])
  71        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
  72        ;;
  73    esac
  74    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
  75    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
  76   ]
  77 );
  78
  79 dnl UTCP debug flags
  80 AC_ARG_ENABLE([utcp_debug], AS_HELP_STRING([--enable-utcp-debug], [compile utcp with debug output]))
  81 AS_IF([test "x$enable_utcp_debug" = "xyes"],
  82   [AX_CHECK_COMPILE_FLAG([-DUTCP_DEBUG], [CPPFLAGS="$CPPFLAGS -DUTCP_DEBUG"])
  83   ]
  84 );
  85
  86 dnl Install test binaries
  87 AC_ARG_ENABLE([install_tests],
  88   [AS_HELP_STRING([--enable-install-tests], [include test binaries in installation])],
  89   [AS_IF([test "x$enable_install_tests" = "xyes"], [install_tests=true], [install_tests=false])],
  90   [install_tests=false]
  91 )
  92
  93 AM_CONDITIONAL(INSTALL_TESTS, test "$install_tests" = true)
  94
  95 dnl Checks for header files.
  96 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
  97
  98 AC_HEADER_STDC
  99 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 100 AC_CHECK_HEADERS([time.h],
 101   [], [], [#include "src/have.h"]
 102 )
 103
 104 dnl Checks for typedefs, structures, and compiler characteristics.
 105 AC_C_CONST
 106 AC_C_VOLATILE
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_HEADER_TIME
 110 AC_STRUCT_TM
 111
 112 MeshLink_ATTRIBUTE(__malloc__)
 113 MeshLink_ATTRIBUTE(__warn_unused_result__)
 114
 115 AC_CHECK_TYPES([socklen_t, struct addrinfo, struct sockaddr_in6], , ,
 116   [#include "src/have.h"]
 117 )
 118
 119 AC_CHECK_TYPES([struct sockaddr_storage], ,AC_MSG_ERROR([System must support struct sockaddr_storage.]),
 120   [#include "src/have.h"]
 121 )
 122
 123 dnl Checks for library functions.
 124 AC_TYPE_SIGNAL
 125 AC_CHECK_FUNCS([asprintf fchmod fork get_current_dir_name gettimeofday random select strdup strerror time usleep],
 126   [], [], [#include "src/have.h"]
 127 )
 128
 129 dnl Support for SunOS
 130
 131 AC_CHECK_FUNC(socket, [], [
 132   AC_CHECK_LIB(socket, connect)
 133 ])
 134 AC_CHECK_FUNC(gethostbyname, [], [
 135   AC_CHECK_LIB(nsl, gethostbyname)
 136 ])
 137
 138 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 139   [], [], [#include "src/have.h"]
 140 )
 141
 142 AC_CACHE_SAVE
 143
 144 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile test/Makefile examples/Makefile])
 145
 146 AC_OUTPUT