git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.1pre7])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([check-news dist-bzip2 std-options subdir-objects])
   8 AC_CONFIG_HEADERS([config.h])
   9 AM_MAINTAINER_MODE
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22 AC_PROG_RANLIB
  23
  24 dnl Check and set OS
  25
  26 AC_CANONICAL_HOST
  27
  28 case $host_os in
  29   *linux*)
  30     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  31     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  32   ;;
  33   *freebsd*)
  34     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  35     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  36   ;;
  37   *darwin*)
  38     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  39     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  40   ;;
  41   *solaris*)
  42     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  43     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  44   ;;
  45   *openbsd*)
  46     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  47     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  48   ;;
  49   *netbsd*)
  50     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  51     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  52   ;;
  53   *dragonfly*)
  54     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  55     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  56   ;;
  57   *bsd*)
  58     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  59     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  60     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  61   ;;
  62   *cygwin*)
  63     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  64     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  65   ;;
  66   *mingw*)
  67     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  68     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  69     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  70   ;;
  71   *)
  72     AC_MSG_ERROR("Unknown operating system.")
  73   ;;
  74 esac
  75
  76 AC_ARG_ENABLE(uml,
  77   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  78   [ AS_IF([test "x$enable_uml" = "xyes"],
  79       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  80         uml=true
  81       ],
  82       [uml=false])
  83   ],
  84   [uml=false]
  85 )
  86
  87 AC_ARG_ENABLE(vde,
  88   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  89   [ AS_IF([test "x$enable_vde" = "xyes"],
  90       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  91         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  92         vde=true
  93       ],
  94       [vde=false])
  95   ],
  96   [vde=false]
  97 )
  98
  99 AC_ARG_ENABLE(tunemu,
 100   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 101   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 102       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 103         tunemu=true
 104       ],
 105       [tunemu=false])
 106   ],
 107   [tunemu=false]
 108 )
 109
 110 AC_ARG_WITH(windows2000,
 111   AS_HELP_STRING([--without-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 112   [ AS_IF([test "x$with_windows2000" = "xyes"],
 113       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 114   ]
 115 )
 116
 117 AM_CONDITIONAL(UML, test "$uml" = true)
 118 AM_CONDITIONAL(VDE, test "$vde" = true)
 119 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 120
 121 AC_CACHE_SAVE
 122
 123 if test -d /sw/include ; then
 124   CPPFLAGS="$CPPFLAGS -I/sw/include"
 125 fi
 126 if test -d /sw/lib ; then
 127   LIBS="$LIBS -L/sw/lib"
 128 fi
 129
 130 dnl Checks for header files.
 131 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 132
 133 AC_HEADER_STDC
 134 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 135 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 136   [], [], [#include "have.h"]
 137 )
 138 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 139   [], [], [#include "have.h"]
 140 )
 141 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 142   [], [], [#include "have.h"]
 143 )
 144
 145 dnl Checks for typedefs, structures, and compiler characteristics.
 146 AC_C_CONST
 147 AC_C_VOLATILE
 148 AC_TYPE_PID_T
 149 AC_TYPE_SIZE_T
 150 AC_HEADER_TIME
 151 AC_STRUCT_TM
 152
 153 tinc_ATTRIBUTE(__malloc__)
 154
 155 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 156   [#include "have.h"]
 157 )
 158
 159 dnl Checks for library functions.
 160 AC_TYPE_SIGNAL
 161 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 162   [], [], [#include "have.h"]
 163 )
 164
 165 dnl Support for SunOS
 166
 167 AC_CHECK_FUNC(socket, [], [
 168   AC_CHECK_LIB(socket, connect)
 169 ])
 170 AC_CHECK_FUNC(gethostbyname, [], [
 171   AC_CHECK_LIB(nsl, gethostbyname)
 172 ])
 173
 174 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 175   [], [], [#include "have.h"]
 176 )
 177
 178 AC_CACHE_SAVE
 179
 180 dnl These are defined in files in m4/
 181
 182 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 183
 184 tinc_CURSES
 185 tinc_READLINE
 186 tinc_ZLIB
 187 tinc_LZO
 188
 189 if test "$with_libgcrypt" = yes; then
 190         AM_PATH_LIBGCRYPT([1.4.0], [], [])
 191         ln -sf gcrypt/cipher.c gcrypt/cipher.h gcrypt/crypto.c gcrypt/crypto.h gcrypt/digest.c gcrypt/digest.h gcrypt/ecdh.c gcrypt/ecdh.h gcrypt/ecdsa.c gcrypt/ecdsa.h gcrypt/ecdsagen.c gcrypt/ecdsagen.h gcrypt/prf.c gcrypt/prf.h gcrypt/rsa.c gcrypt/rsa.h gcrypt/rsagen.c gcrypt/rsagen.h src/
 192 else
 193         tinc_OPENSSL
 194         ln -sf openssl/cipher.c openssl/cipher.h openssl/crypto.c openssl/crypto.h openssl/digest.c openssl/digest.h openssl/ecdh.c openssl/ecdh.h openssl/ecdsa.c openssl/ecdsa.h openssl/ecdsagen.c openssl/ecdsagen.h openssl/prf.c openssl/prf.h openssl/rsa.c openssl/rsa.h openssl/rsagen.c openssl/rsagen.h src/
 195 fi
 196
 197
 198 dnl Check if support for jumbograms is requested
 199 AC_ARG_ENABLE(jumbograms,
 200   AS_HELP_STRING([--disable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 201   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 202       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 203   ]
 204 )
 205
 206 AC_SUBST(INCLUDES)
 207
 208 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile gui/Makefile])
 209
 210 AC_OUTPUT