git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.1pre7])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([check-news dist-bzip2 std-options subdir-objects])
   8 AC_CONFIG_HEADERS([config.h])
   9 AM_MAINTAINER_MODE
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22 AC_PROG_RANLIB
  23
  24 dnl Check and set OS
  25
  26 AC_CANONICAL_HOST
  27
  28 case $host_os in
  29   *linux*)
  30     linux=true
  31     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  32   ;;
  33   *freebsd*)
  34     bsd=true
  35     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  36   ;;
  37   *darwin*)
  38     bsd=true
  39     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  40   ;;
  41   *solaris*)
  42     solaris=true
  43     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  44   ;;
  45   *openbsd*)
  46     bsd=true
  47     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  48   ;;
  49   *netbsd*)
  50     bsd=true
  51     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  52   ;;
  53   *dragonfly*)
  54     bsd=true
  55     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  56   ;;
  57   *bsd*)
  58     bsd=true
  59     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  60     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  61   ;;
  62   *cygwin*)
  63     cygwin=true
  64     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  65   ;;
  66   *mingw*)
  67     mingw=true
  68     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  69     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  70   ;;
  71   *)
  72     AC_MSG_ERROR("Unknown operating system.")
  73   ;;
  74 esac
  75
  76 AC_ARG_ENABLE(uml,
  77   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  78   [ AS_IF([test "x$enable_uml" = "xyes"],
  79       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  80         uml=true
  81       ],
  82       [uml=false])
  83   ],
  84   [uml=false]
  85 )
  86
  87 AC_ARG_ENABLE(vde,
  88   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  89   [ AS_IF([test "x$enable_vde" = "xyes"],
  90       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  91         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  92         vde=true
  93       ],
  94       [vde=false])
  95   ],
  96   [vde=false]
  97 )
  98
  99 AC_ARG_ENABLE(tunemu,
 100   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 101   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 102       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 103         tunemu=true
 104       ],
 105       [tunemu=false])
 106   ],
 107   [tunemu=false]
 108 )
 109
 110 AC_ARG_WITH(windows2000,
 111   AS_HELP_STRING([--without-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 112   [ AS_IF([test "x$with_windows2000" = "xyes"],
 113       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 114   ]
 115 )
 116
 117 AM_CONDITIONAL(LINUX, test "$linux" = true)
 118 AM_CONDITIONAL(BSD, test "$bsd" = true)
 119 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 120 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 121 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 122 AM_CONDITIONAL(UML, test "$uml" = true)
 123 AM_CONDITIONAL(VDE, test "$vde" = true)
 124 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 125
 126 AC_CACHE_SAVE
 127
 128 if test -d /sw/include ; then
 129   CPPFLAGS="$CPPFLAGS -I/sw/include"
 130 fi
 131 if test -d /sw/lib ; then
 132   LIBS="$LIBS -L/sw/lib"
 133 fi
 134
 135 dnl Checks for header files.
 136 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 137
 138 AC_HEADER_STDC
 139 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 140 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 141   [], [], [#include "src/have.h"]
 142 )
 143 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 144   [], [], [#include "src/have.h"]
 145 )
 146 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 147   [], [], [#include "src/have.h"]
 148 )
 149
 150 dnl Checks for typedefs, structures, and compiler characteristics.
 151 AC_C_CONST
 152 AC_C_VOLATILE
 153 AC_TYPE_PID_T
 154 AC_TYPE_SIZE_T
 155 AC_HEADER_TIME
 156 AC_STRUCT_TM
 157
 158 tinc_ATTRIBUTE(__malloc__)
 159 tinc_ATTRIBUTE(__warn_unused_result__)
 160
 161 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 162   [#include "src/have.h"]
 163 )
 164
 165 dnl Checks for library functions.
 166 AC_TYPE_SIGNAL
 167 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 168   [], [], [#include "src/have.h"]
 169 )
 170
 171 dnl Support for SunOS
 172
 173 AC_CHECK_FUNC(socket, [], [
 174   AC_CHECK_LIB(socket, connect)
 175 ])
 176 AC_CHECK_FUNC(gethostbyname, [], [
 177   AC_CHECK_LIB(nsl, gethostbyname)
 178 ])
 179
 180 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 181   [], [], [#include "src/have.h"]
 182 )
 183
 184 AC_CACHE_SAVE
 185
 186 dnl These are defined in files in m4/
 187
 188 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 189
 190 tinc_CURSES
 191 tinc_READLINE
 192 tinc_ZLIB
 193 tinc_LZO
 194
 195 if test "$with_libgcrypt" = yes; then
 196         gcrypt=true
 197         AM_PATH_LIBGCRYPT([1.4.0], [], [])
 198 else
 199         openssl=true
 200         tinc_OPENSSL
 201 fi
 202
 203 AM_CONDITIONAL(OPENSSL, test "$openssl" = true)
 204 AM_CONDITIONAL(GCRYPT, test "$grypt" = true)
 205
 206 dnl Check if support for jumbograms is requested
 207 AC_ARG_ENABLE(jumbograms,
 208   AS_HELP_STRING([--disable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 209   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 210       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 211   ]
 212 )
 213
 214 AC_SUBST(INCLUDES)
 215
 216 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile gui/Makefile])
 217
 218 AC_OUTPUT