git.meshlink.io Git - catta/blob - m4/acx_pthread.m4

   1 dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   2 dnl
   3 dnl @summary figure out how to build C programs using POSIX threads
   4 dnl
   5 dnl This macro figures out how to build C programs using POSIX threads.
   6 dnl It sets the PTHREAD_LIBS output variable to the threads library and
   7 dnl linker flags, and the PTHREAD_CFLAGS output variable to any special
   8 dnl C compiler flags that are needed. (The user can also force certain
   9 dnl compiler flags/libs to be tested by setting these environment
  10 dnl variables.)
  11 dnl
  12 dnl Also sets PTHREAD_CC to any special C compiler that is needed for
  13 dnl multi-threaded programs (defaults to the value of CC otherwise).
  14 dnl (This is necessary on AIX to use the special cc_r compiler alias.)
  15 dnl
  16 dnl NOTE: You are assumed to not only compile your program with these
  17 dnl flags, but also link it with them as well. e.g. you should link
  18 dnl with $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS
  19 dnl $LIBS
  20 dnl
  21 dnl If you are only building threads programs, you may wish to use
  22 dnl these variables in your default LIBS, CFLAGS, and CC:
  23 dnl
  24 dnl        LIBS="$PTHREAD_LIBS $LIBS"
  25 dnl        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  26 dnl        CC="$PTHREAD_CC"
  27 dnl
  28 dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
  29 dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
  30 dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  31 dnl
  32 dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
  33 dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
  34 dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
  35 dnl default action will define HAVE_PTHREAD.
  36 dnl
  37 dnl Please let the authors know if this macro fails on any platform, or
  38 dnl if you have any other suggestions or comments. This macro was based
  39 dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
  40 dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
  41 dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
  42 dnl We are also grateful for the helpful feedback of numerous users.
  43 dnl
  44 dnl @category InstalledPackages
  45 dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
  46 dnl @version 2006-05-29
  47 dnl @license GPLWithACException
  48 dnl
  49 dnl Checks for GCC shared/pthread inconsistency based on work by
  50 dnl Marcin Owsiany <marcin@owsiany.pl>
  51
  52
  53 AC_DEFUN([ACX_PTHREAD], [
  54 AC_REQUIRE([AC_CANONICAL_HOST])
  55 AC_LANG_SAVE
  56 AC_LANG_C
  57 acx_pthread_ok=no
  58
  59 # We used to check for pthread.h first, but this fails if pthread.h
  60 # requires special compiler flags (e.g. on True64 or Sequent).
  61 # It gets checked for in the link test anyway.
  62
  63 # First of all, check if the user has set any of the PTHREAD_LIBS,
  64 # etcetera environment variables, and if threads linking works using
  65 # them:
  66 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
  67         save_CFLAGS="$CFLAGS"
  68         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  69         save_LIBS="$LIBS"
  70         LIBS="$PTHREAD_LIBS $LIBS"
  71         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
  72         AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
  73         AC_MSG_RESULT($acx_pthread_ok)
  74         if test x"$acx_pthread_ok" = xno; then
  75                 PTHREAD_LIBS=""
  76                 PTHREAD_CFLAGS=""
  77         fi
  78         LIBS="$save_LIBS"
  79         CFLAGS="$save_CFLAGS"
  80 fi
  81
  82 # We must check for the threads library under a number of different
  83 # names; the ordering is very important because some systems
  84 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
  85 # libraries is broken (non-POSIX).
  86
  87 # Create a list of thread flags to try.  Items starting with a "-" are
  88 # C compiler flags, and other items are library names, except for "none"
  89 # which indicates that we try without any flags at all, and "pthread-config"
  90 # which is a program returning the flags for the Pth emulation library.
  91
  92 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
  93
  94 # The ordering *is* (sometimes) important.  Some notes on the
  95 # individual items follow:
  96
  97 # pthreads: AIX (must check this before -lpthread)
  98 # none: in case threads are in libc; should be tried before -Kthread and
  99 #       other compiler flags to prevent continual compiler warnings
 100 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 101 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 102 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 103 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
 104 # -pthreads: Solaris/gcc
 105 # -mthreads: Mingw32/gcc, Lynx/gcc
 106 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 107 #      doesn't hurt to check since this sometimes defines pthreads too;
 108 #      also defines -D_REENTRANT)
 109 #      ... -mt is also the pthreads flag for HP/aCC
 110 # pthread: Linux, etcetera
 111 # --thread-safe: KAI C++
 112 # pthread-config: use pthread-config program (for GNU Pth library)
 113
 114 case "${host_cpu}-${host_os}" in
 115         *solaris*)
 116
 117         # On Solaris (at least, for some versions), libc contains stubbed
 118         # (non-functional) versions of the pthreads routines, so link-based
 119         # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
 120         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 121         # a function called by this macro, so we could check for that, but
 122         # who knows whether they'll stub that too in a future libc.)  So,
 123         # we'll just look for -pthreads and -lpthread first:
 124
 125         acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
 126         ;;
 127 esac
 128
 129 if test x"$acx_pthread_ok" = xno; then
 130 for flag in $acx_pthread_flags; do
 131
 132         case $flag in
 133                 none)
 134                 AC_MSG_CHECKING([whether pthreads work without any flags])
 135                 ;;
 136
 137                 -*)
 138                 AC_MSG_CHECKING([whether pthreads work with $flag])
 139                 PTHREAD_CFLAGS="$flag"
 140                 ;;
 141
 142                 pthread-config)
 143                 AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
 144                 if test x"$acx_pthread_config" = xno; then continue; fi
 145                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 146                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 147                 ;;
 148
 149                 *)
 150                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 151                 PTHREAD_LIBS="-l$flag"
 152                 ;;
 153         esac
 154
 155         save_LIBS="$LIBS"
 156         save_CFLAGS="$CFLAGS"
 157         LIBS="$PTHREAD_LIBS $LIBS"
 158         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 159
 160         # Check for various functions.  We must include pthread.h,
 161         # since some functions may be macros.  (On the Sequent, we
 162         # need a special flag -Kthread to make this header compile.)
 163         # We check for pthread_join because it is in -lpthread on IRIX
 164         # while pthread_create is in libc.  We check for pthread_attr_init
 165         # due to DEC craziness with -lpthreads.  We check for
 166         # pthread_cleanup_push because it is one of the few pthread
 167         # functions on Solaris that doesn't have a non-functional libc stub.
 168         # We try pthread_create on general principles.
 169         AC_TRY_LINK([#include <pthread.h>],
 170                     [pthread_t th; pthread_join(th, 0);
 171                      pthread_attr_init(0); pthread_cleanup_push(0, 0);
 172                      pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 173                     [acx_pthread_ok=yes])
 174
 175         LIBS="$save_LIBS"
 176         CFLAGS="$save_CFLAGS"
 177
 178         AC_MSG_RESULT($acx_pthread_ok)
 179         if test "x$acx_pthread_ok" = xyes; then
 180                 break;
 181         fi
 182
 183         PTHREAD_LIBS=""
 184         PTHREAD_CFLAGS=""
 185 done
 186 fi
 187
 188 # Various other checks:
 189 if test "x$acx_pthread_ok" = xyes; then
 190         save_LIBS="$LIBS"
 191         LIBS="$PTHREAD_LIBS $LIBS"
 192         save_CFLAGS="$CFLAGS"
 193         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 194
 195         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 196         AC_MSG_CHECKING([for joinable pthread attribute])
 197         attr_name=unknown
 198         for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 199             AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
 200                         [attr_name=$attr; break])
 201         done
 202         AC_MSG_RESULT($attr_name)
 203         if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
 204             AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
 205                                [Define to necessary symbol if this constant
 206                                 uses a non-standard name on your system.])
 207         fi
 208
 209         AC_MSG_CHECKING([if more special flags are required for pthreads])
 210         flag=no
 211         case "${host_cpu}-${host_os}" in
 212             *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
 213             *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
 214         esac
 215         AC_MSG_RESULT(${flag})
 216         if test "x$flag" != xno; then
 217             PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 218         fi
 219
 220         LIBS="$save_LIBS"
 221         CFLAGS="$save_CFLAGS"
 222         # More AIX lossage: must compile with xlc_r or cc_r
 223         if test x"$GCC" != xyes; then
 224           AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
 225         else
 226           PTHREAD_CC=$CC
 227         fi
 228
 229    # The next part tries to detect GCC inconsistency with -shared on some
 230    # architectures and systems. The problem is that in certain
 231    # configurations, when -shared is specified, GCC "forgets" to
 232    # internally use various flags which are still necessary.
 233
 234    AC_MSG_CHECKING([whether to check for GCC pthread/shared inconsistencies])
 235    check_inconsistencies=yes
 236    case "${host_cpu}-${host_os}" in
 237      *-darwin*) check_inconsistencies=no ;;
 238    esac
 239    if test x"$GCC" != xyes -o "x$check_inconsistencies" != xyes ; then
 240       AC_MSG_RESULT([no])
 241    else
 242       AC_MSG_RESULT([yes])
 243
 244       # In order not to create several levels of indentation, we test
 245       # the value of "$ok" until we find out the cure or run out of
 246       # ideas.
 247       ok="no"
 248
 249       #
 250       # Prepare the flags
 251       #
 252       save_CFLAGS="$CFLAGS"
 253       save_LIBS="$LIBS"
 254       save_CC="$CC"
 255       # Try with the flags determined by the earlier checks.
 256       #
 257       # -Wl,-z,defs forces link-time symbol resolution, so that the
 258       # linking checks with -shared actually have any value
 259       # The Mingw32 equivalent to -z defs seems to be --error-unresolved-symbols.
 260       #
 261       # FIXME: -fPIC is required for -shared on many architectures,
 262       # so we specify it here, but the right way would probably be to
 263       # properly detect whether it is actually required.
 264       zdefs="-z,defs"
 265       case "${host_os}" in
 266         *mingw32*) zdefs="--unresolved-symbols=report-all,--error-unresolved-symbols"
 267       esac
 268       CFLAGS="-shared -fPIC -Wl,$zdefs $CFLAGS $PTHREAD_CFLAGS"
 269       LIBS="$PTHREAD_LIBS $LIBS"
 270       CC="$PTHREAD_CC"
 271
 272       AC_MSG_CHECKING([whether -pthread is sufficient with -shared])
 273       AC_TRY_LINK([#include <pthread.h>],
 274          [pthread_t th; pthread_join(th, 0);
 275          pthread_attr_init(0); pthread_cleanup_push(0, 0);
 276          pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 277          [ok=yes])
 278
 279       if test "x$ok" = xyes; then
 280          AC_MSG_RESULT([yes])
 281       else
 282          AC_MSG_RESULT([no])
 283       fi
 284
 285       #
 286       # Linux gcc on some architectures such as mips/mipsel forgets
 287       # about -lpthread
 288       #
 289       if test x"$ok" = xno; then
 290          AC_MSG_CHECKING([whether -lpthread fixes that])
 291          LIBS="-lpthread $PTHREAD_LIBS $save_LIBS"
 292          AC_TRY_LINK([#include <pthread.h>],
 293             [pthread_t th; pthread_join(th, 0);
 294             pthread_attr_init(0); pthread_cleanup_push(0, 0);
 295             pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 296             [ok=yes])
 297
 298          if test "x$ok" = xyes; then
 299             AC_MSG_RESULT([yes])
 300             PTHREAD_LIBS="-lpthread $PTHREAD_LIBS"
 301          else
 302             AC_MSG_RESULT([no])
 303          fi
 304       fi
 305       #
 306       # FreeBSD 4.10 gcc forgets to use -lc_r instead of -lc
 307       #
 308       if test x"$ok" = xno; then
 309          AC_MSG_CHECKING([whether -lc_r fixes that])
 310          LIBS="-lc_r $PTHREAD_LIBS $save_LIBS"
 311          AC_TRY_LINK([#include <pthread.h>],
 312              [pthread_t th; pthread_join(th, 0);
 313               pthread_attr_init(0); pthread_cleanup_push(0, 0);
 314               pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 315              [ok=yes])
 316
 317          if test "x$ok" = xyes; then
 318             AC_MSG_RESULT([yes])
 319             PTHREAD_LIBS="-lc_r $PTHREAD_LIBS"
 320          else
 321             AC_MSG_RESULT([no])
 322          fi
 323       fi
 324       if test x"$ok" = xno; then
 325          # OK, we have run out of ideas
 326          AC_MSG_WARN([Impossible to determine how to use pthreads with shared libraries])
 327
 328          # so it's not safe to assume that we may use pthreads
 329          acx_pthread_ok=no
 330       fi
 331
 332       CFLAGS="$save_CFLAGS"
 333       LIBS="$save_LIBS"
 334       CC="$save_CC"
 335    fi
 336 else
 337         PTHREAD_CC="$CC"
 338 fi
 339
 340 AC_SUBST(PTHREAD_LIBS)
 341 AC_SUBST(PTHREAD_CFLAGS)
 342 AC_SUBST(PTHREAD_CC)
 343
 344 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 345 if test x"$acx_pthread_ok" = xyes; then
 346         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 347         :
 348 else
 349         acx_pthread_ok=no
 350         $2
 351 fi
 352 AC_LANG_RESTORE
 353 ])dnl ACX_PTHREAD