git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.12],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [7:1:4])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [4:3:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [4:3:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for sys/filio.h; needed for FIONREAD on Solaris
  89 #
  90 AC_CHECK_HEADER(sys/filio.h,
  91 HAVE_SYS_FILIO_H=yes
  92 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
  93 , [], [
  94 ])
  95
  96 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
  97
  98 #
  99 # Check for sys/sysctl.h; not present on Solaris
 100 #
 101 AC_CHECK_HEADER(sys/sysctl.h,
 102 HAVE_SYS_SYSCTL=yes
 103 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 104 , [], [
 105 #include <sys/types.h>
 106 #include <sys/socket.h>
 107 ])
 108
 109 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 110
 111 #
 112 # Check for struct ip_mreqn
 113 #
 114 AC_MSG_CHECKING(for struct ip_mreqn)
 115 AC_TRY_COMPILE([#include <netinet/in.h>], [
 116         struct ip_mreqn mreq;
 117         mreq.imr_address.s_addr = 0;
 118 ], [
 119         # Yes, we have it...
 120         AC_MSG_RESULT(yes)
 121         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 122 ], [
 123         # We'll just have to try and use struct ip_mreq
 124         AC_MSG_RESULT(no)
 125         AC_MSG_CHECKING(for struct ip_mreq)
 126         AC_TRY_COMPILE([#include <netinet/in.h>], [
 127                 struct ip_mreq mreq;
 128                 mreq.imr_interface.s_addr = 0;
 129         ], [
 130                 # Yes, we have it...
 131                 AC_MSG_RESULT(yes)
 132                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 133         ], [
 134                 # No multicast support
 135                         AC_MSG_RESULT(no)
 136         ])
 137 ])
 138
 139 #
 140 # Detecting the linux distribution for specific things like init scripts.
 141 #
 142 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 143 if test "z$with_distro" = "z"; then
 144     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 145     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 146     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 147     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 148     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 149     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 150     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 151     if test "z$with_distro" = "z"; then
 152         with_distro=`uname -s`
 153     fi
 154 fi
 155 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 156
 157 case $with_distro in
 158     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 159      ;;
 160     netbsd)
 161      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 162      ;;
 163     linux)
 164      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 165      ;;
 166     *)
 167      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 168      ;;
 169 esac
 170
 171 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 172 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 173 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 174 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 175 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 176 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 177 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 178 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 179 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 180 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 181
 182 test_gcc_flag() {
 183     AC_LANG_CONFTEST([int main() {}])
 184     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 185     ret=$?
 186     rm -f conftest.o
 187     return $ret
 188 }
 189
 190 # If using GCC specify some additional parameters
 191 if test "x$GCC" = "xyes" ; then
 192
 193     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 194
 195     if test "x$HAVE_NETLINK" = "xyes" ; then
 196         # Test whether rtnetlink.h can be included when compiled with -std=c99
 197         # some distributions (e.g. archlinux) have broken headers that dont
 198         # define __u64 with -std=c99
 199         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 200         OLDCFLAGS="$CFLAGS"
 201         CFLAGS="-std=c99"
 202         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 203             use_stdc99=yes, use_stdc99=no)
 204
 205         if test x"$use_stdc99" = xyes; then
 206             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 207             AC_MSG_RESULT([yes])
 208         else
 209             AC_MSG_RESULT([no])
 210         fi
 211
 212         CFLAGS="$OLDCFLAGS"
 213     else
 214         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 215     fi
 216
 217     for flag in $DESIRED_FLAGS ; do
 218         AC_MSG_CHECKING([whether $CC accepts $flag])
 219         if test_gcc_flag $flag ; then
 220            CFLAGS="$CFLAGS $flag"
 221            AC_MSG_RESULT([yes])
 222         else
 223            AC_MSG_RESULT([no])
 224         fi
 225     done
 226 fi
 227
 228 # Checks for header files.
 229 AC_HEADER_STDC
 230 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 231 AC_HEADER_STDBOOL
 232
 233 # Checks for typedefs, structures, and compiler characteristics.
 234 AC_C_CONST
 235 AC_TYPE_SIZE_T
 236 AC_HEADER_TIME
 237 AC_HEADER_SYS_WAIT
 238
 239 # Checks for library functions.
 240 AC_FUNC_MEMCMP
 241 AC_FUNC_SELECT_ARGTYPES
 242 AC_FUNC_MALLOC
 243 AC_FUNC_REALLOC
 244 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 245
 246 AC_FUNC_CHOWN
 247 AC_FUNC_STAT
 248 AC_TYPE_MODE_T
 249 AC_TYPE_PID_T
 250
 251 AC_CHECK_DECLS(environ)
 252
 253 enable_chroot=yes
 254 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 255 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 256 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 257
 258 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 259
 260 if test "x$enable_chroot" = "xyes" ; then
 261    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 262 fi
 263
 264 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 265 if test "x$HAVE_DLOPEN" = "xyes" ; then
 266     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 267 fi
 268 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 269
 270 # Check for pkg-config manually first, as if its not installed the
 271 # PKG_PROG_PKG_CONFIG macro won't be defined.
 272 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 273
 274 if test x"$have_pkg_config" = "xno"; then
 275     AC_MSG_ERROR(pkg-config is required to install this program)
 276 fi
 277
 278 PKG_PROG_PKG_CONFIG
 279
 280 #
 281 # Check for GLIB 2.0
 282 #
 283 AC_ARG_ENABLE(glib,
 284         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 285         [case "${enableval}" in
 286                 yes) HAVE_GLIB=yes ;;
 287                 no)  HAVE_GLIB=no ;;
 288                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 289         esac],
 290         [HAVE_GLIB=yes])
 291
 292 if test "x$HAVE_GLIB" = "xyes" ; then
 293         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 294         AC_SUBST(GLIB20_CFLAGS)
 295         AC_SUBST(GLIB20_LIBS)
 296 fi
 297 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 298
 299 #
 300 # Check for Qt 3
 301 #
 302 AC_ARG_ENABLE(qt3,
 303         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 304         [case "${enableval}" in
 305                 yes) HAVE_QT3=yes ;;
 306                 no)  HAVE_QT3=no ;;
 307                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 308         esac],
 309         [HAVE_QT3=yes])
 310
 311 if test "x$HAVE_QT3" = "xyes" ; then
 312         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 313         AC_SUBST(QT3_CFLAGS)
 314         AC_SUBST(QT3_LIBS)
 315             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 316         MOC_QT3="no"
 317             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 318                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 319                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 320         AC_SUBST(MOC_QT3)
 321 fi
 322 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 323
 324 #
 325 # Check for Qt 4
 326 #
 327 AC_ARG_ENABLE(qt4,
 328         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 329         [case "${enableval}" in
 330                 yes) HAVE_QT4=yes ;;
 331                 no)  HAVE_QT4=no ;;
 332                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 333         esac],
 334         [HAVE_QT4=yes])
 335
 336 if test "x$HAVE_QT4" = "xyes" ; then
 337         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 338         AC_SUBST(QT4_CFLAGS)
 339         AC_SUBST(QT4_LIBS)
 340             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 341         MOC_QT4="no"
 342             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 343                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 344                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 345         AC_SUBST(MOC_QT4)
 346 fi
 347 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 348
 349 #
 350 # Check for GTK+
 351 #
 352 AC_ARG_ENABLE(gtk,
 353         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 354         [case "${enableval}" in
 355                 yes) HAVE_GTK=yes ;;
 356                 no)  HAVE_GTK=no ;;
 357                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 358         esac],
 359         [HAVE_GTK=yes])
 360
 361 if test "x$HAVE_GTK" = "xyes" ; then
 362         # Check for GTK 2.0
 363         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 364         AC_SUBST(GTK20_CFLAGS)
 365         AC_SUBST(GTK20_LIBS)
 366
 367         # Check for GLADE 2.0
 368         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 369         AC_SUBST(GLADE20_CFLAGS)
 370         AC_SUBST(GLADE20_LIBS)
 371 fi
 372 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 373
 374 #
 375 # D-BUS
 376 #
 377 AC_ARG_ENABLE(dbus,
 378         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 379         [case "${enableval}" in
 380                 yes) HAVE_DBUS=yes ;;
 381                 no)  HAVE_DBUS=no ;;
 382                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 383         esac],
 384         [HAVE_DBUS=yes])
 385
 386 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 387 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 388
 389 DBUS_VERSION="Disabled"
 390 DBUS_SYS_DIR="Disabled"
 391 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 392 if test "x$HAVE_DBUS" = "xyes" ; then
 393     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 394
 395     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 396
 397     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 398     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 399     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 400     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 401     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 402         DBUS_VERSION_MAJOR="0"
 403     fi
 404     if test "z$DBUS_VERSION_MINOR" = "z"; then
 405         DBUS_VERSION_MINOR="0"
 406     fi
 407     if test "z$DBUS_VERSION_MICRO" = "z"; then
 408         DBUS_VERSION_MICRO="0"
 409     fi
 410
 411     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 412         echo "Error: Couldn't determine the version of your DBUS package."
 413         echo "  This is probably an error in this script, please report it"
 414         echo "  along with the following information:"
 415         echo "      Base DBUS version ='$DBUS_VERSION'"
 416         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 417         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 418         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 419         exit 1
 420     else
 421         echo "Your dbus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 422         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 423         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 424         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 425     fi
 426
 427     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 428     AC_SUBST(DBUS_CFLAGS)
 429     AC_SUBST(DBUS_LIBS)
 430
 431     if ! test -z "$with_dbus_sys" ; then
 432         DBUS_SYS_DIR="$with_dbus_sys"
 433     else
 434         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 435     fi
 436     AC_SUBST(DBUS_SYS_DIR)
 437
 438     if ! test -z "$with_dbus_system_address" ; then
 439         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 440     else
 441         # This is ugly, but D-BUS doesn't export this address for us
 442         # so we have to guess, pretty much all setups i've seen have
 443         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 444         # /var/run upstream so we will try guess first then default
 445         # to /var/run/dbus
 446
 447         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 448         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 449         for sock in $TRY_SOCKETS; do
 450             if test -S $sock; then
 451                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 452             fi
 453         done
 454     fi
 455     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 456
 457 fi
 458 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 459
 460 #
 461 # Expat
 462 #
 463 AC_ARG_ENABLE(expat,
 464         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 465         [case "${enableval}" in
 466                 yes) HAVE_EXPAT=yes ;;
 467                 no)  HAVE_EXPAT=no ;;
 468                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 469         esac],
 470         [HAVE_EXPAT=yes])
 471
 472 if test "x$HAVE_EXPAT" = "xyes" ; then
 473     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 474
 475     if ! $have_expat ; then
 476         AC_MSG_ERROR([*** libexpat not found ***])
 477     fi
 478 fi
 479 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 480
 481 #
 482 # GDBM
 483 #
 484 #
 485 # Check for dbm
 486 #
 487 AC_ARG_ENABLE(dbm,
 488         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 489         [case "${enableval}" in
 490                 yes) HAVE_DBM=yes ;;
 491                 no)  HAVE_DBM=no ;;
 492                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 493         esac],
 494         [HAVE_DBM=no])
 495
 496 AC_ARG_ENABLE(gdbm,
 497         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 498         [case "${enableval}" in
 499                 yes) HAVE_GDBM=yes ;;
 500                 no)  HAVE_GDBM=no ;;
 501                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 502         esac],
 503         [HAVE_GDBM=yes])
 504
 505 if test "x$HAVE_GDBM" = "xyes" ; then
 506     if test "x$HAVE_DBM" = "xyes" ; then
 507         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 508     fi
 509     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 510
 511     if ! $have_gdbm ; then
 512         AC_MSG_ERROR([*** libgdbm not found ***])
 513     fi
 514     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 515 else
 516     if test "x$HAVE_DBM" = "xyes" ; then
 517         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 518
 519         if ! $have_dbm ; then
 520             AC_MSG_ERROR([*** dbm not found ***])
 521         fi
 522         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 523     fi
 524 fi
 525 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 526 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 527
 528 #
 529 # libdaemon
 530 #
 531 AC_ARG_ENABLE(libdaemon,
 532         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 533         [case "${enableval}" in
 534                 yes) HAVE_LIBDAEMON=yes ;;
 535                 no)  HAVE_LIBDAEMON=no ;;
 536                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 537         esac],
 538         [HAVE_LIBDAEMON=yes])
 539
 540 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 541     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 542     AC_SUBST(LIBDAEMON_CFLAGS)
 543     AC_SUBST(LIBDAEMON_LIBS)
 544 fi
 545 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 546
 547 #
 548 # Python stuff
 549 #
 550 AC_ARG_ENABLE(python,
 551     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 552     [case "${enableval}" in
 553           yes) HAVE_PYTHON=yes ;;
 554           no)  HAVE_PYTHON=no ;;
 555           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 556     esac],[HAVE_PYTHON=yes])
 557
 558 HAVE_PYTHON_DBUS=no
 559 HAVE_PYGTK=no
 560
 561 if test "x$HAVE_PYTHON" = "xyes" ; then
 562     AM_PATH_PYTHON([2.4])
 563
 564     AC_ARG_ENABLE(pygtk,
 565         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 566         [case "${enableval}" in
 567                 yes) HAVE_PYGTK=yes ;;
 568                 no)  HAVE_PYGTK=no ;;
 569                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 570         esac],
 571         [HAVE_PYGTK=yes])
 572
 573     if test "x$HAVE_PYGTK" = "xyes" ; then
 574         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 575     fi
 576
 577
 578     if test "x$HAVE_DBUS" = "xyes" ; then
 579         AC_ARG_ENABLE(python-dbus,
 580             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 581             [case "${enableval}" in
 582                    yes) HAVE_PYTHON_DBUS=yes ;;
 583                    no)  HAVE_PYTHON_DBUS=no ;;
 584                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 585             esac],
 586             [HAVE_PYTHON_DBUS=yes])
 587
 588         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 589             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 590         fi
 591
 592         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 593         if test "x$HAVE_GDBM" = "xyes"; then
 594             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 595         fi
 596         if test "x$HAVE_DBM" = "xyes"; then
 597             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 598         fi
 599     fi
 600 fi
 601 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 602 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 603 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 604
 605 #
 606 # Check for mono stuff
 607 #
 608 HAVE_MONO=no
 609 if test "x$HAVE_DBUS" = "xyes" ; then
 610     AC_ARG_ENABLE(mono,
 611             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 612             [case "${enableval}" in
 613                     yes) HAVE_MONO=yes ;;
 614                     no)  HAVE_MONO=no ;;
 615                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 616             esac],
 617             [HAVE_MONO=yes])
 618
 619     if test "x$HAVE_MONO" = "xyes" ; then
 620         AC_PATH_PROG(MCS, mcs)
 621         if test "x$MCS" = "x" ; then
 622             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 623         fi
 624
 625         AC_PATH_PROG(GACUTIL, gacutil)
 626         if test "x$GACUTIL" = "x" ; then
 627             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 628         fi
 629
 630         AC_SUBST(MCS)
 631         AC_SUBST(GACUTIL)
 632     fi
 633 fi
 634 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 635
 636 #
 637 # Check for monodoc stuff
 638 #
 639 HAVE_MONODOC=no
 640 AC_ARG_ENABLE(monodoc,
 641         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 642         [case "${enableval}" in
 643                 yes) HAVE_MONODOC=yes ;;
 644                 no)  HAVE_MONODOC=no ;;
 645                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 646         esac],
 647         [HAVE_MONODOC=yes])
 648
 649 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 650         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 651         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 652
 653         AC_PATH_PROG(MONODOCER, monodocer)
 654         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 655
 656         AC_SUBST(MONODOC_DIR)
 657         AC_SUBST(MONODOCER)
 658         AC_SUBST(MDASSEMBLER)
 659 fi
 660 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 661
 662 #
 663 # Defining Avahi User and Group.
 664 #
 665 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 666 if test -z "$with_avahi_user" ; then
 667     AVAHI_USER=avahi
 668 else
 669     AVAHI_USER=$with_avahi_user
 670 fi
 671 AC_SUBST(AVAHI_USER)
 672 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 673
 674 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 675 if test -z "$with_avahi_group" ; then
 676     AVAHI_GROUP=avahi
 677 else
 678     AVAHI_GROUP=$with_avahi_group
 679 fi
 680 AC_SUBST(AVAHI_GROUP)
 681 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 682
 683 #
 684 # Avahi runtime dir
 685 #
 686 avahi_runtime_dir="${localstatedir}/run"
 687 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 688 AC_SUBST(avahi_runtime_dir)
 689 AC_SUBST(avahi_socket)
 690
 691 #
 692 # Avahi interfaces dir
 693 #
 694 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 695         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 696         AC_SUBST(interfacesdir)
 697 fi
 698
 699 #
 700 # Doxygen
 701 #
 702 DX_HTML_FEATURE(ON)
 703 DX_CHM_FEATURE(OFF)
 704 DX_CHI_FEATURE(OFF)
 705 DX_MAN_FEATURE(OFF)
 706 DX_RTF_FEATURE(OFF)
 707 DX_XML_FEATURE(OFF)
 708 DX_PDF_FEATURE(OFF)
 709 DX_PS_FEATURE(OFF)
 710 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 711
 712 AC_ARG_ENABLE(core-docs,
 713         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 714 [case "${enableval}" in
 715   yes) ENABLE_CORE_DOCS=yes ;;
 716   no)  ENABLE_CORE_DOCS=no ;;
 717   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 718 esac],[ENABLE_CORE_DOCS=no])
 719
 720 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 721
 722 #
 723 # Build and Install man pages
 724 #
 725 AC_ARG_ENABLE(manpages,
 726         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 727 [case "${enableval}" in
 728   yes) manpages=yes ;;
 729   no)  manpages=no ;;
 730   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 731 esac],[manpages=yes])
 732
 733 if test x$manpages = xyes ; then
 734     #
 735     # XMLTOMAN manpage generation
 736     #
 737     AC_ARG_ENABLE(xmltoman,
 738     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 739     [case "${enableval}" in
 740       yes) xmltoman=yes ;;
 741       no)  xmltoman=no ;;
 742       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 743     esac],[xmltoman=yes])
 744
 745     if test x$xmltoman = xyes ; then
 746         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 747     fi
 748
 749     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 750         if ! test -e man/avahi-daemon.8 ; then
 751             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 752             exit 1
 753         fi
 754         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 755         xmltoman=no
 756     fi
 757 fi
 758 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 759 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 760
 761 #
 762 # Conditionally compile test and example programs
 763 #
 764 AC_ARG_ENABLE(tests,
 765         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 766         [case "${enableval}" in
 767                 yes) ENABLE_TESTS=yes ;;
 768                 no)  ENABLE_TESTS=no ;;
 769                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 770         esac],
 771         [ENABLE_TESTS=no])
 772
 773 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 774
 775 #
 776 # Optionally enable libdns_sd compatibility support
 777 #
 778 AC_ARG_ENABLE(compat-libdns_sd,
 779         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 780         [case "${enableval}" in
 781                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 782                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 783                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 784         esac],
 785         [ENABLE_COMPAT_LIBDNS_SD=no])
 786
 787 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 788
 789 #
 790 # Optionally enable HOWL compatibility support
 791 #
 792 AC_ARG_ENABLE(compat-howl,
 793         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 794         [case "${enableval}" in
 795                 yes) ENABLE_COMPAT_HOWL=yes ;;
 796                 no)  ENABLE_COMPAT_HOWL=no ;;
 797                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 798         esac],
 799         [ENABLE_COMPAT_HOWL=no])
 800
 801 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 802
 803
 804 # ==========================================================================
 805 AC_CONFIG_FILES([
 806 Makefile
 807 avahi-common/Makefile
 808 avahi-core/Makefile
 809 avahi-glib/Makefile
 810 avahi-qt/Makefile
 811 avahi-daemon/Makefile
 812 avahi-daemon/avahi-dbus.conf
 813 avahi-discover-standalone/Makefile
 814 avahi-client/Makefile
 815 initscript/Makefile
 816 initscript/debian/Makefile
 817 initscript/gentoo/Makefile
 818 initscript/archlinux/Makefile
 819 initscript/suse/Makefile
 820 initscript/fedora/Makefile
 821 initscript/mandriva/Makefile
 822 initscript/darwin/Makefile
 823 initscript/freebsd/Makefile
 824 initscript/slackware/Makefile
 825 avahi-dnsconfd/Makefile
 826 avahi-utils/Makefile
 827 avahi-python/Makefile
 828 avahi-python/avahi/Makefile
 829 examples/Makefile
 830 common/Makefile
 831 man/Makefile
 832 tests/Makefile
 833 service-type-database/Makefile
 834 avahi-sharp/Makefile
 835 avahi-compat-libdns_sd/Makefile
 836 avahi-compat-howl/Makefile
 837 avahi-compat-howl/samples/Makefile
 838 ])
 839 AC_OUTPUT
 840
 841 # ==========================================================================
 842 echo "
 843  ---{ $PACKAGE_NAME $VERSION }---
 844
 845     prefix:                 ${prefix}
 846     sysconfdir:             ${sysconfdir}
 847     localstatedir:          ${localstatedir}
 848     avahi socket:           ${avahi_socket}
 849     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 850     dbus-1 version:         ${DBUS_VERSION}
 851     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 852     compiler:               ${CC}
 853     cflags:                 ${CFLAGS}
 854     Enable GLIB:            ${HAVE_GLIB}
 855     Enable GTK:             ${HAVE_GTK}
 856     Enable D-BUS:           ${HAVE_DBUS}
 857     Enable Expat:           ${HAVE_EXPAT}
 858     Enable GDBM:            ${HAVE_GDBM}
 859     Enable DBM:             ${HAVE_DBM}
 860     Enable libdaemon:       ${HAVE_LIBDAEMON}
 861     Enable Python:          ${HAVE_PYTHON}
 862     Enable pygtk:           ${HAVE_PYGTK}
 863     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 864     Enable QT3:             ${HAVE_QT3}
 865     Enable QT4:             ${HAVE_QT4}
 866     Enable Mono:            ${HAVE_MONO}
 867     Enable Monodoc:         ${HAVE_MONODOC}
 868     Distribution/OS:        ${with_distro}
 869     User for Avahi:         ${AVAHI_USER}
 870     Group for Avahi:        ${AVAHI_GROUP}
 871     Enable chroot():        ${enable_chroot}
 872 "
 873
 874 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 875
 876 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 877     BUILD_DAEMON=yes
 878 fi
 879
 880 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 881
 882 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 883     BUILD_PYTHON=yes
 884 fi
 885
 886 BUILD_CLIENT="no   (You need avahi-daemon and dbus!)"
 887
 888 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 889     BUILD_CLIENT=yes
 890 fi
 891
 892 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 893    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 894 fi
 895 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 896    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 897 fi
 898
 899
 900 echo "\
 901     Building libavahi-core              yes
 902     Building avahi-daemon:              ${BUILD_DAEMON}
 903     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 904     Building libavahi-client:           ${BUILD_CLIENT}
 905     Building avahi-utils:               ${BUILD_CLIENT}
 906     Building avahi-python:              ${BUILD_PYTHON}
 907     Building libavahi-glib:             ${HAVE_GLIB}
 908     Building avahi-discover-standalone: ${HAVE_GTK}
 909     Building libavahi-qt3:              ${HAVE_QT3}
 910     Building libavahi-qt4:              ${HAVE_QT4}
 911     Building avahi-sharp:               ${HAVE_MONO}
 912     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 913     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 914     Building tests:                     ${ENABLE_TESTS}
 915     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
 916 "