git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125 fi
 126 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 127
 128 if test "z$with_distro" = "z"; then
 129     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 130     exit 1
 131 else
 132 case $with_distro in
 133     debian|gentoo|archlinux|suse|fedora|none)
 134      ;;
 135     *)
 136      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 137      ;;
 138 esac
 139 fi
 140
 141 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 142 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 143 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 144 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 145 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 146
 147 test_gcc_flag() {
 148     AC_LANG_CONFTEST([int main() {}])
 149     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 150     ret=$?
 151     rm -f conftest.o
 152     return $ret
 153 }
 154
 155 # If using GCC specify some additional parameters
 156 if test "x$GCC" = "xyes" ; then
 157
 158     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 159
 160     if test "x$HAVE_NETLINK" = "xyes" ; then
 161         # Test whether rtnetlink.h can be included when compiled with -std=c99
 162         # some distributions (e.g. archlinux) have broken headers that dont
 163         # define __u64 with -std=c99
 164         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 165         OLDCFLAGS="$CFLAGS"
 166         CFLAGS="-std=c99"
 167         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 168             use_stdc99=yes, use_stdc99=no)
 169
 170         if test x"$use_stdc99" = xyes; then
 171             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 172             AC_MSG_RESULT([yes])
 173         else
 174             AC_MSG_RESULT([no])
 175         fi
 176
 177         CFLAGS="$OLDCFLAGS"
 178     else
 179         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 180     fi
 181
 182     for flag in $DESIRED_FLAGS ; do
 183         AC_MSG_CHECKING([whether $CC accepts $flag])
 184         if test_gcc_flag $flag ; then
 185            CFLAGS="$CFLAGS $flag"
 186            AC_MSG_RESULT([yes])
 187         else
 188            AC_MSG_RESULT([no])
 189         fi
 190     done
 191 fi
 192
 193 # Checks for header files.
 194 AC_HEADER_STDC
 195 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 196 AC_HEADER_STDBOOL
 197
 198 # Checks for typedefs, structures, and compiler characteristics.
 199 AC_C_CONST
 200 AC_TYPE_SIZE_T
 201 AC_HEADER_TIME
 202 AC_HEADER_SYS_WAIT
 203
 204 # Checks for library functions.
 205 AC_FUNC_MEMCMP
 206 AC_FUNC_SELECT_ARGTYPES
 207 AC_FUNC_MALLOC
 208 AC_FUNC_REALLOC
 209 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle])
 210
 211 AC_FUNC_CHOWN
 212 AC_FUNC_STAT
 213 AC_TYPE_MODE_T
 214 AC_TYPE_PID_T
 215
 216 AC_CHECK_DECLS(environ)
 217
 218 enable_chroot=yes
 219 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 220 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 221 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 222
 223 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 224
 225 if test "x$enable_chroot" = "xyes" ; then
 226    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 227 fi
 228
 229 # Check for pkg-config manually first, as if its not installed the
 230 # PKG_PROG_PKG_CONFIG macro won't be defined.
 231 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 232
 233 if test x"$have_pkg_config" = "xno"; then
 234     AC_MSG_ERROR(pkg-config is required to install this program)
 235 fi
 236
 237 PKG_PROG_PKG_CONFIG
 238
 239 #
 240 # Check for GLIB 2.0
 241 #
 242 AC_ARG_ENABLE(glib,
 243         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 244         [case "${enableval}" in
 245                 yes) HAVE_GLIB=yes ;;
 246                 no)  HAVE_GLIB=no ;;
 247                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 248         esac],
 249         [HAVE_GLIB=yes])
 250
 251 if test "x$HAVE_GLIB" = "xyes" ; then
 252         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 253         AC_SUBST(GLIB20_CFLAGS)
 254         AC_SUBST(GLIB20_LIBS)
 255 fi
 256 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 257
 258 #
 259 # Check for Qt 3
 260 #
 261 AC_ARG_ENABLE(qt3,
 262         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 263         [case "${enableval}" in
 264                 yes) HAVE_QT3=yes ;;
 265                 no)  HAVE_QT3=no ;;
 266                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 267         esac],
 268         [HAVE_QT3=yes])
 269
 270 if test "x$HAVE_QT3" = "xyes" ; then
 271         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 272         AC_SUBST(QT3_CFLAGS)
 273         AC_SUBST(QT3_LIBS)
 274             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 275         MOC_QT3="no"
 276             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 277                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 278                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 279         AC_SUBST(MOC_QT3)
 280 fi
 281 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 282
 283 #
 284 # Check for Qt 4
 285 #
 286 AC_ARG_ENABLE(qt4,
 287         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 288         [case "${enableval}" in
 289                 yes) HAVE_QT4=yes ;;
 290                 no)  HAVE_QT4=no ;;
 291                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 292         esac],
 293         [HAVE_QT4=yes])
 294
 295 if test "x$HAVE_QT4" = "xyes" ; then
 296         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 297         AC_SUBST(QT4_CFLAGS)
 298         AC_SUBST(QT4_LIBS)
 299             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 300         MOC_QT4="no"
 301             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 302                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 303                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 304         AC_SUBST(MOC_QT4)
 305 fi
 306 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 307
 308 #
 309 # Check for GTK+
 310 #
 311 AC_ARG_ENABLE(gtk,
 312         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 313         [case "${enableval}" in
 314                 yes) HAVE_GTK=yes ;;
 315                 no)  HAVE_GTK=no ;;
 316                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 317         esac],
 318         [HAVE_GTK=yes])
 319
 320 if test "x$HAVE_GTK" = "xyes" ; then
 321         # Check for GTK 2.0
 322         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 323         AC_SUBST(GTK20_CFLAGS)
 324         AC_SUBST(GTK20_LIBS)
 325
 326         # Check for GLADE 2.0
 327         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 328         AC_SUBST(GLADE20_CFLAGS)
 329         AC_SUBST(GLADE20_LIBS)
 330 fi
 331 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 332
 333 #
 334 # D-BUS
 335 #
 336 AC_ARG_ENABLE(dbus,
 337         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 338         [case "${enableval}" in
 339                 yes) HAVE_DBUS=yes ;;
 340                 no)  HAVE_DBUS=no ;;
 341                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 342         esac],
 343         [HAVE_DBUS=yes])
 344
 345 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 346 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 347
 348 if test "x$HAVE_DBUS" = "xyes" ; then
 349     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 350
 351     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 352     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 353     AC_SUBST(DBUS_CFLAGS)
 354     AC_SUBST(DBUS_LIBS)
 355
 356     if ! test -z "$with_dbus_sys" ; then
 357         DBUS_SYS_DIR="$with_dbus_sys"
 358     else
 359         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 360     fi
 361     AC_SUBST(DBUS_SYS_DIR)
 362
 363     if ! test -z "$with_dbus_system_address" ; then
 364         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 365     else
 366         # This is ugly, but D-BUS doesn't export this address for us
 367         # so we have to guess, pretty much all setups i've seen have
 368         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 369         # /var/run upstream so we will try guess first then default
 370         # to /var/run/dbus
 371
 372         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 373         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 374         for sock in $TRY_SOCKETS; do
 375             if test -S $sock; then
 376                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 377             fi
 378         done
 379     fi
 380     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 381
 382 fi
 383 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 384
 385 #
 386 # Expat
 387 #
 388 AC_ARG_ENABLE(expat,
 389         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 390         [case "${enableval}" in
 391                 yes) HAVE_EXPAT=yes ;;
 392                 no)  HAVE_EXPAT=no ;;
 393                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 394         esac],
 395         [HAVE_EXPAT=yes])
 396
 397 if test "x$HAVE_EXPAT" = "xyes" ; then
 398     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 399
 400     if ! $have_expat ; then
 401         AC_MSG_ERROR([*** libexpat not found ***])
 402     fi
 403 fi
 404 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 405
 406 #
 407 # GDBM
 408 #
 409 AC_ARG_ENABLE(gdbm,
 410         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 411         [case "${enableval}" in
 412                 yes) HAVE_GDBM=yes ;;
 413                 no)  HAVE_GDBM=no ;;
 414                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 415         esac],
 416         [HAVE_GDBM=yes])
 417
 418 if test "x$HAVE_GDBM" = "xyes" ; then
 419     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 420
 421     if ! $have_gdbm ; then
 422         AC_MSG_ERROR([*** libgdbm not found ***])
 423     fi
 424     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 425 fi
 426 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 427
 428 #
 429 # libdaemon
 430 #
 431 AC_ARG_ENABLE(libdaemon,
 432         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 433         [case "${enableval}" in
 434                 yes) HAVE_LIBDAEMON=yes ;;
 435                 no)  HAVE_LIBDAEMON=no ;;
 436                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 437         esac],
 438         [HAVE_LIBDAEMON=yes])
 439
 440 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 441     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 442     AC_SUBST(LIBDAEMON_CFLAGS)
 443     AC_SUBST(LIBDAEMON_LIBS)
 444 fi
 445 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 446
 447 #
 448 # Python stuff
 449 #
 450 AC_ARG_ENABLE(python,
 451     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 452     [case "${enableval}" in
 453           yes) HAVE_PYTHON=yes ;;
 454           no)  HAVE_PYTHON=no ;;
 455           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 456     esac],[HAVE_PYTHON=yes])
 457
 458 HAVE_PYTHON_DBUS=no
 459 HAVE_PYGTK=no
 460
 461 if test "x$HAVE_PYTHON" = "xyes" ; then
 462     AM_PATH_PYTHON([2.4])
 463
 464     AC_ARG_ENABLE(pygtk,
 465         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 466         [case "${enableval}" in
 467                 yes) HAVE_PYGTK=yes ;;
 468                 no)  HAVE_PYGTK=no ;;
 469                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 470         esac],
 471         [HAVE_PYGTK=yes])
 472
 473     if test "x$HAVE_PYGTK" = "xyes" ; then
 474         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 475     fi
 476
 477
 478     AC_ARG_ENABLE(python-dbus,
 479         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 480         [case "${enableval}" in
 481                 yes) HAVE_PYTHON_DBUS=yes ;;
 482                 no)  HAVE_PYTHON_DBUS=no ;;
 483                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 484         esac],
 485         [HAVE_PYTHON_DBUS=yes])
 486
 487     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 488         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 489     fi
 490
 491     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 492     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 493 fi
 494 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 495 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 496 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 497
 498 #
 499 # Check for mono stuff
 500 #
 501 AC_ARG_ENABLE(mono,
 502         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 503         [case "${enableval}" in
 504                 yes) HAVE_MONO=yes ;;
 505                 no)  HAVE_MONO=no ;;
 506                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 507         esac],
 508         [HAVE_MONO=yes])
 509
 510 AC_ARG_ENABLE(monodoc,
 511         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 512         [case "${enableval}" in
 513                 yes) HAVE_MONODOC=yes ;;
 514                 no)  HAVE_MONODOC=no ;;
 515                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 516         esac],
 517         [HAVE_MONODOC=yes])
 518
 519 if test "x$HAVE_MONO" = "xyes" ; then
 520         AC_PATH_PROG(MCS, mcs)
 521         if test "x$MCS" = "x" ; then
 522                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 523         fi
 524
 525         AC_PATH_PROG(GACUTIL, gacutil)
 526         if test "x$GACUTIL" = "x" ; then
 527                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 528         fi
 529
 530         AC_SUBST(MCS)
 531         AC_SUBST(GACUTIL)
 532 fi
 533 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 534
 535 #
 536 # Check for monodoc stuff
 537 #
 538 if test "x$HAVE_MONODOC" = "xyes" ; then
 539         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 540         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 541
 542         AC_PATH_PROG(MONODOCER, monodocer)
 543         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 544
 545         AC_SUBST(MONODOC_DIR)
 546         AC_SUBST(MONODOCER)
 547         AC_SUBST(MDASSEMBLER)
 548 fi
 549 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 550
 551 #
 552 # Defining Avahi User and Group.
 553 #
 554 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 555 if test -z "$with_avahi_user" ; then
 556     AVAHI_USER=avahi
 557 else
 558     AVAHI_USER=$with_avahi_user
 559 fi
 560 AC_SUBST(AVAHI_USER)
 561 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 562
 563 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 564 if test -z "$with_avahi_group" ; then
 565     AVAHI_GROUP=avahi
 566 else
 567     AVAHI_GROUP=$with_avahi_group
 568 fi
 569 AC_SUBST(AVAHI_GROUP)
 570 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 571
 572 #
 573 # Avahi runtime dir
 574 #
 575 avahi_runtime_dir="${localstatedir}/run"
 576 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 577 AC_SUBST(avahi_runtime_dir)
 578 AC_SUBST(avahi_socket)
 579
 580 #
 581 # Avahi interfaces dir
 582 #
 583 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 584         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 585         AC_SUBST(interfacesdir)
 586 fi
 587
 588 #
 589 # Doxygen
 590 #
 591 DX_HTML_FEATURE(ON)
 592 DX_CHM_FEATURE(OFF)
 593 DX_CHI_FEATURE(OFF)
 594 DX_MAN_FEATURE(OFF)
 595 DX_RTF_FEATURE(OFF)
 596 DX_XML_FEATURE(OFF)
 597 DX_PDF_FEATURE(OFF)
 598 DX_PS_FEATURE(OFF)
 599 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 600
 601 #
 602 # Build and Install man pages
 603 #
 604 AC_ARG_ENABLE(manpages,
 605         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 606 [case "${enableval}" in
 607   yes) manpages=yes ;;
 608   no)  manpages=no ;;
 609   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 610 esac],[manpages=yes])
 611
 612 if test x$manpages = xyes ; then
 613     #
 614     # XMLTOMAN manpage generation
 615     #
 616     AC_ARG_ENABLE(xmltoman,
 617     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 618     [case "${enableval}" in
 619       yes) xmltoman=yes ;;
 620       no)  xmltoman=no ;;
 621       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 622     esac],[xmltoman=yes])
 623
 624     if test x$xmltoman = xyes ; then
 625         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 626     fi
 627
 628     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 629         if ! test -e man/avahi-daemon.8 ; then
 630             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 631             exit 1
 632         fi
 633         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 634         xmltoman=no
 635     fi
 636 fi
 637 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 638 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 639
 640 #
 641 # Conditionally compile test and example programs
 642 #
 643 AC_ARG_ENABLE(tests,
 644         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 645         [case "${enableval}" in
 646                 yes) ENABLE_TESTS=yes ;;
 647                 no)  ENABLE_TESTS=no ;;
 648                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 649         esac],
 650         [ENABLE_TESTS=no])
 651
 652 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 653
 654 #
 655 # Optionally enable libdns_sd compatibility support
 656 #
 657 AC_ARG_ENABLE(compat-libdns_sd,
 658         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 659         [case "${enableval}" in
 660                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 661                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 662                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 663         esac],
 664         [ENABLE_COMPAT_LIBDNS_SD=no])
 665
 666 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 667
 668 #
 669 # Optionally enable HOWL compatibility support
 670 #
 671 AC_ARG_ENABLE(compat-howl,
 672         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 673         [case "${enableval}" in
 674                 yes) ENABLE_COMPAT_HOWL=yes ;;
 675                 no)  ENABLE_COMPAT_HOWL=no ;;
 676                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 677         esac],
 678         [ENABLE_COMPAT_HOWL=no])
 679
 680 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 681
 682
 683 # ==========================================================================
 684 AC_CONFIG_FILES([
 685 Makefile
 686 avahi-common/Makefile
 687 avahi-core/Makefile
 688 avahi-glib/Makefile
 689 avahi-qt/Makefile
 690 avahi-daemon/Makefile
 691 avahi-daemon/avahi-dbus.conf
 692 avahi-discover-standalone/Makefile
 693 avahi-client/Makefile
 694 initscript/Makefile
 695 initscript/debian/Makefile
 696 initscript/gentoo/Makefile
 697 initscript/archlinux/Makefile
 698 initscript/suse/Makefile
 699 initscript/fedora/Makefile
 700 avahi-dnsconfd/Makefile
 701 avahi-utils/Makefile
 702 avahi-utils/avahi/Makefile
 703 examples/Makefile
 704 common/Makefile
 705 man/Makefile
 706 tests/Makefile
 707 service-type-database/Makefile
 708 avahi-sharp/Makefile
 709 avahi-compat-libdns_sd/Makefile
 710 avahi-compat-howl/Makefile
 711 avahi-compat-howl/samples/Makefile
 712 ])
 713 AC_OUTPUT
 714
 715 # ==========================================================================
 716 echo "
 717  ---{ $PACKAGE_NAME $VERSION }---
 718
 719     prefix:                 ${prefix}
 720     sysconfdir:             ${sysconfdir}
 721     localstatedir:          ${localstatedir}
 722     avahi socket:           ${avahi_socket}
 723     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 724     dbus-1 version:         `pkg-config dbus-1 --modversion`
 725     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 726     compiler:               ${CC}
 727     cflags:                 ${CFLAGS}
 728     Enable GLIB:            ${HAVE_GLIB}
 729     Enable GTK:             ${HAVE_GTK}
 730     Enable D-BUS:           ${HAVE_DBUS}
 731     Enable Expat:           ${HAVE_EXPAT}
 732     Enable GDBM:            ${HAVE_GDBM}
 733     Enable libdaemon:       ${HAVE_LIBDAEMON}
 734     Enable Python:          ${HAVE_PYTHON}
 735     Enable pygtk:           ${HAVE_PYGTK}
 736     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 737     Enable QT3:             ${HAVE_QT3}
 738     Enable QT4:             ${HAVE_QT4}
 739     Enable Mono:            ${HAVE_MONO}
 740     Linux Distro:           ${with_distro}
 741     User for Avahi:         ${AVAHI_USER}
 742     Group for Avahi:        ${AVAHI_GROUP}
 743     Enable chroot():        ${enable_chroot}
 744 "
 745
 746 BUILD_DAEMON="no (!)"
 747
 748 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 749     BUILD_DAEMON=yes
 750 fi
 751
 752 BUILD_UTILS="no (!)"
 753
 754 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 755     BUILD_UTILS=yes
 756 fi
 757
 758 BUILD_CLIENT="no (!)"
 759
 760 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 761     BUILD_CLIENT=yes
 762 fi
 763
 764 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 765    AC_MSG_ERROR([building avahi-compat-libdns_sd without building libavahi-client doesn't work])
 766 fi
 767 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 768    AC_MSG_ERROR([building avahi-compat-howl without building libavahi-client doesn't work])
 769 fi
 770
 771
 772 echo "
 773     Building libavahi-core              yes
 774     Building avahi-daemon:              ${BUILD_DAEMON}
 775     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 776     Building avahi-utils:               ${BUILD_UTILS}
 777     Building libavahi-glib:             ${HAVE_GLIB}
 778     Building libavahi-client:           ${BUILD_CLIENT}
 779     Building avahi-discover-standalone: ${HAVE_GTK}
 780     Building libavahi-qt3:              ${HAVE_QT3}
 781     Building libavahi-qt4:              ${HAVE_QT4}
 782     Building avahi-sharp:               ${HAVE_MONO}
 783     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 784     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 785     Building tests:                     ${ENABLE_TESTS}
 786 "