git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38
  39 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  40     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  41     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  42 fi
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AC_PROG_CXX
  47 AC_GNU_SOURCE
  48 AC_PROG_CPP
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AC_PROG_GCC_TRADITIONAL
  53
  54 # libtool stuff
  55 AC_PROG_LIBTOOL
  56
  57 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  58
  59 #
  60 # Detecting the linux distribution for specific things like init scripts.
  61 #
  62 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
  63 if test "z$with_distro" = "z"; then
  64     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  65     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  66     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
  67     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  68 fi
  69 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
  70
  71 if test "z$with_distro" = "z"; then
  72     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
  73     exit 1
  74 else
  75 case $with_distro in
  76     debian|gentoo|archlinux|suse|none)
  77      ;;
  78     *)
  79      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
  80      ;;
  81 esac
  82 fi
  83
  84 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
  85 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
  86 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
  87 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
  88
  89 test_gcc_flag() {
  90     AC_LANG_CONFTEST([int main() {}])
  91     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  92     ret=$?
  93     rm -f conftest.o
  94     return $ret
  95 }
  96
  97 # If using GCC specify some additional parameters
  98 if test "x$GCC" = "xyes" ; then
  99
 100     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
 101
 102     # Test whether rtnetlink.h can be included when compiled with -std=c99
 103     # some distributions (e.g. archlinux) have broken headers that dont
 104     # define __u64 with -std=c99
 105     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 106     OLDCFLAGS="$CFLAGS"
 107     CFLAGS="-std=c99"
 108     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 109         use_stdc99=yes, use_stdc99=no)
 110
 111     if test x"$use_stdc99" = xyes; then
 112         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 113         AC_MSG_RESULT([yes])
 114     else
 115         AC_MSG_RESULT([no])
 116     fi
 117
 118     CFLAGS="$OLDCFLAGS"
 119
 120     for flag in $DESIRED_FLAGS ; do
 121         AC_MSG_CHECKING([whether $CC accepts $flag])
 122         if test_gcc_flag $flag ; then
 123            CFLAGS="$CFLAGS $flag"
 124            AC_MSG_RESULT([yes])
 125         else
 126            AC_MSG_RESULT([no])
 127         fi
 128     done
 129 fi
 130
 131 # Checks for header files.
 132 AC_HEADER_STDC
 133 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 134
 135 # Checks for typedefs, structures, and compiler characteristics.
 136 AC_C_CONST
 137 AC_TYPE_SIZE_T
 138 AC_HEADER_TIME
 139 AC_HEADER_SYS_WAIT
 140
 141 # Checks for library functions.
 142 AC_FUNC_MEMCMP
 143 AC_FUNC_SELECT_ARGTYPES
 144 AC_FUNC_MALLOC
 145 AC_FUNC_REALLOC
 146 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp])
 147
 148 AC_FUNC_CHOWN
 149 AC_FUNC_STAT
 150 AC_TYPE_MODE_T
 151 AC_TYPE_PID_T
 152
 153 # Check for pkg-config manually first, as if its not installed the
 154 # PKG_PROG_PKG_CONFIG macro won't be defined.
 155 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 156
 157 if test x"$have_pkg_config" == xno; then
 158     AC_MSG_ERROR(pkg-config is required to install this program)
 159 fi
 160
 161 PKG_PROG_PKG_CONFIG
 162
 163 #
 164 # Check for GLIB 2.0
 165 #
 166 AC_ARG_ENABLE(glib,
 167         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 168         [case "${enableval}" in
 169                 yes) HAVE_GLIB=yes ;;
 170                 no)  HAVE_GLIB=no ;;
 171                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 172         esac],
 173         [HAVE_GLIB=yes])
 174
 175 if test "x$HAVE_GLIB" = "xyes" ; then
 176         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 177         AC_SUBST(GLIB20_CFLAGS)
 178         AC_SUBST(GLIB20_LIBS)
 179 fi
 180 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 181
 182 #
 183 # Check for Qt 3
 184 #
 185 AC_ARG_ENABLE(qt3,
 186         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 187         [case "${enableval}" in
 188                 yes) HAVE_QT3=yes ;;
 189                 no)  HAVE_QT3=no ;;
 190                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 191         esac],
 192         [HAVE_QT3=yes])
 193
 194 if test "x$HAVE_QT3" = "xyes" ; then
 195         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 196         AC_SUBST(QT3_CFLAGS)
 197         AC_SUBST(QT3_LIBS)
 198             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 199         MOC_QT3="no"
 200             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 201                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 202                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 203         AC_SUBST(MOC_QT3)
 204 fi
 205 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 206
 207 #
 208 # Check for Qt 4
 209 #
 210 AC_ARG_ENABLE(qt4,
 211         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 212         [case "${enableval}" in
 213                 yes) HAVE_QT4=yes ;;
 214                 no)  HAVE_QT4=no ;;
 215                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 216         esac],
 217         [HAVE_QT4=yes])
 218
 219 if test "x$HAVE_QT4" = "xyes" ; then
 220         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 221         AC_SUBST(QT4_CFLAGS)
 222         AC_SUBST(QT4_LIBS)
 223             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 224         MOC_QT4="no"
 225             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 226                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 227                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 228         AC_SUBST(MOC_QT4)
 229 fi
 230 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 231
 232 #
 233 # Check for GTK+
 234 #
 235 AC_ARG_ENABLE(gtk,
 236         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 237         [case "${enableval}" in
 238                 yes) HAVE_GTK=yes ;;
 239                 no)  HAVE_GTK=no ;;
 240                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 241         esac],
 242         [HAVE_GTK=yes])
 243
 244 if test "x$HAVE_GTK" = "xyes" ; then
 245         # Check for GTK 2.0
 246         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 247         AC_SUBST(GTK20_CFLAGS)
 248         AC_SUBST(GTK20_LIBS)
 249
 250         # Check for GLADE 2.0
 251         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 252         AC_SUBST(GLADE20_CFLAGS)
 253         AC_SUBST(GLADE20_LIBS)
 254 fi
 255 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 256
 257
 258
 259 #
 260 # D-BUS
 261 #
 262 AC_ARG_ENABLE(dbus,
 263         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 264         [case "${enableval}" in
 265                 yes) HAVE_DBUS=yes ;;
 266                 no)  HAVE_DBUS=no ;;
 267                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 268         esac],
 269         [HAVE_DBUS=yes])
 270
 271 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 272 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 273
 274 if test "x$HAVE_DBUS" = "xyes" ; then
 275     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 276
 277     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 278     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 279     AC_SUBST(DBUS_CFLAGS)
 280     AC_SUBST(DBUS_LIBS)
 281
 282     if ! test -z "$with_dbus_sys" ; then
 283         DBUS_SYS_DIR="$with_dbus_sys"
 284     else
 285         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 286     fi
 287     AC_SUBST(DBUS_SYS_DIR)
 288
 289     if ! test -z "$with_dbus_system_address" ; then
 290         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 291     else
 292         # This is ugly, but D-BUS doesn't export this address for us
 293         # so we have to guess, pretty much all setups i've seen have
 294         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 295         # /var/run upstream so we will try guess first then default
 296         # to /var/run/dbus
 297
 298         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 299         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket"
 300         for sock in $TRY_SOCKETS; do
 301             if test -S $sock; then
 302                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 303             fi
 304         done
 305     fi
 306     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 307
 308 fi
 309 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 310
 311 #
 312 # Expat
 313 #
 314 AC_ARG_ENABLE(expat,
 315         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 316         [case "${enableval}" in
 317                 yes) HAVE_EXPAT=yes ;;
 318                 no)  HAVE_EXPAT=no ;;
 319                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 320         esac],
 321         [HAVE_EXPAT=yes])
 322
 323 if test "x$HAVE_EXPAT" = "xyes" ; then
 324     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 325
 326     if ! $have_expat ; then
 327         AC_MSG_ERROR([*** libexpat not found ***])
 328     fi
 329 fi
 330 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 331
 332 #
 333 # libdaemon
 334 #
 335 AC_ARG_ENABLE(libdaemon,
 336         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 337         [case "${enableval}" in
 338                 yes) HAVE_LIBDAEMON=yes ;;
 339                 no)  HAVE_LIBDAEMON=no ;;
 340                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 341         esac],
 342         [HAVE_LIBDAEMON=yes])
 343
 344 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 345     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 346     AC_SUBST(LIBDAEMON_CFLAGS)
 347     AC_SUBST(LIBDAEMON_LIBS)
 348 fi
 349 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 350
 351 #
 352 # Python stuff
 353 #
 354 AC_ARG_ENABLE(python,
 355     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 356     [case "${enableval}" in
 357           yes) HAVE_PYTHON=yes ;;
 358           no)  HAVE_PYTHON=no ;;
 359           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 360     esac],[HAVE_PYTHON=yes])
 361
 362 HAVE_PYTHON_DBUS=no
 363 HAVE_PYGTK=no
 364
 365 if test "x$HAVE_PYTHON" = "xyes" ; then
 366     AM_PATH_PYTHON([2.4])
 367
 368     AC_ARG_ENABLE(pygtk,
 369         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 370         [case "${enableval}" in
 371                 yes) HAVE_PYGTK=yes ;;
 372                 no)  HAVE_PYGTK=no ;;
 373                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 374         esac],
 375         [HAVE_PYGTK=yes])
 376
 377     if test "x$HAVE_PYGTK" = "xyes" ; then
 378         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 379     fi
 380
 381
 382     AC_ARG_ENABLE(python-dbus,
 383         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 384         [case "${enableval}" in
 385                 yes) HAVE_PYTHON_DBUS=yes ;;
 386                 no)  HAVE_PYTHON_DBUS=no ;;
 387                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 388         esac],
 389         [HAVE_PYTHON_DBUS=yes])
 390
 391     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 392         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 393     fi
 394
 395     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 396     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 397 fi
 398 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 399 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 400 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 401
 402 #
 403 # Check for mono stuff
 404 #
 405 AC_ARG_ENABLE(mono,
 406         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 407         [case "${enableval}" in
 408                 yes) HAVE_MONO=yes ;;
 409                 no)  HAVE_MONO=no ;;
 410                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 411         esac],
 412         [HAVE_MONO=yes])
 413
 414 AC_ARG_ENABLE(monodoc,
 415         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 416         [case "${enableval}" in
 417                 yes) HAVE_MONODOC=yes ;;
 418                 no)  HAVE_MONODOC=no ;;
 419                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 420         esac],
 421         [HAVE_MONODOC=yes])
 422
 423 if test "x$HAVE_MONO" = "xyes" ; then
 424         AC_PATH_PROG(MCS, mcs)
 425         if test "x$MCS" = "x" ; then
 426                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 427         fi
 428
 429         AC_PATH_PROG(GACUTIL, gacutil)
 430         if test "x$GACUTIL" = "x" ; then
 431                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 432         fi
 433
 434         AC_SUBST(MCS)
 435         AC_SUBST(GACUTIL)
 436 fi
 437 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 438
 439 #
 440 # Check for monodoc stuff
 441 #
 442 if test "x$HAVE_MONODOC" = "xyes" ; then
 443         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 444         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 445
 446         AC_PATH_PROG(MONODOCER, monodocer)
 447         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 448
 449         AC_SUBST(MONODOC_DIR)
 450         AC_SUBST(MONODOCER)
 451         AC_SUBST(MDASSEMBLER)
 452 fi
 453 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 454
 455 #
 456 # Defining Avahi User and Group.
 457 #
 458 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 459 if test -z "$with_avahi_user" ; then
 460     AVAHI_USER=avahi
 461 else
 462     AVAHI_USER=$with_avahi_user
 463 fi
 464 AC_SUBST(AVAHI_USER)
 465 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 466
 467 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 468 if test -z "$with_avahi_group" ; then
 469     AVAHI_GROUP=avahi
 470 else
 471     AVAHI_GROUP=$with_avahi_group
 472 fi
 473 AC_SUBST(AVAHI_GROUP)
 474 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 475
 476 #
 477 # Avahi runtime dir
 478 #
 479 avahi_runtime_dir="${localstatedir}/run"
 480 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 481 AC_SUBST(avahi_runtime_dir)
 482 AC_SUBST(avahi_socket)
 483
 484
 485 #
 486 # Avahi interfaces dir
 487 #
 488 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 489         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 490         AC_SUBST(interfacesdir)
 491 fi
 492
 493
 494 #
 495 # Doxygen
 496 #
 497 DX_HTML_FEATURE(ON)
 498 DX_CHM_FEATURE(OFF)
 499 DX_CHI_FEATURE(OFF)
 500 DX_MAN_FEATURE(OFF)
 501 DX_RTF_FEATURE(OFF)
 502 DX_XML_FEATURE(OFF)
 503 DX_PDF_FEATURE(OFF)
 504 DX_PS_FEATURE(OFF)
 505 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 506
 507 #
 508 # XMLTOMAN manpage generation
 509 #
 510 AC_ARG_ENABLE(xmltoman,
 511         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 512 [case "${enableval}" in
 513   yes) xmltoman=yes ;;
 514   no)  xmltoman=no ;;
 515   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 516 esac],[xmltoman=yes])
 517
 518 if test x$xmltoman = xyes ; then
 519     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 520
 521     if test x$have_xmltoman = xno ; then
 522         if ! test -e man/avahi-daemon.8 ; then
 523             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 524             exit 1
 525         fi
 526         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 527         xmltoman=no
 528     fi
 529 fi
 530
 531 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 532
 533 # ==========================================================================
 534 AC_CONFIG_FILES([
 535 Makefile
 536 avahi-common/Makefile
 537 avahi-core/Makefile
 538 avahi-glib/Makefile
 539 avahi-qt/Makefile
 540 avahi-daemon/Makefile
 541 avahi-daemon/avahi-dbus.conf
 542 avahi-discover-standalone/Makefile
 543 avahi-client/Makefile
 544 initscript/Makefile
 545 initscript/debian/Makefile
 546 initscript/gentoo/Makefile
 547 initscript/archlinux/Makefile
 548 initscript/suse/Makefile
 549 avahi-dnsconfd/Makefile
 550 avahi-utils/Makefile
 551 avahi-utils/avahi/Makefile
 552 examples/Makefile
 553 common/Makefile
 554 man/Makefile
 555 tests/Makefile
 556 service-type-database/Makefile
 557 avahi-sharp/Makefile
 558 avahi-compat-libdns_sd/Makefile
 559 ])
 560 AC_OUTPUT
 561
 562 # ==========================================================================
 563 echo "
 564  ---{ $PACKAGE_NAME $VERSION }---
 565
 566     prefix:                 ${prefix}
 567     sysconfdir:             ${sysconfdir}
 568     localstatedir:          ${localstatedir}
 569     avahi socket:           ${avahi_socket}
 570     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 571     dbus-1 version:         `pkg-config dbus-1 --modversion`
 572     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 573     compiler:               ${CC}
 574     cflags:                 ${CFLAGS}
 575     Enable GLIB:            ${HAVE_GLIB}
 576     Enable GTK:             ${HAVE_GTK}
 577     Enable D-BUS:           ${HAVE_DBUS}
 578     Enable Expat:           ${HAVE_EXPAT}
 579     Enable libdaemon:       ${HAVE_LIBDAEMON}
 580     Enable Python:          ${HAVE_PYTHON}
 581     Enable pygtk:           ${HAVE_PYGTK}
 582     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 583     Enable QT3:             ${HAVE_QT3}
 584     Enable QT4:             ${HAVE_QT4}
 585     Enable Mono:            ${HAVE_MONO}
 586     Linux Distro:           ${with_distro}
 587     User for Avahi:         ${AVAHI_USER}
 588     Group for Avahi:        ${AVAHI_GROUP}
 589 "
 590
 591 BUILD_DAEMON="no (!)"
 592
 593 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 594     BUILD_DAEMON=yes
 595 fi
 596
 597 BUILD_UTILS="no (!)"
 598
 599 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 600     BUILD_UTILS=yes
 601 fi
 602
 603 BUILD_CLIENT="no (!)"
 604
 605 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 606     BUILD_CLIENT=yes
 607 fi
 608
 609 echo "
 610     Building libavahi-core              yes
 611     Building avahi-daemon:              ${BUILD_DAEMON}
 612     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 613     Building avahi-utils:               ${BUILD_UTILS}
 614     Building libavahi-glib:             ${HAVE_GLIB}
 615     Building libavahi-client:           ${BUILD_CLIENT}
 616     Building avahi-discover-standalone: ${HAVE_GTK}
 617     Building libavahi-qt3:              ${HAVE_QT3}
 618     Building libavahi-qt4:              ${HAVE_QT4}
 619     Building avahi-sharp:               ${HAVE_MONO}
 620     Building avahi-compat-libdns_sd:    ${BUILD_CLIENT}
 621 "