git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.24],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [8:1:5])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [6:0:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:5:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_GOBJECT_VERSION_INFO, [0:1:0])
  36 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:2:0])
  37 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:2:0])
  38 AC_SUBST(LIBAVAHI_UI_VERSION_INFO, [1:1:1])
  39
  40 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  41 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  42 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  43 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 # Checks for programs.
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AC_GNU_SOURCE
  54 AC_PROG_CPP
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_GCC_TRADITIONAL
  59
  60 AM_PROG_CC_C_O
  61
  62 # -fstack-protector
  63 AC_ARG_ENABLE([stack-protector],
  64     [AS_HELP_STRING([--disable-stack-protector],
  65         [Disable GCC's/libc's stack-smashing protection])],
  66     [case "${enableval}" in
  67          yes) enable_ssp=yes ;;
  68           no) enable_ssp=no ;;
  69            *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;
  70      esac],
  71     [enable_ssp=yes])
  72
  73 if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then
  74     AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])
  75     enable_ssp=no
  76 fi
  77
  78 if test x"$enable_ssp" = x"yes"; then
  79     # Check for broken ssp in libc: http://www.avahi.org/ticket/105
  80     # libc's brokenness will get in the way regardless of whether -lssp is
  81     # provided, but provide it anyway (otherwise non-libc ssp would wrongly
  82     # break here)
  83
  84     # Get -lssp if it exists
  85     GCC_STACK_PROTECT_LIB
  86
  87     AC_MSG_CHECKING([whether stack-smashing protection is available])
  88     ssp_old_cflags="$CFLAGS"
  89     ssp_old_ldflags="$LDFLAGS"
  90     CFLAGS="$CFLAGS -Werror -fstack-protector-all -fPIC"
  91     LDFLAGS="$LDFLAGS -Wl,-z,defs"
  92     cat confdefs.h > conftest.c
  93     cat >>conftest.c <<_ACEOF
  94 void test_broken_ssp(c)
  95     const char *c;
  96 {
  97     char arr[[123]], *p; /* beware of possible double-braces if copying this */
  98     for (p = arr; *c; ++p) {
  99         *p = *c;
 100         ++c;
 101     }
 102 }
 103 _ACEOF
 104     rm -f conftest.o
 105
 106     if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then
 107         AC_MSG_RESULT([yes])
 108         AC_MSG_CHECKING([whether stack-smashing protection is buggy])
 109         if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then
 110             AC_MSG_RESULT([no])
 111         else
 112             AC_MSG_RESULT([yes])
 113             enable_ssp=no
 114         fi
 115     else
 116         AC_MSG_RESULT([no])
 117     fi
 118
 119     rm -f conftest.c conftest.o conftest.so
 120
 121     CFLAGS="$ssp_old_cflags"
 122     LDFLAGS="$ssp_old_ldflags"
 123 fi
 124
 125 if test x"$enable_ssp" = x"yes"; then
 126     # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice
 127     GCC_STACK_PROTECT_CC
 128
 129     AC_LANG_PUSH([C++])
 130     GCC_STACK_PROTECT_CXX
 131     AC_LANG_POP([C++])
 132     # XXX: Update the enable_ssp value now for output later?
 133 fi
 134
 135 # libtool stuff
 136 AC_PROG_LIBTOOL
 137
 138 AC_CACHE_CHECK([whether the C++ compiler works], [avahi_cv_sys_cxx_works], [
 139     AC_LANG_PUSH([C++])
 140     AC_COMPILE_IFELSE([int main() { return 0; }], [avahi_cv_sys_cxx_works=yes],
 141         [avahi_cv_sys_cxx_works=no])
 142     AC_LANG_POP([C++])
 143     ])
 144 [ if [ "x$avahi_cv_sys_cxx_works" = "xno" ]; then ]
 145     AC_MSG_FAILURE([The C++ compiler does not work])
 146 [ fi ]
 147
 148 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
 149
 150 #
 151 # Check for netlink.h
 152 #
 153 AC_CHECK_HEADER(linux/netlink.h,
 154 HAVE_NETLINK=yes
 155 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
 156 , [], [
 157 #include <sys/socket.h>
 158 #include <asm/types.h>
 159 ])
 160
 161 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
 162
 163 #
 164 # Check for net/route.h
 165 #
 166 AC_CHECK_HEADER(net/route.h,
 167 HAVE_PF_ROUTE=yes
 168 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
 169 , [], [
 170 #include <sys/types.h>
 171 #include <sys/socket.h>
 172 ])
 173
 174 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
 175
 176 #
 177 # Check for sys/filio.h; needed for FIONREAD on Solaris
 178 #
 179 AC_CHECK_HEADER(sys/filio.h,
 180 HAVE_SYS_FILIO_H=yes
 181 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 182 , [], [
 183 ])
 184
 185 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 186
 187 #
 188 # Check for sys/sysctl.h; not present on Solaris
 189 #
 190 AC_CHECK_HEADER(sys/sysctl.h,
 191 HAVE_SYS_SYSCTL=yes
 192 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 193 , [], [
 194 #include <sys/types.h>
 195 #include <sys/socket.h>
 196 #include <sys/param.h>
 197 ])
 198
 199 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 200
 201 #
 202 # Check for lifconf struct; only present on Solaris
 203 #
 204 AC_MSG_CHECKING(for struct lifconf)
 205 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 206 [AC_TRY_COMPILE(
 207 [#include <sys/socket.h>
 208 #include <net/if.h>
 209 ],[sizeof (struct lifconf);],
 210 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 211 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 212 if test $avahi_cv_has_struct_lifconf = yes; then
 213     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 214 fi
 215
 216 #
 217 # Check for struct ip_mreqn
 218 #
 219 AC_MSG_CHECKING(for struct ip_mreqn)
 220 AC_TRY_COMPILE([#include <netinet/in.h>], [
 221         struct ip_mreqn mreq;
 222         mreq.imr_address.s_addr = 0;
 223 ], [
 224         # Yes, we have it...
 225         AC_MSG_RESULT(yes)
 226         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 227 ], [
 228         # We'll just have to try and use struct ip_mreq
 229         AC_MSG_RESULT(no)
 230         AC_MSG_CHECKING(for struct ip_mreq)
 231         AC_TRY_COMPILE([#include <netinet/in.h>], [
 232                 struct ip_mreq mreq;
 233                 mreq.imr_interface.s_addr = 0;
 234         ], [
 235                 # Yes, we have it...
 236                 AC_MSG_RESULT(yes)
 237                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 238         ], [
 239                 # No multicast support
 240                         AC_MSG_RESULT(no)
 241         ])
 242 ])
 243
 244 #
 245 # Detecting the linux distribution for specific things like init scripts.
 246 #
 247 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 248 if test "z$with_distro" = "z"; then
 249     if test "$cross_compiling" = yes; then
 250         AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 251     else
 252         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 253         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 254         AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 255         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 256         AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 257         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 258         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 259     fi
 260     if test "z$with_distro" = "z"; then
 261         with_distro=`uname -s`
 262     fi
 263 fi
 264 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 265
 266 case $with_distro in
 267     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 268      ;;
 269     netbsd)
 270      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 271      ;;
 272     linux)
 273      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 274      ;;
 275     *)
 276      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 277      ;;
 278 esac
 279
 280 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 281 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 282 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 283 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 284 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 285 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 286 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 287 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 288 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 289 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 290
 291 test_gcc_flag() {
 292     AC_LANG_CONFTEST([int main() {}])
 293     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 294     ret=$?
 295     rm -f conftest.o
 296     return $ret
 297 }
 298
 299 # If using GCC specify some additional parameters
 300 if test "x$GCC" = "xyes" ; then
 301
 302     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 303
 304     if test "x$HAVE_NETLINK" = "xyes" ; then
 305         # Test whether rtnetlink.h can be included when compiled with -std=c99
 306         # some distributions (e.g. archlinux) have broken headers that dont
 307         # define __u64 with -std=c99
 308         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 309         OLDCFLAGS="$CFLAGS"
 310         CFLAGS="-std=c99"
 311         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 312             use_stdc99=yes, use_stdc99=no)
 313
 314         if test x"$use_stdc99" = xyes; then
 315             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 316             AC_MSG_RESULT([yes])
 317         else
 318             AC_MSG_RESULT([no])
 319         fi
 320
 321         CFLAGS="$OLDCFLAGS"
 322     else
 323         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 324     fi
 325
 326     for flag in $DESIRED_FLAGS ; do
 327         AC_MSG_CHECKING([whether $CC accepts $flag])
 328         if test_gcc_flag $flag ; then
 329            CFLAGS="$CFLAGS $flag"
 330            AC_MSG_RESULT([yes])
 331         else
 332            AC_MSG_RESULT([no])
 333         fi
 334     done
 335 fi
 336
 337 # Checks for header files.
 338 AC_HEADER_STDC
 339 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 340 AC_HEADER_STDBOOL
 341
 342 # Checks for typedefs, structures, and compiler characteristics.
 343 AC_C_CONST
 344 AC_TYPE_SIZE_T
 345 AC_HEADER_TIME
 346 AC_HEADER_SYS_WAIT
 347
 348  # Solaris stuff
 349  AC_SEARCH_LIBS([inet_ntop],[nsl])
 350  AC_SEARCH_LIBS([recv],[socket])
 351  AC_CHECK_DECL([CMSG_SPACE],,CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500 -D__EXTENSIONS__")
 352
 353 # Checks for library functions.
 354 AC_FUNC_MEMCMP
 355 AC_FUNC_SELECT_ARGTYPES
 356 # avahi_malloc actually returns NULL for avahi_malloc(0), so it does not matter
 357 # whether libc's malloc does too. (Same for realloc.)
 358 #AC_FUNC_MALLOC
 359 #AC_FUNC_REALLOC
 360 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 361
 362 AC_FUNC_CHOWN
 363 AC_FUNC_STAT
 364 AC_TYPE_MODE_T
 365 AC_TYPE_PID_T
 366
 367 AC_CHECK_DECLS(environ)
 368
 369 # check if gcc's -fvisibility is supported
 370 CHECK_VISIBILITY_HIDDEN
 371
 372 enable_chroot=yes
 373 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 374 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 375 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 376
 377 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 378
 379 if test "x$enable_chroot" = "xyes" ; then
 380    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 381 fi
 382
 383 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 384 if test "x$HAVE_DLOPEN" = "xyes" ; then
 385     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 386 fi
 387 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 388
 389 have_inotify=no
 390 AC_CHECK_HEADERS([sys/inotify.h], [have_inotify=yes])
 391
 392 AM_CONDITIONAL(HAVE_INOTIFY, test "x$have_inotify" = "xyes")
 393
 394 if test "x$have_inotify" = "xyes" ; then
 395    AC_DEFINE([HAVE_INOTIFY], 1, [Enable Linux inotify() usage])
 396 fi
 397
 398 have_kqueue=yes
 399 AC_CHECK_FUNCS([kqueue],,have_kqueue=no)
 400
 401 AM_CONDITIONAL(HAVE_KQUEUE, test "x$have_kqueue" = "xyes")
 402
 403 if test "x$have_kqueue" = "xyes" ; then
 404     AC_DEFINE([HAVE_KQUEUE], 1, [Enable BSD kqueue() usage])
 405 fi
 406
 407 IT_PROG_INTLTOOL([0.35.0])
 408 GETTEXT_PACKAGE=avahi
 409 AC_SUBST([GETTEXT_PACKAGE])
 410 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 411 AM_GLIB_GNU_GETTEXT
 412
 413 avahilocaledir='${prefix}/${DATADIRNAME}/locale'
 414 AC_SUBST(avahilocaledir)
 415
 416
 417 # Check for pkg-config manually first, as if its not installed the
 418 # PKG_PROG_PKG_CONFIG macro won't be defined.
 419 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 420
 421 if test x"$have_pkg_config" = "xno"; then
 422     AC_MSG_ERROR(pkg-config is required to install this program)
 423 fi
 424
 425 PKG_PROG_PKG_CONFIG
 426
 427 #
 428 # Check for GLIB 2.0
 429 #
 430 AC_ARG_ENABLE(glib,
 431         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 432         [case "${enableval}" in
 433                 yes) HAVE_GLIB=yes ;;
 434                 no)  HAVE_GLIB=no ;;
 435                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 436         esac],
 437         [HAVE_GLIB=yes])
 438
 439 if test "x$HAVE_GLIB" = "xyes" ; then
 440         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 441         AC_SUBST(GLIB20_CFLAGS)
 442         AC_SUBST(GLIB20_LIBS)
 443 fi
 444 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 445
 446 #
 447 # Check for GLIB's gobject 2.0
 448 #
 449 AC_ARG_ENABLE(gobject,
 450         AS_HELP_STRING([--disable-gobject],[Disable use of GLib GObject]),
 451         [case "${enableval}" in
 452                 yes) HAVE_GOBJECT=yes ;;
 453                 no)  HAVE_GOBJECT=no ;;
 454                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gobject) ;;
 455         esac],
 456         [HAVE_GOBJECT=yes])
 457
 458 if test "x$HAVE_GOBJECT" = "xyes" ; then
 459         PKG_CHECK_MODULES(GOBJECT, [ glib-2.0 >= 2.4.0 gobject-2.0 ])
 460         AC_SUBST(GOBJECT_CFLAGS)
 461         AC_SUBST(GOBJECT_LIBS)
 462 fi
 463 AM_CONDITIONAL(HAVE_GOBJECT, test "x$HAVE_GOBJECT" = "xyes")
 464
 465 #
 466 # Check for Qt 3
 467 #
 468 AC_ARG_ENABLE(qt3,
 469         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 470         [case "${enableval}" in
 471                 yes) HAVE_QT3=yes ;;
 472                 no)  HAVE_QT3=no ;;
 473                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 474         esac],
 475         [HAVE_QT3=yes])
 476
 477 if test "x$HAVE_QT3" = "xyes" ; then
 478         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 479         AC_SUBST(QT3_CFLAGS)
 480         AC_SUBST(QT3_LIBS)
 481             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 482         AC_PATH_PROGS(MOC_QT3, [moc-qt3 moc], no, [$QT3_PREFIX])
 483         if test "$MOC_QT3" = no; then
 484             AC_MSG_ERROR([Could not find QT3 moc])
 485         fi
 486         AC_SUBST(MOC_QT3)
 487 fi
 488 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 489
 490 #
 491 # Check for Qt 4
 492 #
 493 AC_ARG_ENABLE(qt4,
 494         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 495         [case "${enableval}" in
 496                 yes) HAVE_QT4=yes ;;
 497                 no)  HAVE_QT4=no ;;
 498                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 499         esac],
 500         [HAVE_QT4=yes])
 501
 502 if test "x$HAVE_QT4" = "xyes" ; then
 503         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 504         AC_SUBST(QT4_CFLAGS)
 505         AC_SUBST(QT4_LIBS)
 506             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 507         AC_PATH_PROGS(MOC_QT4, [moc-qt4 moc], no, [$QT4_PREFIX])
 508         if test "$MOC_QT4" = no; then
 509             AC_MSG_ERROR([Could not find QT4 moc])
 510         fi
 511         AC_SUBST(MOC_QT4)
 512 fi
 513 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 514
 515 #
 516 # Check for GTK+
 517 #
 518 AC_ARG_ENABLE(gtk,
 519         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 520         [case "${enableval}" in
 521                 yes) HAVE_GTK=yes ;;
 522                 no)  HAVE_GTK=no ;;
 523                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 524         esac],
 525         [HAVE_GTK=yes])
 526
 527 if test "x$HAVE_GTK" = "xyes" ; then
 528         # Check for GTK 2.0
 529         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 530         AC_SUBST(GTK20_CFLAGS)
 531         AC_SUBST(GTK20_LIBS)
 532
 533         # Check for GLADE 2.0
 534         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 535         AC_SUBST(GLADE20_CFLAGS)
 536         AC_SUBST(GLADE20_LIBS)
 537 fi
 538 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 539
 540 #
 541 # D-Bus
 542 #
 543 AC_ARG_ENABLE(dbus,
 544         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 545         [case "${enableval}" in
 546                 yes) HAVE_DBUS=yes ;;
 547                 no)  HAVE_DBUS=no ;;
 548                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 549         esac],
 550         [HAVE_DBUS=yes])
 551
 552 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 553 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 554
 555 DBUS_VERSION="Disabled"
 556 DBUS_SYS_DIR="Disabled"
 557 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 558 if test "x$HAVE_DBUS" = "xyes" ; then
 559     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 560
 561     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 562
 563     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 564     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 565     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 566     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 567     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 568         DBUS_VERSION_MAJOR="0"
 569     fi
 570     if test "z$DBUS_VERSION_MINOR" = "z"; then
 571         DBUS_VERSION_MINOR="0"
 572     fi
 573     if test "z$DBUS_VERSION_MICRO" = "z"; then
 574         DBUS_VERSION_MICRO="0"
 575     fi
 576
 577     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 578         echo "Error: Couldn't determine the version of your D-Bus package."
 579         echo "  This is probably an error in this script, please report it"
 580         echo "  along with the following information:"
 581         echo "      Base D-Buss version ='$DBUS_VERSION'"
 582         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 583         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 584         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 585         exit 1
 586     else
 587         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 588         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 589         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 590         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 591     fi
 592
 593     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 594     AC_SUBST(DBUS_CFLAGS)
 595     AC_SUBST(DBUS_LIBS)
 596
 597     if ! test -z "$with_dbus_sys" ; then
 598         DBUS_SYS_DIR="$with_dbus_sys"
 599     else
 600         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 601     fi
 602     AC_SUBST(DBUS_SYS_DIR)
 603
 604     if ! test -z "$with_dbus_system_address" ; then
 605         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 606     else
 607         # This is ugly, but D-Bus doesn't export this address for us
 608         # so we have to guess, pretty much all setups i've seen have
 609         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 610         # /var/run upstream so we will try guess first then default
 611         # to /var/run/dbus.
 612
 613         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 614         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 615         for sock in $TRY_SOCKETS; do
 616             if test -S $sock; then
 617                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 618             fi
 619         done
 620     fi
 621     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 622
 623     SAVED_LIBS="$LIBS"
 624     LIBS="$LIBS $DBUS_LIBS"
 625     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 626     LIBS="$SAVED_LIBS"
 627 fi
 628 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 629
 630 #
 631 # Expat
 632 #
 633 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[expat/bsdxml/none]],[XML library to use]))
 634 use_expat=false
 635 use_bsdxml=false
 636
 637 # See what we have
 638 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 639 AC_CHECK_LIB(bsdxml, XML_ParserCreate, [ AC_CHECK_HEADERS(bsdxml.h, have_bsdxml=true, have_bsdxml=false) ], have_bsdxml=false)
 640
 641 if test "x$with_xml" = "xnone"; then
 642         :
 643 elif test "x$with_xml" = "xexpat"; then
 644         use_expat=true
 645         if ! $have_expat ; then
 646                 AC_MSG_ERROR([*** libexpat requested, but not found ***])
 647         fi
 648 elif test "x$with_xml" = "xbsdxml"; then
 649         use_bsdxml=true
 650         if ! $have_bsdxml ; then
 651                 AC_MSG_ERROR([*** libbsdxml requested, but not found ***])
 652         fi
 653 elif test "x$with_xml" != "x"; then
 654         AC_MSG_ERROR([*** unknown with-xml option ***])
 655 else
 656         if $have_expat ; then
 657                 use_expat=true
 658         elif $have_bsdxml ; then
 659                 use_bsdxml=true
 660         else
 661                 AC_MSG_ERROR([*** neither libexpat not libbsdxml could be found ***])
 662         fi
 663 fi
 664
 665 if $use_expat; then
 666         with_xml=expat
 667         XML_CFLAGS=-DUSE_EXPAT_H
 668         XML_LIBS=-lexpat
 669 fi
 670 if $use_bsdxml; then
 671         with_xml=bsdxml
 672         XML_CFLAGS=-DUSE_BSDXML_H
 673         XML_LIBS=-lbsdxml
 674 fi
 675 AC_SUBST(XML_LIBS)
 676 AC_SUBST(XML_CFLAGS)
 677
 678 if $use_expat || $use_bsdxml; then
 679         HAVE_XML=yes
 680 fi
 681
 682 AM_CONDITIONAL(HAVE_XML, test "x$HAVE_XML" = "xyes")
 683
 684 #
 685 # GDBM
 686 #
 687 #
 688 # Check for dbm
 689 #
 690 AC_ARG_ENABLE(dbm,
 691         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 692         [case "${enableval}" in
 693                 yes) HAVE_DBM=yes ;;
 694                 no)  HAVE_DBM=no ;;
 695                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 696         esac],
 697         [HAVE_DBM=no])
 698
 699 AC_ARG_ENABLE(gdbm,
 700         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 701         [case "${enableval}" in
 702                 yes) HAVE_GDBM=yes ;;
 703                 no)  HAVE_GDBM=no ;;
 704                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 705         esac],
 706         [HAVE_GDBM=yes])
 707
 708 if test "x$HAVE_GDBM" = "xyes" ; then
 709     if test "x$HAVE_DBM" = "xyes" ; then
 710         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 711     fi
 712     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 713
 714     if ! $have_gdbm ; then
 715         AC_MSG_ERROR([*** libgdbm not found ***])
 716     fi
 717     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 718 else
 719     if test "x$HAVE_DBM" = "xyes" ; then
 720         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 721
 722         if ! $have_dbm ; then
 723             AC_MSG_ERROR([*** dbm not found ***])
 724         fi
 725         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 726     fi
 727 fi
 728 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 729 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 730
 731 #
 732 # libdaemon
 733 #
 734 AC_ARG_ENABLE(libdaemon,
 735         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 736         [case "${enableval}" in
 737                 yes) HAVE_LIBDAEMON=yes ;;
 738                 no)  HAVE_LIBDAEMON=no ;;
 739                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 740         esac],
 741         [HAVE_LIBDAEMON=yes])
 742
 743 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 744     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.11 ])
 745     AC_SUBST(LIBDAEMON_CFLAGS)
 746     AC_SUBST(LIBDAEMON_LIBS)
 747 fi
 748 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 749
 750 #
 751 # Python stuff
 752 #
 753 AC_ARG_ENABLE(python,
 754     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 755     [case "${enableval}" in
 756           yes) HAVE_PYTHON=yes ;;
 757           no)  HAVE_PYTHON=no ;;
 758           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 759     esac],[HAVE_PYTHON=yes])
 760
 761 HAVE_PYTHON_DBUS=no
 762 HAVE_PYGTK=no
 763
 764 if test "x$HAVE_PYTHON" = "xyes" ; then
 765     AM_PATH_PYTHON([2.4])
 766
 767     AC_ARG_ENABLE(pygtk,
 768         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 769         [case "${enableval}" in
 770                 yes) HAVE_PYGTK=yes ;;
 771                 no)  HAVE_PYGTK=no ;;
 772                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 773         esac],
 774         [HAVE_PYGTK=yes])
 775
 776     if test "x$HAVE_PYGTK" = "xyes" ; then
 777         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 778     fi
 779
 780
 781     if test "x$HAVE_DBUS" = "xyes" ; then
 782         AC_ARG_ENABLE(python-dbus,
 783             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 784             [case "${enableval}" in
 785                    yes) HAVE_PYTHON_DBUS=yes ;;
 786                    no)  HAVE_PYTHON_DBUS=no ;;
 787                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 788             esac],
 789             [HAVE_PYTHON_DBUS=yes])
 790
 791         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 792             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 793         fi
 794
 795         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 796         if test "x$HAVE_GDBM" = "xyes"; then
 797             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 798         fi
 799         if test "x$HAVE_DBM" = "xyes"; then
 800             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 801         fi
 802     fi
 803 fi
 804 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 805 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 806 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 807
 808 #
 809 # Check for mono stuff
 810 #
 811 HAVE_MONO=no
 812 if test "x$HAVE_DBUS" = "xyes" ; then
 813     AC_ARG_ENABLE(mono,
 814             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 815             [case "${enableval}" in
 816                     yes) HAVE_MONO=yes ;;
 817                     no)  HAVE_MONO=no ;;
 818                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 819             esac],
 820             [HAVE_MONO=yes])
 821
 822     if test "x$HAVE_MONO" = "xyes" ; then
 823         AC_PATH_PROG(MCS, mcs)
 824         if test "x$MCS" = "x" ; then
 825             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 826         fi
 827
 828         AC_PATH_PROG(GACUTIL, gacutil)
 829         if test "x$GACUTIL" = "x" ; then
 830             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 831         fi
 832
 833         AC_SUBST(MCS)
 834         AC_SUBST(GACUTIL)
 835     fi
 836 fi
 837 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 838
 839 #
 840 # Check for monodoc stuff
 841 #
 842 HAVE_MONODOC=no
 843 AC_ARG_ENABLE(monodoc,
 844         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 845         [case "${enableval}" in
 846                 yes) HAVE_MONODOC=yes ;;
 847                 no)  HAVE_MONODOC=no ;;
 848                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 849         esac],
 850         [HAVE_MONODOC=yes])
 851
 852 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 853         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 854         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 855
 856         AC_PATH_PROG(MONODOCER, monodocer)
 857         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 858
 859         AC_SUBST(MONODOC_DIR)
 860         AC_SUBST(MONODOCER)
 861         AC_SUBST(MDASSEMBLER)
 862 fi
 863 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 864
 865 #
 866 # Build autoipd?
 867 #
 868 AC_ARG_ENABLE(autoipd,
 869         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 870         [case "${enableval}" in
 871                 yes) ENABLE_AUTOIPD=yes ;;
 872                 no)  ENABLE_AUTOIPD=no ;;
 873                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 874         esac],
 875         [ENABLE_AUTOIPD=yes])
 876
 877 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 878
 879 #
 880 # Defining users and groups
 881 #
 882 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 883 if test -z "$with_avahi_user" ; then
 884     AVAHI_USER=avahi
 885 else
 886     AVAHI_USER=$with_avahi_user
 887 fi
 888 AC_SUBST(AVAHI_USER)
 889 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 890
 891 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 892 if test -z "$with_avahi_group" ; then
 893     AVAHI_GROUP=avahi
 894 else
 895     AVAHI_GROUP=$with_avahi_group
 896 fi
 897 AC_SUBST(AVAHI_GROUP)
 898 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 899
 900 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 901 if test -z "$with_avahi_priv_access_group" ; then
 902     AVAHI_PRIV_ACCESS_GROUP=netdev
 903 else
 904     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 905 fi
 906 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 907 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 908
 909 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autoipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 910 if test -z "$with_autoipd_user" ; then
 911     AVAHI_AUTOIPD_USER=avahi-autoipd
 912 else
 913     AVAHI_AUTOIPD_USER=$with_autoipd_user
 914 fi
 915 AC_SUBST(AVAHI_AUTOIPD_USER)
 916 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 917
 918 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 919 if test -z "$with_autoipd_group" ; then
 920     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 921 else
 922     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 923 fi
 924 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 925 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 926
 927 #
 928 # Avahi runtime dir
 929 #
 930 avahi_runtime_dir="${localstatedir}/run"
 931 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 932 AC_SUBST(avahi_runtime_dir)
 933 AC_SUBST(avahi_socket)
 934
 935 #
 936 # Avahi interfaces dir
 937 #
 938 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 939         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 940         AC_SUBST(interfacesdir)
 941 fi
 942
 943 #
 944 # Doxygen
 945 #
 946 DX_HTML_FEATURE(ON)
 947 DX_CHM_FEATURE(OFF)
 948 DX_CHI_FEATURE(OFF)
 949 DX_MAN_FEATURE(OFF)
 950 DX_RTF_FEATURE(OFF)
 951 DX_XML_FEATURE(ON)
 952 DX_PDF_FEATURE(OFF)
 953 DX_PS_FEATURE(OFF)
 954 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 955
 956 AC_ARG_ENABLE(core-docs,
 957         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 958 [case "${enableval}" in
 959   yes) ENABLE_CORE_DOCS=yes ;;
 960   no)  ENABLE_CORE_DOCS=no ;;
 961   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 962 esac],[ENABLE_CORE_DOCS=no])
 963
 964 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 965
 966 #
 967 # Build and Install man pages
 968 #
 969 AC_ARG_ENABLE(manpages,
 970         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 971 [case "${enableval}" in
 972   yes) manpages=yes ;;
 973   no)  manpages=no ;;
 974   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 975 esac],[manpages=yes])
 976
 977 if test x$manpages = xyes ; then
 978     #
 979     # XMLTOMAN manpage generation
 980     #
 981     AC_ARG_ENABLE(xmltoman,
 982     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 983     [case "${enableval}" in
 984       yes) xmltoman=yes ;;
 985       no)  xmltoman=no ;;
 986       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 987     esac],[xmltoman=yes])
 988
 989     if test x$xmltoman = xyes ; then
 990         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 991     fi
 992
 993     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 994         if ! test -e man/avahi-daemon.8 ; then
 995             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 996             exit 1
 997         fi
 998         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 999         xmltoman=no
1000     fi
1001 fi
1002 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
1003 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1004
1005 #
1006 # Conditionally compile test and example programs
1007 #
1008 AC_ARG_ENABLE(tests,
1009         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
1010         [case "${enableval}" in
1011                 yes) ENABLE_TESTS=yes ;;
1012                 no)  ENABLE_TESTS=no ;;
1013                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
1014         esac],
1015         [ENABLE_TESTS=no])
1016
1017 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
1018
1019 #
1020 # Optionally enable libdns_sd compatibility support
1021 #
1022 AC_ARG_ENABLE(compat-libdns_sd,
1023         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
1024         [case "${enableval}" in
1025                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
1026                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
1027                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
1028         esac],
1029         [ENABLE_COMPAT_LIBDNS_SD=no])
1030
1031 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
1032
1033 #
1034 # Optionally enable HOWL compatibility support
1035 #
1036 AC_ARG_ENABLE(compat-howl,
1037         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
1038         [case "${enableval}" in
1039                 yes) ENABLE_COMPAT_HOWL=yes ;;
1040                 no)  ENABLE_COMPAT_HOWL=no ;;
1041                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
1042         esac],
1043         [ENABLE_COMPAT_HOWL=no])
1044
1045 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
1046
1047
1048 # ==========================================================================
1049 AC_CONFIG_FILES([
1050 Makefile
1051 avahi-common/Makefile
1052 avahi-core/Makefile
1053 avahi-glib/Makefile
1054 avahi-gobject/Makefile
1055 avahi-qt/Makefile
1056 avahi-daemon/Makefile
1057 avahi-daemon/avahi-dbus.conf
1058 avahi-discover-standalone/Makefile
1059 avahi-client/Makefile
1060 initscript/Makefile
1061 initscript/debian/Makefile
1062 initscript/gentoo/Makefile
1063 initscript/archlinux/Makefile
1064 initscript/suse/Makefile
1065 initscript/fedora/Makefile
1066 initscript/mandriva/Makefile
1067 initscript/darwin/Makefile
1068 initscript/freebsd/Makefile
1069 initscript/slackware/Makefile
1070 avahi-dnsconfd/Makefile
1071 avahi-utils/Makefile
1072 avahi-python/Makefile
1073 avahi-python/avahi/Makefile
1074 avahi-python/avahi-discover/Makefile
1075 examples/Makefile
1076 common/Makefile
1077 man/Makefile
1078 tests/Makefile
1079 service-type-database/Makefile
1080 avahi-sharp/Makefile
1081 avahi-ui-sharp/Makefile
1082 avahi-compat-libdns_sd/Makefile
1083 avahi-compat-howl/Makefile
1084 avahi-compat-howl/samples/Makefile
1085 avahi-autoipd/Makefile
1086 avahi-ui/Makefile
1087 po/Makefile.in
1088 ])
1089 AC_OUTPUT
1090
1091 # ==========================================================================
1092 echo "
1093  ---{ $PACKAGE_NAME $VERSION }---
1094
1095     prefix:                                    ${prefix}
1096     sysconfdir:                                ${sysconfdir}
1097     localstatedir:                             ${localstatedir}
1098     avahi socket:                              ${avahi_socket}
1099     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
1100     dbus-1 version:                            ${DBUS_VERSION}
1101     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1102     C Compiler:                                ${CC}
1103     CFLAGS:                                    ${CFLAGS}
1104     Enable GLIB:                               ${HAVE_GLIB}
1105     Enable GLIB GObject:                       ${HAVE_GOBJECT}
1106     Enable GTK:                                ${HAVE_GTK}
1107     Enable D-Bus:                              ${HAVE_DBUS}
1108     With XML:                                  ${with_xml}
1109     Enable GDBM:                               ${HAVE_GDBM}
1110     Enable DBM:                                ${HAVE_DBM}
1111     Enable libdaemon:                          ${HAVE_LIBDAEMON}
1112     Enable Python:                             ${HAVE_PYTHON}
1113     Enable pygtk:                              ${HAVE_PYGTK}
1114     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
1115     Enable QT3:                                ${HAVE_QT3}
1116     Enable QT4:                                ${HAVE_QT4}
1117     Enable Mono:                               ${HAVE_MONO}
1118     Enable Monodoc:                            ${HAVE_MONODOC}
1119     Distribution/OS:                           ${with_distro}
1120     User for avahi-daemon:                     ${AVAHI_USER}
1121     Group for avahi-daemon:                    ${AVAHI_GROUP}
1122     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
1123     User for avahi-autoipd:                    ${AVAHI_AUTOIPD_USER}
1124     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
1125     Enable chroot():                           ${enable_chroot}
1126     Enable Linux inotify:                      ${have_inotify}
1127     Enable stack-smashing protection:          ${enable_ssp}
1128 "
1129
1130 BUILD_DAEMON="no   (You need libdaemon and expat/bsdxml!)"
1131
1132 if test "x$HAVE_XML" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
1133     BUILD_DAEMON=yes
1134 fi
1135
1136 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
1137
1138 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
1139     BUILD_PYTHON=yes
1140 fi
1141
1142 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
1143
1144 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
1145     BUILD_CLIENT=yes
1146 fi
1147
1148 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1149    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
1150 fi
1151 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1152    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
1153 fi
1154 if test "x$ENABLE_AUTOIPD" = "xyes" -a "x$HAVE_LIBDAEMON" != "xyes" ; then
1155    ENABLE_AUTOIPD="no   (You need libdaemon!)"
1156 fi
1157
1158 BUILD_UI="no"
1159 if test "x$HAVE_GTK" = "xyes" -a "x$BUILD_CLIENT" = "xyes" ; then
1160    BUILD_UI="yes"
1161 fi
1162
1163 BUILD_GOBJECT="no"
1164 if test "x$BUILD_CLIENT" = "xyes" -a "x$HAVE_GOBJECT" = "xyes" ; then
1165    BUILD_GOBJECT="yes"
1166 fi
1167
1168 echo "\
1169     Building libavahi-core              yes
1170     Building avahi-daemon:              ${BUILD_DAEMON}
1171     Building avahi-dnsconfd:            ${BUILD_DAEMON}
1172     Building libavahi-client:           ${BUILD_CLIENT}
1173     Building avahi-utils:               ${BUILD_CLIENT}
1174     Building avahi-python:              ${BUILD_PYTHON}
1175     Building libavahi-glib:             ${HAVE_GLIB}
1176     Building libavahi-gobject:          ${BUILD_GOBJECT}
1177     Building avahi-discover-standalone: ${HAVE_GTK}
1178     Building libavahi-qt3:              ${HAVE_QT3}
1179     Building libavahi-qt4:              ${HAVE_QT4}
1180     Building avahi-sharp:               ${HAVE_MONO}
1181     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
1182     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
1183     Building tests:                     ${ENABLE_TESTS}
1184     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
1185     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
1186     Building libavahi-ui:               ${BUILD_UI}
1187 "