git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38
  39 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  40     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  41     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  42 fi
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AC_PROG_CXX
  47 AC_GNU_SOURCE
  48 AC_PROG_CPP
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AC_PROG_GCC_TRADITIONAL
  53
  54 # libtool stuff
  55 AC_PROG_LIBTOOL
  56
  57 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  58
  59 #
  60 # Host specific stuffs
  61 #
  62 case "$host" in
  63   *-netbsd* | *-knetbsd*-gnu)
  64     AC_DEFINE([NETBSD],[],[ Support for NetBSD])
  65     avahi_platform=netbsd
  66     ;;
  67   *-openbsd*)
  68     AC_DEFINE([OPENBSD],[],[ Support for OpenBSD])
  69     avahi_platform=openbsd
  70     ;;
  71   *-solaris*)
  72     AC_DEFINE([SOLARIS],[],[ Support for Sun Solaris])
  73     avahi_platform=solaris
  74     ;;
  75   *-linux*)
  76     AC_DEFINE([LINUX],[],[ Support for GNU/Linux])
  77     AC_DEFINE([HAVE_NETLINK],[],[ Support for netlink.h])
  78     avahi_platform=linux
  79     ;;
  80   *-freebsd* | *-kfreebsd*-gnu)
  81     AC_DEFINE([FREEBSD],[],[ Support for FreeBSD])
  82     avahi_platform=freebsd
  83     ;;
  84   *-apple-darwin*)
  85     AC_DEFINE([DARWIN],[],[ Support for AppleDarwin])
  86     avahi_platform=darwin
  87     ;;
  88 esac
  89
  90 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$avahi_platform" = xlinux ])
  91
  92 #
  93 # Detecting the linux distribution for specific things like init scripts.
  94 #
  95 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
  96 if test "z$with_distro" = "z"; then
  97     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  98     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  99     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 100     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 101 fi
 102 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 103
 104 if test "z$with_distro" = "z"; then
 105     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 106     exit 1
 107 else
 108 case $with_distro in
 109     debian|gentoo|archlinux|suse|none)
 110      ;;
 111     *)
 112      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 113      ;;
 114 esac
 115 fi
 116
 117 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 118 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 119 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 120 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 121
 122 test_gcc_flag() {
 123     AC_LANG_CONFTEST([int main() {}])
 124     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 125     ret=$?
 126     rm -f conftest.o
 127     return $ret
 128 }
 129
 130 # If using GCC specify some additional parameters
 131 if test "x$GCC" = "xyes" ; then
 132
 133     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
 134
 135     # Test whether rtnetlink.h can be included when compiled with -std=c99
 136     # some distributions (e.g. archlinux) have broken headers that dont
 137     # define __u64 with -std=c99
 138     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 139     OLDCFLAGS="$CFLAGS"
 140     CFLAGS="-std=c99"
 141     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 142         use_stdc99=yes, use_stdc99=no)
 143
 144     if test x"$use_stdc99" = xyes; then
 145         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 146         AC_MSG_RESULT([yes])
 147     else
 148         AC_MSG_RESULT([no])
 149     fi
 150
 151     CFLAGS="$OLDCFLAGS"
 152
 153     for flag in $DESIRED_FLAGS ; do
 154         AC_MSG_CHECKING([whether $CC accepts $flag])
 155         if test_gcc_flag $flag ; then
 156            CFLAGS="$CFLAGS $flag"
 157            AC_MSG_RESULT([yes])
 158         else
 159            AC_MSG_RESULT([no])
 160         fi
 161     done
 162 fi
 163
 164 # Checks for header files.
 165 AC_HEADER_STDC
 166 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 167
 168 # Checks for typedefs, structures, and compiler characteristics.
 169 AC_C_CONST
 170 AC_TYPE_SIZE_T
 171 AC_HEADER_TIME
 172 AC_HEADER_SYS_WAIT
 173
 174 # Checks for library functions.
 175 AC_FUNC_MEMCMP
 176 AC_FUNC_SELECT_ARGTYPES
 177 AC_FUNC_MALLOC
 178 AC_FUNC_REALLOC
 179 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp])
 180
 181 AC_FUNC_CHOWN
 182 AC_FUNC_STAT
 183 AC_TYPE_MODE_T
 184 AC_TYPE_PID_T
 185
 186 # Check for pkg-config manually first, as if its not installed the
 187 # PKG_PROG_PKG_CONFIG macro won't be defined.
 188 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 189
 190 if test x"$have_pkg_config" == xno; then
 191     AC_MSG_ERROR(pkg-config is required to install this program)
 192 fi
 193
 194 PKG_PROG_PKG_CONFIG
 195
 196 #
 197 # Check for GLIB 2.0
 198 #
 199 AC_ARG_ENABLE(glib,
 200         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 201         [case "${enableval}" in
 202                 yes) HAVE_GLIB=yes ;;
 203                 no)  HAVE_GLIB=no ;;
 204                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 205         esac],
 206         [HAVE_GLIB=yes])
 207
 208 if test "x$HAVE_GLIB" = "xyes" ; then
 209         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 210         AC_SUBST(GLIB20_CFLAGS)
 211         AC_SUBST(GLIB20_LIBS)
 212 fi
 213 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 214
 215 #
 216 # Check for Qt 3
 217 #
 218 AC_ARG_ENABLE(qt3,
 219         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 220         [case "${enableval}" in
 221                 yes) HAVE_QT3=yes ;;
 222                 no)  HAVE_QT3=no ;;
 223                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 224         esac],
 225         [HAVE_QT3=yes])
 226
 227 if test "x$HAVE_QT3" = "xyes" ; then
 228         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 229         AC_SUBST(QT3_CFLAGS)
 230         AC_SUBST(QT3_LIBS)
 231             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 232         MOC_QT3="no"
 233             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 234                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 235                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 236         AC_SUBST(MOC_QT3)
 237 fi
 238 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 239
 240 #
 241 # Check for Qt 4
 242 #
 243 AC_ARG_ENABLE(qt4,
 244         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 245         [case "${enableval}" in
 246                 yes) HAVE_QT4=yes ;;
 247                 no)  HAVE_QT4=no ;;
 248                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 249         esac],
 250         [HAVE_QT4=yes])
 251
 252 if test "x$HAVE_QT4" = "xyes" ; then
 253         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 254         AC_SUBST(QT4_CFLAGS)
 255         AC_SUBST(QT4_LIBS)
 256             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 257         MOC_QT4="no"
 258             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 259                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 260                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 261         AC_SUBST(MOC_QT4)
 262 fi
 263 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 264
 265 #
 266 # Check for GTK+
 267 #
 268 AC_ARG_ENABLE(gtk,
 269         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 270         [case "${enableval}" in
 271                 yes) HAVE_GTK=yes ;;
 272                 no)  HAVE_GTK=no ;;
 273                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 274         esac],
 275         [HAVE_GTK=yes])
 276
 277 if test "x$HAVE_GTK" = "xyes" ; then
 278         # Check for GTK 2.0
 279         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 280         AC_SUBST(GTK20_CFLAGS)
 281         AC_SUBST(GTK20_LIBS)
 282
 283         # Check for GLADE 2.0
 284         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 285         AC_SUBST(GLADE20_CFLAGS)
 286         AC_SUBST(GLADE20_LIBS)
 287 fi
 288 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 289
 290
 291
 292 #
 293 # D-BUS
 294 #
 295 AC_ARG_ENABLE(dbus,
 296         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 297         [case "${enableval}" in
 298                 yes) HAVE_DBUS=yes ;;
 299                 no)  HAVE_DBUS=no ;;
 300                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 301         esac],
 302         [HAVE_DBUS=yes])
 303
 304 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 305 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 306
 307 if test "x$HAVE_DBUS" = "xyes" ; then
 308     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 309
 310     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 311     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 312     AC_SUBST(DBUS_CFLAGS)
 313     AC_SUBST(DBUS_LIBS)
 314
 315     if ! test -z "$with_dbus_sys" ; then
 316         DBUS_SYS_DIR="$with_dbus_sys"
 317     else
 318         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 319     fi
 320     AC_SUBST(DBUS_SYS_DIR)
 321
 322     if ! test -z "$with_dbus_system_address" ; then
 323         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 324     else
 325         # This is ugly, but D-BUS doesn't export this address for us
 326         # so we have to guess, pretty much all setups i've seen have
 327         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 328         # /var/run upstream so we will try guess first then default
 329         # to /var/run/dbus
 330
 331         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 332         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket"
 333         for sock in $TRY_SOCKETS; do
 334             if test -S $sock; then
 335                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 336             fi
 337         done
 338     fi
 339     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 340
 341 fi
 342 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 343
 344 #
 345 # Expat
 346 #
 347 AC_ARG_ENABLE(expat,
 348         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 349         [case "${enableval}" in
 350                 yes) HAVE_EXPAT=yes ;;
 351                 no)  HAVE_EXPAT=no ;;
 352                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 353         esac],
 354         [HAVE_EXPAT=yes])
 355
 356 if test "x$HAVE_EXPAT" = "xyes" ; then
 357     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 358
 359     if ! $have_expat ; then
 360         AC_MSG_ERROR([*** libexpat not found ***])
 361     fi
 362 fi
 363 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 364
 365 #
 366 # libdaemon
 367 #
 368 AC_ARG_ENABLE(libdaemon,
 369         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 370         [case "${enableval}" in
 371                 yes) HAVE_LIBDAEMON=yes ;;
 372                 no)  HAVE_LIBDAEMON=no ;;
 373                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 374         esac],
 375         [HAVE_LIBDAEMON=yes])
 376
 377 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 378     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 379     AC_SUBST(LIBDAEMON_CFLAGS)
 380     AC_SUBST(LIBDAEMON_LIBS)
 381 fi
 382 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 383
 384 #
 385 # Python stuff
 386 #
 387 AC_ARG_ENABLE(python,
 388     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 389     [case "${enableval}" in
 390           yes) HAVE_PYTHON=yes ;;
 391           no)  HAVE_PYTHON=no ;;
 392           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 393     esac],[HAVE_PYTHON=yes])
 394
 395 HAVE_PYTHON_DBUS=no
 396 HAVE_PYGTK=no
 397
 398 if test "x$HAVE_PYTHON" = "xyes" ; then
 399     AM_PATH_PYTHON([2.4])
 400
 401     AC_ARG_ENABLE(pygtk,
 402         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 403         [case "${enableval}" in
 404                 yes) HAVE_PYGTK=yes ;;
 405                 no)  HAVE_PYGTK=no ;;
 406                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 407         esac],
 408         [HAVE_PYGTK=yes])
 409
 410     if test "x$HAVE_PYGTK" = "xyes" ; then
 411         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 412     fi
 413
 414
 415     AC_ARG_ENABLE(python-dbus,
 416         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 417         [case "${enableval}" in
 418                 yes) HAVE_PYTHON_DBUS=yes ;;
 419                 no)  HAVE_PYTHON_DBUS=no ;;
 420                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 421         esac],
 422         [HAVE_PYTHON_DBUS=yes])
 423
 424     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 425         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 426     fi
 427
 428     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 429     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 430 fi
 431 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 432 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 433 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 434
 435 #
 436 # Check for mono stuff
 437 #
 438 AC_ARG_ENABLE(mono,
 439         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 440         [case "${enableval}" in
 441                 yes) HAVE_MONO=yes ;;
 442                 no)  HAVE_MONO=no ;;
 443                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 444         esac],
 445         [HAVE_MONO=yes])
 446
 447 AC_ARG_ENABLE(monodoc,
 448         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 449         [case "${enableval}" in
 450                 yes) HAVE_MONODOC=yes ;;
 451                 no)  HAVE_MONODOC=no ;;
 452                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 453         esac],
 454         [HAVE_MONODOC=yes])
 455
 456 if test "x$HAVE_MONO" = "xyes" ; then
 457         AC_PATH_PROG(MCS, mcs)
 458         if test "x$MCS" = "x" ; then
 459                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 460         fi
 461
 462         AC_PATH_PROG(GACUTIL, gacutil)
 463         if test "x$GACUTIL" = "x" ; then
 464                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 465         fi
 466
 467         AC_SUBST(MCS)
 468         AC_SUBST(GACUTIL)
 469 fi
 470 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 471
 472 #
 473 # Check for monodoc stuff
 474 #
 475 if test "x$HAVE_MONODOC" = "xyes" ; then
 476         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 477         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 478
 479         AC_PATH_PROG(MONODOCER, monodocer)
 480         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 481
 482         AC_SUBST(MONODOC_DIR)
 483         AC_SUBST(MONODOCER)
 484         AC_SUBST(MDASSEMBLER)
 485 fi
 486 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 487
 488 #
 489 # Defining Avahi User and Group.
 490 #
 491 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 492 if test -z "$with_avahi_user" ; then
 493     AVAHI_USER=avahi
 494 else
 495     AVAHI_USER=$with_avahi_user
 496 fi
 497 AC_SUBST(AVAHI_USER)
 498 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 499
 500 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 501 if test -z "$with_avahi_group" ; then
 502     AVAHI_GROUP=avahi
 503 else
 504     AVAHI_GROUP=$with_avahi_group
 505 fi
 506 AC_SUBST(AVAHI_GROUP)
 507 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 508
 509 #
 510 # Avahi runtime dir
 511 #
 512 avahi_runtime_dir="${localstatedir}/run"
 513 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 514 AC_SUBST(avahi_runtime_dir)
 515 AC_SUBST(avahi_socket)
 516
 517
 518 #
 519 # Avahi interfaces dir
 520 #
 521 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 522         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 523         AC_SUBST(interfacesdir)
 524 fi
 525
 526
 527 #
 528 # Doxygen
 529 #
 530 DX_HTML_FEATURE(ON)
 531 DX_CHM_FEATURE(OFF)
 532 DX_CHI_FEATURE(OFF)
 533 DX_MAN_FEATURE(OFF)
 534 DX_RTF_FEATURE(OFF)
 535 DX_XML_FEATURE(OFF)
 536 DX_PDF_FEATURE(OFF)
 537 DX_PS_FEATURE(OFF)
 538 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 539
 540 #
 541 # XMLTOMAN manpage generation
 542 #
 543 AC_ARG_ENABLE(xmltoman,
 544         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 545 [case "${enableval}" in
 546   yes) xmltoman=yes ;;
 547   no)  xmltoman=no ;;
 548   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 549 esac],[xmltoman=yes])
 550
 551 if test x$xmltoman = xyes ; then
 552     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 553
 554     if test x$have_xmltoman = xno ; then
 555         if ! test -e man/avahi-daemon.8 ; then
 556             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 557             exit 1
 558         fi
 559         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 560         xmltoman=no
 561     fi
 562 fi
 563
 564 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 565
 566 # ==========================================================================
 567 AC_CONFIG_FILES([
 568 Makefile
 569 avahi-common/Makefile
 570 avahi-core/Makefile
 571 avahi-glib/Makefile
 572 avahi-qt/Makefile
 573 avahi-daemon/Makefile
 574 avahi-daemon/avahi-dbus.conf
 575 avahi-discover-standalone/Makefile
 576 avahi-client/Makefile
 577 initscript/Makefile
 578 initscript/debian/Makefile
 579 initscript/gentoo/Makefile
 580 initscript/archlinux/Makefile
 581 initscript/suse/Makefile
 582 avahi-dnsconfd/Makefile
 583 avahi-utils/Makefile
 584 avahi-utils/avahi/Makefile
 585 examples/Makefile
 586 common/Makefile
 587 man/Makefile
 588 tests/Makefile
 589 service-type-database/Makefile
 590 avahi-sharp/Makefile
 591 avahi-compat-libdns_sd/Makefile
 592 ])
 593 AC_OUTPUT
 594
 595 # ==========================================================================
 596 echo "
 597  ---{ $PACKAGE_NAME $VERSION }---
 598
 599     prefix:                 ${prefix}
 600     sysconfdir:             ${sysconfdir}
 601     localstatedir:          ${localstatedir}
 602     avahi socket:           ${avahi_socket}
 603     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 604     dbus-1 version:         `pkg-config dbus-1 --modversion`
 605     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 606     compiler:               ${CC}
 607     cflags:                 ${CFLAGS}
 608     Enable GLIB:            ${HAVE_GLIB}
 609     Enable GTK:             ${HAVE_GTK}
 610     Enable D-BUS:           ${HAVE_DBUS}
 611     Enable Expat:           ${HAVE_EXPAT}
 612     Enable libdaemon:       ${HAVE_LIBDAEMON}
 613     Enable Python:          ${HAVE_PYTHON}
 614     Enable pygtk:           ${HAVE_PYGTK}
 615     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 616     Enable QT3:             ${HAVE_QT3}
 617     Enable QT4:             ${HAVE_QT4}
 618     Enable Mono:            ${HAVE_MONO}
 619     Linux Distro:           ${with_distro}
 620     User for Avahi:         ${AVAHI_USER}
 621     Group for Avahi:        ${AVAHI_GROUP}
 622 "
 623
 624 BUILD_DAEMON="no (!)"
 625
 626 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 627     BUILD_DAEMON=yes
 628 fi
 629
 630 BUILD_UTILS="no (!)"
 631
 632 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 633     BUILD_UTILS=yes
 634 fi
 635
 636 BUILD_CLIENT="no (!)"
 637
 638 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 639     BUILD_CLIENT=yes
 640 fi
 641
 642 echo "
 643     Building libavahi-core              yes
 644     Building avahi-daemon:              ${BUILD_DAEMON}
 645     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 646     Building avahi-utils:               ${BUILD_UTILS}
 647     Building libavahi-glib:             ${HAVE_GLIB}
 648     Building libavahi-client:           ${BUILD_CLIENT}
 649     Building avahi-discover-standalone: ${HAVE_GTK}
 650     Building libavahi-qt3:              ${HAVE_QT3}
 651     Building libavahi-qt4:              ${HAVE_QT4}
 652     Building avahi-sharp:               ${HAVE_MONO}
 653     Building avahi-compat-libdns_sd:    ${BUILD_CLIENT}
 654 "