git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.21],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [7:5:4])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [5:3:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:3:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_GOBJECT_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  37 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  38 AC_SUBST(LIBAVAHI_UI_VERSION_INFO, [0:2:0])
  39
  40 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  41 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  42 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  43 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 # Checks for programs.
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AC_GNU_SOURCE
  54 AC_PROG_CPP
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_GCC_TRADITIONAL
  59
  60 AM_PROG_CC_C_O
  61
  62 # -fstack-protector
  63 AC_ARG_ENABLE([stack-protector],
  64     [AS_HELP_STRING([--disable-stack-protector],
  65         [Disable GCC's/libc's stack-smashing protection])],
  66     [case "${enableval}" in
  67          yes) enable_ssp=yes ;;
  68           no) enable_ssp=no ;;
  69            *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;
  70      esac],
  71     [enable_ssp=yes])
  72
  73 if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then
  74     AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])
  75     enable_ssp=no
  76 fi
  77
  78 if test x"$enable_ssp" = x"yes"; then
  79     # Check for broken ssp in libc: http://www.avahi.org/ticket/105
  80     # libc's brokenness will get in the way regardless of whether -lssp is
  81     # provided, but provide it anyway (otherwise non-libc ssp would wrongly
  82     # break here)
  83
  84     # Get -lssp if it exists
  85     GCC_STACK_PROTECT_LIB
  86
  87     AC_MSG_CHECKING([whether stack-smashing protection is available])
  88     ssp_old_cflags="$CFLAGS"
  89     ssp_old_ldflags="$LDFLAGS"
  90     CFLAGS="$CFLAGS -Werror -fstack-protector-all -fPIC"
  91     LDFLAGS="$LDFLAGS -Wl,-z,defs"
  92     cat confdefs.h > conftest.c
  93     cat >>conftest.c <<_ACEOF
  94 void test_broken_ssp(c)
  95     const char *c;
  96 {
  97     char arr[[123]], *p; /* beware of possible double-braces if copying this */
  98     for (p = arr; *c; ++p) {
  99         *p = *c;
 100         ++c;
 101     }
 102 }
 103 _ACEOF
 104     rm -f conftest.o
 105
 106     if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then
 107         AC_MSG_RESULT([yes])
 108         AC_MSG_CHECKING([whether stack-smashing protection is buggy])
 109         if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then
 110             AC_MSG_RESULT([no])
 111         else
 112             AC_MSG_RESULT([yes])
 113             enable_ssp=no
 114         fi
 115     else
 116         AC_MSG_RESULT([no])
 117     fi
 118
 119     rm -f conftest.c conftest.o conftest.so
 120
 121     CFLAGS="$ssp_old_cflags"
 122     LDFLAGS="$ssp_old_ldflags"
 123 fi
 124
 125 if test x"$enable_ssp" = x"yes"; then
 126     # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice
 127     GCC_STACK_PROTECT_CC
 128
 129     AC_LANG_PUSH([C++])
 130     GCC_STACK_PROTECT_CXX
 131     AC_LANG_POP([C++])
 132     # XXX: Update the enable_ssp value now for output later?
 133 fi
 134
 135 # libtool stuff
 136 AC_PROG_LIBTOOL
 137
 138 AC_CACHE_CHECK([whether the C++ compiler works], [avahi_cv_sys_cxx_works], [
 139     AC_LANG_PUSH([C++])
 140     AC_COMPILE_IFELSE([int main() { return 0; }], [avahi_cv_sys_cxx_works=yes],
 141         [avahi_cv_sys_cxx_works=no])
 142     AC_LANG_POP([C++])
 143     ])
 144 [ if [ "x$avahi_cv_sys_cxx_works" = "xno" ]; then ]
 145     AC_MSG_FAILURE([The C++ compiler does not work])
 146 [ fi ]
 147
 148 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
 149
 150 #
 151 # Check for netlink.h
 152 #
 153 AC_CHECK_HEADER(linux/netlink.h,
 154 HAVE_NETLINK=yes
 155 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
 156 , [], [
 157 #include <sys/socket.h>
 158 #include <asm/types.h>
 159 ])
 160
 161 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
 162
 163 #
 164 # Check for net/route.h
 165 #
 166 AC_CHECK_HEADER(net/route.h,
 167 HAVE_PF_ROUTE=yes
 168 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
 169 , [], [
 170 #include <sys/types.h>
 171 #include <sys/socket.h>
 172 ])
 173
 174 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
 175
 176 #
 177 # Check for sys/filio.h; needed for FIONREAD on Solaris
 178 #
 179 AC_CHECK_HEADER(sys/filio.h,
 180 HAVE_SYS_FILIO_H=yes
 181 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 182 , [], [
 183 ])
 184
 185 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 186
 187 #
 188 # Check for sys/sysctl.h; not present on Solaris
 189 #
 190 AC_CHECK_HEADER(sys/sysctl.h,
 191 HAVE_SYS_SYSCTL=yes
 192 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 193 , [], [
 194 #include <sys/types.h>
 195 #include <sys/socket.h>
 196 #include <sys/param.h>
 197 ])
 198
 199 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 200
 201 #
 202 # Check for lifconf struct; only present on Solaris
 203 #
 204 AC_MSG_CHECKING(for struct lifconf)
 205 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 206 [AC_TRY_COMPILE(
 207 [#include <sys/socket.h>
 208 #include <net/if.h>
 209 ],[sizeof (struct lifconf);],
 210 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 211 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 212 if test $avahi_cv_has_struct_lifconf = yes; then
 213     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 214 fi
 215
 216 #
 217 # Check for struct ip_mreqn
 218 #
 219 AC_MSG_CHECKING(for struct ip_mreqn)
 220 AC_TRY_COMPILE([#include <netinet/in.h>], [
 221         struct ip_mreqn mreq;
 222         mreq.imr_address.s_addr = 0;
 223 ], [
 224         # Yes, we have it...
 225         AC_MSG_RESULT(yes)
 226         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 227 ], [
 228         # We'll just have to try and use struct ip_mreq
 229         AC_MSG_RESULT(no)
 230         AC_MSG_CHECKING(for struct ip_mreq)
 231         AC_TRY_COMPILE([#include <netinet/in.h>], [
 232                 struct ip_mreq mreq;
 233                 mreq.imr_interface.s_addr = 0;
 234         ], [
 235                 # Yes, we have it...
 236                 AC_MSG_RESULT(yes)
 237                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 238         ], [
 239                 # No multicast support
 240                         AC_MSG_RESULT(no)
 241         ])
 242 ])
 243
 244 #
 245 # Detecting the linux distribution for specific things like init scripts.
 246 #
 247 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 248 if test "z$with_distro" = "z"; then
 249     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 250     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 251     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 252     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 253     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 254     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 255     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 256     if test "z$with_distro" = "z"; then
 257         with_distro=`uname -s`
 258     fi
 259 fi
 260 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 261
 262 case $with_distro in
 263     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 264      ;;
 265     netbsd)
 266      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 267      ;;
 268     linux)
 269      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 270      ;;
 271     *)
 272      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 273      ;;
 274 esac
 275
 276 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 277 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 278 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 279 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 280 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 281 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 282 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 283 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 284 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 285 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 286
 287 test_gcc_flag() {
 288     AC_LANG_CONFTEST([int main() {}])
 289     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 290     ret=$?
 291     rm -f conftest.o
 292     return $ret
 293 }
 294
 295 # If using GCC specify some additional parameters
 296 if test "x$GCC" = "xyes" ; then
 297
 298     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -fPIC"
 299
 300     if test "x$HAVE_NETLINK" = "xyes" ; then
 301         # Test whether rtnetlink.h can be included when compiled with -std=c99
 302         # some distributions (e.g. archlinux) have broken headers that dont
 303         # define __u64 with -std=c99
 304         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 305         OLDCFLAGS="$CFLAGS"
 306         CFLAGS="-std=c99"
 307         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 308             use_stdc99=yes, use_stdc99=no)
 309
 310         if test x"$use_stdc99" = xyes; then
 311             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 312             AC_MSG_RESULT([yes])
 313         else
 314             AC_MSG_RESULT([no])
 315         fi
 316
 317         CFLAGS="$OLDCFLAGS"
 318     else
 319         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 320     fi
 321
 322     for flag in $DESIRED_FLAGS ; do
 323         AC_MSG_CHECKING([whether $CC accepts $flag])
 324         if test_gcc_flag $flag ; then
 325            CFLAGS="$CFLAGS $flag"
 326            AC_MSG_RESULT([yes])
 327         else
 328            AC_MSG_RESULT([no])
 329         fi
 330     done
 331 fi
 332
 333 # Checks for header files.
 334 AC_HEADER_STDC
 335 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 336 AC_HEADER_STDBOOL
 337
 338 # Checks for typedefs, structures, and compiler characteristics.
 339 AC_C_CONST
 340 AC_TYPE_SIZE_T
 341 AC_HEADER_TIME
 342 AC_HEADER_SYS_WAIT
 343
 344  # Solaris stuff
 345  AC_SEARCH_LIBS([inet_ntop],[nsl])
 346  AC_SEARCH_LIBS([recv],[socket])
 347  AC_CHECK_DECL([CMSG_SPACE],,CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500 -D__EXTENSIONS__")
 348
 349 # Checks for library functions.
 350 AC_FUNC_MEMCMP
 351 AC_FUNC_SELECT_ARGTYPES
 352 AC_FUNC_MALLOC
 353 AC_FUNC_REALLOC
 354 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 355
 356 AC_FUNC_CHOWN
 357 AC_FUNC_STAT
 358 AC_TYPE_MODE_T
 359 AC_TYPE_PID_T
 360
 361 AC_CHECK_DECLS(environ)
 362
 363 enable_chroot=yes
 364 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 365 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 366 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 367
 368 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 369
 370 if test "x$enable_chroot" = "xyes" ; then
 371    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 372 fi
 373
 374 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 375 if test "x$HAVE_DLOPEN" = "xyes" ; then
 376     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 377 fi
 378 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 379
 380 have_inotify=no
 381 AC_CHECK_HEADERS([linux/inotify.h], [have_inotify=yes])
 382 AC_CHECK_HEADERS([sys/inotify.h], [have_inotify=yes])
 383
 384 AM_CONDITIONAL(HAVE_INOTIFY, test "x$have_inotify" = "xyes")
 385
 386 if test "x$have_inotify" = "xyes" ; then
 387    AC_DEFINE([HAVE_INOTIFY], 1, [Enable Linux inotify() usage])
 388 fi
 389
 390 have_kqueue=yes
 391 AC_CHECK_FUNCS([kqueue],,have_kqueue=no)
 392
 393 AM_CONDITIONAL(HAVE_KQUEUE, test "x$have_kqueue" = "xyes")
 394
 395 if test "x$have_kqueue" = "xyes" ; then
 396     AC_DEFINE([HAVE_KQUEUE], 1, [Enable BSD kqueue() usage])
 397 fi
 398
 399 AM_GNU_GETTEXT([external])
 400
 401 IT_PROG_INTLTOOL([0.35.0])
 402 GETTEXT_PACKAGE=avahi
 403 AC_SUBST([GETTEXT_PACKAGE])
 404 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 405 AM_GLIB_GNU_GETTEXT
 406
 407 avahilocaledir='${prefix}/${DATADIRNAME}/locale'
 408 AC_SUBST(avahilocaledir)
 409
 410
 411 # Check for pkg-config manually first, as if its not installed the
 412 # PKG_PROG_PKG_CONFIG macro won't be defined.
 413 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 414
 415 if test x"$have_pkg_config" = "xno"; then
 416     AC_MSG_ERROR(pkg-config is required to install this program)
 417 fi
 418
 419 PKG_PROG_PKG_CONFIG
 420
 421 #
 422 # Check for GLIB 2.0
 423 #
 424 AC_ARG_ENABLE(glib,
 425         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 426         [case "${enableval}" in
 427                 yes) HAVE_GLIB=yes ;;
 428                 no)  HAVE_GLIB=no ;;
 429                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 430         esac],
 431         [HAVE_GLIB=yes])
 432
 433 if test "x$HAVE_GLIB" = "xyes" ; then
 434         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 435         AC_SUBST(GLIB20_CFLAGS)
 436         AC_SUBST(GLIB20_LIBS)
 437 fi
 438 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 439
 440 #
 441 # Check for GLIB's gobject 2.0
 442 #
 443 AC_ARG_ENABLE(gobject,
 444         AS_HELP_STRING([--disable-gobject],[Disable use of GLib GObject]),
 445         [case "${enableval}" in
 446                 yes) HAVE_GOBJECT=yes ;;
 447                 no)  HAVE_GOBJECT=no ;;
 448                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gobject) ;;
 449         esac],
 450         [HAVE_GOBJECT=yes])
 451
 452 if test "x$HAVE_GOBJECT" = "xyes" ; then
 453         PKG_CHECK_MODULES(GOBJECT, [ glib-2.0 >= 2.4.0 gobject-2.0 ])
 454         AC_SUBST(GOBJECT_CFLAGS)
 455         AC_SUBST(GOBJECT_LIBS)
 456 fi
 457 AM_CONDITIONAL(HAVE_GOBJECT, test "x$HAVE_GOBJECT" = "xyes")
 458
 459 #
 460 # Check for Qt 3
 461 #
 462 AC_ARG_ENABLE(qt3,
 463         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 464         [case "${enableval}" in
 465                 yes) HAVE_QT3=yes ;;
 466                 no)  HAVE_QT3=no ;;
 467                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 468         esac],
 469         [HAVE_QT3=yes])
 470
 471 if test "x$HAVE_QT3" = "xyes" ; then
 472         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 473         AC_SUBST(QT3_CFLAGS)
 474         AC_SUBST(QT3_LIBS)
 475             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 476         MOC_QT3="no"
 477             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 478                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 479                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 480         AC_SUBST(MOC_QT3)
 481 fi
 482 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 483
 484 #
 485 # Check for Qt 4
 486 #
 487 AC_ARG_ENABLE(qt4,
 488         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 489         [case "${enableval}" in
 490                 yes) HAVE_QT4=yes ;;
 491                 no)  HAVE_QT4=no ;;
 492                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 493         esac],
 494         [HAVE_QT4=yes])
 495
 496 if test "x$HAVE_QT4" = "xyes" ; then
 497         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 498         AC_SUBST(QT4_CFLAGS)
 499         AC_SUBST(QT4_LIBS)
 500             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 501         MOC_QT4="no"
 502             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 503                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 504                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 505         AC_SUBST(MOC_QT4)
 506 fi
 507 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 508
 509 #
 510 # Check for GTK+
 511 #
 512 AC_ARG_ENABLE(gtk,
 513         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 514         [case "${enableval}" in
 515                 yes) HAVE_GTK=yes ;;
 516                 no)  HAVE_GTK=no ;;
 517                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 518         esac],
 519         [HAVE_GTK=yes])
 520
 521 if test "x$HAVE_GTK" = "xyes" ; then
 522         # Check for GTK 2.0
 523         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 524         AC_SUBST(GTK20_CFLAGS)
 525         AC_SUBST(GTK20_LIBS)
 526
 527         # Check for GLADE 2.0
 528         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 529         AC_SUBST(GLADE20_CFLAGS)
 530         AC_SUBST(GLADE20_LIBS)
 531 fi
 532 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 533
 534 #
 535 # D-Bus
 536 #
 537 AC_ARG_ENABLE(dbus,
 538         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 539         [case "${enableval}" in
 540                 yes) HAVE_DBUS=yes ;;
 541                 no)  HAVE_DBUS=no ;;
 542                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 543         esac],
 544         [HAVE_DBUS=yes])
 545
 546 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 547 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 548
 549 DBUS_VERSION="Disabled"
 550 DBUS_SYS_DIR="Disabled"
 551 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 552 if test "x$HAVE_DBUS" = "xyes" ; then
 553     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 554
 555     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 556
 557     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 558     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 559     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 560     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 561     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 562         DBUS_VERSION_MAJOR="0"
 563     fi
 564     if test "z$DBUS_VERSION_MINOR" = "z"; then
 565         DBUS_VERSION_MINOR="0"
 566     fi
 567     if test "z$DBUS_VERSION_MICRO" = "z"; then
 568         DBUS_VERSION_MICRO="0"
 569     fi
 570
 571     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 572         echo "Error: Couldn't determine the version of your D-Bus package."
 573         echo "  This is probably an error in this script, please report it"
 574         echo "  along with the following information:"
 575         echo "      Base D-Buss version ='$DBUS_VERSION'"
 576         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 577         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 578         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 579         exit 1
 580     else
 581         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 582         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 583         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 584         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 585     fi
 586
 587     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 588     AC_SUBST(DBUS_CFLAGS)
 589     AC_SUBST(DBUS_LIBS)
 590
 591     if ! test -z "$with_dbus_sys" ; then
 592         DBUS_SYS_DIR="$with_dbus_sys"
 593     else
 594         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 595     fi
 596     AC_SUBST(DBUS_SYS_DIR)
 597
 598     if ! test -z "$with_dbus_system_address" ; then
 599         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 600     else
 601         # This is ugly, but D-Bus doesn't export this address for us
 602         # so we have to guess, pretty much all setups i've seen have
 603         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 604         # /var/run upstream so we will try guess first then default
 605         # to /var/run/dbus.
 606
 607         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 608         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 609         for sock in $TRY_SOCKETS; do
 610             if test -S $sock; then
 611                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 612             fi
 613         done
 614     fi
 615     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 616
 617     SAVED_LIBS="$LIBS"
 618     LIBS="$LIBS $DBUS_LIBS"
 619     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 620     LIBS="$SAVED_LIBS"
 621 fi
 622 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 623
 624 #
 625 # Expat
 626 #
 627 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[expat/bsdxml/none]],[XML library to use]))
 628 use_expat=false
 629 use_bsdxml=false
 630
 631 # See what we have
 632 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 633 AC_CHECK_LIB(bsdxml, XML_ParserCreate, [ AC_CHECK_HEADERS(bsdxml.h, have_bsdxml=true, have_bsdxml=false) ], have_bsdxml=false)
 634
 635 if test "x$with_xml" = "xnone"; then
 636         :
 637 elif test "x$with_xml" = "xexpat"; then
 638         use_expat=true
 639         if ! $have_expat ; then
 640                 AC_MSG_ERROR([*** libexpat requested, but not found ***])
 641         fi
 642 elif test "x$with_xml" = "xbsdxml"; then
 643         use_bsdxml=true
 644         if ! $have_bsdxml ; then
 645                 AC_MSG_ERROR([*** libbsdxml requested, but not found ***])
 646         fi
 647 elif test "x$with_xml" != "x"; then
 648         AC_MSG_ERROR([*** unknown with-xml option ***])
 649 else
 650         if $have_expat ; then
 651                 use_expat=true
 652         elif $have_bsdxml ; then
 653                 use_bsdxml=true
 654         else
 655                 AC_MSG_ERROR([*** neither libexpat not libbsdxml could be found ***])
 656         fi
 657 fi
 658
 659 if $use_expat; then
 660         with_xml=expat
 661         XML_CFLAGS=-DUSE_EXPAT_H
 662         XML_LIBS=-lexpat
 663 fi
 664 if $use_bsdxml; then
 665         with_xml=bsdxml
 666         XML_CFLAGS=-DUSE_BSDXML_H
 667         XML_LIBS=-lbsdxml
 668 fi
 669 AC_SUBST(XML_LIBS)
 670 AC_SUBST(XML_CFLAGS)
 671
 672 if $use_expat || $use_bsdxml; then
 673         HAVE_XML=yes
 674 fi
 675
 676 AM_CONDITIONAL(HAVE_XML, test "x$HAVE_XML" = "xyes")
 677
 678 #
 679 # GDBM
 680 #
 681 #
 682 # Check for dbm
 683 #
 684 AC_ARG_ENABLE(dbm,
 685         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 686         [case "${enableval}" in
 687                 yes) HAVE_DBM=yes ;;
 688                 no)  HAVE_DBM=no ;;
 689                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 690         esac],
 691         [HAVE_DBM=no])
 692
 693 AC_ARG_ENABLE(gdbm,
 694         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 695         [case "${enableval}" in
 696                 yes) HAVE_GDBM=yes ;;
 697                 no)  HAVE_GDBM=no ;;
 698                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 699         esac],
 700         [HAVE_GDBM=yes])
 701
 702 if test "x$HAVE_GDBM" = "xyes" ; then
 703     if test "x$HAVE_DBM" = "xyes" ; then
 704         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 705     fi
 706     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 707
 708     if ! $have_gdbm ; then
 709         AC_MSG_ERROR([*** libgdbm not found ***])
 710     fi
 711     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 712 else
 713     if test "x$HAVE_DBM" = "xyes" ; then
 714         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 715
 716         if ! $have_dbm ; then
 717             AC_MSG_ERROR([*** dbm not found ***])
 718         fi
 719         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 720     fi
 721 fi
 722 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 723 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 724
 725 #
 726 # libdaemon
 727 #
 728 AC_ARG_ENABLE(libdaemon,
 729         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 730         [case "${enableval}" in
 731                 yes) HAVE_LIBDAEMON=yes ;;
 732                 no)  HAVE_LIBDAEMON=no ;;
 733                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 734         esac],
 735         [HAVE_LIBDAEMON=yes])
 736
 737 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 738     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.11 ])
 739     AC_SUBST(LIBDAEMON_CFLAGS)
 740     AC_SUBST(LIBDAEMON_LIBS)
 741 fi
 742 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 743
 744 #
 745 # Python stuff
 746 #
 747 AC_ARG_ENABLE(python,
 748     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 749     [case "${enableval}" in
 750           yes) HAVE_PYTHON=yes ;;
 751           no)  HAVE_PYTHON=no ;;
 752           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 753     esac],[HAVE_PYTHON=yes])
 754
 755 HAVE_PYTHON_DBUS=no
 756 HAVE_PYGTK=no
 757
 758 if test "x$HAVE_PYTHON" = "xyes" ; then
 759     AM_PATH_PYTHON([2.4])
 760
 761     AC_ARG_ENABLE(pygtk,
 762         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 763         [case "${enableval}" in
 764                 yes) HAVE_PYGTK=yes ;;
 765                 no)  HAVE_PYGTK=no ;;
 766                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 767         esac],
 768         [HAVE_PYGTK=yes])
 769
 770     if test "x$HAVE_PYGTK" = "xyes" ; then
 771         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 772     fi
 773
 774
 775     if test "x$HAVE_DBUS" = "xyes" ; then
 776         AC_ARG_ENABLE(python-dbus,
 777             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 778             [case "${enableval}" in
 779                    yes) HAVE_PYTHON_DBUS=yes ;;
 780                    no)  HAVE_PYTHON_DBUS=no ;;
 781                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 782             esac],
 783             [HAVE_PYTHON_DBUS=yes])
 784
 785         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 786             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 787         fi
 788
 789         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 790         if test "x$HAVE_GDBM" = "xyes"; then
 791             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 792         fi
 793         if test "x$HAVE_DBM" = "xyes"; then
 794             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 795         fi
 796     fi
 797 fi
 798 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 799 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 800 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 801
 802 #
 803 # Check for mono stuff
 804 #
 805 HAVE_MONO=no
 806 if test "x$HAVE_DBUS" = "xyes" ; then
 807     AC_ARG_ENABLE(mono,
 808             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 809             [case "${enableval}" in
 810                     yes) HAVE_MONO=yes ;;
 811                     no)  HAVE_MONO=no ;;
 812                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 813             esac],
 814             [HAVE_MONO=yes])
 815
 816     if test "x$HAVE_MONO" = "xyes" ; then
 817         AC_PATH_PROG(MCS, mcs)
 818         if test "x$MCS" = "x" ; then
 819             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 820         fi
 821
 822         AC_PATH_PROG(GACUTIL, gacutil)
 823         if test "x$GACUTIL" = "x" ; then
 824             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 825         fi
 826
 827         AC_SUBST(MCS)
 828         AC_SUBST(GACUTIL)
 829     fi
 830 fi
 831 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 832
 833 #
 834 # Check for monodoc stuff
 835 #
 836 HAVE_MONODOC=no
 837 AC_ARG_ENABLE(monodoc,
 838         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 839         [case "${enableval}" in
 840                 yes) HAVE_MONODOC=yes ;;
 841                 no)  HAVE_MONODOC=no ;;
 842                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 843         esac],
 844         [HAVE_MONODOC=yes])
 845
 846 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 847         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 848         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 849
 850         AC_PATH_PROG(MONODOCER, monodocer)
 851         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 852
 853         AC_SUBST(MONODOC_DIR)
 854         AC_SUBST(MONODOCER)
 855         AC_SUBST(MDASSEMBLER)
 856 fi
 857 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 858
 859 #
 860 # Build autoipd?
 861 #
 862 AC_ARG_ENABLE(autoipd,
 863         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 864         [case "${enableval}" in
 865                 yes) ENABLE_AUTOIPD=yes ;;
 866                 no)  ENABLE_AUTOIPD=no ;;
 867                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 868         esac],
 869         [ENABLE_AUTOIPD=yes])
 870
 871 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 872
 873 #
 874 # Defining users and groups
 875 #
 876 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 877 if test -z "$with_avahi_user" ; then
 878     AVAHI_USER=avahi
 879 else
 880     AVAHI_USER=$with_avahi_user
 881 fi
 882 AC_SUBST(AVAHI_USER)
 883 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 884
 885 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 886 if test -z "$with_avahi_group" ; then
 887     AVAHI_GROUP=avahi
 888 else
 889     AVAHI_GROUP=$with_avahi_group
 890 fi
 891 AC_SUBST(AVAHI_GROUP)
 892 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 893
 894 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 895 if test -z "$with_avahi_priv_access_group" ; then
 896     AVAHI_PRIV_ACCESS_GROUP=netdev
 897 else
 898     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 899 fi
 900 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 901 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 902
 903 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autoipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 904 if test -z "$with_autoipd_user" ; then
 905     AVAHI_AUTOIPD_USER=avahi-autoipd
 906 else
 907     AVAHI_AUTOIPD_USER=$with_autoipd_user
 908 fi
 909 AC_SUBST(AVAHI_AUTOIPD_USER)
 910 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 911
 912 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 913 if test -z "$with_autoipd_group" ; then
 914     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 915 else
 916     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 917 fi
 918 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 919 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 920
 921 #
 922 # Avahi runtime dir
 923 #
 924 avahi_runtime_dir="${localstatedir}/run"
 925 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 926 AC_SUBST(avahi_runtime_dir)
 927 AC_SUBST(avahi_socket)
 928
 929 #
 930 # Avahi interfaces dir
 931 #
 932 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 933         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 934         AC_SUBST(interfacesdir)
 935 fi
 936
 937 #
 938 # Doxygen
 939 #
 940 DX_HTML_FEATURE(ON)
 941 DX_CHM_FEATURE(OFF)
 942 DX_CHI_FEATURE(OFF)
 943 DX_MAN_FEATURE(OFF)
 944 DX_RTF_FEATURE(OFF)
 945 DX_XML_FEATURE(ON)
 946 DX_PDF_FEATURE(OFF)
 947 DX_PS_FEATURE(OFF)
 948 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 949
 950 AC_ARG_ENABLE(core-docs,
 951         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 952 [case "${enableval}" in
 953   yes) ENABLE_CORE_DOCS=yes ;;
 954   no)  ENABLE_CORE_DOCS=no ;;
 955   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 956 esac],[ENABLE_CORE_DOCS=no])
 957
 958 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 959
 960 #
 961 # Build and Install man pages
 962 #
 963 AC_ARG_ENABLE(manpages,
 964         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 965 [case "${enableval}" in
 966   yes) manpages=yes ;;
 967   no)  manpages=no ;;
 968   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 969 esac],[manpages=yes])
 970
 971 if test x$manpages = xyes ; then
 972     #
 973     # XMLTOMAN manpage generation
 974     #
 975     AC_ARG_ENABLE(xmltoman,
 976     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 977     [case "${enableval}" in
 978       yes) xmltoman=yes ;;
 979       no)  xmltoman=no ;;
 980       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 981     esac],[xmltoman=yes])
 982
 983     if test x$xmltoman = xyes ; then
 984         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 985     fi
 986
 987     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 988         if ! test -e man/avahi-daemon.8 ; then
 989             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 990             exit 1
 991         fi
 992         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 993         xmltoman=no
 994     fi
 995 fi
 996 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 997 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 998
 999 #
1000 # Conditionally compile test and example programs
1001 #
1002 AC_ARG_ENABLE(tests,
1003         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
1004         [case "${enableval}" in
1005                 yes) ENABLE_TESTS=yes ;;
1006                 no)  ENABLE_TESTS=no ;;
1007                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
1008         esac],
1009         [ENABLE_TESTS=no])
1010
1011 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
1012
1013 #
1014 # Optionally enable libdns_sd compatibility support
1015 #
1016 AC_ARG_ENABLE(compat-libdns_sd,
1017         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
1018         [case "${enableval}" in
1019                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
1020                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
1021                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
1022         esac],
1023         [ENABLE_COMPAT_LIBDNS_SD=no])
1024
1025 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
1026
1027 #
1028 # Optionally enable HOWL compatibility support
1029 #
1030 AC_ARG_ENABLE(compat-howl,
1031         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
1032         [case "${enableval}" in
1033                 yes) ENABLE_COMPAT_HOWL=yes ;;
1034                 no)  ENABLE_COMPAT_HOWL=no ;;
1035                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
1036         esac],
1037         [ENABLE_COMPAT_HOWL=no])
1038
1039 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
1040
1041
1042 # ==========================================================================
1043 AC_CONFIG_FILES([
1044 Makefile
1045 avahi-common/Makefile
1046 avahi-core/Makefile
1047 avahi-glib/Makefile
1048 avahi-gobject/Makefile
1049 avahi-qt/Makefile
1050 avahi-daemon/Makefile
1051 avahi-daemon/avahi-dbus.conf
1052 avahi-discover-standalone/Makefile
1053 avahi-client/Makefile
1054 initscript/Makefile
1055 initscript/debian/Makefile
1056 initscript/gentoo/Makefile
1057 initscript/archlinux/Makefile
1058 initscript/suse/Makefile
1059 initscript/fedora/Makefile
1060 initscript/mandriva/Makefile
1061 initscript/darwin/Makefile
1062 initscript/freebsd/Makefile
1063 initscript/slackware/Makefile
1064 avahi-dnsconfd/Makefile
1065 avahi-utils/Makefile
1066 avahi-python/Makefile
1067 avahi-python/avahi/Makefile
1068 avahi-python/avahi-discover/Makefile
1069 examples/Makefile
1070 common/Makefile
1071 man/Makefile
1072 tests/Makefile
1073 service-type-database/Makefile
1074 avahi-sharp/Makefile
1075 avahi-ui-sharp/Makefile
1076 avahi-compat-libdns_sd/Makefile
1077 avahi-compat-howl/Makefile
1078 avahi-compat-howl/samples/Makefile
1079 avahi-autoipd/Makefile
1080 avahi-ui/Makefile
1081 po/Makefile.in
1082 ])
1083 AC_OUTPUT
1084
1085 # ==========================================================================
1086 echo "
1087  ---{ $PACKAGE_NAME $VERSION }---
1088
1089     prefix:                                    ${prefix}
1090     sysconfdir:                                ${sysconfdir}
1091     localstatedir:                             ${localstatedir}
1092     avahi socket:                              ${avahi_socket}
1093     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
1094     dbus-1 version:                            ${DBUS_VERSION}
1095     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1096     C Compiler:                                ${CC}
1097     CFLAGS:                                    ${CFLAGS}
1098     Enable GLIB:                               ${HAVE_GLIB}
1099     Enable GLIB GObject:                       ${HAVE_GOBJECT}
1100     Enable GTK:                                ${HAVE_GTK}
1101     Enable D-Bus:                              ${HAVE_DBUS}
1102     With XML:                                  ${with_xml}
1103     Enable GDBM:                               ${HAVE_GDBM}
1104     Enable DBM:                                ${HAVE_DBM}
1105     Enable libdaemon:                          ${HAVE_LIBDAEMON}
1106     Enable Python:                             ${HAVE_PYTHON}
1107     Enable pygtk:                              ${HAVE_PYGTK}
1108     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
1109     Enable QT3:                                ${HAVE_QT3}
1110     Enable QT4:                                ${HAVE_QT4}
1111     Enable Mono:                               ${HAVE_MONO}
1112     Enable Monodoc:                            ${HAVE_MONODOC}
1113     Distribution/OS:                           ${with_distro}
1114     User for avahi-daemon:                     ${AVAHI_USER}
1115     Group for avahi-daemon:                    ${AVAHI_GROUP}
1116     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
1117     User for avahi-autoipd:                    ${AVAHI_AUTOIPD_USER}
1118     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
1119     Enable chroot():                           ${enable_chroot}
1120     Enable Linux inotify:                      ${have_inotify}
1121     Enable stack-smashing protection:          ${enable_ssp}
1122 "
1123
1124 BUILD_DAEMON="no   (You need libdaemon and expat/bsdxml!)"
1125
1126 if test "x$HAVE_XML" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
1127     BUILD_DAEMON=yes
1128 fi
1129
1130 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
1131
1132 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
1133     BUILD_PYTHON=yes
1134 fi
1135
1136 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
1137
1138 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
1139     BUILD_CLIENT=yes
1140 fi
1141
1142 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1143    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
1144 fi
1145 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1146    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
1147 fi
1148 if test "x$ENABLE_AUTOIPD" = "xyes" -a "x$HAVE_LIBDAEMON" != "xyes" ; then
1149    ENABLE_AUTOIPD="no   (You need libdaemon!)"
1150 fi
1151
1152 BUILD_UI="no"
1153 if test "x$HAVE_GTK" = "xyes" -a "x$BUILD_CLIENT" = "xyes" ; then
1154    BUILD_UI="yes"
1155 fi
1156
1157 echo "\
1158     Building libavahi-core              yes
1159     Building avahi-daemon:              ${BUILD_DAEMON}
1160     Building avahi-dnsconfd:            ${BUILD_DAEMON}
1161     Building libavahi-client:           ${BUILD_CLIENT}
1162     Building avahi-utils:               ${BUILD_CLIENT}
1163     Building avahi-python:              ${BUILD_PYTHON}
1164     Building libavahi-glib:             ${HAVE_GLIB}
1165     Building libavahi-gobject:          ${HAVE_GOBJECT}
1166     Building avahi-discover-standalone: ${HAVE_GTK}
1167     Building libavahi-qt3:              ${HAVE_QT3}
1168     Building libavahi-qt4:              ${HAVE_QT4}
1169     Building avahi-sharp:               ${HAVE_MONO}
1170     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
1171     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
1172     Building tests:                     ${ENABLE_TESTS}
1173     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
1174     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
1175     Building libavahi-ui:               ${BUILD_UI}
1176 "