git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [3:0:0])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [3:0:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [3:0:0])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:0:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, darwin, netbsd, freebsd or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125     if test "z$with_distro" = "z"; then
 126         with_distro=`uname -s`
 127     fi
 128 fi
 129 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 130
 131 case $with_distro in
 132     debian|gentoo|archlinux|suse|fedora|darwin|none)
 133      ;;
 134     netbsd|freebsd)
 135      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 136      ;;
 137     linux)
 138      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 139      ;;
 140     *)
 141      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 142      ;;
 143 esac
 144
 145 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 146 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 147 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 148 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 149 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 150 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 151 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 152 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 153
 154 test_gcc_flag() {
 155     AC_LANG_CONFTEST([int main() {}])
 156     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 157     ret=$?
 158     rm -f conftest.o
 159     return $ret
 160 }
 161
 162 # If using GCC specify some additional parameters
 163 if test "x$GCC" = "xyes" ; then
 164
 165     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 166
 167     if test "x$HAVE_NETLINK" = "xyes" ; then
 168         # Test whether rtnetlink.h can be included when compiled with -std=c99
 169         # some distributions (e.g. archlinux) have broken headers that dont
 170         # define __u64 with -std=c99
 171         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 172         OLDCFLAGS="$CFLAGS"
 173         CFLAGS="-std=c99"
 174         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 175             use_stdc99=yes, use_stdc99=no)
 176
 177         if test x"$use_stdc99" = xyes; then
 178             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 179             AC_MSG_RESULT([yes])
 180         else
 181             AC_MSG_RESULT([no])
 182         fi
 183
 184         CFLAGS="$OLDCFLAGS"
 185     else
 186         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 187     fi
 188
 189     for flag in $DESIRED_FLAGS ; do
 190         AC_MSG_CHECKING([whether $CC accepts $flag])
 191         if test_gcc_flag $flag ; then
 192            CFLAGS="$CFLAGS $flag"
 193            AC_MSG_RESULT([yes])
 194         else
 195            AC_MSG_RESULT([no])
 196         fi
 197     done
 198 fi
 199
 200 # Checks for header files.
 201 AC_HEADER_STDC
 202 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 203 AC_HEADER_STDBOOL
 204
 205 # Checks for typedefs, structures, and compiler characteristics.
 206 AC_C_CONST
 207 AC_TYPE_SIZE_T
 208 AC_HEADER_TIME
 209 AC_HEADER_SYS_WAIT
 210
 211 # Checks for library functions.
 212 AC_FUNC_MEMCMP
 213 AC_FUNC_SELECT_ARGTYPES
 214 AC_FUNC_MALLOC
 215 AC_FUNC_REALLOC
 216 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 217
 218 AC_FUNC_CHOWN
 219 AC_FUNC_STAT
 220 AC_TYPE_MODE_T
 221 AC_TYPE_PID_T
 222
 223 AC_CHECK_DECLS(environ)
 224
 225 enable_chroot=yes
 226 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 227 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 228 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 229
 230 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 231
 232 if test "x$enable_chroot" = "xyes" ; then
 233    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 234 fi
 235
 236 # Check for pkg-config manually first, as if its not installed the
 237 # PKG_PROG_PKG_CONFIG macro won't be defined.
 238 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 239
 240 if test x"$have_pkg_config" = "xno"; then
 241     AC_MSG_ERROR(pkg-config is required to install this program)
 242 fi
 243
 244 PKG_PROG_PKG_CONFIG
 245
 246 #
 247 # Check for GLIB 2.0
 248 #
 249 AC_ARG_ENABLE(glib,
 250         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 251         [case "${enableval}" in
 252                 yes) HAVE_GLIB=yes ;;
 253                 no)  HAVE_GLIB=no ;;
 254                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 255         esac],
 256         [HAVE_GLIB=yes])
 257
 258 if test "x$HAVE_GLIB" = "xyes" ; then
 259         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 260         AC_SUBST(GLIB20_CFLAGS)
 261         AC_SUBST(GLIB20_LIBS)
 262 fi
 263 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 264
 265 #
 266 # Check for Qt 3
 267 #
 268 AC_ARG_ENABLE(qt3,
 269         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 270         [case "${enableval}" in
 271                 yes) HAVE_QT3=yes ;;
 272                 no)  HAVE_QT3=no ;;
 273                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 274         esac],
 275         [HAVE_QT3=yes])
 276
 277 if test "x$HAVE_QT3" = "xyes" ; then
 278         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 279         AC_SUBST(QT3_CFLAGS)
 280         AC_SUBST(QT3_LIBS)
 281             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 282         MOC_QT3="no"
 283             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 284                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 285                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 286         AC_SUBST(MOC_QT3)
 287 fi
 288 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 289
 290 #
 291 # Check for Qt 4
 292 #
 293 AC_ARG_ENABLE(qt4,
 294         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 295         [case "${enableval}" in
 296                 yes) HAVE_QT4=yes ;;
 297                 no)  HAVE_QT4=no ;;
 298                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 299         esac],
 300         [HAVE_QT4=yes])
 301
 302 if test "x$HAVE_QT4" = "xyes" ; then
 303         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 304         AC_SUBST(QT4_CFLAGS)
 305         AC_SUBST(QT4_LIBS)
 306             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 307         MOC_QT4="no"
 308             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 309                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 310                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 311         AC_SUBST(MOC_QT4)
 312 fi
 313 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 314
 315 #
 316 # Check for GTK+
 317 #
 318 AC_ARG_ENABLE(gtk,
 319         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 320         [case "${enableval}" in
 321                 yes) HAVE_GTK=yes ;;
 322                 no)  HAVE_GTK=no ;;
 323                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 324         esac],
 325         [HAVE_GTK=yes])
 326
 327 if test "x$HAVE_GTK" = "xyes" ; then
 328         # Check for GTK 2.0
 329         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 330         AC_SUBST(GTK20_CFLAGS)
 331         AC_SUBST(GTK20_LIBS)
 332
 333         # Check for GLADE 2.0
 334         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 335         AC_SUBST(GLADE20_CFLAGS)
 336         AC_SUBST(GLADE20_LIBS)
 337 fi
 338 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 339
 340 #
 341 # D-BUS
 342 #
 343 AC_ARG_ENABLE(dbus,
 344         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 345         [case "${enableval}" in
 346                 yes) HAVE_DBUS=yes ;;
 347                 no)  HAVE_DBUS=no ;;
 348                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 349         esac],
 350         [HAVE_DBUS=yes])
 351
 352 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 353 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 354
 355 DBUS_VERSION="Not installed!"
 356 if test "x$HAVE_DBUS" = "xyes" ; then
 357     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 358
 359     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 360     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 361     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 362     AC_SUBST(DBUS_CFLAGS)
 363     AC_SUBST(DBUS_LIBS)
 364
 365     if ! test -z "$with_dbus_sys" ; then
 366         DBUS_SYS_DIR="$with_dbus_sys"
 367     else
 368         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 369     fi
 370     AC_SUBST(DBUS_SYS_DIR)
 371
 372     if ! test -z "$with_dbus_system_address" ; then
 373         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 374     else
 375         # This is ugly, but D-BUS doesn't export this address for us
 376         # so we have to guess, pretty much all setups i've seen have
 377         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 378         # /var/run upstream so we will try guess first then default
 379         # to /var/run/dbus
 380
 381         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 382         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 383         for sock in $TRY_SOCKETS; do
 384             if test -S $sock; then
 385                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 386             fi
 387         done
 388     fi
 389     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 390
 391 fi
 392 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 393
 394 #
 395 # Expat
 396 #
 397 AC_ARG_ENABLE(expat,
 398         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 399         [case "${enableval}" in
 400                 yes) HAVE_EXPAT=yes ;;
 401                 no)  HAVE_EXPAT=no ;;
 402                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 403         esac],
 404         [HAVE_EXPAT=yes])
 405
 406 if test "x$HAVE_EXPAT" = "xyes" ; then
 407     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 408
 409     if ! $have_expat ; then
 410         AC_MSG_ERROR([*** libexpat not found ***])
 411     fi
 412 fi
 413 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 414
 415 #
 416 # GDBM
 417 #
 418 AC_ARG_ENABLE(gdbm,
 419         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 420         [case "${enableval}" in
 421                 yes) HAVE_GDBM=yes ;;
 422                 no)  HAVE_GDBM=no ;;
 423                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 424         esac],
 425         [HAVE_GDBM=yes])
 426
 427 if test "x$HAVE_GDBM" = "xyes" ; then
 428     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 429
 430     if ! $have_gdbm ; then
 431         AC_MSG_ERROR([*** libgdbm not found ***])
 432     fi
 433     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 434 fi
 435 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 436
 437 #
 438 # libdaemon
 439 #
 440 AC_ARG_ENABLE(libdaemon,
 441         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 442         [case "${enableval}" in
 443                 yes) HAVE_LIBDAEMON=yes ;;
 444                 no)  HAVE_LIBDAEMON=no ;;
 445                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 446         esac],
 447         [HAVE_LIBDAEMON=yes])
 448
 449 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 450     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 451     AC_SUBST(LIBDAEMON_CFLAGS)
 452     AC_SUBST(LIBDAEMON_LIBS)
 453 fi
 454 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 455
 456 #
 457 # Python stuff
 458 #
 459 AC_ARG_ENABLE(python,
 460     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 461     [case "${enableval}" in
 462           yes) HAVE_PYTHON=yes ;;
 463           no)  HAVE_PYTHON=no ;;
 464           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 465     esac],[HAVE_PYTHON=yes])
 466
 467 HAVE_PYTHON_DBUS=no
 468 HAVE_PYGTK=no
 469
 470 if test "x$HAVE_PYTHON" = "xyes" ; then
 471     AM_PATH_PYTHON([2.4])
 472
 473     AC_ARG_ENABLE(pygtk,
 474         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 475         [case "${enableval}" in
 476                 yes) HAVE_PYGTK=yes ;;
 477                 no)  HAVE_PYGTK=no ;;
 478                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 479         esac],
 480         [HAVE_PYGTK=yes])
 481
 482     if test "x$HAVE_PYGTK" = "xyes" ; then
 483         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 484     fi
 485
 486
 487     AC_ARG_ENABLE(python-dbus,
 488         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 489         [case "${enableval}" in
 490                 yes) HAVE_PYTHON_DBUS=yes ;;
 491                 no)  HAVE_PYTHON_DBUS=no ;;
 492                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 493         esac],
 494         [HAVE_PYTHON_DBUS=yes])
 495
 496     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 497         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 498     fi
 499
 500     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 501     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 502 fi
 503 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 504 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 505 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 506
 507 #
 508 # Check for mono stuff
 509 #
 510 AC_ARG_ENABLE(mono,
 511         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 512         [case "${enableval}" in
 513                 yes) HAVE_MONO=yes ;;
 514                 no)  HAVE_MONO=no ;;
 515                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 516         esac],
 517         [HAVE_MONO=yes])
 518
 519 AC_ARG_ENABLE(monodoc,
 520         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 521         [case "${enableval}" in
 522                 yes) HAVE_MONODOC=yes ;;
 523                 no)  HAVE_MONODOC=no ;;
 524                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 525         esac],
 526         [HAVE_MONODOC=yes])
 527
 528 if test "x$HAVE_MONO" = "xyes" ; then
 529         AC_PATH_PROG(MCS, mcs)
 530         if test "x$MCS" = "x" ; then
 531                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 532         fi
 533
 534         AC_PATH_PROG(GACUTIL, gacutil)
 535         if test "x$GACUTIL" = "x" ; then
 536                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 537         fi
 538
 539         AC_SUBST(MCS)
 540         AC_SUBST(GACUTIL)
 541 fi
 542 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 543
 544 #
 545 # Check for monodoc stuff
 546 #
 547 if test "x$HAVE_MONODOC" = "xyes" ; then
 548         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 549         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 550
 551         AC_PATH_PROG(MONODOCER, monodocer)
 552         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 553
 554         AC_SUBST(MONODOC_DIR)
 555         AC_SUBST(MONODOCER)
 556         AC_SUBST(MDASSEMBLER)
 557 fi
 558 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 559
 560 #
 561 # Defining Avahi User and Group.
 562 #
 563 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 564 if test -z "$with_avahi_user" ; then
 565     AVAHI_USER=avahi
 566 else
 567     AVAHI_USER=$with_avahi_user
 568 fi
 569 AC_SUBST(AVAHI_USER)
 570 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 571
 572 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 573 if test -z "$with_avahi_group" ; then
 574     AVAHI_GROUP=avahi
 575 else
 576     AVAHI_GROUP=$with_avahi_group
 577 fi
 578 AC_SUBST(AVAHI_GROUP)
 579 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 580
 581 #
 582 # Avahi runtime dir
 583 #
 584 avahi_runtime_dir="${localstatedir}/run"
 585 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 586 AC_SUBST(avahi_runtime_dir)
 587 AC_SUBST(avahi_socket)
 588
 589 #
 590 # Avahi interfaces dir
 591 #
 592 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 593         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 594         AC_SUBST(interfacesdir)
 595 fi
 596
 597 #
 598 # Doxygen
 599 #
 600 DX_HTML_FEATURE(ON)
 601 DX_CHM_FEATURE(OFF)
 602 DX_CHI_FEATURE(OFF)
 603 DX_MAN_FEATURE(OFF)
 604 DX_RTF_FEATURE(OFF)
 605 DX_XML_FEATURE(OFF)
 606 DX_PDF_FEATURE(OFF)
 607 DX_PS_FEATURE(OFF)
 608 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 609
 610 #
 611 # Build and Install man pages
 612 #
 613 AC_ARG_ENABLE(manpages,
 614         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 615 [case "${enableval}" in
 616   yes) manpages=yes ;;
 617   no)  manpages=no ;;
 618   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 619 esac],[manpages=yes])
 620
 621 if test x$manpages = xyes ; then
 622     #
 623     # XMLTOMAN manpage generation
 624     #
 625     AC_ARG_ENABLE(xmltoman,
 626     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 627     [case "${enableval}" in
 628       yes) xmltoman=yes ;;
 629       no)  xmltoman=no ;;
 630       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 631     esac],[xmltoman=yes])
 632
 633     if test x$xmltoman = xyes ; then
 634         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 635     fi
 636
 637     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 638         if ! test -e man/avahi-daemon.8 ; then
 639             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 640             exit 1
 641         fi
 642         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 643         xmltoman=no
 644     fi
 645 fi
 646 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 647 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 648
 649 #
 650 # Conditionally compile test and example programs
 651 #
 652 AC_ARG_ENABLE(tests,
 653         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 654         [case "${enableval}" in
 655                 yes) ENABLE_TESTS=yes ;;
 656                 no)  ENABLE_TESTS=no ;;
 657                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 658         esac],
 659         [ENABLE_TESTS=no])
 660
 661 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 662
 663 #
 664 # Optionally enable libdns_sd compatibility support
 665 #
 666 AC_ARG_ENABLE(compat-libdns_sd,
 667         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 668         [case "${enableval}" in
 669                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 670                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 671                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 672         esac],
 673         [ENABLE_COMPAT_LIBDNS_SD=no])
 674
 675 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 676
 677 #
 678 # Optionally enable HOWL compatibility support
 679 #
 680 AC_ARG_ENABLE(compat-howl,
 681         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 682         [case "${enableval}" in
 683                 yes) ENABLE_COMPAT_HOWL=yes ;;
 684                 no)  ENABLE_COMPAT_HOWL=no ;;
 685                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 686         esac],
 687         [ENABLE_COMPAT_HOWL=no])
 688
 689 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 690
 691
 692 # ==========================================================================
 693 AC_CONFIG_FILES([
 694 Makefile
 695 avahi-common/Makefile
 696 avahi-core/Makefile
 697 avahi-glib/Makefile
 698 avahi-qt/Makefile
 699 avahi-daemon/Makefile
 700 avahi-daemon/avahi-dbus.conf
 701 avahi-discover-standalone/Makefile
 702 avahi-client/Makefile
 703 initscript/Makefile
 704 initscript/debian/Makefile
 705 initscript/gentoo/Makefile
 706 initscript/archlinux/Makefile
 707 initscript/suse/Makefile
 708 initscript/fedora/Makefile
 709 initscript/darwin/Makefile
 710 avahi-dnsconfd/Makefile
 711 avahi-utils/Makefile
 712 avahi-python/Makefile
 713 avahi-python/avahi/Makefile
 714 examples/Makefile
 715 common/Makefile
 716 man/Makefile
 717 tests/Makefile
 718 service-type-database/Makefile
 719 avahi-sharp/Makefile
 720 avahi-compat-libdns_sd/Makefile
 721 avahi-compat-howl/Makefile
 722 avahi-compat-howl/samples/Makefile
 723 ])
 724 AC_OUTPUT
 725
 726 # ==========================================================================
 727 echo "
 728  ---{ $PACKAGE_NAME $VERSION }---
 729
 730     prefix:                 ${prefix}
 731     sysconfdir:             ${sysconfdir}
 732     localstatedir:          ${localstatedir}
 733     avahi socket:           ${avahi_socket}
 734     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 735     dbus-1 version:         ${DBUS_VERSION}
 736     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 737     compiler:               ${CC}
 738     cflags:                 ${CFLAGS}
 739     Enable GLIB:            ${HAVE_GLIB}
 740     Enable GTK:             ${HAVE_GTK}
 741     Enable D-BUS:           ${HAVE_DBUS}
 742     Enable Expat:           ${HAVE_EXPAT}
 743     Enable GDBM:            ${HAVE_GDBM}
 744     Enable libdaemon:       ${HAVE_LIBDAEMON}
 745     Enable Python:          ${HAVE_PYTHON}
 746     Enable pygtk:           ${HAVE_PYGTK}
 747     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 748     Enable QT3:             ${HAVE_QT3}
 749     Enable QT4:             ${HAVE_QT4}
 750     Enable Mono:            ${HAVE_MONO}
 751     Distribution/OS:        ${with_distro}
 752     User for Avahi:         ${AVAHI_USER}
 753     Group for Avahi:        ${AVAHI_GROUP}
 754     Enable chroot():        ${enable_chroot}
 755 "
 756
 757 BUILD_DAEMON="no (!)"
 758
 759 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 760     BUILD_DAEMON=yes
 761 fi
 762
 763 BUILD_PYTHON="no"
 764
 765 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 766     BUILD_PYTHON=yes
 767 fi
 768
 769 BUILD_CLIENT="no (!)"
 770
 771 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 772     BUILD_CLIENT=yes
 773 fi
 774
 775 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 776    AC_MSG_ERROR([building avahi-compat-libdns_sd without building libavahi-client doesn't work])
 777 fi
 778 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 779    AC_MSG_ERROR([building avahi-compat-howl without building libavahi-client doesn't work])
 780 fi
 781
 782
 783 echo "
 784     Building libavahi-core              yes
 785     Building avahi-daemon:              ${BUILD_DAEMON}
 786     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 787     Building libavahi-client:           ${BUILD_CLIENT}
 788     Building avahi-utils:               ${BUILD_CLIENT}
 789     Building avahi-python:              ${BUILD_PYTHON}
 790     Building libavahi-glib:             ${HAVE_GLIB}
 791     Building avahi-discover-standalone: ${HAVE_GTK}
 792     Building libavahi-qt3:              ${HAVE_QT3}
 793     Building libavahi-qt4:              ${HAVE_QT4}
 794     Building avahi-sharp:               ${HAVE_MONO}
 795     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 796     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 797     Building tests:                     ${ENABLE_TESTS}
 798 "