git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.3],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [4:1:1])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [3:3:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [3:2:0])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:0:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, darwin, netbsd, freebsd or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125     if test "z$with_distro" = "z"; then
 126         with_distro=`uname -s`
 127     fi
 128 fi
 129 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 130
 131 case $with_distro in
 132     debian|gentoo|archlinux|suse|fedora|darwin|freebsd|none)
 133      ;;
 134     netbsd)
 135      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 136      ;;
 137     linux)
 138      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 139      ;;
 140     *)
 141      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 142      ;;
 143 esac
 144
 145 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 146 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 147 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 148 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 149 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 150 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 151 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 152 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 153
 154 test_gcc_flag() {
 155     AC_LANG_CONFTEST([int main() {}])
 156     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 157     ret=$?
 158     rm -f conftest.o
 159     return $ret
 160 }
 161
 162 # If using GCC specify some additional parameters
 163 if test "x$GCC" = "xyes" ; then
 164
 165     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 166
 167     if test "x$HAVE_NETLINK" = "xyes" ; then
 168         # Test whether rtnetlink.h can be included when compiled with -std=c99
 169         # some distributions (e.g. archlinux) have broken headers that dont
 170         # define __u64 with -std=c99
 171         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 172         OLDCFLAGS="$CFLAGS"
 173         CFLAGS="-std=c99"
 174         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 175             use_stdc99=yes, use_stdc99=no)
 176
 177         if test x"$use_stdc99" = xyes; then
 178             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 179             AC_MSG_RESULT([yes])
 180         else
 181             AC_MSG_RESULT([no])
 182         fi
 183
 184         CFLAGS="$OLDCFLAGS"
 185     else
 186         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 187     fi
 188
 189     for flag in $DESIRED_FLAGS ; do
 190         AC_MSG_CHECKING([whether $CC accepts $flag])
 191         if test_gcc_flag $flag ; then
 192            CFLAGS="$CFLAGS $flag"
 193            AC_MSG_RESULT([yes])
 194         else
 195            AC_MSG_RESULT([no])
 196         fi
 197     done
 198 fi
 199
 200 # Checks for header files.
 201 AC_HEADER_STDC
 202 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 203 AC_HEADER_STDBOOL
 204
 205 # Checks for typedefs, structures, and compiler characteristics.
 206 AC_C_CONST
 207 AC_TYPE_SIZE_T
 208 AC_HEADER_TIME
 209 AC_HEADER_SYS_WAIT
 210
 211 # Checks for library functions.
 212 AC_FUNC_MEMCMP
 213 AC_FUNC_SELECT_ARGTYPES
 214 AC_FUNC_MALLOC
 215 AC_FUNC_REALLOC
 216 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 217
 218 AC_FUNC_CHOWN
 219 AC_FUNC_STAT
 220 AC_TYPE_MODE_T
 221 AC_TYPE_PID_T
 222
 223 AC_CHECK_DECLS(environ)
 224
 225 enable_chroot=yes
 226 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 227 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 228 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 229
 230 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 231
 232 if test "x$enable_chroot" = "xyes" ; then
 233    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 234 fi
 235
 236 # Check for pkg-config manually first, as if its not installed the
 237 # PKG_PROG_PKG_CONFIG macro won't be defined.
 238 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 239
 240 if test x"$have_pkg_config" = "xno"; then
 241     AC_MSG_ERROR(pkg-config is required to install this program)
 242 fi
 243
 244 PKG_PROG_PKG_CONFIG
 245
 246 #
 247 # Check for GLIB 2.0
 248 #
 249 AC_ARG_ENABLE(glib,
 250         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 251         [case "${enableval}" in
 252                 yes) HAVE_GLIB=yes ;;
 253                 no)  HAVE_GLIB=no ;;
 254                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 255         esac],
 256         [HAVE_GLIB=yes])
 257
 258 if test "x$HAVE_GLIB" = "xyes" ; then
 259         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 260         AC_SUBST(GLIB20_CFLAGS)
 261         AC_SUBST(GLIB20_LIBS)
 262 fi
 263 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 264
 265 #
 266 # Check for Qt 3
 267 #
 268 AC_ARG_ENABLE(qt3,
 269         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 270         [case "${enableval}" in
 271                 yes) HAVE_QT3=yes ;;
 272                 no)  HAVE_QT3=no ;;
 273                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 274         esac],
 275         [HAVE_QT3=yes])
 276
 277 if test "x$HAVE_QT3" = "xyes" ; then
 278         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 279         AC_SUBST(QT3_CFLAGS)
 280         AC_SUBST(QT3_LIBS)
 281             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 282         MOC_QT3="no"
 283             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 284                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 285                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 286         AC_SUBST(MOC_QT3)
 287 fi
 288 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 289
 290 #
 291 # Check for Qt 4
 292 #
 293 AC_ARG_ENABLE(qt4,
 294         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 295         [case "${enableval}" in
 296                 yes) HAVE_QT4=yes ;;
 297                 no)  HAVE_QT4=no ;;
 298                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 299         esac],
 300         [HAVE_QT4=yes])
 301
 302 if test "x$HAVE_QT4" = "xyes" ; then
 303         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 304         AC_SUBST(QT4_CFLAGS)
 305         AC_SUBST(QT4_LIBS)
 306             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 307         MOC_QT4="no"
 308             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 309                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 310                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 311         AC_SUBST(MOC_QT4)
 312 fi
 313 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 314
 315 #
 316 # Check for GTK+
 317 #
 318 AC_ARG_ENABLE(gtk,
 319         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 320         [case "${enableval}" in
 321                 yes) HAVE_GTK=yes ;;
 322                 no)  HAVE_GTK=no ;;
 323                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 324         esac],
 325         [HAVE_GTK=yes])
 326
 327 if test "x$HAVE_GTK" = "xyes" ; then
 328         # Check for GTK 2.0
 329         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 330         AC_SUBST(GTK20_CFLAGS)
 331         AC_SUBST(GTK20_LIBS)
 332
 333         # Check for GLADE 2.0
 334         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 335         AC_SUBST(GLADE20_CFLAGS)
 336         AC_SUBST(GLADE20_LIBS)
 337 fi
 338 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 339
 340 #
 341 # D-BUS
 342 #
 343 AC_ARG_ENABLE(dbus,
 344         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 345         [case "${enableval}" in
 346                 yes) HAVE_DBUS=yes ;;
 347                 no)  HAVE_DBUS=no ;;
 348                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 349         esac],
 350         [HAVE_DBUS=yes])
 351
 352 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 353 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 354
 355 DBUS_VERSION="Disabled"
 356 DBUS_SYS_DIR="Disabled"
 357 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 358 if test "x$HAVE_DBUS" = "xyes" ; then
 359     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 360
 361     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 362
 363     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 364     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 365     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 366     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 367     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 368         DBUS_VERSION_MAJOR="0"
 369     fi
 370     if test "z$DBUS_VERSION_MINOR" = "z"; then
 371         DBUS_VERSION_MINOR="0"
 372     fi
 373     if test "z$DBUS_VERSION_MICRO" = "z"; then
 374         DBUS_VERSION_MICRO="0"
 375     fi
 376
 377     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 378         echo "Error: Couldn't determine the version of your DBUS package."
 379         echo "  This is probably an error in this script, please report it"
 380         echo "  along with the following information:"
 381         echo "      Base DBUS version ='$DBUS_VERSION'"
 382         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 383         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 384         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 385         exit 1
 386     else
 387         echo "Your dbus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 388         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 389         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 390         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 391     fi
 392
 393     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 394     AC_SUBST(DBUS_CFLAGS)
 395     AC_SUBST(DBUS_LIBS)
 396
 397     if ! test -z "$with_dbus_sys" ; then
 398         DBUS_SYS_DIR="$with_dbus_sys"
 399     else
 400         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 401     fi
 402     AC_SUBST(DBUS_SYS_DIR)
 403
 404     if ! test -z "$with_dbus_system_address" ; then
 405         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 406     else
 407         # This is ugly, but D-BUS doesn't export this address for us
 408         # so we have to guess, pretty much all setups i've seen have
 409         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 410         # /var/run upstream so we will try guess first then default
 411         # to /var/run/dbus
 412
 413         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 414         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 415         for sock in $TRY_SOCKETS; do
 416             if test -S $sock; then
 417                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 418             fi
 419         done
 420     fi
 421     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 422
 423 fi
 424 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 425
 426 #
 427 # Expat
 428 #
 429 AC_ARG_ENABLE(expat,
 430         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 431         [case "${enableval}" in
 432                 yes) HAVE_EXPAT=yes ;;
 433                 no)  HAVE_EXPAT=no ;;
 434                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 435         esac],
 436         [HAVE_EXPAT=yes])
 437
 438 if test "x$HAVE_EXPAT" = "xyes" ; then
 439     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 440
 441     if ! $have_expat ; then
 442         AC_MSG_ERROR([*** libexpat not found ***])
 443     fi
 444 fi
 445 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 446
 447 #
 448 # GDBM
 449 #
 450 AC_ARG_ENABLE(gdbm,
 451         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 452         [case "${enableval}" in
 453                 yes) HAVE_GDBM=yes ;;
 454                 no)  HAVE_GDBM=no ;;
 455                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 456         esac],
 457         [HAVE_GDBM=yes])
 458
 459 if test "x$HAVE_GDBM" = "xyes" ; then
 460     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 461
 462     if ! $have_gdbm ; then
 463         AC_MSG_ERROR([*** libgdbm not found ***])
 464     fi
 465     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 466 fi
 467 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 468
 469 #
 470 # libdaemon
 471 #
 472 AC_ARG_ENABLE(libdaemon,
 473         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 474         [case "${enableval}" in
 475                 yes) HAVE_LIBDAEMON=yes ;;
 476                 no)  HAVE_LIBDAEMON=no ;;
 477                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 478         esac],
 479         [HAVE_LIBDAEMON=yes])
 480
 481 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 482     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 483     AC_SUBST(LIBDAEMON_CFLAGS)
 484     AC_SUBST(LIBDAEMON_LIBS)
 485 fi
 486 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 487
 488 #
 489 # Python stuff
 490 #
 491 AC_ARG_ENABLE(python,
 492     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 493     [case "${enableval}" in
 494           yes) HAVE_PYTHON=yes ;;
 495           no)  HAVE_PYTHON=no ;;
 496           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 497     esac],[HAVE_PYTHON=yes])
 498
 499 HAVE_PYTHON_DBUS=no
 500 HAVE_PYGTK=no
 501
 502 if test "x$HAVE_PYTHON" = "xyes" ; then
 503     AM_PATH_PYTHON([2.4])
 504
 505     AC_ARG_ENABLE(pygtk,
 506         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 507         [case "${enableval}" in
 508                 yes) HAVE_PYGTK=yes ;;
 509                 no)  HAVE_PYGTK=no ;;
 510                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 511         esac],
 512         [HAVE_PYGTK=yes])
 513
 514     if test "x$HAVE_PYGTK" = "xyes" ; then
 515         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 516     fi
 517
 518
 519     if test "x$HAVE_DBUS" = "xyes" ; then
 520         AC_ARG_ENABLE(python-dbus,
 521             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 522             [case "${enableval}" in
 523                    yes) HAVE_PYTHON_DBUS=yes ;;
 524                    no)  HAVE_PYTHON_DBUS=no ;;
 525                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 526             esac],
 527             [HAVE_PYTHON_DBUS=yes])
 528
 529         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 530             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 531         fi
 532
 533         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 534         AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 535     fi
 536 fi
 537 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 538 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 539 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 540
 541 #
 542 # Check for mono stuff
 543 #
 544 HAVE_MONO=no
 545 if test "x$HAVE_DBUS" = "xyes" ; then
 546     AC_ARG_ENABLE(mono,
 547             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 548             [case "${enableval}" in
 549                     yes) HAVE_MONO=yes ;;
 550                     no)  HAVE_MONO=no ;;
 551                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 552             esac],
 553             [HAVE_MONO=yes])
 554
 555     if test "x$HAVE_MONO" = "xyes" ; then
 556         AC_PATH_PROG(MCS, mcs)
 557         if test "x$MCS" = "x" ; then
 558             AC_MSG_ERROR([Can not find "mcs" in your PATH])
 559         fi
 560
 561         AC_PATH_PROG(GACUTIL, gacutil)
 562         if test "x$GACUTIL" = "x" ; then
 563             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 564         fi
 565
 566         AC_SUBST(MCS)
 567         AC_SUBST(GACUTIL)
 568     fi
 569 fi
 570 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 571
 572 #
 573 # Check for monodoc stuff
 574 #
 575 HAVE_MONODOC=no
 576 AC_ARG_ENABLE(monodoc,
 577         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 578         [case "${enableval}" in
 579                 yes) HAVE_MONODOC=yes ;;
 580                 no)  HAVE_MONODOC=no ;;
 581                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 582         esac],
 583         [HAVE_MONODOC=yes])
 584
 585 if test "x$HAVE_MONODOC" = "xyes" ; then
 586         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 587         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 588
 589         AC_PATH_PROG(MONODOCER, monodocer)
 590         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 591
 592         AC_SUBST(MONODOC_DIR)
 593         AC_SUBST(MONODOCER)
 594         AC_SUBST(MDASSEMBLER)
 595 fi
 596 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 597
 598 #
 599 # Defining Avahi User and Group.
 600 #
 601 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 602 if test -z "$with_avahi_user" ; then
 603     AVAHI_USER=avahi
 604 else
 605     AVAHI_USER=$with_avahi_user
 606 fi
 607 AC_SUBST(AVAHI_USER)
 608 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 609
 610 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 611 if test -z "$with_avahi_group" ; then
 612     AVAHI_GROUP=avahi
 613 else
 614     AVAHI_GROUP=$with_avahi_group
 615 fi
 616 AC_SUBST(AVAHI_GROUP)
 617 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 618
 619 #
 620 # Avahi runtime dir
 621 #
 622 avahi_runtime_dir="${localstatedir}/run"
 623 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 624 AC_SUBST(avahi_runtime_dir)
 625 AC_SUBST(avahi_socket)
 626
 627 #
 628 # Avahi interfaces dir
 629 #
 630 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 631         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 632         AC_SUBST(interfacesdir)
 633 fi
 634
 635 #
 636 # Doxygen
 637 #
 638 DX_HTML_FEATURE(ON)
 639 DX_CHM_FEATURE(OFF)
 640 DX_CHI_FEATURE(OFF)
 641 DX_MAN_FEATURE(OFF)
 642 DX_RTF_FEATURE(OFF)
 643 DX_XML_FEATURE(OFF)
 644 DX_PDF_FEATURE(OFF)
 645 DX_PS_FEATURE(OFF)
 646 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 647
 648 #
 649 # Build and Install man pages
 650 #
 651 AC_ARG_ENABLE(manpages,
 652         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 653 [case "${enableval}" in
 654   yes) manpages=yes ;;
 655   no)  manpages=no ;;
 656   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 657 esac],[manpages=yes])
 658
 659 if test x$manpages = xyes ; then
 660     #
 661     # XMLTOMAN manpage generation
 662     #
 663     AC_ARG_ENABLE(xmltoman,
 664     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 665     [case "${enableval}" in
 666       yes) xmltoman=yes ;;
 667       no)  xmltoman=no ;;
 668       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 669     esac],[xmltoman=yes])
 670
 671     if test x$xmltoman = xyes ; then
 672         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 673     fi
 674
 675     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 676         if ! test -e man/avahi-daemon.8 ; then
 677             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 678             exit 1
 679         fi
 680         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 681         xmltoman=no
 682     fi
 683 fi
 684 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 685 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 686
 687 #
 688 # Conditionally compile test and example programs
 689 #
 690 AC_ARG_ENABLE(tests,
 691         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 692         [case "${enableval}" in
 693                 yes) ENABLE_TESTS=yes ;;
 694                 no)  ENABLE_TESTS=no ;;
 695                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 696         esac],
 697         [ENABLE_TESTS=no])
 698
 699 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 700
 701 #
 702 # Optionally enable libdns_sd compatibility support
 703 #
 704 AC_ARG_ENABLE(compat-libdns_sd,
 705         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 706         [case "${enableval}" in
 707                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 708                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 709                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 710         esac],
 711         [ENABLE_COMPAT_LIBDNS_SD=no])
 712
 713 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 714
 715 #
 716 # Optionally enable HOWL compatibility support
 717 #
 718 AC_ARG_ENABLE(compat-howl,
 719         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 720         [case "${enableval}" in
 721                 yes) ENABLE_COMPAT_HOWL=yes ;;
 722                 no)  ENABLE_COMPAT_HOWL=no ;;
 723                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 724         esac],
 725         [ENABLE_COMPAT_HOWL=no])
 726
 727 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 728
 729
 730 # ==========================================================================
 731 AC_CONFIG_FILES([
 732 Makefile
 733 avahi-common/Makefile
 734 avahi-core/Makefile
 735 avahi-glib/Makefile
 736 avahi-qt/Makefile
 737 avahi-daemon/Makefile
 738 avahi-daemon/avahi-dbus.conf
 739 avahi-discover-standalone/Makefile
 740 avahi-client/Makefile
 741 initscript/Makefile
 742 initscript/debian/Makefile
 743 initscript/gentoo/Makefile
 744 initscript/archlinux/Makefile
 745 initscript/suse/Makefile
 746 initscript/fedora/Makefile
 747 initscript/darwin/Makefile
 748 initscript/freebsd/Makefile
 749 avahi-dnsconfd/Makefile
 750 avahi-utils/Makefile
 751 avahi-python/Makefile
 752 avahi-python/avahi/Makefile
 753 examples/Makefile
 754 common/Makefile
 755 man/Makefile
 756 tests/Makefile
 757 service-type-database/Makefile
 758 avahi-sharp/Makefile
 759 avahi-compat-libdns_sd/Makefile
 760 avahi-compat-howl/Makefile
 761 avahi-compat-howl/samples/Makefile
 762 ])
 763 AC_OUTPUT
 764
 765 # ==========================================================================
 766 echo "
 767  ---{ $PACKAGE_NAME $VERSION }---
 768
 769     prefix:                 ${prefix}
 770     sysconfdir:             ${sysconfdir}
 771     localstatedir:          ${localstatedir}
 772     avahi socket:           ${avahi_socket}
 773     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 774     dbus-1 version:         ${DBUS_VERSION}
 775     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 776     compiler:               ${CC}
 777     cflags:                 ${CFLAGS}
 778     Enable GLIB:            ${HAVE_GLIB}
 779     Enable GTK:             ${HAVE_GTK}
 780     Enable D-BUS:           ${HAVE_DBUS}
 781     Enable Expat:           ${HAVE_EXPAT}
 782     Enable GDBM:            ${HAVE_GDBM}
 783     Enable libdaemon:       ${HAVE_LIBDAEMON}
 784     Enable Python:          ${HAVE_PYTHON}
 785     Enable pygtk:           ${HAVE_PYGTK}
 786     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 787     Enable QT3:             ${HAVE_QT3}
 788     Enable QT4:             ${HAVE_QT4}
 789     Enable Mono:            ${HAVE_MONO}
 790     Enable Monodoc:         ${HAVE_MONODOC}
 791     Distribution/OS:        ${with_distro}
 792     User for Avahi:         ${AVAHI_USER}
 793     Group for Avahi:        ${AVAHI_GROUP}
 794     Enable chroot():        ${enable_chroot}
 795 "
 796
 797 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 798
 799 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 800     BUILD_DAEMON=yes
 801 fi
 802
 803 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 804
 805 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 806     BUILD_PYTHON=yes
 807 fi
 808
 809 BUILD_CLIENT="no   (You need avahi-daemon and dbus!)"
 810
 811 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 812     BUILD_CLIENT=yes
 813 fi
 814
 815 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 816    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 817 fi
 818 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 819    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 820 fi
 821
 822
 823 echo "\
 824     Building libavahi-core              yes
 825     Building avahi-daemon:              ${BUILD_DAEMON}
 826     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 827     Building libavahi-client:           ${BUILD_CLIENT}
 828     Building avahi-utils:               ${BUILD_CLIENT}
 829     Building avahi-python:              ${BUILD_PYTHON}
 830     Building libavahi-glib:             ${HAVE_GLIB}
 831     Building avahi-discover-standalone: ${HAVE_GTK}
 832     Building libavahi-qt3:              ${HAVE_QT3}
 833     Building libavahi-qt4:              ${HAVE_QT4}
 834     Building avahi-sharp:               ${HAVE_MONO}
 835     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 836     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 837     Building tests:                     ${ENABLE_TESTS}
 838 "