git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.4],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [5:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [3:3:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [3:2:0])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:0:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 126     if test "z$with_distro" = "z"; then
 127         with_distro=`uname -s`
 128     fi
 129 fi
 130 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 131
 132 case $with_distro in
 133     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|none)
 134      ;;
 135     netbsd)
 136      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 137      ;;
 138     linux)
 139      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 140      ;;
 141     *)
 142      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 143      ;;
 144 esac
 145
 146 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 147 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 148 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 149 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 150 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 151 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 152 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 153 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 154 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 155
 156 test_gcc_flag() {
 157     AC_LANG_CONFTEST([int main() {}])
 158     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 159     ret=$?
 160     rm -f conftest.o
 161     return $ret
 162 }
 163
 164 # If using GCC specify some additional parameters
 165 if test "x$GCC" = "xyes" ; then
 166
 167     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 168
 169     if test "x$HAVE_NETLINK" = "xyes" ; then
 170         # Test whether rtnetlink.h can be included when compiled with -std=c99
 171         # some distributions (e.g. archlinux) have broken headers that dont
 172         # define __u64 with -std=c99
 173         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 174         OLDCFLAGS="$CFLAGS"
 175         CFLAGS="-std=c99"
 176         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 177             use_stdc99=yes, use_stdc99=no)
 178
 179         if test x"$use_stdc99" = xyes; then
 180             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 181             AC_MSG_RESULT([yes])
 182         else
 183             AC_MSG_RESULT([no])
 184         fi
 185
 186         CFLAGS="$OLDCFLAGS"
 187     else
 188         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 189     fi
 190
 191     for flag in $DESIRED_FLAGS ; do
 192         AC_MSG_CHECKING([whether $CC accepts $flag])
 193         if test_gcc_flag $flag ; then
 194            CFLAGS="$CFLAGS $flag"
 195            AC_MSG_RESULT([yes])
 196         else
 197            AC_MSG_RESULT([no])
 198         fi
 199     done
 200 fi
 201
 202 # Checks for header files.
 203 AC_HEADER_STDC
 204 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 205 AC_HEADER_STDBOOL
 206
 207 # Checks for typedefs, structures, and compiler characteristics.
 208 AC_C_CONST
 209 AC_TYPE_SIZE_T
 210 AC_HEADER_TIME
 211 AC_HEADER_SYS_WAIT
 212
 213 # Checks for library functions.
 214 AC_FUNC_MEMCMP
 215 AC_FUNC_SELECT_ARGTYPES
 216 AC_FUNC_MALLOC
 217 AC_FUNC_REALLOC
 218 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 219
 220 AC_FUNC_CHOWN
 221 AC_FUNC_STAT
 222 AC_TYPE_MODE_T
 223 AC_TYPE_PID_T
 224
 225 AC_CHECK_DECLS(environ)
 226
 227 enable_chroot=yes
 228 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 229 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 230 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 231
 232 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 233
 234 if test "x$enable_chroot" = "xyes" ; then
 235    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 236 fi
 237
 238 # Check for pkg-config manually first, as if its not installed the
 239 # PKG_PROG_PKG_CONFIG macro won't be defined.
 240 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 241
 242 if test x"$have_pkg_config" = "xno"; then
 243     AC_MSG_ERROR(pkg-config is required to install this program)
 244 fi
 245
 246 PKG_PROG_PKG_CONFIG
 247
 248 #
 249 # Check for GLIB 2.0
 250 #
 251 AC_ARG_ENABLE(glib,
 252         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 253         [case "${enableval}" in
 254                 yes) HAVE_GLIB=yes ;;
 255                 no)  HAVE_GLIB=no ;;
 256                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 257         esac],
 258         [HAVE_GLIB=yes])
 259
 260 if test "x$HAVE_GLIB" = "xyes" ; then
 261         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 262         AC_SUBST(GLIB20_CFLAGS)
 263         AC_SUBST(GLIB20_LIBS)
 264 fi
 265 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 266
 267 #
 268 # Check for Qt 3
 269 #
 270 AC_ARG_ENABLE(qt3,
 271         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 272         [case "${enableval}" in
 273                 yes) HAVE_QT3=yes ;;
 274                 no)  HAVE_QT3=no ;;
 275                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 276         esac],
 277         [HAVE_QT3=yes])
 278
 279 if test "x$HAVE_QT3" = "xyes" ; then
 280         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 281         AC_SUBST(QT3_CFLAGS)
 282         AC_SUBST(QT3_LIBS)
 283             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 284         MOC_QT3="no"
 285             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 286                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 287                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 288         AC_SUBST(MOC_QT3)
 289 fi
 290 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 291
 292 #
 293 # Check for Qt 4
 294 #
 295 AC_ARG_ENABLE(qt4,
 296         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 297         [case "${enableval}" in
 298                 yes) HAVE_QT4=yes ;;
 299                 no)  HAVE_QT4=no ;;
 300                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 301         esac],
 302         [HAVE_QT4=yes])
 303
 304 if test "x$HAVE_QT4" = "xyes" ; then
 305         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 306         AC_SUBST(QT4_CFLAGS)
 307         AC_SUBST(QT4_LIBS)
 308             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 309         MOC_QT4="no"
 310             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 311                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 312                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 313         AC_SUBST(MOC_QT4)
 314 fi
 315 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 316
 317 #
 318 # Check for GTK+
 319 #
 320 AC_ARG_ENABLE(gtk,
 321         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 322         [case "${enableval}" in
 323                 yes) HAVE_GTK=yes ;;
 324                 no)  HAVE_GTK=no ;;
 325                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 326         esac],
 327         [HAVE_GTK=yes])
 328
 329 if test "x$HAVE_GTK" = "xyes" ; then
 330         # Check for GTK 2.0
 331         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 332         AC_SUBST(GTK20_CFLAGS)
 333         AC_SUBST(GTK20_LIBS)
 334
 335         # Check for GLADE 2.0
 336         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 337         AC_SUBST(GLADE20_CFLAGS)
 338         AC_SUBST(GLADE20_LIBS)
 339 fi
 340 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 341
 342 #
 343 # D-BUS
 344 #
 345 AC_ARG_ENABLE(dbus,
 346         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 347         [case "${enableval}" in
 348                 yes) HAVE_DBUS=yes ;;
 349                 no)  HAVE_DBUS=no ;;
 350                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 351         esac],
 352         [HAVE_DBUS=yes])
 353
 354 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 355 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 356
 357 DBUS_VERSION="Disabled"
 358 DBUS_SYS_DIR="Disabled"
 359 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 360 if test "x$HAVE_DBUS" = "xyes" ; then
 361     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 362
 363     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 364
 365     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 366     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 367     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 368     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 369     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 370         DBUS_VERSION_MAJOR="0"
 371     fi
 372     if test "z$DBUS_VERSION_MINOR" = "z"; then
 373         DBUS_VERSION_MINOR="0"
 374     fi
 375     if test "z$DBUS_VERSION_MICRO" = "z"; then
 376         DBUS_VERSION_MICRO="0"
 377     fi
 378
 379     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 380         echo "Error: Couldn't determine the version of your DBUS package."
 381         echo "  This is probably an error in this script, please report it"
 382         echo "  along with the following information:"
 383         echo "      Base DBUS version ='$DBUS_VERSION'"
 384         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 385         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 386         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 387         exit 1
 388     else
 389         echo "Your dbus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 390         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 391         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 392         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 393     fi
 394
 395     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 396     AC_SUBST(DBUS_CFLAGS)
 397     AC_SUBST(DBUS_LIBS)
 398
 399     if ! test -z "$with_dbus_sys" ; then
 400         DBUS_SYS_DIR="$with_dbus_sys"
 401     else
 402         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 403     fi
 404     AC_SUBST(DBUS_SYS_DIR)
 405
 406     if ! test -z "$with_dbus_system_address" ; then
 407         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 408     else
 409         # This is ugly, but D-BUS doesn't export this address for us
 410         # so we have to guess, pretty much all setups i've seen have
 411         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 412         # /var/run upstream so we will try guess first then default
 413         # to /var/run/dbus
 414
 415         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 416         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 417         for sock in $TRY_SOCKETS; do
 418             if test -S $sock; then
 419                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 420             fi
 421         done
 422     fi
 423     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 424
 425 fi
 426 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 427
 428 #
 429 # Expat
 430 #
 431 AC_ARG_ENABLE(expat,
 432         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 433         [case "${enableval}" in
 434                 yes) HAVE_EXPAT=yes ;;
 435                 no)  HAVE_EXPAT=no ;;
 436                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 437         esac],
 438         [HAVE_EXPAT=yes])
 439
 440 if test "x$HAVE_EXPAT" = "xyes" ; then
 441     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 442
 443     if ! $have_expat ; then
 444         AC_MSG_ERROR([*** libexpat not found ***])
 445     fi
 446 fi
 447 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 448
 449 #
 450 # GDBM
 451 #
 452 AC_ARG_ENABLE(gdbm,
 453         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 454         [case "${enableval}" in
 455                 yes) HAVE_GDBM=yes ;;
 456                 no)  HAVE_GDBM=no ;;
 457                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 458         esac],
 459         [HAVE_GDBM=yes])
 460
 461 if test "x$HAVE_GDBM" = "xyes" ; then
 462     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 463
 464     if ! $have_gdbm ; then
 465         AC_MSG_ERROR([*** libgdbm not found ***])
 466     fi
 467     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 468 fi
 469 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 470
 471 #
 472 # libdaemon
 473 #
 474 AC_ARG_ENABLE(libdaemon,
 475         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 476         [case "${enableval}" in
 477                 yes) HAVE_LIBDAEMON=yes ;;
 478                 no)  HAVE_LIBDAEMON=no ;;
 479                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 480         esac],
 481         [HAVE_LIBDAEMON=yes])
 482
 483 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 484     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 485     AC_SUBST(LIBDAEMON_CFLAGS)
 486     AC_SUBST(LIBDAEMON_LIBS)
 487 fi
 488 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 489
 490 #
 491 # Python stuff
 492 #
 493 AC_ARG_ENABLE(python,
 494     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 495     [case "${enableval}" in
 496           yes) HAVE_PYTHON=yes ;;
 497           no)  HAVE_PYTHON=no ;;
 498           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 499     esac],[HAVE_PYTHON=yes])
 500
 501 HAVE_PYTHON_DBUS=no
 502 HAVE_PYGTK=no
 503
 504 if test "x$HAVE_PYTHON" = "xyes" ; then
 505     AM_PATH_PYTHON([2.4])
 506
 507     AC_ARG_ENABLE(pygtk,
 508         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 509         [case "${enableval}" in
 510                 yes) HAVE_PYGTK=yes ;;
 511                 no)  HAVE_PYGTK=no ;;
 512                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 513         esac],
 514         [HAVE_PYGTK=yes])
 515
 516     if test "x$HAVE_PYGTK" = "xyes" ; then
 517         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 518     fi
 519
 520
 521     if test "x$HAVE_DBUS" = "xyes" ; then
 522         AC_ARG_ENABLE(python-dbus,
 523             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 524             [case "${enableval}" in
 525                    yes) HAVE_PYTHON_DBUS=yes ;;
 526                    no)  HAVE_PYTHON_DBUS=no ;;
 527                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 528             esac],
 529             [HAVE_PYTHON_DBUS=yes])
 530
 531         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 532             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 533         fi
 534
 535         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 536         AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 537     fi
 538 fi
 539 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 540 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 541 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 542
 543 #
 544 # Check for mono stuff
 545 #
 546 HAVE_MONO=no
 547 if test "x$HAVE_DBUS" = "xyes" ; then
 548     AC_ARG_ENABLE(mono,
 549             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 550             [case "${enableval}" in
 551                     yes) HAVE_MONO=yes ;;
 552                     no)  HAVE_MONO=no ;;
 553                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 554             esac],
 555             [HAVE_MONO=yes])
 556
 557     if test "x$HAVE_MONO" = "xyes" ; then
 558         AC_PATH_PROG(MCS, mcs)
 559         if test "x$MCS" = "x" ; then
 560             AC_MSG_ERROR([Can not find "mcs" in your PATH])
 561         fi
 562
 563         AC_PATH_PROG(GACUTIL, gacutil)
 564         if test "x$GACUTIL" = "x" ; then
 565             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 566         fi
 567
 568         AC_SUBST(MCS)
 569         AC_SUBST(GACUTIL)
 570     fi
 571 fi
 572 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 573
 574 #
 575 # Check for monodoc stuff
 576 #
 577 HAVE_MONODOC=no
 578 AC_ARG_ENABLE(monodoc,
 579         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 580         [case "${enableval}" in
 581                 yes) HAVE_MONODOC=yes ;;
 582                 no)  HAVE_MONODOC=no ;;
 583                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 584         esac],
 585         [HAVE_MONODOC=yes])
 586
 587 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 588         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 589         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 590
 591         AC_PATH_PROG(MONODOCER, monodocer)
 592         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 593
 594         AC_SUBST(MONODOC_DIR)
 595         AC_SUBST(MONODOCER)
 596         AC_SUBST(MDASSEMBLER)
 597 fi
 598 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 599
 600 #
 601 # Defining Avahi User and Group.
 602 #
 603 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 604 if test -z "$with_avahi_user" ; then
 605     AVAHI_USER=avahi
 606 else
 607     AVAHI_USER=$with_avahi_user
 608 fi
 609 AC_SUBST(AVAHI_USER)
 610 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 611
 612 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 613 if test -z "$with_avahi_group" ; then
 614     AVAHI_GROUP=avahi
 615 else
 616     AVAHI_GROUP=$with_avahi_group
 617 fi
 618 AC_SUBST(AVAHI_GROUP)
 619 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 620
 621 #
 622 # Avahi runtime dir
 623 #
 624 avahi_runtime_dir="${localstatedir}/run"
 625 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 626 AC_SUBST(avahi_runtime_dir)
 627 AC_SUBST(avahi_socket)
 628
 629 #
 630 # Avahi interfaces dir
 631 #
 632 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 633         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 634         AC_SUBST(interfacesdir)
 635 fi
 636
 637 #
 638 # Doxygen
 639 #
 640 DX_HTML_FEATURE(ON)
 641 DX_CHM_FEATURE(OFF)
 642 DX_CHI_FEATURE(OFF)
 643 DX_MAN_FEATURE(OFF)
 644 DX_RTF_FEATURE(OFF)
 645 DX_XML_FEATURE(OFF)
 646 DX_PDF_FEATURE(OFF)
 647 DX_PS_FEATURE(OFF)
 648 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 649
 650 #
 651 # Build and Install man pages
 652 #
 653 AC_ARG_ENABLE(manpages,
 654         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 655 [case "${enableval}" in
 656   yes) manpages=yes ;;
 657   no)  manpages=no ;;
 658   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 659 esac],[manpages=yes])
 660
 661 if test x$manpages = xyes ; then
 662     #
 663     # XMLTOMAN manpage generation
 664     #
 665     AC_ARG_ENABLE(xmltoman,
 666     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 667     [case "${enableval}" in
 668       yes) xmltoman=yes ;;
 669       no)  xmltoman=no ;;
 670       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 671     esac],[xmltoman=yes])
 672
 673     if test x$xmltoman = xyes ; then
 674         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 675     fi
 676
 677     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 678         if ! test -e man/avahi-daemon.8 ; then
 679             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 680             exit 1
 681         fi
 682         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 683         xmltoman=no
 684     fi
 685 fi
 686 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 687 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 688
 689 #
 690 # Conditionally compile test and example programs
 691 #
 692 AC_ARG_ENABLE(tests,
 693         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 694         [case "${enableval}" in
 695                 yes) ENABLE_TESTS=yes ;;
 696                 no)  ENABLE_TESTS=no ;;
 697                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 698         esac],
 699         [ENABLE_TESTS=no])
 700
 701 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 702
 703 #
 704 # Optionally enable libdns_sd compatibility support
 705 #
 706 AC_ARG_ENABLE(compat-libdns_sd,
 707         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 708         [case "${enableval}" in
 709                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 710                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 711                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 712         esac],
 713         [ENABLE_COMPAT_LIBDNS_SD=no])
 714
 715 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 716
 717 #
 718 # Optionally enable HOWL compatibility support
 719 #
 720 AC_ARG_ENABLE(compat-howl,
 721         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 722         [case "${enableval}" in
 723                 yes) ENABLE_COMPAT_HOWL=yes ;;
 724                 no)  ENABLE_COMPAT_HOWL=no ;;
 725                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 726         esac],
 727         [ENABLE_COMPAT_HOWL=no])
 728
 729 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 730
 731
 732 # ==========================================================================
 733 AC_CONFIG_FILES([
 734 Makefile
 735 avahi-common/Makefile
 736 avahi-core/Makefile
 737 avahi-glib/Makefile
 738 avahi-qt/Makefile
 739 avahi-daemon/Makefile
 740 avahi-daemon/avahi-dbus.conf
 741 avahi-discover-standalone/Makefile
 742 avahi-client/Makefile
 743 initscript/Makefile
 744 initscript/debian/Makefile
 745 initscript/gentoo/Makefile
 746 initscript/archlinux/Makefile
 747 initscript/suse/Makefile
 748 initscript/fedora/Makefile
 749 initscript/mandriva/Makefile
 750 initscript/darwin/Makefile
 751 initscript/freebsd/Makefile
 752 avahi-dnsconfd/Makefile
 753 avahi-utils/Makefile
 754 avahi-python/Makefile
 755 avahi-python/avahi/Makefile
 756 examples/Makefile
 757 common/Makefile
 758 man/Makefile
 759 tests/Makefile
 760 service-type-database/Makefile
 761 avahi-sharp/Makefile
 762 avahi-compat-libdns_sd/Makefile
 763 avahi-compat-howl/Makefile
 764 avahi-compat-howl/samples/Makefile
 765 ])
 766 AC_OUTPUT
 767
 768 # ==========================================================================
 769 echo "
 770  ---{ $PACKAGE_NAME $VERSION }---
 771
 772     prefix:                 ${prefix}
 773     sysconfdir:             ${sysconfdir}
 774     localstatedir:          ${localstatedir}
 775     avahi socket:           ${avahi_socket}
 776     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 777     dbus-1 version:         ${DBUS_VERSION}
 778     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 779     compiler:               ${CC}
 780     cflags:                 ${CFLAGS}
 781     Enable GLIB:            ${HAVE_GLIB}
 782     Enable GTK:             ${HAVE_GTK}
 783     Enable D-BUS:           ${HAVE_DBUS}
 784     Enable Expat:           ${HAVE_EXPAT}
 785     Enable GDBM:            ${HAVE_GDBM}
 786     Enable libdaemon:       ${HAVE_LIBDAEMON}
 787     Enable Python:          ${HAVE_PYTHON}
 788     Enable pygtk:           ${HAVE_PYGTK}
 789     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 790     Enable QT3:             ${HAVE_QT3}
 791     Enable QT4:             ${HAVE_QT4}
 792     Enable Mono:            ${HAVE_MONO}
 793     Enable Monodoc:         ${HAVE_MONODOC}
 794     Distribution/OS:        ${with_distro}
 795     User for Avahi:         ${AVAHI_USER}
 796     Group for Avahi:        ${AVAHI_GROUP}
 797     Enable chroot():        ${enable_chroot}
 798 "
 799
 800 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 801
 802 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 803     BUILD_DAEMON=yes
 804 fi
 805
 806 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 807
 808 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 809     BUILD_PYTHON=yes
 810 fi
 811
 812 BUILD_CLIENT="no   (You need avahi-daemon and dbus!)"
 813
 814 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 815     BUILD_CLIENT=yes
 816 fi
 817
 818 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 819    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 820 fi
 821 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 822    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 823 fi
 824
 825
 826 echo "\
 827     Building libavahi-core              yes
 828     Building avahi-daemon:              ${BUILD_DAEMON}
 829     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 830     Building libavahi-client:           ${BUILD_CLIENT}
 831     Building avahi-utils:               ${BUILD_CLIENT}
 832     Building avahi-python:              ${BUILD_PYTHON}
 833     Building libavahi-glib:             ${HAVE_GLIB}
 834     Building avahi-discover-standalone: ${HAVE_GTK}
 835     Building libavahi-qt3:              ${HAVE_QT3}
 836     Building libavahi-qt4:              ${HAVE_QT4}
 837     Building avahi-sharp:               ${HAVE_MONO}
 838     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 839     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 840     Building tests:                     ${ENABLE_TESTS}
 841 "