git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124 fi
 125 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 126
 127 if test "z$with_distro" = "z"; then
 128     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 129     exit 1
 130 else
 131 case $with_distro in
 132     debian|gentoo|archlinux|suse|none)
 133      ;;
 134     *)
 135      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 136      ;;
 137 esac
 138 fi
 139
 140 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 141 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 142 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 143 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 144
 145 test_gcc_flag() {
 146     AC_LANG_CONFTEST([int main() {}])
 147     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 148     ret=$?
 149     rm -f conftest.o
 150     return $ret
 151 }
 152
 153 # If using GCC specify some additional parameters
 154 if test "x$GCC" = "xyes" ; then
 155
 156     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
 157
 158     # Test whether rtnetlink.h can be included when compiled with -std=c99
 159     # some distributions (e.g. archlinux) have broken headers that dont
 160     # define __u64 with -std=c99
 161     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 162     OLDCFLAGS="$CFLAGS"
 163     CFLAGS="-std=c99"
 164     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 165         use_stdc99=yes, use_stdc99=no)
 166
 167     if test x"$use_stdc99" = xyes; then
 168         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 169         AC_MSG_RESULT([yes])
 170     else
 171         AC_MSG_RESULT([no])
 172     fi
 173
 174     CFLAGS="$OLDCFLAGS"
 175
 176     for flag in $DESIRED_FLAGS ; do
 177         AC_MSG_CHECKING([whether $CC accepts $flag])
 178         if test_gcc_flag $flag ; then
 179            CFLAGS="$CFLAGS $flag"
 180            AC_MSG_RESULT([yes])
 181         else
 182            AC_MSG_RESULT([no])
 183         fi
 184     done
 185 fi
 186
 187 # Checks for header files.
 188 AC_HEADER_STDC
 189 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 190 AC_HEADER_STDBOOL
 191
 192 # Checks for typedefs, structures, and compiler characteristics.
 193 AC_C_CONST
 194 AC_TYPE_SIZE_T
 195 AC_HEADER_TIME
 196 AC_HEADER_SYS_WAIT
 197
 198 # Checks for library functions.
 199 AC_FUNC_MEMCMP
 200 AC_FUNC_SELECT_ARGTYPES
 201 AC_FUNC_MALLOC
 202 AC_FUNC_REALLOC
 203 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname])
 204
 205 AC_FUNC_CHOWN
 206 AC_FUNC_STAT
 207 AC_TYPE_MODE_T
 208 AC_TYPE_PID_T
 209
 210 AC_CHECK_DECLS(environ)
 211
 212 # Check for pkg-config manually first, as if its not installed the
 213 # PKG_PROG_PKG_CONFIG macro won't be defined.
 214 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 215
 216 if test x"$have_pkg_config" == xno; then
 217     AC_MSG_ERROR(pkg-config is required to install this program)
 218 fi
 219
 220 PKG_PROG_PKG_CONFIG
 221
 222 #
 223 # Check for GLIB 2.0
 224 #
 225 AC_ARG_ENABLE(glib,
 226         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 227         [case "${enableval}" in
 228                 yes) HAVE_GLIB=yes ;;
 229                 no)  HAVE_GLIB=no ;;
 230                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 231         esac],
 232         [HAVE_GLIB=yes])
 233
 234 if test "x$HAVE_GLIB" = "xyes" ; then
 235         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 236         AC_SUBST(GLIB20_CFLAGS)
 237         AC_SUBST(GLIB20_LIBS)
 238 fi
 239 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 240
 241 #
 242 # Check for Qt 3
 243 #
 244 AC_ARG_ENABLE(qt3,
 245         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 246         [case "${enableval}" in
 247                 yes) HAVE_QT3=yes ;;
 248                 no)  HAVE_QT3=no ;;
 249                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 250         esac],
 251         [HAVE_QT3=yes])
 252
 253 if test "x$HAVE_QT3" = "xyes" ; then
 254         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 255         AC_SUBST(QT3_CFLAGS)
 256         AC_SUBST(QT3_LIBS)
 257             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 258         MOC_QT3="no"
 259             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 260                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 261                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 262         AC_SUBST(MOC_QT3)
 263 fi
 264 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 265
 266 #
 267 # Check for Qt 4
 268 #
 269 AC_ARG_ENABLE(qt4,
 270         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 271         [case "${enableval}" in
 272                 yes) HAVE_QT4=yes ;;
 273                 no)  HAVE_QT4=no ;;
 274                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 275         esac],
 276         [HAVE_QT4=yes])
 277
 278 if test "x$HAVE_QT4" = "xyes" ; then
 279         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 280         AC_SUBST(QT4_CFLAGS)
 281         AC_SUBST(QT4_LIBS)
 282             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 283         MOC_QT4="no"
 284             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 285                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 286                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 287         AC_SUBST(MOC_QT4)
 288 fi
 289 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 290
 291 #
 292 # Check for GTK+
 293 #
 294 AC_ARG_ENABLE(gtk,
 295         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 296         [case "${enableval}" in
 297                 yes) HAVE_GTK=yes ;;
 298                 no)  HAVE_GTK=no ;;
 299                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 300         esac],
 301         [HAVE_GTK=yes])
 302
 303 if test "x$HAVE_GTK" = "xyes" ; then
 304         # Check for GTK 2.0
 305         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 306         AC_SUBST(GTK20_CFLAGS)
 307         AC_SUBST(GTK20_LIBS)
 308
 309         # Check for GLADE 2.0
 310         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 311         AC_SUBST(GLADE20_CFLAGS)
 312         AC_SUBST(GLADE20_LIBS)
 313 fi
 314 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 315
 316 #
 317 # D-BUS
 318 #
 319 AC_ARG_ENABLE(dbus,
 320         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 321         [case "${enableval}" in
 322                 yes) HAVE_DBUS=yes ;;
 323                 no)  HAVE_DBUS=no ;;
 324                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 325         esac],
 326         [HAVE_DBUS=yes])
 327
 328 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 329 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 330
 331 if test "x$HAVE_DBUS" = "xyes" ; then
 332     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 333
 334     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 335     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 336     AC_SUBST(DBUS_CFLAGS)
 337     AC_SUBST(DBUS_LIBS)
 338
 339     if ! test -z "$with_dbus_sys" ; then
 340         DBUS_SYS_DIR="$with_dbus_sys"
 341     else
 342         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 343     fi
 344     AC_SUBST(DBUS_SYS_DIR)
 345
 346     if ! test -z "$with_dbus_system_address" ; then
 347         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 348     else
 349         # This is ugly, but D-BUS doesn't export this address for us
 350         # so we have to guess, pretty much all setups i've seen have
 351         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 352         # /var/run upstream so we will try guess first then default
 353         # to /var/run/dbus
 354
 355         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 356         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket"
 357         for sock in $TRY_SOCKETS; do
 358             if test -S $sock; then
 359                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 360             fi
 361         done
 362     fi
 363     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 364
 365 fi
 366 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 367
 368 #
 369 # Expat
 370 #
 371 AC_ARG_ENABLE(expat,
 372         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 373         [case "${enableval}" in
 374                 yes) HAVE_EXPAT=yes ;;
 375                 no)  HAVE_EXPAT=no ;;
 376                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 377         esac],
 378         [HAVE_EXPAT=yes])
 379
 380 if test "x$HAVE_EXPAT" = "xyes" ; then
 381     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 382
 383     if ! $have_expat ; then
 384         AC_MSG_ERROR([*** libexpat not found ***])
 385     fi
 386 fi
 387 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 388
 389 #
 390 # libdaemon
 391 #
 392 AC_ARG_ENABLE(libdaemon,
 393         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 394         [case "${enableval}" in
 395                 yes) HAVE_LIBDAEMON=yes ;;
 396                 no)  HAVE_LIBDAEMON=no ;;
 397                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 398         esac],
 399         [HAVE_LIBDAEMON=yes])
 400
 401 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 402     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 403     AC_SUBST(LIBDAEMON_CFLAGS)
 404     AC_SUBST(LIBDAEMON_LIBS)
 405 fi
 406 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 407
 408 #
 409 # Python stuff
 410 #
 411 AC_ARG_ENABLE(python,
 412     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 413     [case "${enableval}" in
 414           yes) HAVE_PYTHON=yes ;;
 415           no)  HAVE_PYTHON=no ;;
 416           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 417     esac],[HAVE_PYTHON=yes])
 418
 419 HAVE_PYTHON_DBUS=no
 420 HAVE_PYGTK=no
 421
 422 if test "x$HAVE_PYTHON" = "xyes" ; then
 423     AM_PATH_PYTHON([2.4])
 424
 425     AC_ARG_ENABLE(pygtk,
 426         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 427         [case "${enableval}" in
 428                 yes) HAVE_PYGTK=yes ;;
 429                 no)  HAVE_PYGTK=no ;;
 430                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 431         esac],
 432         [HAVE_PYGTK=yes])
 433
 434     if test "x$HAVE_PYGTK" = "xyes" ; then
 435         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 436     fi
 437
 438
 439     AC_ARG_ENABLE(python-dbus,
 440         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 441         [case "${enableval}" in
 442                 yes) HAVE_PYTHON_DBUS=yes ;;
 443                 no)  HAVE_PYTHON_DBUS=no ;;
 444                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 445         esac],
 446         [HAVE_PYTHON_DBUS=yes])
 447
 448     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 449         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 450     fi
 451
 452     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 453     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 454 fi
 455 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 456 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 457 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 458
 459 #
 460 # Check for mono stuff
 461 #
 462 AC_ARG_ENABLE(mono,
 463         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 464         [case "${enableval}" in
 465                 yes) HAVE_MONO=yes ;;
 466                 no)  HAVE_MONO=no ;;
 467                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 468         esac],
 469         [HAVE_MONO=yes])
 470
 471 AC_ARG_ENABLE(monodoc,
 472         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 473         [case "${enableval}" in
 474                 yes) HAVE_MONODOC=yes ;;
 475                 no)  HAVE_MONODOC=no ;;
 476                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 477         esac],
 478         [HAVE_MONODOC=yes])
 479
 480 if test "x$HAVE_MONO" = "xyes" ; then
 481         AC_PATH_PROG(MCS, mcs)
 482         if test "x$MCS" = "x" ; then
 483                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 484         fi
 485
 486         AC_PATH_PROG(GACUTIL, gacutil)
 487         if test "x$GACUTIL" = "x" ; then
 488                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 489         fi
 490
 491         AC_SUBST(MCS)
 492         AC_SUBST(GACUTIL)
 493 fi
 494 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 495
 496 #
 497 # Check for monodoc stuff
 498 #
 499 if test "x$HAVE_MONODOC" = "xyes" ; then
 500         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 501         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 502
 503         AC_PATH_PROG(MONODOCER, monodocer)
 504         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 505
 506         AC_SUBST(MONODOC_DIR)
 507         AC_SUBST(MONODOCER)
 508         AC_SUBST(MDASSEMBLER)
 509 fi
 510 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 511
 512 #
 513 # Defining Avahi User and Group.
 514 #
 515 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 516 if test -z "$with_avahi_user" ; then
 517     AVAHI_USER=avahi
 518 else
 519     AVAHI_USER=$with_avahi_user
 520 fi
 521 AC_SUBST(AVAHI_USER)
 522 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 523
 524 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 525 if test -z "$with_avahi_group" ; then
 526     AVAHI_GROUP=avahi
 527 else
 528     AVAHI_GROUP=$with_avahi_group
 529 fi
 530 AC_SUBST(AVAHI_GROUP)
 531 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 532
 533 #
 534 # Avahi runtime dir
 535 #
 536 avahi_runtime_dir="${localstatedir}/run"
 537 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 538 AC_SUBST(avahi_runtime_dir)
 539 AC_SUBST(avahi_socket)
 540
 541 #
 542 # Avahi interfaces dir
 543 #
 544 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 545         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 546         AC_SUBST(interfacesdir)
 547 fi
 548
 549 #
 550 # Doxygen
 551 #
 552 DX_HTML_FEATURE(ON)
 553 DX_CHM_FEATURE(OFF)
 554 DX_CHI_FEATURE(OFF)
 555 DX_MAN_FEATURE(OFF)
 556 DX_RTF_FEATURE(OFF)
 557 DX_XML_FEATURE(OFF)
 558 DX_PDF_FEATURE(OFF)
 559 DX_PS_FEATURE(OFF)
 560 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 561
 562 #
 563 # XMLTOMAN manpage generation
 564 #
 565 AC_ARG_ENABLE(xmltoman,
 566         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 567 [case "${enableval}" in
 568   yes) xmltoman=yes ;;
 569   no)  xmltoman=no ;;
 570   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 571 esac],[xmltoman=yes])
 572
 573 if test x$xmltoman = xyes ; then
 574     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 575
 576     if test x$have_xmltoman = xno ; then
 577         if ! test -e man/avahi-daemon.8 ; then
 578             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 579             exit 1
 580         fi
 581         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 582         xmltoman=no
 583     fi
 584 fi
 585
 586 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 587
 588 #
 589 # Conditionally compile test and example programs
 590 #
 591 AC_ARG_ENABLE(tests,
 592         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 593         [case "${enableval}" in
 594                 yes) ENABLE_TESTS=yes ;;
 595                 no)  ENABLE_TESTS=no ;;
 596                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 597         esac],
 598         [ENABLE_TESTS=no])
 599
 600 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 601
 602 #
 603 # Optionally enable libdns_sd compatibility support
 604 #
 605 AC_ARG_ENABLE(compat-libdns_sd,
 606         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 607         [case "${enableval}" in
 608                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 609                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 610                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 611         esac],
 612         [ENABLE_COMPAT_LIBDNS_SD=no])
 613
 614 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 615
 616 #
 617 # Optionally enable HOWL compatibility support
 618 #
 619 AC_ARG_ENABLE(compat-howl,
 620         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 621         [case "${enableval}" in
 622                 yes) ENABLE_COMPAT_HOWL=yes ;;
 623                 no)  ENABLE_COMPAT_HOWL=no ;;
 624                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 625         esac],
 626         [ENABLE_COMPAT_HOWL=no])
 627
 628 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 629
 630
 631 # ==========================================================================
 632 AC_CONFIG_FILES([
 633 Makefile
 634 avahi-common/Makefile
 635 avahi-core/Makefile
 636 avahi-glib/Makefile
 637 avahi-qt/Makefile
 638 avahi-daemon/Makefile
 639 avahi-daemon/avahi-dbus.conf
 640 avahi-discover-standalone/Makefile
 641 avahi-client/Makefile
 642 initscript/Makefile
 643 initscript/debian/Makefile
 644 initscript/gentoo/Makefile
 645 initscript/archlinux/Makefile
 646 initscript/suse/Makefile
 647 avahi-dnsconfd/Makefile
 648 avahi-utils/Makefile
 649 avahi-utils/avahi/Makefile
 650 examples/Makefile
 651 common/Makefile
 652 man/Makefile
 653 tests/Makefile
 654 service-type-database/Makefile
 655 avahi-sharp/Makefile
 656 avahi-compat-libdns_sd/Makefile
 657 avahi-compat-howl/Makefile
 658 avahi-compat-howl/samples/Makefile
 659 ])
 660 AC_OUTPUT
 661
 662 # ==========================================================================
 663 echo "
 664  ---{ $PACKAGE_NAME $VERSION }---
 665
 666     prefix:                 ${prefix}
 667     sysconfdir:             ${sysconfdir}
 668     localstatedir:          ${localstatedir}
 669     avahi socket:           ${avahi_socket}
 670     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 671     dbus-1 version:         `pkg-config dbus-1 --modversion`
 672     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 673     compiler:               ${CC}
 674     cflags:                 ${CFLAGS}
 675     Enable GLIB:            ${HAVE_GLIB}
 676     Enable GTK:             ${HAVE_GTK}
 677     Enable D-BUS:           ${HAVE_DBUS}
 678     Enable Expat:           ${HAVE_EXPAT}
 679     Enable libdaemon:       ${HAVE_LIBDAEMON}
 680     Enable Python:          ${HAVE_PYTHON}
 681     Enable pygtk:           ${HAVE_PYGTK}
 682     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 683     Enable QT3:             ${HAVE_QT3}
 684     Enable QT4:             ${HAVE_QT4}
 685     Enable Mono:            ${HAVE_MONO}
 686     Linux Distro:           ${with_distro}
 687     User for Avahi:         ${AVAHI_USER}
 688     Group for Avahi:        ${AVAHI_GROUP}
 689 "
 690
 691 BUILD_DAEMON="no (!)"
 692
 693 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 694     BUILD_DAEMON=yes
 695 fi
 696
 697 BUILD_UTILS="no (!)"
 698
 699 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 700     BUILD_UTILS=yes
 701 fi
 702
 703 BUILD_CLIENT="no (!)"
 704
 705 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 706     BUILD_CLIENT=yes
 707 fi
 708
 709 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 710    AC_MSG_ERROR([building avahi-compat-libdns_sd without building libavahi-client doesn't work])
 711 fi
 712 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 713    AC_MSG_ERROR([building avahi-compat-howl without building libavahi-client doesn't work])
 714 fi
 715
 716
 717 echo "
 718     Building libavahi-core              yes
 719     Building avahi-daemon:              ${BUILD_DAEMON}
 720     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 721     Building avahi-utils:               ${BUILD_UTILS}
 722     Building libavahi-glib:             ${HAVE_GLIB}
 723     Building libavahi-client:           ${BUILD_CLIENT}
 724     Building avahi-discover-standalone: ${HAVE_GTK}
 725     Building libavahi-qt3:              ${HAVE_QT3}
 726     Building libavahi-qt4:              ${HAVE_QT4}
 727     Building avahi-sharp:               ${HAVE_MONO}
 728     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 729     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 730     Building tests:                     ${ENABLE_TESTS}
 731 "