git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.18],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [7:4:4])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [5:1:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:2:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37 AC_SUBST(LIBAVAHI_UI_VERSION_INFO, [0:0:0])
  38
  39 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  40 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  41 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  42 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  43
  44 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  45     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  46     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  47 fi
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CXX
  52 AC_GNU_SOURCE
  53 AC_PROG_CPP
  54 AC_PROG_INSTALL
  55 AC_PROG_LN_S
  56 AC_PROG_MAKE_SET
  57 AC_PROG_GCC_TRADITIONAL
  58
  59 # -fstack-protector
  60 AC_ARG_ENABLE([stack-protector],
  61     [AS_HELP_STRING([--disable-stack-protector],
  62         [Disable GCC's/libc's stack-smashing protection])],
  63     [case "${enableval}" in
  64          yes) enable_ssp=yes ;;
  65           no) enable_ssp=no ;;
  66            *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;
  67      esac],
  68     [enable_ssp=yes])
  69
  70 if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then
  71     AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])
  72     enable_ssp=no
  73 fi
  74
  75 if test x"$enable_ssp" = x"yes"; then
  76     # Check for broken ssp in libc: http://www.avahi.org/ticket/105
  77     # libc's brokenness will get in the way regardless of whether -lssp is
  78     # provided, but provide it anyway (otherwise non-libc ssp would wrongly
  79     # break here)
  80
  81     # Get -lssp if it exists
  82     GCC_STACK_PROTECT_LIB
  83
  84     AC_MSG_CHECKING([whether stack-smashing protection is available])
  85     ssp_old_cflags="$CFLAGS"
  86     ssp_old_ldflags="$LDFLAGS"
  87     CFLAGS="$CFLAGS -fstack-protector-all -fPIC"
  88     LDFLAGS="$LDFLAGS -Wl,-z,defs"
  89     cat confdefs.h > conftest.c
  90     cat >>conftest.c <<_ACEOF
  91 void test_broken_ssp(c)
  92     const char *c;
  93 {
  94     char arr[[123]], *p; /* beware of possible double-braces if copying this */
  95     for (p = arr; *c; ++p) {
  96         *p = *c;
  97         ++c;
  98     }
  99 }
 100 _ACEOF
 101     rm -f conftest.o
 102
 103     if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then
 104         AC_MSG_RESULT([yes])
 105         AC_MSG_CHECKING([whether stack-smashing protection is buggy])
 106         if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then
 107             AC_MSG_RESULT([no])
 108         else
 109             AC_MSG_RESULT([yes])
 110             enable_ssp=no
 111         fi
 112     else
 113         AC_MSG_RESULT([no])
 114     fi
 115
 116     rm -f conftest.c conftest.o conftest.so
 117
 118     CFLAGS="$ssp_old_cflags"
 119     LDFLAGS="$ssp_old_ldflags"
 120 fi
 121
 122 if test x"$enable_ssp" = x"yes"; then
 123     # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice
 124     GCC_STACK_PROTECT_CC
 125
 126     AC_LANG_PUSH([C++])
 127     GCC_STACK_PROTECT_CXX
 128     AC_LANG_POP([C++])
 129     # XXX: Update the enable_ssp value now for output later?
 130 fi
 131
 132 # libtool stuff
 133 AC_PROG_LIBTOOL
 134
 135 AC_CACHE_CHECK([whether the C++ compiler works], [avahi_cv_sys_cxx_works], [
 136     AC_LANG_PUSH([C++])
 137     AC_COMPILE_IFELSE([int main() { return 0; }], [avahi_cv_sys_cxx_works=yes],
 138         [avahi_cv_sys_cxx_works=no])
 139     AC_LANG_POP([C++])
 140     ])
 141 [ if [ "x$avahi_cv_sys_cxx_works" = "xno" ]; then ]
 142     AC_MSG_FAILURE([The C++ compiler does not work])
 143 [ fi ]
 144
 145 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
 146
 147 #
 148 # Check for netlink.h
 149 #
 150 AC_CHECK_HEADER(linux/netlink.h,
 151 HAVE_NETLINK=yes
 152 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
 153 , [], [
 154 #include <sys/socket.h>
 155 #include <asm/types.h>
 156 ])
 157
 158 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
 159
 160 #
 161 # Check for net/route.h
 162 #
 163 AC_CHECK_HEADER(net/route.h,
 164 HAVE_PF_ROUTE=yes
 165 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
 166 , [], [
 167 #include <sys/types.h>
 168 #include <sys/socket.h>
 169 ])
 170
 171 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
 172
 173 #
 174 # Check for sys/filio.h; needed for FIONREAD on Solaris
 175 #
 176 AC_CHECK_HEADER(sys/filio.h,
 177 HAVE_SYS_FILIO_H=yes
 178 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 179 , [], [
 180 ])
 181
 182 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 183
 184 #
 185 # Check for sys/sysctl.h; not present on Solaris
 186 #
 187 AC_CHECK_HEADER(sys/sysctl.h,
 188 HAVE_SYS_SYSCTL=yes
 189 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 190 , [], [
 191 #include <sys/types.h>
 192 #include <sys/socket.h>
 193 #include <sys/param.h>
 194 ])
 195
 196 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 197
 198 #
 199 # Check for lifconf struct; only present on Solaris
 200 #
 201 AC_MSG_CHECKING(for struct lifconf)
 202 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 203 [AC_TRY_COMPILE(
 204 [#include <sys/socket.h>
 205 #include <net/if.h>
 206 ],[sizeof (struct lifconf);],
 207 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 208 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 209 if test $avahi_cv_has_struct_lifconf = yes; then
 210     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 211 fi
 212
 213 #
 214 # Check for struct ip_mreqn
 215 #
 216 AC_MSG_CHECKING(for struct ip_mreqn)
 217 AC_TRY_COMPILE([#include <netinet/in.h>], [
 218         struct ip_mreqn mreq;
 219         mreq.imr_address.s_addr = 0;
 220 ], [
 221         # Yes, we have it...
 222         AC_MSG_RESULT(yes)
 223         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 224 ], [
 225         # We'll just have to try and use struct ip_mreq
 226         AC_MSG_RESULT(no)
 227         AC_MSG_CHECKING(for struct ip_mreq)
 228         AC_TRY_COMPILE([#include <netinet/in.h>], [
 229                 struct ip_mreq mreq;
 230                 mreq.imr_interface.s_addr = 0;
 231         ], [
 232                 # Yes, we have it...
 233                 AC_MSG_RESULT(yes)
 234                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 235         ], [
 236                 # No multicast support
 237                         AC_MSG_RESULT(no)
 238         ])
 239 ])
 240
 241 #
 242 # Detecting the linux distribution for specific things like init scripts.
 243 #
 244 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 245 if test "z$with_distro" = "z"; then
 246     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 247     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 248     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 249     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 250     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 251     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 252     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 253     if test "z$with_distro" = "z"; then
 254         with_distro=`uname -s`
 255     fi
 256 fi
 257 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 258
 259 case $with_distro in
 260     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 261      ;;
 262     netbsd)
 263      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 264      ;;
 265     linux)
 266      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 267      ;;
 268     *)
 269      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 270      ;;
 271 esac
 272
 273 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 274 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 275 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 276 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 277 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 278 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 279 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 280 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 281 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 282 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 283
 284 test_gcc_flag() {
 285     AC_LANG_CONFTEST([int main() {}])
 286     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 287     ret=$?
 288     rm -f conftest.o
 289     return $ret
 290 }
 291
 292 # If using GCC specify some additional parameters
 293 if test "x$GCC" = "xyes" ; then
 294
 295     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -fPIC"
 296
 297     if test "x$HAVE_NETLINK" = "xyes" ; then
 298         # Test whether rtnetlink.h can be included when compiled with -std=c99
 299         # some distributions (e.g. archlinux) have broken headers that dont
 300         # define __u64 with -std=c99
 301         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 302         OLDCFLAGS="$CFLAGS"
 303         CFLAGS="-std=c99"
 304         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 305             use_stdc99=yes, use_stdc99=no)
 306
 307         if test x"$use_stdc99" = xyes; then
 308             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 309             AC_MSG_RESULT([yes])
 310         else
 311             AC_MSG_RESULT([no])
 312         fi
 313
 314         CFLAGS="$OLDCFLAGS"
 315     else
 316         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 317     fi
 318
 319     for flag in $DESIRED_FLAGS ; do
 320         AC_MSG_CHECKING([whether $CC accepts $flag])
 321         if test_gcc_flag $flag ; then
 322            CFLAGS="$CFLAGS $flag"
 323            AC_MSG_RESULT([yes])
 324         else
 325            AC_MSG_RESULT([no])
 326         fi
 327     done
 328 fi
 329
 330 # Checks for header files.
 331 AC_HEADER_STDC
 332 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 333 AC_HEADER_STDBOOL
 334
 335 # Checks for typedefs, structures, and compiler characteristics.
 336 AC_C_CONST
 337 AC_TYPE_SIZE_T
 338 AC_HEADER_TIME
 339 AC_HEADER_SYS_WAIT
 340
 341 # Checks for library functions.
 342 AC_FUNC_MEMCMP
 343 AC_FUNC_SELECT_ARGTYPES
 344 AC_FUNC_MALLOC
 345 AC_FUNC_REALLOC
 346 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 347
 348 AC_FUNC_CHOWN
 349 AC_FUNC_STAT
 350 AC_TYPE_MODE_T
 351 AC_TYPE_PID_T
 352
 353 AC_CHECK_DECLS(environ)
 354
 355 enable_chroot=yes
 356 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 357 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 358 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 359
 360 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 361
 362 if test "x$enable_chroot" = "xyes" ; then
 363    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 364 fi
 365
 366 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 367 if test "x$HAVE_DLOPEN" = "xyes" ; then
 368     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 369 fi
 370 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 371
 372 have_inotify=no
 373 AC_CHECK_HEADERS([linux/inotify.h], [have_inotify=yes])
 374 AC_CHECK_HEADERS([sys/inotify.h], [have_inotify=yes])
 375
 376 AM_CONDITIONAL(HAVE_INOTIFY, test "x$have_inotify" = "xyes")
 377
 378 if test "x$have_inotify" = "xyes" ; then
 379    AC_DEFINE([HAVE_INOTIFY], 1, [Enable Linux inotify() usage])
 380 fi
 381
 382 # Check for pkg-config manually first, as if its not installed the
 383 # PKG_PROG_PKG_CONFIG macro won't be defined.
 384 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 385
 386 if test x"$have_pkg_config" = "xno"; then
 387     AC_MSG_ERROR(pkg-config is required to install this program)
 388 fi
 389
 390 PKG_PROG_PKG_CONFIG
 391
 392 #
 393 # Check for GLIB 2.0
 394 #
 395 AC_ARG_ENABLE(glib,
 396         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 397         [case "${enableval}" in
 398                 yes) HAVE_GLIB=yes ;;
 399                 no)  HAVE_GLIB=no ;;
 400                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 401         esac],
 402         [HAVE_GLIB=yes])
 403
 404 if test "x$HAVE_GLIB" = "xyes" ; then
 405         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 406         AC_SUBST(GLIB20_CFLAGS)
 407         AC_SUBST(GLIB20_LIBS)
 408 fi
 409 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 410
 411 #
 412 # Check for Qt 3
 413 #
 414 AC_ARG_ENABLE(qt3,
 415         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 416         [case "${enableval}" in
 417                 yes) HAVE_QT3=yes ;;
 418                 no)  HAVE_QT3=no ;;
 419                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 420         esac],
 421         [HAVE_QT3=yes])
 422
 423 if test "x$HAVE_QT3" = "xyes" ; then
 424         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 425         AC_SUBST(QT3_CFLAGS)
 426         AC_SUBST(QT3_LIBS)
 427             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 428         MOC_QT3="no"
 429             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 430                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 431                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 432         AC_SUBST(MOC_QT3)
 433 fi
 434 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 435
 436 #
 437 # Check for Qt 4
 438 #
 439 AC_ARG_ENABLE(qt4,
 440         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 441         [case "${enableval}" in
 442                 yes) HAVE_QT4=yes ;;
 443                 no)  HAVE_QT4=no ;;
 444                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 445         esac],
 446         [HAVE_QT4=yes])
 447
 448 if test "x$HAVE_QT4" = "xyes" ; then
 449         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 450         AC_SUBST(QT4_CFLAGS)
 451         AC_SUBST(QT4_LIBS)
 452             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 453         MOC_QT4="no"
 454             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 455                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 456                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 457         AC_SUBST(MOC_QT4)
 458 fi
 459 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 460
 461 #
 462 # Check for GTK+
 463 #
 464 AC_ARG_ENABLE(gtk,
 465         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 466         [case "${enableval}" in
 467                 yes) HAVE_GTK=yes ;;
 468                 no)  HAVE_GTK=no ;;
 469                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 470         esac],
 471         [HAVE_GTK=yes])
 472
 473 if test "x$HAVE_GTK" = "xyes" ; then
 474         # Check for GTK 2.0
 475         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 476         AC_SUBST(GTK20_CFLAGS)
 477         AC_SUBST(GTK20_LIBS)
 478
 479         # Check for GLADE 2.0
 480         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 481         AC_SUBST(GLADE20_CFLAGS)
 482         AC_SUBST(GLADE20_LIBS)
 483 fi
 484 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 485
 486 #
 487 # D-Bus
 488 #
 489 AC_ARG_ENABLE(dbus,
 490         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 491         [case "${enableval}" in
 492                 yes) HAVE_DBUS=yes ;;
 493                 no)  HAVE_DBUS=no ;;
 494                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 495         esac],
 496         [HAVE_DBUS=yes])
 497
 498 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 499 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 500
 501 DBUS_VERSION="Disabled"
 502 DBUS_SYS_DIR="Disabled"
 503 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 504 if test "x$HAVE_DBUS" = "xyes" ; then
 505     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 506
 507     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 508
 509     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 510     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 511     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 512     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 513     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 514         DBUS_VERSION_MAJOR="0"
 515     fi
 516     if test "z$DBUS_VERSION_MINOR" = "z"; then
 517         DBUS_VERSION_MINOR="0"
 518     fi
 519     if test "z$DBUS_VERSION_MICRO" = "z"; then
 520         DBUS_VERSION_MICRO="0"
 521     fi
 522
 523     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 524         echo "Error: Couldn't determine the version of your D-Bus package."
 525         echo "  This is probably an error in this script, please report it"
 526         echo "  along with the following information:"
 527         echo "      Base D-Buss version ='$DBUS_VERSION'"
 528         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 529         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 530         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 531         exit 1
 532     else
 533         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 534         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 535         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 536         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 537     fi
 538
 539     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 540     AC_SUBST(DBUS_CFLAGS)
 541     AC_SUBST(DBUS_LIBS)
 542
 543     if ! test -z "$with_dbus_sys" ; then
 544         DBUS_SYS_DIR="$with_dbus_sys"
 545     else
 546         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 547     fi
 548     AC_SUBST(DBUS_SYS_DIR)
 549
 550     if ! test -z "$with_dbus_system_address" ; then
 551         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 552     else
 553         # This is ugly, but D-Bus doesn't export this address for us
 554         # so we have to guess, pretty much all setups i've seen have
 555         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 556         # /var/run upstream so we will try guess first then default
 557         # to /var/run/dbus.
 558
 559         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 560         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 561         for sock in $TRY_SOCKETS; do
 562             if test -S $sock; then
 563                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 564             fi
 565         done
 566     fi
 567     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 568
 569     SAVED_LIBS="$LIBS"
 570     LIBS="$LIBS $DBUS_LIBS"
 571     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 572     LIBS="$SAVED_LIBS"
 573 fi
 574 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 575
 576 #
 577 # Expat
 578 #
 579 AC_ARG_ENABLE(expat,
 580         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 581         [case "${enableval}" in
 582                 yes) HAVE_EXPAT=yes ;;
 583                 no)  HAVE_EXPAT=no ;;
 584                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 585         esac],
 586         [HAVE_EXPAT=yes])
 587
 588 if test "x$HAVE_EXPAT" = "xyes" ; then
 589     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 590
 591     if ! $have_expat ; then
 592         AC_MSG_ERROR([*** libexpat not found ***])
 593     fi
 594 fi
 595 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 596
 597 #
 598 # GDBM
 599 #
 600 #
 601 # Check for dbm
 602 #
 603 AC_ARG_ENABLE(dbm,
 604         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 605         [case "${enableval}" in
 606                 yes) HAVE_DBM=yes ;;
 607                 no)  HAVE_DBM=no ;;
 608                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 609         esac],
 610         [HAVE_DBM=no])
 611
 612 AC_ARG_ENABLE(gdbm,
 613         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 614         [case "${enableval}" in
 615                 yes) HAVE_GDBM=yes ;;
 616                 no)  HAVE_GDBM=no ;;
 617                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 618         esac],
 619         [HAVE_GDBM=yes])
 620
 621 if test "x$HAVE_GDBM" = "xyes" ; then
 622     if test "x$HAVE_DBM" = "xyes" ; then
 623         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 624     fi
 625     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 626
 627     if ! $have_gdbm ; then
 628         AC_MSG_ERROR([*** libgdbm not found ***])
 629     fi
 630     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 631 else
 632     if test "x$HAVE_DBM" = "xyes" ; then
 633         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 634
 635         if ! $have_dbm ; then
 636             AC_MSG_ERROR([*** dbm not found ***])
 637         fi
 638         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 639     fi
 640 fi
 641 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 642 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 643
 644 #
 645 # libdaemon
 646 #
 647 AC_ARG_ENABLE(libdaemon,
 648         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 649         [case "${enableval}" in
 650                 yes) HAVE_LIBDAEMON=yes ;;
 651                 no)  HAVE_LIBDAEMON=no ;;
 652                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 653         esac],
 654         [HAVE_LIBDAEMON=yes])
 655
 656 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 657     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 658     AC_SUBST(LIBDAEMON_CFLAGS)
 659     AC_SUBST(LIBDAEMON_LIBS)
 660 fi
 661 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 662
 663 #
 664 # Python stuff
 665 #
 666 AC_ARG_ENABLE(python,
 667     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 668     [case "${enableval}" in
 669           yes) HAVE_PYTHON=yes ;;
 670           no)  HAVE_PYTHON=no ;;
 671           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 672     esac],[HAVE_PYTHON=yes])
 673
 674 HAVE_PYTHON_DBUS=no
 675 HAVE_PYGTK=no
 676
 677 if test "x$HAVE_PYTHON" = "xyes" ; then
 678     AM_PATH_PYTHON([2.4])
 679
 680     AC_ARG_ENABLE(pygtk,
 681         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 682         [case "${enableval}" in
 683                 yes) HAVE_PYGTK=yes ;;
 684                 no)  HAVE_PYGTK=no ;;
 685                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 686         esac],
 687         [HAVE_PYGTK=yes])
 688
 689     if test "x$HAVE_PYGTK" = "xyes" ; then
 690         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 691     fi
 692
 693
 694     if test "x$HAVE_DBUS" = "xyes" ; then
 695         AC_ARG_ENABLE(python-dbus,
 696             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 697             [case "${enableval}" in
 698                    yes) HAVE_PYTHON_DBUS=yes ;;
 699                    no)  HAVE_PYTHON_DBUS=no ;;
 700                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 701             esac],
 702             [HAVE_PYTHON_DBUS=yes])
 703
 704         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 705             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 706         fi
 707
 708         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 709         if test "x$HAVE_GDBM" = "xyes"; then
 710             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 711         fi
 712         if test "x$HAVE_DBM" = "xyes"; then
 713             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 714         fi
 715     fi
 716 fi
 717 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 718 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 719 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 720
 721 #
 722 # Check for mono stuff
 723 #
 724 HAVE_MONO=no
 725 if test "x$HAVE_DBUS" = "xyes" ; then
 726     AC_ARG_ENABLE(mono,
 727             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 728             [case "${enableval}" in
 729                     yes) HAVE_MONO=yes ;;
 730                     no)  HAVE_MONO=no ;;
 731                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 732             esac],
 733             [HAVE_MONO=yes])
 734
 735     if test "x$HAVE_MONO" = "xyes" ; then
 736         AC_PATH_PROG(MCS, mcs)
 737         if test "x$MCS" = "x" ; then
 738             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 739         fi
 740
 741         AC_PATH_PROG(GACUTIL, gacutil)
 742         if test "x$GACUTIL" = "x" ; then
 743             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 744         fi
 745
 746         AC_SUBST(MCS)
 747         AC_SUBST(GACUTIL)
 748     fi
 749 fi
 750 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 751
 752 #
 753 # Check for monodoc stuff
 754 #
 755 HAVE_MONODOC=no
 756 AC_ARG_ENABLE(monodoc,
 757         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 758         [case "${enableval}" in
 759                 yes) HAVE_MONODOC=yes ;;
 760                 no)  HAVE_MONODOC=no ;;
 761                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 762         esac],
 763         [HAVE_MONODOC=yes])
 764
 765 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 766         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 767         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 768
 769         AC_PATH_PROG(MONODOCER, monodocer)
 770         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 771
 772         AC_SUBST(MONODOC_DIR)
 773         AC_SUBST(MONODOCER)
 774         AC_SUBST(MDASSEMBLER)
 775 fi
 776 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 777
 778 #
 779 # Build autoipd?
 780 #
 781 AC_ARG_ENABLE(autoipd,
 782         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 783         [case "${enableval}" in
 784                 yes) ENABLE_AUTOIPD=yes ;;
 785                 no)  ENABLE_AUTOIPD=no ;;
 786                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 787         esac],
 788         [ENABLE_AUTOIPD=yes])
 789
 790 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 791
 792 #
 793 # Defining users and groups
 794 #
 795 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 796 if test -z "$with_avahi_user" ; then
 797     AVAHI_USER=avahi
 798 else
 799     AVAHI_USER=$with_avahi_user
 800 fi
 801 AC_SUBST(AVAHI_USER)
 802 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 803
 804 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 805 if test -z "$with_avahi_group" ; then
 806     AVAHI_GROUP=avahi
 807 else
 808     AVAHI_GROUP=$with_avahi_group
 809 fi
 810 AC_SUBST(AVAHI_GROUP)
 811 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 812
 813 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 814 if test -z "$with_avahi_priv_access_group" ; then
 815     AVAHI_PRIV_ACCESS_GROUP=netdev
 816 else
 817     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 818 fi
 819 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 820 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 821
 822 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autoipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 823 if test -z "$with_autoipd_user" ; then
 824     AVAHI_AUTOIPD_USER=avahi-autoipd
 825 else
 826     AVAHI_AUTOIPD_USER=$with_autoipd_user
 827 fi
 828 AC_SUBST(AVAHI_AUTOIPD_USER)
 829 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 830
 831 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 832 if test -z "$with_autoipd_group" ; then
 833     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 834 else
 835     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 836 fi
 837 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 838 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 839
 840 #
 841 # Avahi runtime dir
 842 #
 843 avahi_runtime_dir="${localstatedir}/run"
 844 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 845 AC_SUBST(avahi_runtime_dir)
 846 AC_SUBST(avahi_socket)
 847
 848 #
 849 # Avahi interfaces dir
 850 #
 851 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 852         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 853         AC_SUBST(interfacesdir)
 854 fi
 855
 856 #
 857 # Doxygen
 858 #
 859 DX_HTML_FEATURE(ON)
 860 DX_CHM_FEATURE(OFF)
 861 DX_CHI_FEATURE(OFF)
 862 DX_MAN_FEATURE(OFF)
 863 DX_RTF_FEATURE(OFF)
 864 DX_XML_FEATURE(OFF)
 865 DX_PDF_FEATURE(OFF)
 866 DX_PS_FEATURE(OFF)
 867 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 868
 869 AC_ARG_ENABLE(core-docs,
 870         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 871 [case "${enableval}" in
 872   yes) ENABLE_CORE_DOCS=yes ;;
 873   no)  ENABLE_CORE_DOCS=no ;;
 874   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 875 esac],[ENABLE_CORE_DOCS=no])
 876
 877 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 878
 879 #
 880 # Build and Install man pages
 881 #
 882 AC_ARG_ENABLE(manpages,
 883         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 884 [case "${enableval}" in
 885   yes) manpages=yes ;;
 886   no)  manpages=no ;;
 887   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 888 esac],[manpages=yes])
 889
 890 if test x$manpages = xyes ; then
 891     #
 892     # XMLTOMAN manpage generation
 893     #
 894     AC_ARG_ENABLE(xmltoman,
 895     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 896     [case "${enableval}" in
 897       yes) xmltoman=yes ;;
 898       no)  xmltoman=no ;;
 899       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 900     esac],[xmltoman=yes])
 901
 902     if test x$xmltoman = xyes ; then
 903         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 904     fi
 905
 906     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 907         if ! test -e man/avahi-daemon.8 ; then
 908             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 909             exit 1
 910         fi
 911         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 912         xmltoman=no
 913     fi
 914 fi
 915 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 916 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 917
 918 #
 919 # Conditionally compile test and example programs
 920 #
 921 AC_ARG_ENABLE(tests,
 922         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 923         [case "${enableval}" in
 924                 yes) ENABLE_TESTS=yes ;;
 925                 no)  ENABLE_TESTS=no ;;
 926                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 927         esac],
 928         [ENABLE_TESTS=no])
 929
 930 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 931
 932 #
 933 # Optionally enable libdns_sd compatibility support
 934 #
 935 AC_ARG_ENABLE(compat-libdns_sd,
 936         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 937         [case "${enableval}" in
 938                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 939                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 940                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 941         esac],
 942         [ENABLE_COMPAT_LIBDNS_SD=no])
 943
 944 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 945
 946 #
 947 # Optionally enable HOWL compatibility support
 948 #
 949 AC_ARG_ENABLE(compat-howl,
 950         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 951         [case "${enableval}" in
 952                 yes) ENABLE_COMPAT_HOWL=yes ;;
 953                 no)  ENABLE_COMPAT_HOWL=no ;;
 954                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 955         esac],
 956         [ENABLE_COMPAT_HOWL=no])
 957
 958 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 959
 960
 961 # ==========================================================================
 962 AC_CONFIG_FILES([
 963 Makefile
 964 avahi-common/Makefile
 965 avahi-core/Makefile
 966 avahi-glib/Makefile
 967 avahi-qt/Makefile
 968 avahi-daemon/Makefile
 969 avahi-daemon/avahi-dbus.conf
 970 avahi-discover-standalone/Makefile
 971 avahi-client/Makefile
 972 initscript/Makefile
 973 initscript/debian/Makefile
 974 initscript/gentoo/Makefile
 975 initscript/archlinux/Makefile
 976 initscript/suse/Makefile
 977 initscript/fedora/Makefile
 978 initscript/mandriva/Makefile
 979 initscript/darwin/Makefile
 980 initscript/freebsd/Makefile
 981 initscript/slackware/Makefile
 982 avahi-dnsconfd/Makefile
 983 avahi-utils/Makefile
 984 avahi-python/Makefile
 985 avahi-python/avahi/Makefile
 986 examples/Makefile
 987 common/Makefile
 988 man/Makefile
 989 tests/Makefile
 990 service-type-database/Makefile
 991 avahi-sharp/Makefile
 992 avahi-compat-libdns_sd/Makefile
 993 avahi-compat-howl/Makefile
 994 avahi-compat-howl/samples/Makefile
 995 avahi-autoipd/Makefile
 996 avahi-ui/Makefile
 997 ])
 998 AC_OUTPUT
 999
1000 # ==========================================================================
1001 echo "
1002  ---{ $PACKAGE_NAME $VERSION }---
1003
1004     prefix:                                    ${prefix}
1005     sysconfdir:                                ${sysconfdir}
1006     localstatedir:                             ${localstatedir}
1007     avahi socket:                              ${avahi_socket}
1008     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
1009     dbus-1 version:                            ${DBUS_VERSION}
1010     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1011     C Compiler:                                ${CC}
1012     CFLAGS:                                    ${CFLAGS}
1013     Enable GLIB:                               ${HAVE_GLIB}
1014     Enable GTK:                                ${HAVE_GTK}
1015     Enable D-Bus:                              ${HAVE_DBUS}
1016     Enable Expat:                              ${HAVE_EXPAT}
1017     Enable GDBM:                               ${HAVE_GDBM}
1018     Enable DBM:                                ${HAVE_DBM}
1019     Enable libdaemon:                          ${HAVE_LIBDAEMON}
1020     Enable Python:                             ${HAVE_PYTHON}
1021     Enable pygtk:                              ${HAVE_PYGTK}
1022     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
1023     Enable QT3:                                ${HAVE_QT3}
1024     Enable QT4:                                ${HAVE_QT4}
1025     Enable Mono:                               ${HAVE_MONO}
1026     Enable Monodoc:                            ${HAVE_MONODOC}
1027     Distribution/OS:                           ${with_distro}
1028     User for avahi-daemon:                     ${AVAHI_USER}
1029     Group for avahi-daemon:                    ${AVAHI_GROUP}
1030     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
1031     User for avahi-autoipd:                    ${AVAHI_AUTOIPD_USER}
1032     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
1033     Enable chroot():                           ${enable_chroot}
1034     Enable Linux inotify:                      ${have_inotify}
1035     Enable stack-smashing protection:          ${enable_ssp}
1036 "
1037
1038 BUILD_DAEMON="no   (You need libdaemon and expat!)"
1039
1040 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
1041     BUILD_DAEMON=yes
1042 fi
1043
1044 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
1045
1046 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
1047     BUILD_PYTHON=yes
1048 fi
1049
1050 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
1051
1052 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
1053     BUILD_CLIENT=yes
1054 fi
1055
1056 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1057    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
1058 fi
1059 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1060    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
1061 fi
1062 if test "x$ENABLE_AUTOIPD" = "xyes" -a "x$HAVE_LIBDAEMON" != "xyes" ; then
1063    ENABLE_AUTOIPD="no   (You need libdaemon!)"
1064 fi
1065
1066 BUILD_UI="no"
1067 if test "x$HAVE_GTK" = "xyes" -a "x$BUILD_CLIENT" = "xyes" ; then
1068    BUILD_UI="yes"
1069 fi
1070
1071 echo "\
1072     Building libavahi-core              yes
1073     Building avahi-daemon:              ${BUILD_DAEMON}
1074     Building avahi-dnsconfd:            ${BUILD_DAEMON}
1075     Building libavahi-client:           ${BUILD_CLIENT}
1076     Building avahi-utils:               ${BUILD_CLIENT}
1077     Building avahi-python:              ${BUILD_PYTHON}
1078     Building libavahi-glib:             ${HAVE_GLIB}
1079     Building avahi-discover-standalone: ${HAVE_GTK}
1080     Building libavahi-qt3:              ${HAVE_QT3}
1081     Building libavahi-qt4:              ${HAVE_QT4}
1082     Building avahi-sharp:               ${HAVE_MONO}
1083     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
1084     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
1085     Building tests:                     ${ENABLE_TESTS}
1086     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
1087     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
1088     Building libavahi-ui:               ${BUILD_UI}
1089 "