git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.9],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [6:0:3])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [4:1:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [4:1:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:0:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 126     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 127     if test "z$with_distro" = "z"; then
 128         with_distro=`uname -s`
 129     fi
 130 fi
 131 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 132
 133 case $with_distro in
 134     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 135      ;;
 136     netbsd)
 137      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 138      ;;
 139     linux)
 140      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 141      ;;
 142     *)
 143      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 144      ;;
 145 esac
 146
 147 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 148 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 149 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 150 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 151 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 152 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 153 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 154 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 155 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 156 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 157
 158 test_gcc_flag() {
 159     AC_LANG_CONFTEST([int main() {}])
 160     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 161     ret=$?
 162     rm -f conftest.o
 163     return $ret
 164 }
 165
 166 # If using GCC specify some additional parameters
 167 if test "x$GCC" = "xyes" ; then
 168
 169     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 170
 171     if test "x$HAVE_NETLINK" = "xyes" ; then
 172         # Test whether rtnetlink.h can be included when compiled with -std=c99
 173         # some distributions (e.g. archlinux) have broken headers that dont
 174         # define __u64 with -std=c99
 175         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 176         OLDCFLAGS="$CFLAGS"
 177         CFLAGS="-std=c99"
 178         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 179             use_stdc99=yes, use_stdc99=no)
 180
 181         if test x"$use_stdc99" = xyes; then
 182             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 183             AC_MSG_RESULT([yes])
 184         else
 185             AC_MSG_RESULT([no])
 186         fi
 187
 188         CFLAGS="$OLDCFLAGS"
 189     else
 190         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 191     fi
 192
 193     for flag in $DESIRED_FLAGS ; do
 194         AC_MSG_CHECKING([whether $CC accepts $flag])
 195         if test_gcc_flag $flag ; then
 196            CFLAGS="$CFLAGS $flag"
 197            AC_MSG_RESULT([yes])
 198         else
 199            AC_MSG_RESULT([no])
 200         fi
 201     done
 202 fi
 203
 204 # Checks for header files.
 205 AC_HEADER_STDC
 206 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 207 AC_HEADER_STDBOOL
 208
 209 # Checks for typedefs, structures, and compiler characteristics.
 210 AC_C_CONST
 211 AC_TYPE_SIZE_T
 212 AC_HEADER_TIME
 213 AC_HEADER_SYS_WAIT
 214
 215 # Checks for library functions.
 216 AC_FUNC_MEMCMP
 217 AC_FUNC_SELECT_ARGTYPES
 218 AC_FUNC_MALLOC
 219 AC_FUNC_REALLOC
 220 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 221
 222 AC_FUNC_CHOWN
 223 AC_FUNC_STAT
 224 AC_TYPE_MODE_T
 225 AC_TYPE_PID_T
 226
 227 AC_CHECK_DECLS(environ)
 228
 229 enable_chroot=yes
 230 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 231 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 232 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 233
 234 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 235
 236 if test "x$enable_chroot" = "xyes" ; then
 237    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 238 fi
 239
 240 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 241 if test "x$HAVE_DLOPEN" = "xyes" ; then
 242     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 243 fi
 244 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 245
 246 # Check for pkg-config manually first, as if its not installed the
 247 # PKG_PROG_PKG_CONFIG macro won't be defined.
 248 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 249
 250 if test x"$have_pkg_config" = "xno"; then
 251     AC_MSG_ERROR(pkg-config is required to install this program)
 252 fi
 253
 254 PKG_PROG_PKG_CONFIG
 255
 256 #
 257 # Check for GLIB 2.0
 258 #
 259 AC_ARG_ENABLE(glib,
 260         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 261         [case "${enableval}" in
 262                 yes) HAVE_GLIB=yes ;;
 263                 no)  HAVE_GLIB=no ;;
 264                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 265         esac],
 266         [HAVE_GLIB=yes])
 267
 268 if test "x$HAVE_GLIB" = "xyes" ; then
 269         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 270         AC_SUBST(GLIB20_CFLAGS)
 271         AC_SUBST(GLIB20_LIBS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 274
 275 #
 276 # Check for Qt 3
 277 #
 278 AC_ARG_ENABLE(qt3,
 279         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 280         [case "${enableval}" in
 281                 yes) HAVE_QT3=yes ;;
 282                 no)  HAVE_QT3=no ;;
 283                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 284         esac],
 285         [HAVE_QT3=yes])
 286
 287 if test "x$HAVE_QT3" = "xyes" ; then
 288         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 289         AC_SUBST(QT3_CFLAGS)
 290         AC_SUBST(QT3_LIBS)
 291             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 292         MOC_QT3="no"
 293             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 294                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 295                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 296         AC_SUBST(MOC_QT3)
 297 fi
 298 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 299
 300 #
 301 # Check for Qt 4
 302 #
 303 AC_ARG_ENABLE(qt4,
 304         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 305         [case "${enableval}" in
 306                 yes) HAVE_QT4=yes ;;
 307                 no)  HAVE_QT4=no ;;
 308                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 309         esac],
 310         [HAVE_QT4=yes])
 311
 312 if test "x$HAVE_QT4" = "xyes" ; then
 313         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 314         AC_SUBST(QT4_CFLAGS)
 315         AC_SUBST(QT4_LIBS)
 316             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 317         MOC_QT4="no"
 318             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 319                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 320                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 321         AC_SUBST(MOC_QT4)
 322 fi
 323 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 324
 325 #
 326 # Check for GTK+
 327 #
 328 AC_ARG_ENABLE(gtk,
 329         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 330         [case "${enableval}" in
 331                 yes) HAVE_GTK=yes ;;
 332                 no)  HAVE_GTK=no ;;
 333                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 334         esac],
 335         [HAVE_GTK=yes])
 336
 337 if test "x$HAVE_GTK" = "xyes" ; then
 338         # Check for GTK 2.0
 339         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 340         AC_SUBST(GTK20_CFLAGS)
 341         AC_SUBST(GTK20_LIBS)
 342
 343         # Check for GLADE 2.0
 344         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 345         AC_SUBST(GLADE20_CFLAGS)
 346         AC_SUBST(GLADE20_LIBS)
 347 fi
 348 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 349
 350 #
 351 # D-BUS
 352 #
 353 AC_ARG_ENABLE(dbus,
 354         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 355         [case "${enableval}" in
 356                 yes) HAVE_DBUS=yes ;;
 357                 no)  HAVE_DBUS=no ;;
 358                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 359         esac],
 360         [HAVE_DBUS=yes])
 361
 362 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 363 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 364
 365 DBUS_VERSION="Disabled"
 366 DBUS_SYS_DIR="Disabled"
 367 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 368 if test "x$HAVE_DBUS" = "xyes" ; then
 369     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 370
 371     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 372
 373     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 374     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 375     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 376     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 377     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 378         DBUS_VERSION_MAJOR="0"
 379     fi
 380     if test "z$DBUS_VERSION_MINOR" = "z"; then
 381         DBUS_VERSION_MINOR="0"
 382     fi
 383     if test "z$DBUS_VERSION_MICRO" = "z"; then
 384         DBUS_VERSION_MICRO="0"
 385     fi
 386
 387     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 388         echo "Error: Couldn't determine the version of your DBUS package."
 389         echo "  This is probably an error in this script, please report it"
 390         echo "  along with the following information:"
 391         echo "      Base DBUS version ='$DBUS_VERSION'"
 392         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 393         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 394         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 395         exit 1
 396     else
 397         echo "Your dbus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 398         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 399         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 400         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 401     fi
 402
 403     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 404     AC_SUBST(DBUS_CFLAGS)
 405     AC_SUBST(DBUS_LIBS)
 406
 407     if ! test -z "$with_dbus_sys" ; then
 408         DBUS_SYS_DIR="$with_dbus_sys"
 409     else
 410         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 411     fi
 412     AC_SUBST(DBUS_SYS_DIR)
 413
 414     if ! test -z "$with_dbus_system_address" ; then
 415         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 416     else
 417         # This is ugly, but D-BUS doesn't export this address for us
 418         # so we have to guess, pretty much all setups i've seen have
 419         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 420         # /var/run upstream so we will try guess first then default
 421         # to /var/run/dbus
 422
 423         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 424         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 425         for sock in $TRY_SOCKETS; do
 426             if test -S $sock; then
 427                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 428             fi
 429         done
 430     fi
 431     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 432
 433 fi
 434 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 435
 436 #
 437 # Expat
 438 #
 439 AC_ARG_ENABLE(expat,
 440         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 441         [case "${enableval}" in
 442                 yes) HAVE_EXPAT=yes ;;
 443                 no)  HAVE_EXPAT=no ;;
 444                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 445         esac],
 446         [HAVE_EXPAT=yes])
 447
 448 if test "x$HAVE_EXPAT" = "xyes" ; then
 449     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 450
 451     if ! $have_expat ; then
 452         AC_MSG_ERROR([*** libexpat not found ***])
 453     fi
 454 fi
 455 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 456
 457 #
 458 # GDBM
 459 #
 460 AC_ARG_ENABLE(gdbm,
 461         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 462         [case "${enableval}" in
 463                 yes) HAVE_GDBM=yes ;;
 464                 no)  HAVE_GDBM=no ;;
 465                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 466         esac],
 467         [HAVE_GDBM=yes])
 468
 469 if test "x$HAVE_GDBM" = "xyes" ; then
 470     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 471
 472     if ! $have_gdbm ; then
 473         AC_MSG_ERROR([*** libgdbm not found ***])
 474     fi
 475     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 476 fi
 477 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 478
 479 #
 480 # libdaemon
 481 #
 482 AC_ARG_ENABLE(libdaemon,
 483         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 484         [case "${enableval}" in
 485                 yes) HAVE_LIBDAEMON=yes ;;
 486                 no)  HAVE_LIBDAEMON=no ;;
 487                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 488         esac],
 489         [HAVE_LIBDAEMON=yes])
 490
 491 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 492     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 493     AC_SUBST(LIBDAEMON_CFLAGS)
 494     AC_SUBST(LIBDAEMON_LIBS)
 495 fi
 496 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 497
 498 #
 499 # Python stuff
 500 #
 501 AC_ARG_ENABLE(python,
 502     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 503     [case "${enableval}" in
 504           yes) HAVE_PYTHON=yes ;;
 505           no)  HAVE_PYTHON=no ;;
 506           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 507     esac],[HAVE_PYTHON=yes])
 508
 509 HAVE_PYTHON_DBUS=no
 510 HAVE_PYGTK=no
 511
 512 if test "x$HAVE_PYTHON" = "xyes" ; then
 513     AM_PATH_PYTHON([2.4])
 514
 515     AC_ARG_ENABLE(pygtk,
 516         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 517         [case "${enableval}" in
 518                 yes) HAVE_PYGTK=yes ;;
 519                 no)  HAVE_PYGTK=no ;;
 520                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 521         esac],
 522         [HAVE_PYGTK=yes])
 523
 524     if test "x$HAVE_PYGTK" = "xyes" ; then
 525         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 526     fi
 527
 528
 529     if test "x$HAVE_DBUS" = "xyes" ; then
 530         AC_ARG_ENABLE(python-dbus,
 531             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 532             [case "${enableval}" in
 533                    yes) HAVE_PYTHON_DBUS=yes ;;
 534                    no)  HAVE_PYTHON_DBUS=no ;;
 535                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 536             esac],
 537             [HAVE_PYTHON_DBUS=yes])
 538
 539         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 540             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 541         fi
 542
 543         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 544         AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 545     fi
 546 fi
 547 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 548 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 549 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 550
 551 #
 552 # Check for mono stuff
 553 #
 554 HAVE_MONO=no
 555 if test "x$HAVE_DBUS" = "xyes" ; then
 556     AC_ARG_ENABLE(mono,
 557             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 558             [case "${enableval}" in
 559                     yes) HAVE_MONO=yes ;;
 560                     no)  HAVE_MONO=no ;;
 561                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 562             esac],
 563             [HAVE_MONO=yes])
 564
 565     if test "x$HAVE_MONO" = "xyes" ; then
 566         AC_PATH_PROG(MCS, mcs)
 567         if test "x$MCS" = "x" ; then
 568             AC_MSG_ERROR([Can not find "mcs" in your PATH])
 569         fi
 570
 571         AC_PATH_PROG(GACUTIL, gacutil)
 572         if test "x$GACUTIL" = "x" ; then
 573             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 574         fi
 575
 576         AC_SUBST(MCS)
 577         AC_SUBST(GACUTIL)
 578     fi
 579 fi
 580 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 581
 582 #
 583 # Check for monodoc stuff
 584 #
 585 HAVE_MONODOC=no
 586 AC_ARG_ENABLE(monodoc,
 587         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 588         [case "${enableval}" in
 589                 yes) HAVE_MONODOC=yes ;;
 590                 no)  HAVE_MONODOC=no ;;
 591                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 592         esac],
 593         [HAVE_MONODOC=yes])
 594
 595 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 596         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 597         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 598
 599         AC_PATH_PROG(MONODOCER, monodocer)
 600         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 601
 602         AC_SUBST(MONODOC_DIR)
 603         AC_SUBST(MONODOCER)
 604         AC_SUBST(MDASSEMBLER)
 605 fi
 606 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 607
 608 #
 609 # Defining Avahi User and Group.
 610 #
 611 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 612 if test -z "$with_avahi_user" ; then
 613     AVAHI_USER=avahi
 614 else
 615     AVAHI_USER=$with_avahi_user
 616 fi
 617 AC_SUBST(AVAHI_USER)
 618 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 619
 620 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 621 if test -z "$with_avahi_group" ; then
 622     AVAHI_GROUP=avahi
 623 else
 624     AVAHI_GROUP=$with_avahi_group
 625 fi
 626 AC_SUBST(AVAHI_GROUP)
 627 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 628
 629 #
 630 # Avahi runtime dir
 631 #
 632 avahi_runtime_dir="${localstatedir}/run"
 633 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 634 AC_SUBST(avahi_runtime_dir)
 635 AC_SUBST(avahi_socket)
 636
 637 #
 638 # Avahi interfaces dir
 639 #
 640 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 641         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 642         AC_SUBST(interfacesdir)
 643 fi
 644
 645 #
 646 # Doxygen
 647 #
 648 DX_HTML_FEATURE(ON)
 649 DX_CHM_FEATURE(OFF)
 650 DX_CHI_FEATURE(OFF)
 651 DX_MAN_FEATURE(OFF)
 652 DX_RTF_FEATURE(OFF)
 653 DX_XML_FEATURE(OFF)
 654 DX_PDF_FEATURE(OFF)
 655 DX_PS_FEATURE(OFF)
 656 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 657
 658 #
 659 # Build and Install man pages
 660 #
 661 AC_ARG_ENABLE(manpages,
 662         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 663 [case "${enableval}" in
 664   yes) manpages=yes ;;
 665   no)  manpages=no ;;
 666   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 667 esac],[manpages=yes])
 668
 669 if test x$manpages = xyes ; then
 670     #
 671     # XMLTOMAN manpage generation
 672     #
 673     AC_ARG_ENABLE(xmltoman,
 674     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 675     [case "${enableval}" in
 676       yes) xmltoman=yes ;;
 677       no)  xmltoman=no ;;
 678       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 679     esac],[xmltoman=yes])
 680
 681     if test x$xmltoman = xyes ; then
 682         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 683     fi
 684
 685     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 686         if ! test -e man/avahi-daemon.8 ; then
 687             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 688             exit 1
 689         fi
 690         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 691         xmltoman=no
 692     fi
 693 fi
 694 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 695 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 696
 697 #
 698 # Conditionally compile test and example programs
 699 #
 700 AC_ARG_ENABLE(tests,
 701         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 702         [case "${enableval}" in
 703                 yes) ENABLE_TESTS=yes ;;
 704                 no)  ENABLE_TESTS=no ;;
 705                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 706         esac],
 707         [ENABLE_TESTS=no])
 708
 709 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 710
 711 #
 712 # Optionally enable libdns_sd compatibility support
 713 #
 714 AC_ARG_ENABLE(compat-libdns_sd,
 715         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 716         [case "${enableval}" in
 717                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 718                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 719                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 720         esac],
 721         [ENABLE_COMPAT_LIBDNS_SD=no])
 722
 723 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 724
 725 #
 726 # Optionally enable HOWL compatibility support
 727 #
 728 AC_ARG_ENABLE(compat-howl,
 729         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 730         [case "${enableval}" in
 731                 yes) ENABLE_COMPAT_HOWL=yes ;;
 732                 no)  ENABLE_COMPAT_HOWL=no ;;
 733                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 734         esac],
 735         [ENABLE_COMPAT_HOWL=no])
 736
 737 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 738
 739
 740 # ==========================================================================
 741 AC_CONFIG_FILES([
 742 Makefile
 743 avahi-common/Makefile
 744 avahi-core/Makefile
 745 avahi-glib/Makefile
 746 avahi-qt/Makefile
 747 avahi-daemon/Makefile
 748 avahi-daemon/avahi-dbus.conf
 749 avahi-discover-standalone/Makefile
 750 avahi-client/Makefile
 751 initscript/Makefile
 752 initscript/debian/Makefile
 753 initscript/gentoo/Makefile
 754 initscript/archlinux/Makefile
 755 initscript/suse/Makefile
 756 initscript/fedora/Makefile
 757 initscript/mandriva/Makefile
 758 initscript/darwin/Makefile
 759 initscript/freebsd/Makefile
 760 initscript/slackware/Makefile
 761 avahi-dnsconfd/Makefile
 762 avahi-utils/Makefile
 763 avahi-python/Makefile
 764 avahi-python/avahi/Makefile
 765 examples/Makefile
 766 common/Makefile
 767 man/Makefile
 768 tests/Makefile
 769 service-type-database/Makefile
 770 avahi-sharp/Makefile
 771 avahi-compat-libdns_sd/Makefile
 772 avahi-compat-howl/Makefile
 773 avahi-compat-howl/samples/Makefile
 774 ])
 775 AC_OUTPUT
 776
 777 # ==========================================================================
 778 echo "
 779  ---{ $PACKAGE_NAME $VERSION }---
 780
 781     prefix:                 ${prefix}
 782     sysconfdir:             ${sysconfdir}
 783     localstatedir:          ${localstatedir}
 784     avahi socket:           ${avahi_socket}
 785     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 786     dbus-1 version:         ${DBUS_VERSION}
 787     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 788     compiler:               ${CC}
 789     cflags:                 ${CFLAGS}
 790     Enable GLIB:            ${HAVE_GLIB}
 791     Enable GTK:             ${HAVE_GTK}
 792     Enable D-BUS:           ${HAVE_DBUS}
 793     Enable Expat:           ${HAVE_EXPAT}
 794     Enable GDBM:            ${HAVE_GDBM}
 795     Enable libdaemon:       ${HAVE_LIBDAEMON}
 796     Enable Python:          ${HAVE_PYTHON}
 797     Enable pygtk:           ${HAVE_PYGTK}
 798     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 799     Enable QT3:             ${HAVE_QT3}
 800     Enable QT4:             ${HAVE_QT4}
 801     Enable Mono:            ${HAVE_MONO}
 802     Enable Monodoc:         ${HAVE_MONODOC}
 803     Distribution/OS:        ${with_distro}
 804     User for Avahi:         ${AVAHI_USER}
 805     Group for Avahi:        ${AVAHI_GROUP}
 806     Enable chroot():        ${enable_chroot}
 807 "
 808
 809 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 810
 811 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 812     BUILD_DAEMON=yes
 813 fi
 814
 815 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 816
 817 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 818     BUILD_PYTHON=yes
 819 fi
 820
 821 BUILD_CLIENT="no   (You need avahi-daemon and dbus!)"
 822
 823 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 824     BUILD_CLIENT=yes
 825 fi
 826
 827 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 828    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 829 fi
 830 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 831    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 832 fi
 833
 834
 835 echo "\
 836     Building libavahi-core              yes
 837     Building avahi-daemon:              ${BUILD_DAEMON}
 838     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 839     Building libavahi-client:           ${BUILD_CLIENT}
 840     Building avahi-utils:               ${BUILD_CLIENT}
 841     Building avahi-python:              ${BUILD_PYTHON}
 842     Building libavahi-glib:             ${HAVE_GLIB}
 843     Building avahi-discover-standalone: ${HAVE_GTK}
 844     Building libavahi-qt3:              ${HAVE_QT3}
 845     Building libavahi-qt4:              ${HAVE_QT4}
 846     Building avahi-sharp:               ${HAVE_MONO}
 847     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 848     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 849     Building tests:                     ${ENABLE_TESTS}
 850 "