git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.9],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [6:0:3])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [4:1:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [4:1:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:0:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 126     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 127     if test "z$with_distro" = "z"; then
 128         with_distro=`uname -s`
 129     fi
 130 fi
 131 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 132
 133 case $with_distro in
 134     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 135      ;;
 136     netbsd)
 137      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 138      ;;
 139     linux)
 140      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 141      ;;
 142     *)
 143      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 144      ;;
 145 esac
 146
 147 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 148 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 149 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 150 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 151 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 152 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 153 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 154 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 155 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 156 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 157
 158 test_gcc_flag() {
 159     AC_LANG_CONFTEST([int main() {}])
 160     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 161     ret=$?
 162     rm -f conftest.o
 163     return $ret
 164 }
 165
 166 # If using GCC specify some additional parameters
 167 if test "x$GCC" = "xyes" ; then
 168
 169     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 170
 171     if test "x$HAVE_NETLINK" = "xyes" ; then
 172         # Test whether rtnetlink.h can be included when compiled with -std=c99
 173         # some distributions (e.g. archlinux) have broken headers that dont
 174         # define __u64 with -std=c99
 175         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 176         OLDCFLAGS="$CFLAGS"
 177         CFLAGS="-std=c99"
 178         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 179             use_stdc99=yes, use_stdc99=no)
 180
 181         if test x"$use_stdc99" = xyes; then
 182             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 183             AC_MSG_RESULT([yes])
 184         else
 185             AC_MSG_RESULT([no])
 186         fi
 187
 188         CFLAGS="$OLDCFLAGS"
 189     else
 190         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 191     fi
 192
 193     for flag in $DESIRED_FLAGS ; do
 194         AC_MSG_CHECKING([whether $CC accepts $flag])
 195         if test_gcc_flag $flag ; then
 196            CFLAGS="$CFLAGS $flag"
 197            AC_MSG_RESULT([yes])
 198         else
 199            AC_MSG_RESULT([no])
 200         fi
 201     done
 202 fi
 203
 204 # Checks for header files.
 205 AC_HEADER_STDC
 206 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 207 AC_HEADER_STDBOOL
 208
 209 # Checks for typedefs, structures, and compiler characteristics.
 210 AC_C_CONST
 211 AC_TYPE_SIZE_T
 212 AC_HEADER_TIME
 213 AC_HEADER_SYS_WAIT
 214
 215 # Checks for library functions.
 216 AC_FUNC_MEMCMP
 217 AC_FUNC_SELECT_ARGTYPES
 218 AC_FUNC_MALLOC
 219 AC_FUNC_REALLOC
 220 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 221
 222 AC_FUNC_CHOWN
 223 AC_FUNC_STAT
 224 AC_TYPE_MODE_T
 225 AC_TYPE_PID_T
 226
 227 AC_CHECK_DECLS(environ)
 228
 229 enable_chroot=yes
 230 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 231 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 232 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 233
 234 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 235
 236 if test "x$enable_chroot" = "xyes" ; then
 237    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 238 fi
 239
 240 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 241 if test "x$HAVE_DLOPEN" = "xyes" ; then
 242     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 243 fi
 244 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 245
 246 # Check for pkg-config manually first, as if its not installed the
 247 # PKG_PROG_PKG_CONFIG macro won't be defined.
 248 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 249
 250 if test x"$have_pkg_config" = "xno"; then
 251     AC_MSG_ERROR(pkg-config is required to install this program)
 252 fi
 253
 254 PKG_PROG_PKG_CONFIG
 255
 256 #
 257 # Check for GLIB 2.0
 258 #
 259 AC_ARG_ENABLE(glib,
 260         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 261         [case "${enableval}" in
 262                 yes) HAVE_GLIB=yes ;;
 263                 no)  HAVE_GLIB=no ;;
 264                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 265         esac],
 266         [HAVE_GLIB=yes])
 267
 268 if test "x$HAVE_GLIB" = "xyes" ; then
 269         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 270         AC_SUBST(GLIB20_CFLAGS)
 271         AC_SUBST(GLIB20_LIBS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 274
 275 #
 276 # Check for Qt 3
 277 #
 278 AC_ARG_ENABLE(qt3,
 279         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 280         [case "${enableval}" in
 281                 yes) HAVE_QT3=yes ;;
 282                 no)  HAVE_QT3=no ;;
 283                 auto)  HAVE_QT3=auto ;;
 284                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 285         esac],
 286         [HAVE_QT3=yes])
 287
 288 if test "x$HAVE_QT3" = "xauto" ; then
 289         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ], [ HAVE_QT3="yes"], [ HAVE_QT3="no" && AC_MSG_RESULT([no]) ])
 290 else if test "x$HAVE_QT3" = "xyes" ; then
 291         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 292      fi
 293 fi
 294
 295 if test "x$HAVE_QT3" = "xyes" ; then
 296         AC_SUBST(QT3_CFLAGS)
 297         AC_SUBST(QT3_LIBS)
 298             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 299         MOC_QT3="no"
 300             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 301                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 302                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 303         AC_SUBST(MOC_QT3)
 304 fi
 305 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 306
 307 #
 308 # Check for Qt 4
 309 #
 310 AC_ARG_ENABLE(qt4,
 311         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 312         [case "${enableval}" in
 313                 yes) HAVE_QT4=yes ;;
 314                 no)  HAVE_QT4=no ;;
 315                 auto)  HAVE_QT4=auto ;;
 316                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 317         esac],
 318         [HAVE_QT4=yes])
 319
 320 if test "x$HAVE_QT4" = "xauto" ; then
 321         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ], [ HAVE_QT4="yes"], [ HAVE_QT4="no" && AC_MSG_RESULT([no]) ])
 322 else if test "x$HAVE_QT4" = "xyes" ; then
 323         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 324      fi
 325 fi
 326
 327 if test "x$HAVE_QT4" = "xyes" ; then
 328         AC_SUBST(QT4_CFLAGS)
 329         AC_SUBST(QT4_LIBS)
 330             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 331         MOC_QT4="no"
 332             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 333                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 334                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 335         AC_SUBST(MOC_QT4)
 336 fi
 337 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 338
 339 #
 340 # Check for GTK+
 341 #
 342 AC_ARG_ENABLE(gtk,
 343         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 344         [case "${enableval}" in
 345                 yes) HAVE_GTK=yes ;;
 346                 no)  HAVE_GTK=no ;;
 347                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 348         esac],
 349         [HAVE_GTK=yes])
 350
 351 if test "x$HAVE_GTK" = "xyes" ; then
 352         # Check for GTK 2.0
 353         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 354         AC_SUBST(GTK20_CFLAGS)
 355         AC_SUBST(GTK20_LIBS)
 356
 357         # Check for GLADE 2.0
 358         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 359         AC_SUBST(GLADE20_CFLAGS)
 360         AC_SUBST(GLADE20_LIBS)
 361 fi
 362 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 363
 364 #
 365 # D-BUS
 366 #
 367 AC_ARG_ENABLE(dbus,
 368         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 369         [case "${enableval}" in
 370                 yes) HAVE_DBUS=yes ;;
 371                 no)  HAVE_DBUS=no ;;
 372                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 373         esac],
 374         [HAVE_DBUS=yes])
 375
 376 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 377 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 378
 379 DBUS_VERSION="Disabled"
 380 DBUS_SYS_DIR="Disabled"
 381 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 382 if test "x$HAVE_DBUS" = "xyes" ; then
 383     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 384
 385     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 386
 387     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 388     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 389     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 390     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 391     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 392         DBUS_VERSION_MAJOR="0"
 393     fi
 394     if test "z$DBUS_VERSION_MINOR" = "z"; then
 395         DBUS_VERSION_MINOR="0"
 396     fi
 397     if test "z$DBUS_VERSION_MICRO" = "z"; then
 398         DBUS_VERSION_MICRO="0"
 399     fi
 400
 401     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 402         echo "Error: Couldn't determine the version of your DBUS package."
 403         echo "  This is probably an error in this script, please report it"
 404         echo "  along with the following information:"
 405         echo "      Base DBUS version ='$DBUS_VERSION'"
 406         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 407         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 408         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 409         exit 1
 410     else
 411         echo "Your dbus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 412         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 413         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 414         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 415     fi
 416
 417     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 418     AC_SUBST(DBUS_CFLAGS)
 419     AC_SUBST(DBUS_LIBS)
 420
 421     if ! test -z "$with_dbus_sys" ; then
 422         DBUS_SYS_DIR="$with_dbus_sys"
 423     else
 424         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 425     fi
 426     AC_SUBST(DBUS_SYS_DIR)
 427
 428     if ! test -z "$with_dbus_system_address" ; then
 429         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 430     else
 431         # This is ugly, but D-BUS doesn't export this address for us
 432         # so we have to guess, pretty much all setups i've seen have
 433         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 434         # /var/run upstream so we will try guess first then default
 435         # to /var/run/dbus
 436
 437         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 438         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 439         for sock in $TRY_SOCKETS; do
 440             if test -S $sock; then
 441                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 442             fi
 443         done
 444     fi
 445     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 446
 447 fi
 448 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 449
 450 #
 451 # Expat
 452 #
 453 AC_ARG_ENABLE(expat,
 454         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 455         [case "${enableval}" in
 456                 yes) HAVE_EXPAT=yes ;;
 457                 no)  HAVE_EXPAT=no ;;
 458                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 459         esac],
 460         [HAVE_EXPAT=yes])
 461
 462 if test "x$HAVE_EXPAT" = "xyes" ; then
 463     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 464
 465     if ! $have_expat ; then
 466         AC_MSG_ERROR([*** libexpat not found ***])
 467     fi
 468 fi
 469 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 470
 471 #
 472 # GDBM
 473 #
 474 AC_ARG_ENABLE(gdbm,
 475         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 476         [case "${enableval}" in
 477                 yes) HAVE_GDBM=yes ;;
 478                 no)  HAVE_GDBM=no ;;
 479                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 480         esac],
 481         [HAVE_GDBM=yes])
 482
 483 if test "x$HAVE_GDBM" = "xyes" ; then
 484     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 485
 486     if ! $have_gdbm ; then
 487         AC_MSG_ERROR([*** libgdbm not found ***])
 488     fi
 489     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 490 fi
 491 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 492
 493 #
 494 # libdaemon
 495 #
 496 AC_ARG_ENABLE(libdaemon,
 497         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 498         [case "${enableval}" in
 499                 yes) HAVE_LIBDAEMON=yes ;;
 500                 no)  HAVE_LIBDAEMON=no ;;
 501                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 502         esac],
 503         [HAVE_LIBDAEMON=yes])
 504
 505 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 506     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 507     AC_SUBST(LIBDAEMON_CFLAGS)
 508     AC_SUBST(LIBDAEMON_LIBS)
 509 fi
 510 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 511
 512 #
 513 # Python stuff
 514 #
 515 AC_ARG_ENABLE(python,
 516     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 517     [case "${enableval}" in
 518           yes) HAVE_PYTHON=yes ;;
 519           no)  HAVE_PYTHON=no ;;
 520           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 521     esac],[HAVE_PYTHON=yes])
 522
 523 HAVE_PYTHON_DBUS=no
 524 HAVE_PYGTK=no
 525
 526 if test "x$HAVE_PYTHON" = "xyes" ; then
 527     AM_PATH_PYTHON([2.4])
 528
 529     AC_ARG_ENABLE(pygtk,
 530         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 531         [case "${enableval}" in
 532                 yes) HAVE_PYGTK=yes ;;
 533                 no)  HAVE_PYGTK=no ;;
 534                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 535         esac],
 536         [HAVE_PYGTK=yes])
 537
 538     if test "x$HAVE_PYGTK" = "xyes" ; then
 539         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 540     fi
 541
 542
 543     if test "x$HAVE_DBUS" = "xyes" ; then
 544         AC_ARG_ENABLE(python-dbus,
 545             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 546             [case "${enableval}" in
 547                    yes) HAVE_PYTHON_DBUS=yes ;;
 548                    no)  HAVE_PYTHON_DBUS=no ;;
 549                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 550             esac],
 551             [HAVE_PYTHON_DBUS=yes])
 552
 553         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 554             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 555         fi
 556
 557         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 558         AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 559     fi
 560 fi
 561 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 562 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 563 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 564
 565 #
 566 # Check for mono stuff
 567 #
 568 HAVE_MONO=no
 569 if test "x$HAVE_DBUS" = "xyes" ; then
 570     AC_ARG_ENABLE(mono,
 571             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 572             [case "${enableval}" in
 573                     yes) HAVE_MONO=yes ;;
 574                     no)  HAVE_MONO=no ;;
 575                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 576             esac],
 577             [HAVE_MONO=yes])
 578
 579     if test "x$HAVE_MONO" = "xyes" ; then
 580         AC_PATH_PROG(MCS, mcs)
 581         if test "x$MCS" = "x" ; then
 582             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 583         fi
 584
 585         AC_PATH_PROG(GACUTIL, gacutil)
 586         if test "x$GACUTIL" = "x" ; then
 587             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 588         fi
 589
 590         AC_SUBST(MCS)
 591         AC_SUBST(GACUTIL)
 592     fi
 593 fi
 594 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 595
 596 #
 597 # Check for monodoc stuff
 598 #
 599 HAVE_MONODOC=no
 600 AC_ARG_ENABLE(monodoc,
 601         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 602         [case "${enableval}" in
 603                 yes) HAVE_MONODOC=yes ;;
 604                 no)  HAVE_MONODOC=no ;;
 605                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 606         esac],
 607         [HAVE_MONODOC=yes])
 608
 609 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 610         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 611         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 612
 613         AC_PATH_PROG(MONODOCER, monodocer)
 614         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 615
 616         AC_SUBST(MONODOC_DIR)
 617         AC_SUBST(MONODOCER)
 618         AC_SUBST(MDASSEMBLER)
 619 fi
 620 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 621
 622 #
 623 # Defining Avahi User and Group.
 624 #
 625 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 626 if test -z "$with_avahi_user" ; then
 627     AVAHI_USER=avahi
 628 else
 629     AVAHI_USER=$with_avahi_user
 630 fi
 631 AC_SUBST(AVAHI_USER)
 632 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 633
 634 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 635 if test -z "$with_avahi_group" ; then
 636     AVAHI_GROUP=avahi
 637 else
 638     AVAHI_GROUP=$with_avahi_group
 639 fi
 640 AC_SUBST(AVAHI_GROUP)
 641 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 642
 643 #
 644 # Avahi runtime dir
 645 #
 646 avahi_runtime_dir="${localstatedir}/run"
 647 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 648 AC_SUBST(avahi_runtime_dir)
 649 AC_SUBST(avahi_socket)
 650
 651 #
 652 # Avahi interfaces dir
 653 #
 654 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 655         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 656         AC_SUBST(interfacesdir)
 657 fi
 658
 659 #
 660 # Doxygen
 661 #
 662 DX_HTML_FEATURE(ON)
 663 DX_CHM_FEATURE(OFF)
 664 DX_CHI_FEATURE(OFF)
 665 DX_MAN_FEATURE(OFF)
 666 DX_RTF_FEATURE(OFF)
 667 DX_XML_FEATURE(OFF)
 668 DX_PDF_FEATURE(OFF)
 669 DX_PS_FEATURE(OFF)
 670 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 671
 672 #
 673 # Build and Install man pages
 674 #
 675 AC_ARG_ENABLE(manpages,
 676         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 677 [case "${enableval}" in
 678   yes) manpages=yes ;;
 679   no)  manpages=no ;;
 680   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 681 esac],[manpages=yes])
 682
 683 if test x$manpages = xyes ; then
 684     #
 685     # XMLTOMAN manpage generation
 686     #
 687     AC_ARG_ENABLE(xmltoman,
 688     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 689     [case "${enableval}" in
 690       yes) xmltoman=yes ;;
 691       no)  xmltoman=no ;;
 692       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 693     esac],[xmltoman=yes])
 694
 695     if test x$xmltoman = xyes ; then
 696         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 697     fi
 698
 699     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 700         if ! test -e man/avahi-daemon.8 ; then
 701             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 702             exit 1
 703         fi
 704         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 705         xmltoman=no
 706     fi
 707 fi
 708 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 709 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 710
 711 #
 712 # Conditionally compile test and example programs
 713 #
 714 AC_ARG_ENABLE(tests,
 715         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 716         [case "${enableval}" in
 717                 yes) ENABLE_TESTS=yes ;;
 718                 no)  ENABLE_TESTS=no ;;
 719                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 720         esac],
 721         [ENABLE_TESTS=no])
 722
 723 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 724
 725 #
 726 # Optionally enable libdns_sd compatibility support
 727 #
 728 AC_ARG_ENABLE(compat-libdns_sd,
 729         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 730         [case "${enableval}" in
 731                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 732                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 733                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 734         esac],
 735         [ENABLE_COMPAT_LIBDNS_SD=no])
 736
 737 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 738
 739 #
 740 # Optionally enable HOWL compatibility support
 741 #
 742 AC_ARG_ENABLE(compat-howl,
 743         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 744         [case "${enableval}" in
 745                 yes) ENABLE_COMPAT_HOWL=yes ;;
 746                 no)  ENABLE_COMPAT_HOWL=no ;;
 747                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 748         esac],
 749         [ENABLE_COMPAT_HOWL=no])
 750
 751 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 752
 753
 754 # ==========================================================================
 755 AC_CONFIG_FILES([
 756 Makefile
 757 avahi-common/Makefile
 758 avahi-core/Makefile
 759 avahi-glib/Makefile
 760 avahi-qt/Makefile
 761 avahi-daemon/Makefile
 762 avahi-daemon/avahi-dbus.conf
 763 avahi-discover-standalone/Makefile
 764 avahi-client/Makefile
 765 initscript/Makefile
 766 initscript/debian/Makefile
 767 initscript/gentoo/Makefile
 768 initscript/archlinux/Makefile
 769 initscript/suse/Makefile
 770 initscript/fedora/Makefile
 771 initscript/mandriva/Makefile
 772 initscript/darwin/Makefile
 773 initscript/freebsd/Makefile
 774 initscript/slackware/Makefile
 775 avahi-dnsconfd/Makefile
 776 avahi-utils/Makefile
 777 avahi-python/Makefile
 778 avahi-python/avahi/Makefile
 779 examples/Makefile
 780 common/Makefile
 781 man/Makefile
 782 tests/Makefile
 783 service-type-database/Makefile
 784 avahi-sharp/Makefile
 785 avahi-compat-libdns_sd/Makefile
 786 avahi-compat-howl/Makefile
 787 avahi-compat-howl/samples/Makefile
 788 ])
 789 AC_OUTPUT
 790
 791 # ==========================================================================
 792 echo "
 793  ---{ $PACKAGE_NAME $VERSION }---
 794
 795     prefix:                 ${prefix}
 796     sysconfdir:             ${sysconfdir}
 797     localstatedir:          ${localstatedir}
 798     avahi socket:           ${avahi_socket}
 799     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 800     dbus-1 version:         ${DBUS_VERSION}
 801     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 802     compiler:               ${CC}
 803     cflags:                 ${CFLAGS}
 804     Enable GLIB:            ${HAVE_GLIB}
 805     Enable GTK:             ${HAVE_GTK}
 806     Enable D-BUS:           ${HAVE_DBUS}
 807     Enable Expat:           ${HAVE_EXPAT}
 808     Enable GDBM:            ${HAVE_GDBM}
 809     Enable libdaemon:       ${HAVE_LIBDAEMON}
 810     Enable Python:          ${HAVE_PYTHON}
 811     Enable pygtk:           ${HAVE_PYGTK}
 812     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 813     Enable QT3:             ${HAVE_QT3}
 814     Enable QT4:             ${HAVE_QT4}
 815     Enable Mono:            ${HAVE_MONO}
 816     Enable Monodoc:         ${HAVE_MONODOC}
 817     Distribution/OS:        ${with_distro}
 818     User for Avahi:         ${AVAHI_USER}
 819     Group for Avahi:        ${AVAHI_GROUP}
 820     Enable chroot():        ${enable_chroot}
 821 "
 822
 823 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 824
 825 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 826     BUILD_DAEMON=yes
 827 fi
 828
 829 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 830
 831 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 832     BUILD_PYTHON=yes
 833 fi
 834
 835 BUILD_CLIENT="no   (You need avahi-daemon and dbus!)"
 836
 837 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 838     BUILD_CLIENT=yes
 839 fi
 840
 841 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 842    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 843 fi
 844 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 845    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 846 fi
 847
 848
 849 echo "\
 850     Building libavahi-core              yes
 851     Building avahi-daemon:              ${BUILD_DAEMON}
 852     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 853     Building libavahi-client:           ${BUILD_CLIENT}
 854     Building avahi-utils:               ${BUILD_CLIENT}
 855     Building avahi-python:              ${BUILD_PYTHON}
 856     Building libavahi-glib:             ${HAVE_GLIB}
 857     Building avahi-discover-standalone: ${HAVE_GTK}
 858     Building libavahi-qt3:              ${HAVE_QT3}
 859     Building libavahi-qt4:              ${HAVE_QT4}
 860     Building avahi-sharp:               ${HAVE_MONO}
 861     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 862     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 863     Building tests:                     ${ENABLE_TESTS}
 864 "