git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.16],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [7:3:4])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [4:5:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:1:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37
  38 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  39 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  40 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  41 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  42
  43 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  44     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  45     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  46 fi
  47
  48 # Checks for programs.
  49 AC_PROG_CC
  50 AC_PROG_CXX
  51 AC_GNU_SOURCE
  52 AC_PROG_CPP
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55 AC_PROG_MAKE_SET
  56 AC_PROG_GCC_TRADITIONAL
  57
  58 # libtool stuff
  59 AC_PROG_LIBTOOL
  60
  61 AC_CACHE_CHECK([whether the C++ compiler works], [avahi_cv_sys_cxx_works], [
  62     AC_LANG_PUSH([C++])
  63     AC_COMPILE_IFELSE([int main() { }], [avahi_cv_sys_cxx_works=yes],
  64         [avahi_cv_sys_cxx_works=no])
  65     AC_LANG_POP([C++])
  66     ])
  67 [ if [ "x$avahi_cv_sys_cxx_works" = "xno" ]; then ]
  68     AC_MSG_FAILURE([The C++ compiler does not work])
  69 [ fi ]
  70
  71 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  72
  73 #
  74 # Check for netlink.h
  75 #
  76 AC_CHECK_HEADER(linux/netlink.h,
  77 HAVE_NETLINK=yes
  78 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  79 , [], [
  80 #include <sys/socket.h>
  81 #include <asm/types.h>
  82 ])
  83
  84 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  85
  86 #
  87 # Check for net/route.h
  88 #
  89 AC_CHECK_HEADER(net/route.h,
  90 HAVE_PF_ROUTE=yes
  91 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  92 , [], [
  93 #include <sys/types.h>
  94 #include <sys/socket.h>
  95 ])
  96
  97 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  98
  99 #
 100 # Check for sys/filio.h; needed for FIONREAD on Solaris
 101 #
 102 AC_CHECK_HEADER(sys/filio.h,
 103 HAVE_SYS_FILIO_H=yes
 104 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 105 , [], [
 106 ])
 107
 108 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 109
 110 #
 111 # Check for sys/sysctl.h; not present on Solaris
 112 #
 113 AC_CHECK_HEADER(sys/sysctl.h,
 114 HAVE_SYS_SYSCTL=yes
 115 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 116 , [], [
 117 #include <sys/types.h>
 118 #include <sys/socket.h>
 119 #include <sys/param.h>
 120 ])
 121
 122 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 123
 124 #
 125 # Check for lifconf struct; only present on Solaris
 126 #
 127 AC_MSG_CHECKING(for struct lifconf)
 128 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 129 [AC_TRY_COMPILE(
 130 [#include <sys/socket.h>
 131 #include <net/if.h>
 132 ],[sizeof (struct lifconf);],
 133 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 134 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 135 if test $avahi_cv_has_struct_lifconf = yes; then
 136     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 137 fi
 138
 139 #
 140 # Check for struct ip_mreqn
 141 #
 142 AC_MSG_CHECKING(for struct ip_mreqn)
 143 AC_TRY_COMPILE([#include <netinet/in.h>], [
 144         struct ip_mreqn mreq;
 145         mreq.imr_address.s_addr = 0;
 146 ], [
 147         # Yes, we have it...
 148         AC_MSG_RESULT(yes)
 149         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 150 ], [
 151         # We'll just have to try and use struct ip_mreq
 152         AC_MSG_RESULT(no)
 153         AC_MSG_CHECKING(for struct ip_mreq)
 154         AC_TRY_COMPILE([#include <netinet/in.h>], [
 155                 struct ip_mreq mreq;
 156                 mreq.imr_interface.s_addr = 0;
 157         ], [
 158                 # Yes, we have it...
 159                 AC_MSG_RESULT(yes)
 160                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 161         ], [
 162                 # No multicast support
 163                         AC_MSG_RESULT(no)
 164         ])
 165 ])
 166
 167 #
 168 # Detecting the linux distribution for specific things like init scripts.
 169 #
 170 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 171 if test "z$with_distro" = "z"; then
 172     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 173     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 174     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 175     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 176     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 177     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 178     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 179     if test "z$with_distro" = "z"; then
 180         with_distro=`uname -s`
 181     fi
 182 fi
 183 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 184
 185 case $with_distro in
 186     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 187      ;;
 188     netbsd)
 189      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 190      ;;
 191     linux)
 192      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 193      ;;
 194     *)
 195      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 196      ;;
 197 esac
 198
 199 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 200 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 201 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 202 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 203 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 204 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 205 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 206 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 207 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 208 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 209
 210 test_gcc_flag() {
 211     AC_LANG_CONFTEST([int main() {}])
 212     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 213     ret=$?
 214     rm -f conftest.o
 215     return $ret
 216 }
 217
 218 # If using GCC specify some additional parameters
 219 if test "x$GCC" = "xyes" ; then
 220
 221     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 222
 223     if test "x$HAVE_NETLINK" = "xyes" ; then
 224         # Test whether rtnetlink.h can be included when compiled with -std=c99
 225         # some distributions (e.g. archlinux) have broken headers that dont
 226         # define __u64 with -std=c99
 227         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 228         OLDCFLAGS="$CFLAGS"
 229         CFLAGS="-std=c99"
 230         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 231             use_stdc99=yes, use_stdc99=no)
 232
 233         if test x"$use_stdc99" = xyes; then
 234             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 235             AC_MSG_RESULT([yes])
 236         else
 237             AC_MSG_RESULT([no])
 238         fi
 239
 240         CFLAGS="$OLDCFLAGS"
 241     else
 242         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 243     fi
 244
 245     for flag in $DESIRED_FLAGS ; do
 246         AC_MSG_CHECKING([whether $CC accepts $flag])
 247         if test_gcc_flag $flag ; then
 248            CFLAGS="$CFLAGS $flag"
 249            AC_MSG_RESULT([yes])
 250         else
 251            AC_MSG_RESULT([no])
 252         fi
 253     done
 254 fi
 255
 256 # Checks for header files.
 257 AC_HEADER_STDC
 258 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 259 AC_HEADER_STDBOOL
 260
 261 # Checks for typedefs, structures, and compiler characteristics.
 262 AC_C_CONST
 263 AC_TYPE_SIZE_T
 264 AC_HEADER_TIME
 265 AC_HEADER_SYS_WAIT
 266
 267 # Checks for library functions.
 268 AC_FUNC_MEMCMP
 269 AC_FUNC_SELECT_ARGTYPES
 270 AC_FUNC_MALLOC
 271 AC_FUNC_REALLOC
 272 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 273
 274 AC_FUNC_CHOWN
 275 AC_FUNC_STAT
 276 AC_TYPE_MODE_T
 277 AC_TYPE_PID_T
 278
 279 AC_CHECK_DECLS(environ)
 280
 281 enable_chroot=yes
 282 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 283 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 284 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 285
 286 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 287
 288 if test "x$enable_chroot" = "xyes" ; then
 289    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 290 fi
 291
 292 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 293 if test "x$HAVE_DLOPEN" = "xyes" ; then
 294     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 295 fi
 296 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 297
 298 # Check for pkg-config manually first, as if its not installed the
 299 # PKG_PROG_PKG_CONFIG macro won't be defined.
 300 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 301
 302 if test x"$have_pkg_config" = "xno"; then
 303     AC_MSG_ERROR(pkg-config is required to install this program)
 304 fi
 305
 306 PKG_PROG_PKG_CONFIG
 307
 308 #
 309 # Check for GLIB 2.0
 310 #
 311 AC_ARG_ENABLE(glib,
 312         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 313         [case "${enableval}" in
 314                 yes) HAVE_GLIB=yes ;;
 315                 no)  HAVE_GLIB=no ;;
 316                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 317         esac],
 318         [HAVE_GLIB=yes])
 319
 320 if test "x$HAVE_GLIB" = "xyes" ; then
 321         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 322         AC_SUBST(GLIB20_CFLAGS)
 323         AC_SUBST(GLIB20_LIBS)
 324 fi
 325 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 326
 327 #
 328 # Check for Qt 3
 329 #
 330 AC_ARG_ENABLE(qt3,
 331         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 332         [case "${enableval}" in
 333                 yes) HAVE_QT3=yes ;;
 334                 no)  HAVE_QT3=no ;;
 335                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 336         esac],
 337         [HAVE_QT3=yes])
 338
 339 if test "x$HAVE_QT3" = "xyes" ; then
 340         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 341         AC_SUBST(QT3_CFLAGS)
 342         AC_SUBST(QT3_LIBS)
 343             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 344         MOC_QT3="no"
 345             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 346                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 347                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 348         AC_SUBST(MOC_QT3)
 349 fi
 350 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 351
 352 #
 353 # Check for Qt 4
 354 #
 355 AC_ARG_ENABLE(qt4,
 356         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 357         [case "${enableval}" in
 358                 yes) HAVE_QT4=yes ;;
 359                 no)  HAVE_QT4=no ;;
 360                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 361         esac],
 362         [HAVE_QT4=yes])
 363
 364 if test "x$HAVE_QT4" = "xyes" ; then
 365         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 366         AC_SUBST(QT4_CFLAGS)
 367         AC_SUBST(QT4_LIBS)
 368             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 369         MOC_QT4="no"
 370             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 371                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 372                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 373         AC_SUBST(MOC_QT4)
 374 fi
 375 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 376
 377 #
 378 # Check for GTK+
 379 #
 380 AC_ARG_ENABLE(gtk,
 381         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 382         [case "${enableval}" in
 383                 yes) HAVE_GTK=yes ;;
 384                 no)  HAVE_GTK=no ;;
 385                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 386         esac],
 387         [HAVE_GTK=yes])
 388
 389 if test "x$HAVE_GTK" = "xyes" ; then
 390         # Check for GTK 2.0
 391         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 392         AC_SUBST(GTK20_CFLAGS)
 393         AC_SUBST(GTK20_LIBS)
 394
 395         # Check for GLADE 2.0
 396         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 397         AC_SUBST(GLADE20_CFLAGS)
 398         AC_SUBST(GLADE20_LIBS)
 399 fi
 400 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 401
 402 #
 403 # D-Bus
 404 #
 405 AC_ARG_ENABLE(dbus,
 406         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 407         [case "${enableval}" in
 408                 yes) HAVE_DBUS=yes ;;
 409                 no)  HAVE_DBUS=no ;;
 410                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 411         esac],
 412         [HAVE_DBUS=yes])
 413
 414 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 415 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 416
 417 DBUS_VERSION="Disabled"
 418 DBUS_SYS_DIR="Disabled"
 419 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 420 if test "x$HAVE_DBUS" = "xyes" ; then
 421     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 422
 423     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 424
 425     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 426     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 427     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 428     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 429     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 430         DBUS_VERSION_MAJOR="0"
 431     fi
 432     if test "z$DBUS_VERSION_MINOR" = "z"; then
 433         DBUS_VERSION_MINOR="0"
 434     fi
 435     if test "z$DBUS_VERSION_MICRO" = "z"; then
 436         DBUS_VERSION_MICRO="0"
 437     fi
 438
 439     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 440         echo "Error: Couldn't determine the version of your D-Bus package."
 441         echo "  This is probably an error in this script, please report it"
 442         echo "  along with the following information:"
 443         echo "      Base D-Buss version ='$DBUS_VERSION'"
 444         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 445         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 446         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 447         exit 1
 448     else
 449         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 450         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 451         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 452         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 453     fi
 454
 455     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 456     AC_SUBST(DBUS_CFLAGS)
 457     AC_SUBST(DBUS_LIBS)
 458
 459     if ! test -z "$with_dbus_sys" ; then
 460         DBUS_SYS_DIR="$with_dbus_sys"
 461     else
 462         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 463     fi
 464     AC_SUBST(DBUS_SYS_DIR)
 465
 466     if ! test -z "$with_dbus_system_address" ; then
 467         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 468     else
 469         # This is ugly, but D-Bus doesn't export this address for us
 470         # so we have to guess, pretty much all setups i've seen have
 471         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 472         # /var/run upstream so we will try guess first then default
 473         # to /var/run/dbus.
 474
 475         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 476         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 477         for sock in $TRY_SOCKETS; do
 478             if test -S $sock; then
 479                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 480             fi
 481         done
 482     fi
 483     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 484
 485     SAVED_LIBS="$LIBS"
 486     LIBS="$LIBS $DBUS_LIBS"
 487     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 488     LIBS="$SAVED_LIBS"
 489 fi
 490 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 491
 492 #
 493 # Expat
 494 #
 495 AC_ARG_ENABLE(expat,
 496         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 497         [case "${enableval}" in
 498                 yes) HAVE_EXPAT=yes ;;
 499                 no)  HAVE_EXPAT=no ;;
 500                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 501         esac],
 502         [HAVE_EXPAT=yes])
 503
 504 if test "x$HAVE_EXPAT" = "xyes" ; then
 505     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 506
 507     if ! $have_expat ; then
 508         AC_MSG_ERROR([*** libexpat not found ***])
 509     fi
 510 fi
 511 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 512
 513 #
 514 # GDBM
 515 #
 516 #
 517 # Check for dbm
 518 #
 519 AC_ARG_ENABLE(dbm,
 520         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 521         [case "${enableval}" in
 522                 yes) HAVE_DBM=yes ;;
 523                 no)  HAVE_DBM=no ;;
 524                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 525         esac],
 526         [HAVE_DBM=no])
 527
 528 AC_ARG_ENABLE(gdbm,
 529         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 530         [case "${enableval}" in
 531                 yes) HAVE_GDBM=yes ;;
 532                 no)  HAVE_GDBM=no ;;
 533                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 534         esac],
 535         [HAVE_GDBM=yes])
 536
 537 if test "x$HAVE_GDBM" = "xyes" ; then
 538     if test "x$HAVE_DBM" = "xyes" ; then
 539         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 540     fi
 541     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 542
 543     if ! $have_gdbm ; then
 544         AC_MSG_ERROR([*** libgdbm not found ***])
 545     fi
 546     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 547 else
 548     if test "x$HAVE_DBM" = "xyes" ; then
 549         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 550
 551         if ! $have_dbm ; then
 552             AC_MSG_ERROR([*** dbm not found ***])
 553         fi
 554         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 555     fi
 556 fi
 557 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 558 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 559
 560 #
 561 # libdaemon
 562 #
 563 AC_ARG_ENABLE(libdaemon,
 564         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 565         [case "${enableval}" in
 566                 yes) HAVE_LIBDAEMON=yes ;;
 567                 no)  HAVE_LIBDAEMON=no ;;
 568                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 569         esac],
 570         [HAVE_LIBDAEMON=yes])
 571
 572 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 573     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 574     AC_SUBST(LIBDAEMON_CFLAGS)
 575     AC_SUBST(LIBDAEMON_LIBS)
 576 fi
 577 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 578
 579 #
 580 # Python stuff
 581 #
 582 AC_ARG_ENABLE(python,
 583     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 584     [case "${enableval}" in
 585           yes) HAVE_PYTHON=yes ;;
 586           no)  HAVE_PYTHON=no ;;
 587           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 588     esac],[HAVE_PYTHON=yes])
 589
 590 HAVE_PYTHON_DBUS=no
 591 HAVE_PYGTK=no
 592
 593 if test "x$HAVE_PYTHON" = "xyes" ; then
 594     AM_PATH_PYTHON([2.4])
 595
 596     AC_ARG_ENABLE(pygtk,
 597         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 598         [case "${enableval}" in
 599                 yes) HAVE_PYGTK=yes ;;
 600                 no)  HAVE_PYGTK=no ;;
 601                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 602         esac],
 603         [HAVE_PYGTK=yes])
 604
 605     if test "x$HAVE_PYGTK" = "xyes" ; then
 606         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 607     fi
 608
 609
 610     if test "x$HAVE_DBUS" = "xyes" ; then
 611         AC_ARG_ENABLE(python-dbus,
 612             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 613             [case "${enableval}" in
 614                    yes) HAVE_PYTHON_DBUS=yes ;;
 615                    no)  HAVE_PYTHON_DBUS=no ;;
 616                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 617             esac],
 618             [HAVE_PYTHON_DBUS=yes])
 619
 620         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 621             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 622         fi
 623
 624         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 625         if test "x$HAVE_GDBM" = "xyes"; then
 626             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 627         fi
 628         if test "x$HAVE_DBM" = "xyes"; then
 629             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 630         fi
 631     fi
 632 fi
 633 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 634 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 635 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 636
 637 #
 638 # Check for mono stuff
 639 #
 640 HAVE_MONO=no
 641 if test "x$HAVE_DBUS" = "xyes" ; then
 642     AC_ARG_ENABLE(mono,
 643             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 644             [case "${enableval}" in
 645                     yes) HAVE_MONO=yes ;;
 646                     no)  HAVE_MONO=no ;;
 647                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 648             esac],
 649             [HAVE_MONO=yes])
 650
 651     if test "x$HAVE_MONO" = "xyes" ; then
 652         AC_PATH_PROG(MCS, mcs)
 653         if test "x$MCS" = "x" ; then
 654             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 655         fi
 656
 657         AC_PATH_PROG(GACUTIL, gacutil)
 658         if test "x$GACUTIL" = "x" ; then
 659             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 660         fi
 661
 662         AC_SUBST(MCS)
 663         AC_SUBST(GACUTIL)
 664     fi
 665 fi
 666 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 667
 668 #
 669 # Check for monodoc stuff
 670 #
 671 HAVE_MONODOC=no
 672 AC_ARG_ENABLE(monodoc,
 673         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 674         [case "${enableval}" in
 675                 yes) HAVE_MONODOC=yes ;;
 676                 no)  HAVE_MONODOC=no ;;
 677                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 678         esac],
 679         [HAVE_MONODOC=yes])
 680
 681 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 682         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 683         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 684
 685         AC_PATH_PROG(MONODOCER, monodocer)
 686         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 687
 688         AC_SUBST(MONODOC_DIR)
 689         AC_SUBST(MONODOCER)
 690         AC_SUBST(MDASSEMBLER)
 691 fi
 692 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 693
 694 #
 695 # Build autoipd?
 696 #
 697 AC_ARG_ENABLE(autoipd,
 698         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 699         [case "${enableval}" in
 700                 yes) ENABLE_AUTOIPD=yes ;;
 701                 no)  ENABLE_AUTOIPD=no ;;
 702                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 703         esac],
 704         [ENABLE_AUTOIPD=yes])
 705
 706 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 707
 708 #
 709 # Defining users and groups
 710 #
 711 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 712 if test -z "$with_avahi_user" ; then
 713     AVAHI_USER=avahi
 714 else
 715     AVAHI_USER=$with_avahi_user
 716 fi
 717 AC_SUBST(AVAHI_USER)
 718 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 719
 720 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 721 if test -z "$with_avahi_group" ; then
 722     AVAHI_GROUP=avahi
 723 else
 724     AVAHI_GROUP=$with_avahi_group
 725 fi
 726 AC_SUBST(AVAHI_GROUP)
 727 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 728
 729 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 730 if test -z "$with_avahi_priv_access_group" ; then
 731     AVAHI_PRIV_ACCESS_GROUP=netdev
 732 else
 733     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 734 fi
 735 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 736 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 737
 738 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 739 if test -z "$with_autoipd_user" ; then
 740     AVAHI_AUTOIPD_USER=avahi-autoipd
 741 else
 742     AVAHI_AUTOIPD_USER=$with_autoipd_user
 743 fi
 744 AC_SUBST(AVAHI_AUTOIPD_USER)
 745 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 746
 747 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 748 if test -z "$with_autoipd_group" ; then
 749     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 750 else
 751     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 752 fi
 753 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 754 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 755
 756 #
 757 # Avahi runtime dir
 758 #
 759 avahi_runtime_dir="${localstatedir}/run"
 760 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 761 AC_SUBST(avahi_runtime_dir)
 762 AC_SUBST(avahi_socket)
 763
 764 #
 765 # Avahi interfaces dir
 766 #
 767 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 768         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 769         AC_SUBST(interfacesdir)
 770 fi
 771
 772 #
 773 # Doxygen
 774 #
 775 DX_HTML_FEATURE(ON)
 776 DX_CHM_FEATURE(OFF)
 777 DX_CHI_FEATURE(OFF)
 778 DX_MAN_FEATURE(OFF)
 779 DX_RTF_FEATURE(OFF)
 780 DX_XML_FEATURE(OFF)
 781 DX_PDF_FEATURE(OFF)
 782 DX_PS_FEATURE(OFF)
 783 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 784
 785 AC_ARG_ENABLE(core-docs,
 786         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 787 [case "${enableval}" in
 788   yes) ENABLE_CORE_DOCS=yes ;;
 789   no)  ENABLE_CORE_DOCS=no ;;
 790   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 791 esac],[ENABLE_CORE_DOCS=no])
 792
 793 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 794
 795 #
 796 # Build and Install man pages
 797 #
 798 AC_ARG_ENABLE(manpages,
 799         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 800 [case "${enableval}" in
 801   yes) manpages=yes ;;
 802   no)  manpages=no ;;
 803   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 804 esac],[manpages=yes])
 805
 806 if test x$manpages = xyes ; then
 807     #
 808     # XMLTOMAN manpage generation
 809     #
 810     AC_ARG_ENABLE(xmltoman,
 811     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 812     [case "${enableval}" in
 813       yes) xmltoman=yes ;;
 814       no)  xmltoman=no ;;
 815       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 816     esac],[xmltoman=yes])
 817
 818     if test x$xmltoman = xyes ; then
 819         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 820     fi
 821
 822     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 823         if ! test -e man/avahi-daemon.8 ; then
 824             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 825             exit 1
 826         fi
 827         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 828         xmltoman=no
 829     fi
 830 fi
 831 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 832 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 833
 834 #
 835 # Conditionally compile test and example programs
 836 #
 837 AC_ARG_ENABLE(tests,
 838         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 839         [case "${enableval}" in
 840                 yes) ENABLE_TESTS=yes ;;
 841                 no)  ENABLE_TESTS=no ;;
 842                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 843         esac],
 844         [ENABLE_TESTS=no])
 845
 846 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 847
 848 #
 849 # Optionally enable libdns_sd compatibility support
 850 #
 851 AC_ARG_ENABLE(compat-libdns_sd,
 852         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 853         [case "${enableval}" in
 854                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 855                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 856                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 857         esac],
 858         [ENABLE_COMPAT_LIBDNS_SD=no])
 859
 860 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 861
 862 #
 863 # Optionally enable HOWL compatibility support
 864 #
 865 AC_ARG_ENABLE(compat-howl,
 866         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 867         [case "${enableval}" in
 868                 yes) ENABLE_COMPAT_HOWL=yes ;;
 869                 no)  ENABLE_COMPAT_HOWL=no ;;
 870                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 871         esac],
 872         [ENABLE_COMPAT_HOWL=no])
 873
 874 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 875
 876
 877 # ==========================================================================
 878 AC_CONFIG_FILES([
 879 Makefile
 880 avahi-common/Makefile
 881 avahi-core/Makefile
 882 avahi-glib/Makefile
 883 avahi-qt/Makefile
 884 avahi-daemon/Makefile
 885 avahi-daemon/avahi-dbus.conf
 886 avahi-discover-standalone/Makefile
 887 avahi-client/Makefile
 888 initscript/Makefile
 889 initscript/debian/Makefile
 890 initscript/gentoo/Makefile
 891 initscript/archlinux/Makefile
 892 initscript/suse/Makefile
 893 initscript/fedora/Makefile
 894 initscript/mandriva/Makefile
 895 initscript/darwin/Makefile
 896 initscript/freebsd/Makefile
 897 initscript/slackware/Makefile
 898 avahi-dnsconfd/Makefile
 899 avahi-utils/Makefile
 900 avahi-python/Makefile
 901 avahi-python/avahi/Makefile
 902 examples/Makefile
 903 common/Makefile
 904 man/Makefile
 905 tests/Makefile
 906 service-type-database/Makefile
 907 avahi-sharp/Makefile
 908 avahi-compat-libdns_sd/Makefile
 909 avahi-compat-howl/Makefile
 910 avahi-compat-howl/samples/Makefile
 911 avahi-autoipd/Makefile
 912 ])
 913 AC_OUTPUT
 914
 915 # ==========================================================================
 916 echo "
 917  ---{ $PACKAGE_NAME $VERSION }---
 918
 919     prefix:                                    ${prefix}
 920     sysconfdir:                                ${sysconfdir}
 921     localstatedir:                             ${localstatedir}
 922     avahi socket:                              ${avahi_socket}
 923     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
 924     dbus-1 version:                            ${DBUS_VERSION}
 925     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 926     C Compiler:                                ${CC}
 927     CFLAGS:                                    ${CFLAGS}
 928     Enable GLIB:                               ${HAVE_GLIB}
 929     Enable GTK:                                ${HAVE_GTK}
 930     Enable D-Bus:                              ${HAVE_DBUS}
 931     Enable Expat:                              ${HAVE_EXPAT}
 932     Enable GDBM:                               ${HAVE_GDBM}
 933     Enable DBM:                                ${HAVE_DBM}
 934     Enable libdaemon:                          ${HAVE_LIBDAEMON}
 935     Enable Python:                             ${HAVE_PYTHON}
 936     Enable pygtk:                              ${HAVE_PYGTK}
 937     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
 938     Enable QT3:                                ${HAVE_QT3}
 939     Enable QT4:                                ${HAVE_QT4}
 940     Enable Mono:                               ${HAVE_MONO}
 941     Enable Monodoc:                            ${HAVE_MONODOC}
 942     Distribution/OS:                           ${with_distro}
 943     User for avahi-daemon:                     ${AVAHI_USER}
 944     Group for avahi-daemon:                    ${AVAHI_GROUP}
 945     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
 946     User for avahi-autopid:                    ${AVAHI_AUTOIPD_USER}
 947     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
 948     Enable chroot():                           ${enable_chroot}
 949 "
 950
 951 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 952
 953 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 954     BUILD_DAEMON=yes
 955 fi
 956
 957 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 958
 959 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 960     BUILD_PYTHON=yes
 961 fi
 962
 963 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
 964
 965 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 966     BUILD_CLIENT=yes
 967 fi
 968
 969 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 970    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 971 fi
 972 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 973    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 974 fi
 975
 976
 977 echo "\
 978     Building libavahi-core              yes
 979     Building avahi-daemon:              ${BUILD_DAEMON}
 980     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 981     Building libavahi-client:           ${BUILD_CLIENT}
 982     Building avahi-utils:               ${BUILD_CLIENT}
 983     Building avahi-python:              ${BUILD_PYTHON}
 984     Building libavahi-glib:             ${HAVE_GLIB}
 985     Building avahi-discover-standalone: ${HAVE_GTK}
 986     Building libavahi-qt3:              ${HAVE_QT3}
 987     Building libavahi-qt4:              ${HAVE_QT4}
 988     Building avahi-sharp:               ${HAVE_MONO}
 989     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 990     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 991     Building tests:                     ${ENABLE_TESTS}
 992     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
 993     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
 994 "