git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.5],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37
  38 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  39     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  40     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  41 fi
  42
  43 # Checks for programs.
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AC_GNU_SOURCE
  47 AC_PROG_CPP
  48 AC_PROG_INSTALL
  49 AC_PROG_LN_S
  50 AC_PROG_MAKE_SET
  51 AC_PROG_GCC_TRADITIONAL
  52
  53 # libtool stuff
  54 AC_PROG_LIBTOOL
  55
  56 #
  57 # Detecting the linux distribution for specific things like init scripts.
  58 #
  59 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
  60 if test "z$with_distro" = "z"; then
  61     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  62     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  63     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
  64     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  65 fi
  66 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
  67
  68 if test "z$with_distro" = "z"; then
  69     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
  70     exit 1
  71 else
  72 case $with_distro in
  73     debian|gentoo|archlinux|suse|none)
  74      ;;
  75     *)
  76      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
  77      ;;
  78 esac
  79 fi
  80
  81 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
  82 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
  83 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
  84 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
  85
  86 test_gcc_flag() {
  87     AC_LANG_CONFTEST([int main() {}])
  88     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  89     ret=$?
  90     rm -f conftest.o
  91     return $ret
  92 }
  93
  94 # If using GCC specify some additional parameters
  95 if test "x$GCC" = "xyes" ; then
  96
  97     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  98
  99     # Test whether rtnetlink.h can be included when compiled with -std=c99
 100     # some distributions (e.g. archlinux) have broken headers that dont
 101     # define __u64 with -std=c99
 102     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 103     OLDCFLAGS="$CFLAGS"
 104     CFLAGS="-std=c99"
 105     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 106         use_stdc99=yes, use_stdc99=no)
 107
 108     if test x"$use_stdc99" = xyes; then
 109         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 110         AC_MSG_RESULT([yes])
 111     else
 112         AC_MSG_RESULT([no])
 113     fi
 114
 115     CFLAGS="$OLDCFLAGS"
 116
 117     for flag in $DESIRED_FLAGS ; do
 118         AC_MSG_CHECKING([whether $CC accepts $flag])
 119         if test_gcc_flag $flag ; then
 120            CFLAGS="$CFLAGS $flag"
 121            AC_MSG_RESULT([yes])
 122         else
 123            AC_MSG_RESULT([no])
 124         fi
 125     done
 126 fi
 127
 128 # Checks for header files.
 129 AC_HEADER_STDC
 130 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 131
 132 # Checks for typedefs, structures, and compiler characteristics.
 133 AC_C_CONST
 134 AC_TYPE_SIZE_T
 135 AC_HEADER_TIME
 136 AC_HEADER_SYS_WAIT
 137
 138 # Checks for library functions.
 139 AC_FUNC_MEMCMP
 140 AC_FUNC_SELECT_ARGTYPES
 141 AC_FUNC_MALLOC
 142 AC_FUNC_REALLOC
 143 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp])
 144
 145 AC_FUNC_CHOWN
 146 AC_FUNC_STAT
 147 AC_TYPE_MODE_T
 148 AC_TYPE_PID_T
 149
 150 # Check for pkg-config manually first, as if its not installed the
 151 # PKG_PROG_PKG_CONFIG macro won't be defined.
 152 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 153
 154 if test x"$have_pkg_config" == xno; then
 155     AC_MSG_ERROR(pkg-config is required to install this program)
 156 fi
 157
 158 PKG_PROG_PKG_CONFIG
 159
 160 #
 161 # Check for GLIB 2.0
 162 #
 163 AC_ARG_ENABLE(glib,
 164         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 165         [case "${enableval}" in
 166                 yes) HAVE_GLIB=yes ;;
 167                 no)  HAVE_GLIB=no ;;
 168                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 169         esac],
 170         [HAVE_GLIB=yes])
 171
 172 if test "x$HAVE_GLIB" = "xyes" ; then
 173         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 174         AC_SUBST(GLIB20_CFLAGS)
 175         AC_SUBST(GLIB20_LIBS)
 176 fi
 177 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 178
 179 #
 180 # Check for Qt 3
 181 #
 182 AC_ARG_ENABLE(qt3,
 183         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 184         [case "${enableval}" in
 185                 yes) HAVE_QT3=yes ;;
 186                 no)  HAVE_QT3=no ;;
 187                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 188         esac],
 189         [HAVE_QT3=yes])
 190
 191 if test "x$HAVE_QT3" = "xyes" ; then
 192         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 193         AC_SUBST(QT3_CFLAGS)
 194         AC_SUBST(QT3_LIBS)
 195             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 196         MOC_QT3="no"
 197             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 198                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 199                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 200         AC_SUBST(MOC_QT3)
 201 fi
 202 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 203
 204 #
 205 # Check for Qt 4
 206 #
 207 AC_ARG_ENABLE(qt4,
 208         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 209         [case "${enableval}" in
 210                 yes) HAVE_QT4=yes ;;
 211                 no)  HAVE_QT4=no ;;
 212                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 213         esac],
 214         [HAVE_QT4=yes])
 215
 216 if test "x$HAVE_QT4" = "xyes" ; then
 217         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 218         AC_SUBST(QT4_CFLAGS)
 219         AC_SUBST(QT4_LIBS)
 220             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 221         MOC_QT4="no"
 222             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 223                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 224                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 225         AC_SUBST(MOC_QT4)
 226 fi
 227 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 228
 229 #
 230 # Check for GTK+
 231 #
 232 AC_ARG_ENABLE(gtk,
 233         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 234         [case "${enableval}" in
 235                 yes) HAVE_GTK=yes ;;
 236                 no)  HAVE_GTK=no ;;
 237                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 238         esac],
 239         [HAVE_GTK=yes])
 240
 241 if test "x$HAVE_GTK" = "xyes" ; then
 242         # Check for GTK 2.0
 243         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 244         AC_SUBST(GTK20_CFLAGS)
 245         AC_SUBST(GTK20_LIBS)
 246
 247         # Check for GLADE 2.0
 248         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 249         AC_SUBST(GLADE20_CFLAGS)
 250         AC_SUBST(GLADE20_LIBS)
 251 fi
 252 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 253
 254
 255
 256 #
 257 # D-BUS
 258 #
 259 AC_ARG_ENABLE(dbus,
 260         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 261         [case "${enableval}" in
 262                 yes) HAVE_DBUS=yes ;;
 263                 no)  HAVE_DBUS=no ;;
 264                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 265         esac],
 266         [HAVE_DBUS=yes])
 267
 268 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 269 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 270
 271 if test "x$HAVE_DBUS" = "xyes" ; then
 272     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 273
 274     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 275     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 276     AC_SUBST(DBUS_CFLAGS)
 277     AC_SUBST(DBUS_LIBS)
 278
 279     if ! test -z "$with_dbus_sys" ; then
 280         DBUS_SYS_DIR="$with_dbus_sys"
 281     else
 282         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 283     fi
 284     AC_SUBST(DBUS_SYS_DIR)
 285
 286     if ! test -z "$with_dbus_system_address" ; then
 287         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 288     else
 289         # Note this default path is hardcoded in D-BUS and should
 290         # not use $localstatedir
 291         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 292     fi
 293     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 294
 295 fi
 296 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 297
 298 #
 299 # Expat
 300 #
 301 AC_ARG_ENABLE(expat,
 302         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 303         [case "${enableval}" in
 304                 yes) HAVE_EXPAT=yes ;;
 305                 no)  HAVE_EXPAT=no ;;
 306                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 307         esac],
 308         [HAVE_EXPAT=yes])
 309
 310 if test "x$HAVE_EXPAT" = "xyes" ; then
 311     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 312
 313     if ! $have_expat ; then
 314         AC_MSG_ERROR([*** libexpat not found ***])
 315     fi
 316 fi
 317 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 318
 319 #
 320 # libdaemon
 321 #
 322 AC_ARG_ENABLE(libdaemon,
 323         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 324         [case "${enableval}" in
 325                 yes) HAVE_LIBDAEMON=yes ;;
 326                 no)  HAVE_LIBDAEMON=no ;;
 327                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 328         esac],
 329         [HAVE_LIBDAEMON=yes])
 330
 331 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 332     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 333     AC_SUBST(LIBDAEMON_CFLAGS)
 334     AC_SUBST(LIBDAEMON_LIBS)
 335 fi
 336 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 337
 338 #
 339 # Python stuff
 340 #
 341 AC_ARG_ENABLE(python,
 342     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 343     [case "${enableval}" in
 344           yes) HAVE_PYTHON=yes ;;
 345           no)  HAVE_PYTHON=no ;;
 346           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 347     esac],[HAVE_PYTHON=yes])
 348
 349 HAVE_PYTHON_DBUS=no
 350 HAVE_PYGTK=no
 351
 352 if test "x$HAVE_PYTHON" = "xyes" ; then
 353     AM_PATH_PYTHON([2.4])
 354
 355     AC_ARG_ENABLE(pygtk,
 356         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 357         [case "${enableval}" in
 358                 yes) HAVE_PYGTK=yes ;;
 359                 no)  HAVE_PYGTK=no ;;
 360                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 361         esac],
 362         [HAVE_PYGTK=yes])
 363
 364     if test "x$HAVE_PYGTK" = "xyes" ; then
 365         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 366     fi
 367
 368
 369     AC_ARG_ENABLE(python-dbus,
 370         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 371         [case "${enableval}" in
 372                 yes) HAVE_PYTHON_DBUS=yes ;;
 373                 no)  HAVE_PYTHON_DBUS=no ;;
 374                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 375         esac],
 376         [HAVE_PYTHON_DBUS=yes])
 377
 378     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 379         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 380     fi
 381
 382     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 383     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 384 fi
 385 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 386 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 387 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 388
 389 #
 390 # Check for mono stuff
 391 #
 392 AC_ARG_ENABLE(mono,
 393         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 394         [case "${enableval}" in
 395                 yes) HAVE_MONO=yes ;;
 396                 no)  HAVE_MONO=no ;;
 397                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 398         esac],
 399         [HAVE_MONO=yes])
 400
 401 AC_ARG_ENABLE(mono-docs,
 402         AS_HELP_STRING([--disable-mono-docs],[Disable documentation for mono bindings]),
 403         [case "${enableval}" in
 404                 yes) HAVE_MONODOC=yes ;;
 405                 no)  HAVE_MONODOC=no ;;
 406                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono-docs) ;;
 407         esac],
 408         [HAVE_MONODOC=yes])
 409
 410 if test "x$HAVE_MONO" = "xyes" ; then
 411         AC_PATH_PROG(MCS, mcs)
 412         if test "x$MCS" = "x" ; then
 413                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 414         fi
 415
 416         AC_PATH_PROG(GACUTIL, gacutil)
 417         if test "x$GACUTIL" = "x" ; then
 418                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 419         fi
 420
 421         AC_SUBST(MCS)
 422         AC_SUBST(GACUTIL)
 423 fi
 424 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 425
 426 #
 427 # Check for monodoc stuff
 428 #
 429 if test "x$HAVE_MONODOC" = "xyes" ; then
 430         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 431         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 432
 433         AC_PATH_PROG(MONODOCER, monodocer)
 434         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 435
 436         AC_SUBST(MONODOC_DIR)
 437         AC_SUBST(MONODOCER)
 438         AC_SUBST(MDASSEMBLER)
 439 fi
 440 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 441
 442 #
 443 # Defining Avahi User and Group.
 444 #
 445 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 446 if test -z "$with_avahi_user" ; then
 447     AVAHI_USER=avahi
 448 else
 449     AVAHI_USER=$with_avahi_user
 450 fi
 451 AC_SUBST(AVAHI_USER)
 452 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 453
 454 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 455 if test -z "$with_avahi_group" ; then
 456     AVAHI_GROUP=avahi
 457 else
 458     AVAHI_GROUP=$with_avahi_group
 459 fi
 460 AC_SUBST(AVAHI_GROUP)
 461 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 462
 463 #
 464 # Avahi runtime dir
 465 #
 466 avahi_runtime_dir="${localstatedir}/run"
 467 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 468 AC_SUBST(avahi_runtime_dir)
 469 AC_SUBST(avahi_socket)
 470
 471
 472 #
 473 # Avahi interfaces dir
 474 #
 475 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 476         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 477         AC_SUBST(interfacesdir)
 478 fi
 479
 480
 481 #
 482 # Doxygen
 483 #
 484 DX_HTML_FEATURE(ON)
 485 DX_CHM_FEATURE(OFF)
 486 DX_CHI_FEATURE(OFF)
 487 DX_MAN_FEATURE(OFF)
 488 DX_RTF_FEATURE(OFF)
 489 DX_XML_FEATURE(OFF)
 490 DX_PDF_FEATURE(OFF)
 491 DX_PS_FEATURE(OFF)
 492 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 493
 494 #
 495 # XMLTOMAN manpage generation
 496 #
 497 AC_ARG_ENABLE(xmltoman,
 498         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 499 [case "${enableval}" in
 500   yes) xmltoman=yes ;;
 501   no)  xmltoman=no ;;
 502   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 503 esac],[xmltoman=yes])
 504
 505 if test x$xmltoman = xyes ; then
 506     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 507
 508     if test x$have_xmltoman = xno ; then
 509         if ! test -e man/avahi-daemon.8 ; then
 510             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 511             exit 1
 512         fi
 513         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 514         xmltoman=no
 515     fi
 516 fi
 517
 518 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 519
 520 # ==========================================================================
 521 AC_CONFIG_FILES([
 522 Makefile
 523 avahi-common/Makefile
 524 avahi-core/Makefile
 525 avahi-glib/Makefile
 526 avahi-qt/Makefile
 527 avahi-daemon/Makefile
 528 avahi-daemon/avahi-dbus.conf
 529 avahi-discover-standalone/Makefile
 530 avahi-client/Makefile
 531 initscript/Makefile
 532 initscript/debian/Makefile
 533 initscript/gentoo/Makefile
 534 initscript/archlinux/Makefile
 535 initscript/suse/Makefile
 536 avahi-dnsconfd/Makefile
 537 avahi-utils/Makefile
 538 avahi-utils/avahi/Makefile
 539 examples/Makefile
 540 common/Makefile
 541 man/Makefile
 542 tests/Makefile
 543 service-type-database/Makefile
 544 avahi-sharp/Makefile
 545 ])
 546 AC_OUTPUT
 547
 548 # ==========================================================================
 549 echo "
 550  ---{ $PACKAGE_NAME $VERSION }---
 551
 552     prefix:                 ${prefix}
 553     sysconfdir:             ${sysconfdir}
 554     localstatedir:          ${localstatedir}
 555     avahi socket:           ${avahi_socket}
 556     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 557     dbus-1 version:         `pkg-config dbus-1 --modversion`
 558     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 559     compiler:               ${CC}
 560     cflags:                 ${CFLAGS}
 561     Enable GLIB:            ${HAVE_GLIB}
 562     Enable GTK:             ${HAVE_GTK}
 563     Enable D-BUS:           ${HAVE_DBUS}
 564     Enable Expat:           ${HAVE_EXPAT}
 565     Enable libdaemon:       ${HAVE_LIBDAEMON}
 566     Enable Python:          ${HAVE_PYTHON}
 567     Enable pygtk:           ${HAVE_PYGTK}
 568     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 569     Enable QT3:             ${HAVE_QT3}
 570     Enable QT4:             ${HAVE_QT4}
 571     Enable Mono:            ${HAVE_MONO}
 572     Linux Distro:           ${with_distro}
 573     User for Avahi:         ${AVAHI_USER}
 574     Group for Avahi:        ${AVAHI_GROUP}
 575 "
 576
 577 BUILD_DAEMON="no (!)"
 578
 579 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 580     BUILD_DAEMON=yes
 581 fi
 582
 583 BUILD_UTILS="no (!)"
 584
 585 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 586     BUILD_UTILS=yes
 587 fi
 588
 589 BUILD_CLIENT="no (!)"
 590
 591 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 592     BUILD_CLIENT=yes
 593 fi
 594
 595 echo "
 596     Building libavahi-core              yes
 597     Building avahi-daemon:              ${BUILD_DAEMON}
 598     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 599     Building avahi-utils:               ${BUILD_UTILS}
 600     Building libavahi-glib:             ${HAVE_GLIB}
 601     Building libavahi-client:           ${BUILD_CLIENT}
 602     Building avahi-discover-standalone: ${HAVE_GTK}
 603     Building libavahi-qt3:              ${HAVE_QT3}
 604     Building libavahi-qt4:              ${HAVE_QT4}
 605     Building avahi-sharp:               ${HAVE_MONO}
 606 "