git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.12],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [7:1:4])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [4:3:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [4:3:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for sys/filio.h; needed for FIONREAD on Solaris
  89 #
  90 AC_CHECK_HEADER(sys/filio.h,
  91 HAVE_SYS_FILIO_H=yes
  92 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
  93 , [], [
  94 ])
  95
  96 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
  97
  98 #
  99 # Check for sys/sysctl.h; not present on Solaris
 100 #
 101 AC_CHECK_HEADER(sys/sysctl.h,
 102 HAVE_SYS_SYSCTL=yes
 103 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 104 , [], [
 105 #include <sys/types.h>
 106 #include <sys/socket.h>
 107 ])
 108
 109 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 110
 111 #
 112 # Check for struct ip_mreqn
 113 #
 114 AC_MSG_CHECKING(for struct ip_mreqn)
 115 AC_TRY_COMPILE([#include <netinet/in.h>], [
 116         struct ip_mreqn mreq;
 117         mreq.imr_address.s_addr = 0;
 118 ], [
 119         # Yes, we have it...
 120         AC_MSG_RESULT(yes)
 121         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 122 ], [
 123         # We'll just have to try and use struct ip_mreq
 124         AC_MSG_RESULT(no)
 125         AC_MSG_CHECKING(for struct ip_mreq)
 126         AC_TRY_COMPILE([#include <netinet/in.h>], [
 127                 struct ip_mreq mreq;
 128                 mreq.imr_interface.s_addr = 0;
 129         ], [
 130                 # Yes, we have it...
 131                 AC_MSG_RESULT(yes)
 132                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 133         ], [
 134                 # No multicast support
 135                         AC_MSG_RESULT(no)
 136         ])
 137 ])
 138
 139 #
 140 # Detecting the linux distribution for specific things like init scripts.
 141 #
 142 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 143 if test "z$with_distro" = "z"; then
 144     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 145     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 146     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 147     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 148     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 149     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 150     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 151     if test "z$with_distro" = "z"; then
 152         with_distro=`uname -s`
 153     fi
 154 fi
 155 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 156
 157 case $with_distro in
 158     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 159      ;;
 160     netbsd)
 161      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 162      ;;
 163     linux)
 164      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 165      ;;
 166     *)
 167      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 168      ;;
 169 esac
 170
 171 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 172 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 173 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 174 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 175 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 176 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 177 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 178 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 179 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 180 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 181
 182 test_gcc_flag() {
 183     AC_LANG_CONFTEST([int main() {}])
 184     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 185     ret=$?
 186     rm -f conftest.o
 187     return $ret
 188 }
 189
 190 # If using GCC specify some additional parameters
 191 if test "x$GCC" = "xyes" ; then
 192
 193     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 194
 195     if test "x$HAVE_NETLINK" = "xyes" ; then
 196         # Test whether rtnetlink.h can be included when compiled with -std=c99
 197         # some distributions (e.g. archlinux) have broken headers that dont
 198         # define __u64 with -std=c99
 199         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 200         OLDCFLAGS="$CFLAGS"
 201         CFLAGS="-std=c99"
 202         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 203             use_stdc99=yes, use_stdc99=no)
 204
 205         if test x"$use_stdc99" = xyes; then
 206             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 207             AC_MSG_RESULT([yes])
 208         else
 209             AC_MSG_RESULT([no])
 210         fi
 211
 212         CFLAGS="$OLDCFLAGS"
 213     else
 214         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 215     fi
 216
 217     for flag in $DESIRED_FLAGS ; do
 218         AC_MSG_CHECKING([whether $CC accepts $flag])
 219         if test_gcc_flag $flag ; then
 220            CFLAGS="$CFLAGS $flag"
 221            AC_MSG_RESULT([yes])
 222         else
 223            AC_MSG_RESULT([no])
 224         fi
 225     done
 226 fi
 227
 228 # Checks for header files.
 229 AC_HEADER_STDC
 230 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 231 AC_HEADER_STDBOOL
 232
 233 # Checks for typedefs, structures, and compiler characteristics.
 234 AC_C_CONST
 235 AC_TYPE_SIZE_T
 236 AC_HEADER_TIME
 237 AC_HEADER_SYS_WAIT
 238
 239 # Checks for library functions.
 240 AC_FUNC_MEMCMP
 241 AC_FUNC_SELECT_ARGTYPES
 242 AC_FUNC_MALLOC
 243 AC_FUNC_REALLOC
 244 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 245
 246 AC_FUNC_CHOWN
 247 AC_FUNC_STAT
 248 AC_TYPE_MODE_T
 249 AC_TYPE_PID_T
 250
 251 AC_CHECK_DECLS(environ)
 252
 253 enable_chroot=yes
 254 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 255 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 256 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 257
 258 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 259
 260 if test "x$enable_chroot" = "xyes" ; then
 261    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 262 fi
 263
 264 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 265 if test "x$HAVE_DLOPEN" = "xyes" ; then
 266     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 267 fi
 268 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 269
 270 # Check for pkg-config manually first, as if its not installed the
 271 # PKG_PROG_PKG_CONFIG macro won't be defined.
 272 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 273
 274 if test x"$have_pkg_config" = "xno"; then
 275     AC_MSG_ERROR(pkg-config is required to install this program)
 276 fi
 277
 278 PKG_PROG_PKG_CONFIG
 279
 280 #
 281 # Check for GLIB 2.0
 282 #
 283 AC_ARG_ENABLE(glib,
 284         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 285         [case "${enableval}" in
 286                 yes) HAVE_GLIB=yes ;;
 287                 no)  HAVE_GLIB=no ;;
 288                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 289         esac],
 290         [HAVE_GLIB=yes])
 291
 292 if test "x$HAVE_GLIB" = "xyes" ; then
 293         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 294         AC_SUBST(GLIB20_CFLAGS)
 295         AC_SUBST(GLIB20_LIBS)
 296 fi
 297 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 298
 299 #
 300 # Check for Qt 3
 301 #
 302 AC_ARG_ENABLE(qt3,
 303         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 304         [case "${enableval}" in
 305                 yes) HAVE_QT3=yes ;;
 306                 no)  HAVE_QT3=no ;;
 307                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 308         esac],
 309         [HAVE_QT3=yes])
 310
 311 if test "x$HAVE_QT3" = "xyes" ; then
 312         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 313         AC_SUBST(QT3_CFLAGS)
 314         AC_SUBST(QT3_LIBS)
 315             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 316         MOC_QT3="no"
 317             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 318                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 319                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 320         AC_SUBST(MOC_QT3)
 321 fi
 322 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 323
 324 #
 325 # Check for Qt 4
 326 #
 327 AC_ARG_ENABLE(qt4,
 328         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 329         [case "${enableval}" in
 330                 yes) HAVE_QT4=yes ;;
 331                 no)  HAVE_QT4=no ;;
 332                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 333         esac],
 334         [HAVE_QT4=yes])
 335
 336 if test "x$HAVE_QT4" = "xyes" ; then
 337         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 338         AC_SUBST(QT4_CFLAGS)
 339         AC_SUBST(QT4_LIBS)
 340             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 341         MOC_QT4="no"
 342             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 343                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 344                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 345         AC_SUBST(MOC_QT4)
 346 fi
 347 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 348
 349 #
 350 # Check for GTK+
 351 #
 352 AC_ARG_ENABLE(gtk,
 353         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 354         [case "${enableval}" in
 355                 yes) HAVE_GTK=yes ;;
 356                 no)  HAVE_GTK=no ;;
 357                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 358         esac],
 359         [HAVE_GTK=yes])
 360
 361 if test "x$HAVE_GTK" = "xyes" ; then
 362         # Check for GTK 2.0
 363         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 364         AC_SUBST(GTK20_CFLAGS)
 365         AC_SUBST(GTK20_LIBS)
 366
 367         # Check for GLADE 2.0
 368         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 369         AC_SUBST(GLADE20_CFLAGS)
 370         AC_SUBST(GLADE20_LIBS)
 371 fi
 372 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 373
 374 #
 375 # D-BUS
 376 #
 377 AC_ARG_ENABLE(dbus,
 378         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 379         [case "${enableval}" in
 380                 yes) HAVE_DBUS=yes ;;
 381                 no)  HAVE_DBUS=no ;;
 382                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 383         esac],
 384         [HAVE_DBUS=yes])
 385
 386 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 387 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 388
 389 DBUS_VERSION="Disabled"
 390 DBUS_SYS_DIR="Disabled"
 391 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 392 if test "x$HAVE_DBUS" = "xyes" ; then
 393     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 394
 395     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 396
 397     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 398     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 399     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 400     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 401     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 402         DBUS_VERSION_MAJOR="0"
 403     fi
 404     if test "z$DBUS_VERSION_MINOR" = "z"; then
 405         DBUS_VERSION_MINOR="0"
 406     fi
 407     if test "z$DBUS_VERSION_MICRO" = "z"; then
 408         DBUS_VERSION_MICRO="0"
 409     fi
 410
 411     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 412         echo "Error: Couldn't determine the version of your DBUS package."
 413         echo "  This is probably an error in this script, please report it"
 414         echo "  along with the following information:"
 415         echo "      Base DBUS version ='$DBUS_VERSION'"
 416         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 417         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 418         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 419         exit 1
 420     else
 421         echo "Your dbus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 422         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 423         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 424         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 425     fi
 426
 427     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 428     AC_SUBST(DBUS_CFLAGS)
 429     AC_SUBST(DBUS_LIBS)
 430
 431     if ! test -z "$with_dbus_sys" ; then
 432         DBUS_SYS_DIR="$with_dbus_sys"
 433     else
 434         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 435     fi
 436     AC_SUBST(DBUS_SYS_DIR)
 437
 438     if ! test -z "$with_dbus_system_address" ; then
 439         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 440     else
 441         # This is ugly, but D-BUS doesn't export this address for us
 442         # so we have to guess, pretty much all setups i've seen have
 443         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 444         # /var/run upstream so we will try guess first then default
 445         # to /var/run/dbus
 446
 447         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 448         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 449         for sock in $TRY_SOCKETS; do
 450             if test -S $sock; then
 451                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 452             fi
 453         done
 454     fi
 455     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 456
 457 fi
 458 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 459
 460 #
 461 # Expat
 462 #
 463 AC_ARG_ENABLE(expat,
 464         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 465         [case "${enableval}" in
 466                 yes) HAVE_EXPAT=yes ;;
 467                 no)  HAVE_EXPAT=no ;;
 468                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 469         esac],
 470         [HAVE_EXPAT=yes])
 471
 472 if test "x$HAVE_EXPAT" = "xyes" ; then
 473     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 474
 475     if ! $have_expat ; then
 476         AC_MSG_ERROR([*** libexpat not found ***])
 477     fi
 478 fi
 479 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 480
 481 #
 482 # GDBM
 483 #
 484 AC_ARG_ENABLE(gdbm,
 485         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 486         [case "${enableval}" in
 487                 yes) HAVE_GDBM=yes ;;
 488                 no)  HAVE_GDBM=no ;;
 489                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 490         esac],
 491         [HAVE_GDBM=yes])
 492
 493 if test "x$HAVE_GDBM" = "xyes" ; then
 494     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 495
 496     if ! $have_gdbm ; then
 497         AC_MSG_ERROR([*** libgdbm not found ***])
 498     fi
 499     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 500 fi
 501 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 502
 503 #
 504 # libdaemon
 505 #
 506 AC_ARG_ENABLE(libdaemon,
 507         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 508         [case "${enableval}" in
 509                 yes) HAVE_LIBDAEMON=yes ;;
 510                 no)  HAVE_LIBDAEMON=no ;;
 511                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 512         esac],
 513         [HAVE_LIBDAEMON=yes])
 514
 515 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 516     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 517     AC_SUBST(LIBDAEMON_CFLAGS)
 518     AC_SUBST(LIBDAEMON_LIBS)
 519 fi
 520 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 521
 522 #
 523 # Python stuff
 524 #
 525 AC_ARG_ENABLE(python,
 526     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 527     [case "${enableval}" in
 528           yes) HAVE_PYTHON=yes ;;
 529           no)  HAVE_PYTHON=no ;;
 530           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 531     esac],[HAVE_PYTHON=yes])
 532
 533 HAVE_PYTHON_DBUS=no
 534 HAVE_PYGTK=no
 535
 536 if test "x$HAVE_PYTHON" = "xyes" ; then
 537     AM_PATH_PYTHON([2.4])
 538
 539     AC_ARG_ENABLE(pygtk,
 540         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 541         [case "${enableval}" in
 542                 yes) HAVE_PYGTK=yes ;;
 543                 no)  HAVE_PYGTK=no ;;
 544                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 545         esac],
 546         [HAVE_PYGTK=yes])
 547
 548     if test "x$HAVE_PYGTK" = "xyes" ; then
 549         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 550     fi
 551
 552
 553     if test "x$HAVE_DBUS" = "xyes" ; then
 554         AC_ARG_ENABLE(python-dbus,
 555             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 556             [case "${enableval}" in
 557                    yes) HAVE_PYTHON_DBUS=yes ;;
 558                    no)  HAVE_PYTHON_DBUS=no ;;
 559                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 560             esac],
 561             [HAVE_PYTHON_DBUS=yes])
 562
 563         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 564             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 565         fi
 566
 567         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 568         if test "x$HAVE_GDBM" = "xyes"; then
 569             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 570         fi
 571     fi
 572 fi
 573 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 574 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 575 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 576
 577 #
 578 # Check for mono stuff
 579 #
 580 HAVE_MONO=no
 581 if test "x$HAVE_DBUS" = "xyes" ; then
 582     AC_ARG_ENABLE(mono,
 583             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 584             [case "${enableval}" in
 585                     yes) HAVE_MONO=yes ;;
 586                     no)  HAVE_MONO=no ;;
 587                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 588             esac],
 589             [HAVE_MONO=yes])
 590
 591     if test "x$HAVE_MONO" = "xyes" ; then
 592         AC_PATH_PROG(MCS, mcs)
 593         if test "x$MCS" = "x" ; then
 594             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 595         fi
 596
 597         AC_PATH_PROG(GACUTIL, gacutil)
 598         if test "x$GACUTIL" = "x" ; then
 599             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 600         fi
 601
 602         AC_SUBST(MCS)
 603         AC_SUBST(GACUTIL)
 604     fi
 605 fi
 606 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 607
 608 #
 609 # Check for monodoc stuff
 610 #
 611 HAVE_MONODOC=no
 612 AC_ARG_ENABLE(monodoc,
 613         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 614         [case "${enableval}" in
 615                 yes) HAVE_MONODOC=yes ;;
 616                 no)  HAVE_MONODOC=no ;;
 617                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 618         esac],
 619         [HAVE_MONODOC=yes])
 620
 621 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 622         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 623         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 624
 625         AC_PATH_PROG(MONODOCER, monodocer)
 626         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 627
 628         AC_SUBST(MONODOC_DIR)
 629         AC_SUBST(MONODOCER)
 630         AC_SUBST(MDASSEMBLER)
 631 fi
 632 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 633
 634 #
 635 # Defining Avahi User and Group.
 636 #
 637 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 638 if test -z "$with_avahi_user" ; then
 639     AVAHI_USER=avahi
 640 else
 641     AVAHI_USER=$with_avahi_user
 642 fi
 643 AC_SUBST(AVAHI_USER)
 644 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 645
 646 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 647 if test -z "$with_avahi_group" ; then
 648     AVAHI_GROUP=avahi
 649 else
 650     AVAHI_GROUP=$with_avahi_group
 651 fi
 652 AC_SUBST(AVAHI_GROUP)
 653 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 654
 655 #
 656 # Avahi runtime dir
 657 #
 658 avahi_runtime_dir="${localstatedir}/run"
 659 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 660 AC_SUBST(avahi_runtime_dir)
 661 AC_SUBST(avahi_socket)
 662
 663 #
 664 # Avahi interfaces dir
 665 #
 666 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 667         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 668         AC_SUBST(interfacesdir)
 669 fi
 670
 671 #
 672 # Doxygen
 673 #
 674 DX_HTML_FEATURE(ON)
 675 DX_CHM_FEATURE(OFF)
 676 DX_CHI_FEATURE(OFF)
 677 DX_MAN_FEATURE(OFF)
 678 DX_RTF_FEATURE(OFF)
 679 DX_XML_FEATURE(OFF)
 680 DX_PDF_FEATURE(OFF)
 681 DX_PS_FEATURE(OFF)
 682 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 683
 684 #
 685 # Build and Install man pages
 686 #
 687 AC_ARG_ENABLE(manpages,
 688         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 689 [case "${enableval}" in
 690   yes) manpages=yes ;;
 691   no)  manpages=no ;;
 692   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 693 esac],[manpages=yes])
 694
 695 if test x$manpages = xyes ; then
 696     #
 697     # XMLTOMAN manpage generation
 698     #
 699     AC_ARG_ENABLE(xmltoman,
 700     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 701     [case "${enableval}" in
 702       yes) xmltoman=yes ;;
 703       no)  xmltoman=no ;;
 704       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 705     esac],[xmltoman=yes])
 706
 707     if test x$xmltoman = xyes ; then
 708         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 709     fi
 710
 711     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 712         if ! test -e man/avahi-daemon.8 ; then
 713             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 714             exit 1
 715         fi
 716         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 717         xmltoman=no
 718     fi
 719 fi
 720 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 721 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 722
 723 #
 724 # Conditionally compile test and example programs
 725 #
 726 AC_ARG_ENABLE(tests,
 727         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 728         [case "${enableval}" in
 729                 yes) ENABLE_TESTS=yes ;;
 730                 no)  ENABLE_TESTS=no ;;
 731                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 732         esac],
 733         [ENABLE_TESTS=no])
 734
 735 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 736
 737 #
 738 # Optionally enable libdns_sd compatibility support
 739 #
 740 AC_ARG_ENABLE(compat-libdns_sd,
 741         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 742         [case "${enableval}" in
 743                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 744                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 745                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 746         esac],
 747         [ENABLE_COMPAT_LIBDNS_SD=no])
 748
 749 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 750
 751 #
 752 # Optionally enable HOWL compatibility support
 753 #
 754 AC_ARG_ENABLE(compat-howl,
 755         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 756         [case "${enableval}" in
 757                 yes) ENABLE_COMPAT_HOWL=yes ;;
 758                 no)  ENABLE_COMPAT_HOWL=no ;;
 759                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 760         esac],
 761         [ENABLE_COMPAT_HOWL=no])
 762
 763 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 764
 765
 766 # ==========================================================================
 767 AC_CONFIG_FILES([
 768 Makefile
 769 avahi-common/Makefile
 770 avahi-core/Makefile
 771 avahi-glib/Makefile
 772 avahi-qt/Makefile
 773 avahi-daemon/Makefile
 774 avahi-daemon/avahi-dbus.conf
 775 avahi-discover-standalone/Makefile
 776 avahi-client/Makefile
 777 initscript/Makefile
 778 initscript/debian/Makefile
 779 initscript/gentoo/Makefile
 780 initscript/archlinux/Makefile
 781 initscript/suse/Makefile
 782 initscript/fedora/Makefile
 783 initscript/mandriva/Makefile
 784 initscript/darwin/Makefile
 785 initscript/freebsd/Makefile
 786 initscript/slackware/Makefile
 787 avahi-dnsconfd/Makefile
 788 avahi-utils/Makefile
 789 avahi-python/Makefile
 790 avahi-python/avahi/Makefile
 791 examples/Makefile
 792 common/Makefile
 793 man/Makefile
 794 tests/Makefile
 795 service-type-database/Makefile
 796 avahi-sharp/Makefile
 797 avahi-compat-libdns_sd/Makefile
 798 avahi-compat-howl/Makefile
 799 avahi-compat-howl/samples/Makefile
 800 ])
 801 AC_OUTPUT
 802
 803 # ==========================================================================
 804 echo "
 805  ---{ $PACKAGE_NAME $VERSION }---
 806
 807     prefix:                 ${prefix}
 808     sysconfdir:             ${sysconfdir}
 809     localstatedir:          ${localstatedir}
 810     avahi socket:           ${avahi_socket}
 811     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 812     dbus-1 version:         ${DBUS_VERSION}
 813     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 814     compiler:               ${CC}
 815     cflags:                 ${CFLAGS}
 816     Enable GLIB:            ${HAVE_GLIB}
 817     Enable GTK:             ${HAVE_GTK}
 818     Enable D-BUS:           ${HAVE_DBUS}
 819     Enable Expat:           ${HAVE_EXPAT}
 820     Enable GDBM:            ${HAVE_GDBM}
 821     Enable libdaemon:       ${HAVE_LIBDAEMON}
 822     Enable Python:          ${HAVE_PYTHON}
 823     Enable pygtk:           ${HAVE_PYGTK}
 824     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 825     Enable QT3:             ${HAVE_QT3}
 826     Enable QT4:             ${HAVE_QT4}
 827     Enable Mono:            ${HAVE_MONO}
 828     Enable Monodoc:         ${HAVE_MONODOC}
 829     Distribution/OS:        ${with_distro}
 830     User for Avahi:         ${AVAHI_USER}
 831     Group for Avahi:        ${AVAHI_GROUP}
 832     Enable chroot():        ${enable_chroot}
 833 "
 834
 835 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 836
 837 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 838     BUILD_DAEMON=yes
 839 fi
 840
 841 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 842
 843 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 844     BUILD_PYTHON=yes
 845 fi
 846
 847 BUILD_CLIENT="no   (You need avahi-daemon and dbus!)"
 848
 849 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 850     BUILD_CLIENT=yes
 851 fi
 852
 853 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 854    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 855 fi
 856 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 857    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 858 fi
 859
 860
 861 echo "\
 862     Building libavahi-core              yes
 863     Building avahi-daemon:              ${BUILD_DAEMON}
 864     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 865     Building libavahi-client:           ${BUILD_CLIENT}
 866     Building avahi-utils:               ${BUILD_CLIENT}
 867     Building avahi-python:              ${BUILD_PYTHON}
 868     Building libavahi-glib:             ${HAVE_GLIB}
 869     Building avahi-discover-standalone: ${HAVE_GTK}
 870     Building libavahi-qt3:              ${HAVE_QT3}
 871     Building libavahi-qt4:              ${HAVE_QT4}
 872     Building avahi-sharp:               ${HAVE_MONO}
 873     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 874     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 875     Building tests:                     ${ENABLE_TESTS}
 876 "