git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.23],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [8:0:5])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [5:5:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:4:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_GOBJECT_VERSION_INFO, [0:1:0])
  36 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:2:0])
  37 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:2:0])
  38 AC_SUBST(LIBAVAHI_UI_VERSION_INFO, [1:0:1])
  39
  40 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  41 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  42 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  43 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 # Checks for programs.
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AC_GNU_SOURCE
  54 AC_PROG_CPP
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_GCC_TRADITIONAL
  59
  60 AM_PROG_CC_C_O
  61
  62 # -fstack-protector
  63 AC_ARG_ENABLE([stack-protector],
  64     [AS_HELP_STRING([--disable-stack-protector],
  65         [Disable GCC's/libc's stack-smashing protection])],
  66     [case "${enableval}" in
  67          yes) enable_ssp=yes ;;
  68           no) enable_ssp=no ;;
  69            *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;
  70      esac],
  71     [enable_ssp=yes])
  72
  73 if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then
  74     AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])
  75     enable_ssp=no
  76 fi
  77
  78 if test x"$enable_ssp" = x"yes"; then
  79     # Check for broken ssp in libc: http://www.avahi.org/ticket/105
  80     # libc's brokenness will get in the way regardless of whether -lssp is
  81     # provided, but provide it anyway (otherwise non-libc ssp would wrongly
  82     # break here)
  83
  84     # Get -lssp if it exists
  85     GCC_STACK_PROTECT_LIB
  86
  87     AC_MSG_CHECKING([whether stack-smashing protection is available])
  88     ssp_old_cflags="$CFLAGS"
  89     ssp_old_ldflags="$LDFLAGS"
  90     CFLAGS="$CFLAGS -Werror -fstack-protector-all -fPIC"
  91     LDFLAGS="$LDFLAGS -Wl,-z,defs"
  92     cat confdefs.h > conftest.c
  93     cat >>conftest.c <<_ACEOF
  94 void test_broken_ssp(c)
  95     const char *c;
  96 {
  97     char arr[[123]], *p; /* beware of possible double-braces if copying this */
  98     for (p = arr; *c; ++p) {
  99         *p = *c;
 100         ++c;
 101     }
 102 }
 103 _ACEOF
 104     rm -f conftest.o
 105
 106     if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then
 107         AC_MSG_RESULT([yes])
 108         AC_MSG_CHECKING([whether stack-smashing protection is buggy])
 109         if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then
 110             AC_MSG_RESULT([no])
 111         else
 112             AC_MSG_RESULT([yes])
 113             enable_ssp=no
 114         fi
 115     else
 116         AC_MSG_RESULT([no])
 117     fi
 118
 119     rm -f conftest.c conftest.o conftest.so
 120
 121     CFLAGS="$ssp_old_cflags"
 122     LDFLAGS="$ssp_old_ldflags"
 123 fi
 124
 125 if test x"$enable_ssp" = x"yes"; then
 126     # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice
 127     GCC_STACK_PROTECT_CC
 128
 129     AC_LANG_PUSH([C++])
 130     GCC_STACK_PROTECT_CXX
 131     AC_LANG_POP([C++])
 132     # XXX: Update the enable_ssp value now for output later?
 133 fi
 134
 135 # libtool stuff
 136 AC_PROG_LIBTOOL
 137
 138 AC_CACHE_CHECK([whether the C++ compiler works], [avahi_cv_sys_cxx_works], [
 139     AC_LANG_PUSH([C++])
 140     AC_COMPILE_IFELSE([int main() { return 0; }], [avahi_cv_sys_cxx_works=yes],
 141         [avahi_cv_sys_cxx_works=no])
 142     AC_LANG_POP([C++])
 143     ])
 144 [ if [ "x$avahi_cv_sys_cxx_works" = "xno" ]; then ]
 145     AC_MSG_FAILURE([The C++ compiler does not work])
 146 [ fi ]
 147
 148 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
 149
 150 #
 151 # Check for netlink.h
 152 #
 153 AC_CHECK_HEADER(linux/netlink.h,
 154 HAVE_NETLINK=yes
 155 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
 156 , [], [
 157 #include <sys/socket.h>
 158 #include <asm/types.h>
 159 ])
 160
 161 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
 162
 163 #
 164 # Check for net/route.h
 165 #
 166 AC_CHECK_HEADER(net/route.h,
 167 HAVE_PF_ROUTE=yes
 168 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
 169 , [], [
 170 #include <sys/types.h>
 171 #include <sys/socket.h>
 172 ])
 173
 174 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
 175
 176 #
 177 # Check for sys/filio.h; needed for FIONREAD on Solaris
 178 #
 179 AC_CHECK_HEADER(sys/filio.h,
 180 HAVE_SYS_FILIO_H=yes
 181 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 182 , [], [
 183 ])
 184
 185 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 186
 187 #
 188 # Check for sys/sysctl.h; not present on Solaris
 189 #
 190 AC_CHECK_HEADER(sys/sysctl.h,
 191 HAVE_SYS_SYSCTL=yes
 192 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 193 , [], [
 194 #include <sys/types.h>
 195 #include <sys/socket.h>
 196 #include <sys/param.h>
 197 ])
 198
 199 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 200
 201 #
 202 # Check for lifconf struct; only present on Solaris
 203 #
 204 AC_MSG_CHECKING(for struct lifconf)
 205 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 206 [AC_TRY_COMPILE(
 207 [#include <sys/socket.h>
 208 #include <net/if.h>
 209 ],[sizeof (struct lifconf);],
 210 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 211 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 212 if test $avahi_cv_has_struct_lifconf = yes; then
 213     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 214 fi
 215
 216 #
 217 # Check for struct ip_mreqn
 218 #
 219 AC_MSG_CHECKING(for struct ip_mreqn)
 220 AC_TRY_COMPILE([#include <netinet/in.h>], [
 221         struct ip_mreqn mreq;
 222         mreq.imr_address.s_addr = 0;
 223 ], [
 224         # Yes, we have it...
 225         AC_MSG_RESULT(yes)
 226         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 227 ], [
 228         # We'll just have to try and use struct ip_mreq
 229         AC_MSG_RESULT(no)
 230         AC_MSG_CHECKING(for struct ip_mreq)
 231         AC_TRY_COMPILE([#include <netinet/in.h>], [
 232                 struct ip_mreq mreq;
 233                 mreq.imr_interface.s_addr = 0;
 234         ], [
 235                 # Yes, we have it...
 236                 AC_MSG_RESULT(yes)
 237                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 238         ], [
 239                 # No multicast support
 240                         AC_MSG_RESULT(no)
 241         ])
 242 ])
 243
 244 #
 245 # Detecting the linux distribution for specific things like init scripts.
 246 #
 247 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 248 if test "z$with_distro" = "z"; then
 249     if test "$cross_compiling" = yes; then
 250         AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 251     else
 252         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 253         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 254         AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 255         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 256         AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 257         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 258         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 259     fi
 260     if test "z$with_distro" = "z"; then
 261         with_distro=`uname -s`
 262     fi
 263 fi
 264 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 265
 266 case $with_distro in
 267     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 268      ;;
 269     netbsd)
 270      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 271      ;;
 272     linux)
 273      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 274      ;;
 275     *)
 276      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 277      ;;
 278 esac
 279
 280 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 281 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 282 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 283 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 284 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 285 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 286 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 287 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 288 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 289 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 290
 291 test_gcc_flag() {
 292     AC_LANG_CONFTEST([int main() {}])
 293     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 294     ret=$?
 295     rm -f conftest.o
 296     return $ret
 297 }
 298
 299 # If using GCC specify some additional parameters
 300 if test "x$GCC" = "xyes" ; then
 301
 302     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 303
 304     if test "x$HAVE_NETLINK" = "xyes" ; then
 305         # Test whether rtnetlink.h can be included when compiled with -std=c99
 306         # some distributions (e.g. archlinux) have broken headers that dont
 307         # define __u64 with -std=c99
 308         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 309         OLDCFLAGS="$CFLAGS"
 310         CFLAGS="-std=c99"
 311         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 312             use_stdc99=yes, use_stdc99=no)
 313
 314         if test x"$use_stdc99" = xyes; then
 315             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 316             AC_MSG_RESULT([yes])
 317         else
 318             AC_MSG_RESULT([no])
 319         fi
 320
 321         CFLAGS="$OLDCFLAGS"
 322     else
 323         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 324     fi
 325
 326     for flag in $DESIRED_FLAGS ; do
 327         AC_MSG_CHECKING([whether $CC accepts $flag])
 328         if test_gcc_flag $flag ; then
 329            CFLAGS="$CFLAGS $flag"
 330            AC_MSG_RESULT([yes])
 331         else
 332            AC_MSG_RESULT([no])
 333         fi
 334     done
 335 fi
 336
 337 # Checks for header files.
 338 AC_HEADER_STDC
 339 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 340 AC_HEADER_STDBOOL
 341
 342 # Checks for typedefs, structures, and compiler characteristics.
 343 AC_C_CONST
 344 AC_TYPE_SIZE_T
 345 AC_HEADER_TIME
 346 AC_HEADER_SYS_WAIT
 347
 348  # Solaris stuff
 349  AC_SEARCH_LIBS([inet_ntop],[nsl])
 350  AC_SEARCH_LIBS([recv],[socket])
 351  AC_CHECK_DECL([CMSG_SPACE],,CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500 -D__EXTENSIONS__")
 352
 353 # Checks for library functions.
 354 AC_FUNC_MEMCMP
 355 AC_FUNC_SELECT_ARGTYPES
 356 # avahi_malloc actually returns NULL for avahi_malloc(0), so it does not matter
 357 # whether libc's malloc does too. (Same for realloc.)
 358 #AC_FUNC_MALLOC
 359 #AC_FUNC_REALLOC
 360 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 361
 362 AC_FUNC_CHOWN
 363 AC_FUNC_STAT
 364 AC_TYPE_MODE_T
 365 AC_TYPE_PID_T
 366
 367 AC_CHECK_DECLS(environ)
 368
 369 # check if gcc's -fvisibility is supported
 370 CHECK_VISIBILITY_HIDDEN
 371
 372 enable_chroot=yes
 373 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 374 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 375 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 376
 377 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 378
 379 if test "x$enable_chroot" = "xyes" ; then
 380    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 381 fi
 382
 383 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 384 if test "x$HAVE_DLOPEN" = "xyes" ; then
 385     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 386 fi
 387 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 388
 389 have_inotify=no
 390 AC_CHECK_HEADERS([linux/inotify.h], [have_inotify=yes])
 391 AC_CHECK_HEADERS([sys/inotify.h], [have_inotify=yes])
 392
 393 AM_CONDITIONAL(HAVE_INOTIFY, test "x$have_inotify" = "xyes")
 394
 395 if test "x$have_inotify" = "xyes" ; then
 396    AC_DEFINE([HAVE_INOTIFY], 1, [Enable Linux inotify() usage])
 397 fi
 398
 399 have_kqueue=yes
 400 AC_CHECK_FUNCS([kqueue],,have_kqueue=no)
 401
 402 AM_CONDITIONAL(HAVE_KQUEUE, test "x$have_kqueue" = "xyes")
 403
 404 if test "x$have_kqueue" = "xyes" ; then
 405     AC_DEFINE([HAVE_KQUEUE], 1, [Enable BSD kqueue() usage])
 406 fi
 407
 408 IT_PROG_INTLTOOL([0.35.0])
 409 GETTEXT_PACKAGE=avahi
 410 AC_SUBST([GETTEXT_PACKAGE])
 411 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 412 AM_GLIB_GNU_GETTEXT
 413
 414 avahilocaledir='${prefix}/${DATADIRNAME}/locale'
 415 AC_SUBST(avahilocaledir)
 416
 417
 418 # Check for pkg-config manually first, as if its not installed the
 419 # PKG_PROG_PKG_CONFIG macro won't be defined.
 420 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 421
 422 if test x"$have_pkg_config" = "xno"; then
 423     AC_MSG_ERROR(pkg-config is required to install this program)
 424 fi
 425
 426 PKG_PROG_PKG_CONFIG
 427
 428 #
 429 # Check for GLIB 2.0
 430 #
 431 AC_ARG_ENABLE(glib,
 432         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 433         [case "${enableval}" in
 434                 yes) HAVE_GLIB=yes ;;
 435                 no)  HAVE_GLIB=no ;;
 436                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 437         esac],
 438         [HAVE_GLIB=yes])
 439
 440 if test "x$HAVE_GLIB" = "xyes" ; then
 441         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 442         AC_SUBST(GLIB20_CFLAGS)
 443         AC_SUBST(GLIB20_LIBS)
 444 fi
 445 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 446
 447 #
 448 # Check for GLIB's gobject 2.0
 449 #
 450 AC_ARG_ENABLE(gobject,
 451         AS_HELP_STRING([--disable-gobject],[Disable use of GLib GObject]),
 452         [case "${enableval}" in
 453                 yes) HAVE_GOBJECT=yes ;;
 454                 no)  HAVE_GOBJECT=no ;;
 455                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gobject) ;;
 456         esac],
 457         [HAVE_GOBJECT=yes])
 458
 459 if test "x$HAVE_GOBJECT" = "xyes" ; then
 460         PKG_CHECK_MODULES(GOBJECT, [ glib-2.0 >= 2.4.0 gobject-2.0 ])
 461         AC_SUBST(GOBJECT_CFLAGS)
 462         AC_SUBST(GOBJECT_LIBS)
 463 fi
 464 AM_CONDITIONAL(HAVE_GOBJECT, test "x$HAVE_GOBJECT" = "xyes")
 465
 466 #
 467 # Check for Qt 3
 468 #
 469 AC_ARG_ENABLE(qt3,
 470         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 471         [case "${enableval}" in
 472                 yes) HAVE_QT3=yes ;;
 473                 no)  HAVE_QT3=no ;;
 474                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 475         esac],
 476         [HAVE_QT3=yes])
 477
 478 if test "x$HAVE_QT3" = "xyes" ; then
 479         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 480         AC_SUBST(QT3_CFLAGS)
 481         AC_SUBST(QT3_LIBS)
 482             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 483         AC_PATH_PROGS(MOC_QT3, [moc-qt3 moc], no, [$QT3_PREFIX])
 484         if test "$MOC_QT3" = no; then
 485             AC_MSG_ERROR([Could not find QT3 moc])
 486         fi
 487         AC_SUBST(MOC_QT3)
 488 fi
 489 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 490
 491 #
 492 # Check for Qt 4
 493 #
 494 AC_ARG_ENABLE(qt4,
 495         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 496         [case "${enableval}" in
 497                 yes) HAVE_QT4=yes ;;
 498                 no)  HAVE_QT4=no ;;
 499                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 500         esac],
 501         [HAVE_QT4=yes])
 502
 503 if test "x$HAVE_QT4" = "xyes" ; then
 504         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 505         AC_SUBST(QT4_CFLAGS)
 506         AC_SUBST(QT4_LIBS)
 507             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 508         AC_PATH_PROGS(MOC_QT4, [moc-qt4 moc], no, [$QT4_PREFIX])
 509         if test "$MOC_QT4" = no; then
 510             AC_MSG_ERROR([Could not find QT4 moc])
 511         fi
 512         AC_SUBST(MOC_QT4)
 513 fi
 514 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 515
 516 #
 517 # Check for GTK+
 518 #
 519 AC_ARG_ENABLE(gtk,
 520         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 521         [case "${enableval}" in
 522                 yes) HAVE_GTK=yes ;;
 523                 no)  HAVE_GTK=no ;;
 524                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 525         esac],
 526         [HAVE_GTK=yes])
 527
 528 if test "x$HAVE_GTK" = "xyes" ; then
 529         # Check for GTK 2.0
 530         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 531         AC_SUBST(GTK20_CFLAGS)
 532         AC_SUBST(GTK20_LIBS)
 533
 534         # Check for GLADE 2.0
 535         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 536         AC_SUBST(GLADE20_CFLAGS)
 537         AC_SUBST(GLADE20_LIBS)
 538 fi
 539 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 540
 541 #
 542 # D-Bus
 543 #
 544 AC_ARG_ENABLE(dbus,
 545         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 546         [case "${enableval}" in
 547                 yes) HAVE_DBUS=yes ;;
 548                 no)  HAVE_DBUS=no ;;
 549                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 550         esac],
 551         [HAVE_DBUS=yes])
 552
 553 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 554 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 555
 556 DBUS_VERSION="Disabled"
 557 DBUS_SYS_DIR="Disabled"
 558 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 559 if test "x$HAVE_DBUS" = "xyes" ; then
 560     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 561
 562     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 563
 564     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 565     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 566     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 567     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 568     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 569         DBUS_VERSION_MAJOR="0"
 570     fi
 571     if test "z$DBUS_VERSION_MINOR" = "z"; then
 572         DBUS_VERSION_MINOR="0"
 573     fi
 574     if test "z$DBUS_VERSION_MICRO" = "z"; then
 575         DBUS_VERSION_MICRO="0"
 576     fi
 577
 578     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 579         echo "Error: Couldn't determine the version of your D-Bus package."
 580         echo "  This is probably an error in this script, please report it"
 581         echo "  along with the following information:"
 582         echo "      Base D-Buss version ='$DBUS_VERSION'"
 583         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 584         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 585         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 586         exit 1
 587     else
 588         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 589         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 590         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 591         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 592     fi
 593
 594     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 595     AC_SUBST(DBUS_CFLAGS)
 596     AC_SUBST(DBUS_LIBS)
 597
 598     if ! test -z "$with_dbus_sys" ; then
 599         DBUS_SYS_DIR="$with_dbus_sys"
 600     else
 601         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 602     fi
 603     AC_SUBST(DBUS_SYS_DIR)
 604
 605     if ! test -z "$with_dbus_system_address" ; then
 606         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 607     else
 608         # This is ugly, but D-Bus doesn't export this address for us
 609         # so we have to guess, pretty much all setups i've seen have
 610         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 611         # /var/run upstream so we will try guess first then default
 612         # to /var/run/dbus.
 613
 614         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 615         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 616         for sock in $TRY_SOCKETS; do
 617             if test -S $sock; then
 618                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 619             fi
 620         done
 621     fi
 622     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 623
 624     SAVED_LIBS="$LIBS"
 625     LIBS="$LIBS $DBUS_LIBS"
 626     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 627     LIBS="$SAVED_LIBS"
 628 fi
 629 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 630
 631 #
 632 # Expat
 633 #
 634 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[expat/bsdxml/none]],[XML library to use]))
 635 use_expat=false
 636 use_bsdxml=false
 637
 638 # See what we have
 639 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 640 AC_CHECK_LIB(bsdxml, XML_ParserCreate, [ AC_CHECK_HEADERS(bsdxml.h, have_bsdxml=true, have_bsdxml=false) ], have_bsdxml=false)
 641
 642 if test "x$with_xml" = "xnone"; then
 643         :
 644 elif test "x$with_xml" = "xexpat"; then
 645         use_expat=true
 646         if ! $have_expat ; then
 647                 AC_MSG_ERROR([*** libexpat requested, but not found ***])
 648         fi
 649 elif test "x$with_xml" = "xbsdxml"; then
 650         use_bsdxml=true
 651         if ! $have_bsdxml ; then
 652                 AC_MSG_ERROR([*** libbsdxml requested, but not found ***])
 653         fi
 654 elif test "x$with_xml" != "x"; then
 655         AC_MSG_ERROR([*** unknown with-xml option ***])
 656 else
 657         if $have_expat ; then
 658                 use_expat=true
 659         elif $have_bsdxml ; then
 660                 use_bsdxml=true
 661         else
 662                 AC_MSG_ERROR([*** neither libexpat not libbsdxml could be found ***])
 663         fi
 664 fi
 665
 666 if $use_expat; then
 667         with_xml=expat
 668         XML_CFLAGS=-DUSE_EXPAT_H
 669         XML_LIBS=-lexpat
 670 fi
 671 if $use_bsdxml; then
 672         with_xml=bsdxml
 673         XML_CFLAGS=-DUSE_BSDXML_H
 674         XML_LIBS=-lbsdxml
 675 fi
 676 AC_SUBST(XML_LIBS)
 677 AC_SUBST(XML_CFLAGS)
 678
 679 if $use_expat || $use_bsdxml; then
 680         HAVE_XML=yes
 681 fi
 682
 683 AM_CONDITIONAL(HAVE_XML, test "x$HAVE_XML" = "xyes")
 684
 685 #
 686 # GDBM
 687 #
 688 #
 689 # Check for dbm
 690 #
 691 AC_ARG_ENABLE(dbm,
 692         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 693         [case "${enableval}" in
 694                 yes) HAVE_DBM=yes ;;
 695                 no)  HAVE_DBM=no ;;
 696                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 697         esac],
 698         [HAVE_DBM=no])
 699
 700 AC_ARG_ENABLE(gdbm,
 701         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 702         [case "${enableval}" in
 703                 yes) HAVE_GDBM=yes ;;
 704                 no)  HAVE_GDBM=no ;;
 705                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 706         esac],
 707         [HAVE_GDBM=yes])
 708
 709 if test "x$HAVE_GDBM" = "xyes" ; then
 710     if test "x$HAVE_DBM" = "xyes" ; then
 711         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 712     fi
 713     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 714
 715     if ! $have_gdbm ; then
 716         AC_MSG_ERROR([*** libgdbm not found ***])
 717     fi
 718     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 719 else
 720     if test "x$HAVE_DBM" = "xyes" ; then
 721         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 722
 723         if ! $have_dbm ; then
 724             AC_MSG_ERROR([*** dbm not found ***])
 725         fi
 726         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 727     fi
 728 fi
 729 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 730 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 731
 732 #
 733 # libdaemon
 734 #
 735 AC_ARG_ENABLE(libdaemon,
 736         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 737         [case "${enableval}" in
 738                 yes) HAVE_LIBDAEMON=yes ;;
 739                 no)  HAVE_LIBDAEMON=no ;;
 740                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 741         esac],
 742         [HAVE_LIBDAEMON=yes])
 743
 744 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 745     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.11 ])
 746     AC_SUBST(LIBDAEMON_CFLAGS)
 747     AC_SUBST(LIBDAEMON_LIBS)
 748 fi
 749 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 750
 751 #
 752 # Python stuff
 753 #
 754 AC_ARG_ENABLE(python,
 755     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 756     [case "${enableval}" in
 757           yes) HAVE_PYTHON=yes ;;
 758           no)  HAVE_PYTHON=no ;;
 759           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 760     esac],[HAVE_PYTHON=yes])
 761
 762 HAVE_PYTHON_DBUS=no
 763 HAVE_PYGTK=no
 764
 765 if test "x$HAVE_PYTHON" = "xyes" ; then
 766     AM_PATH_PYTHON([2.4])
 767
 768     AC_ARG_ENABLE(pygtk,
 769         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 770         [case "${enableval}" in
 771                 yes) HAVE_PYGTK=yes ;;
 772                 no)  HAVE_PYGTK=no ;;
 773                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 774         esac],
 775         [HAVE_PYGTK=yes])
 776
 777     if test "x$HAVE_PYGTK" = "xyes" ; then
 778         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 779     fi
 780
 781
 782     if test "x$HAVE_DBUS" = "xyes" ; then
 783         AC_ARG_ENABLE(python-dbus,
 784             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 785             [case "${enableval}" in
 786                    yes) HAVE_PYTHON_DBUS=yes ;;
 787                    no)  HAVE_PYTHON_DBUS=no ;;
 788                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 789             esac],
 790             [HAVE_PYTHON_DBUS=yes])
 791
 792         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 793             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 794         fi
 795
 796         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 797         if test "x$HAVE_GDBM" = "xyes"; then
 798             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 799         fi
 800         if test "x$HAVE_DBM" = "xyes"; then
 801             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 802         fi
 803     fi
 804 fi
 805 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 806 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 807 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 808
 809 #
 810 # Check for mono stuff
 811 #
 812 HAVE_MONO=no
 813 if test "x$HAVE_DBUS" = "xyes" ; then
 814     AC_ARG_ENABLE(mono,
 815             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 816             [case "${enableval}" in
 817                     yes) HAVE_MONO=yes ;;
 818                     no)  HAVE_MONO=no ;;
 819                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 820             esac],
 821             [HAVE_MONO=yes])
 822
 823     if test "x$HAVE_MONO" = "xyes" ; then
 824         AC_PATH_PROG(MCS, mcs)
 825         if test "x$MCS" = "x" ; then
 826             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 827         fi
 828
 829         AC_PATH_PROG(GACUTIL, gacutil)
 830         if test "x$GACUTIL" = "x" ; then
 831             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 832         fi
 833
 834         AC_SUBST(MCS)
 835         AC_SUBST(GACUTIL)
 836     fi
 837 fi
 838 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 839
 840 #
 841 # Check for monodoc stuff
 842 #
 843 HAVE_MONODOC=no
 844 AC_ARG_ENABLE(monodoc,
 845         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 846         [case "${enableval}" in
 847                 yes) HAVE_MONODOC=yes ;;
 848                 no)  HAVE_MONODOC=no ;;
 849                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 850         esac],
 851         [HAVE_MONODOC=yes])
 852
 853 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 854         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 855         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 856
 857         AC_PATH_PROG(MONODOCER, monodocer)
 858         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 859
 860         AC_SUBST(MONODOC_DIR)
 861         AC_SUBST(MONODOCER)
 862         AC_SUBST(MDASSEMBLER)
 863 fi
 864 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 865
 866 #
 867 # Build autoipd?
 868 #
 869 AC_ARG_ENABLE(autoipd,
 870         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 871         [case "${enableval}" in
 872                 yes) ENABLE_AUTOIPD=yes ;;
 873                 no)  ENABLE_AUTOIPD=no ;;
 874                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 875         esac],
 876         [ENABLE_AUTOIPD=yes])
 877
 878 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 879
 880 #
 881 # Defining users and groups
 882 #
 883 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 884 if test -z "$with_avahi_user" ; then
 885     AVAHI_USER=avahi
 886 else
 887     AVAHI_USER=$with_avahi_user
 888 fi
 889 AC_SUBST(AVAHI_USER)
 890 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 891
 892 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 893 if test -z "$with_avahi_group" ; then
 894     AVAHI_GROUP=avahi
 895 else
 896     AVAHI_GROUP=$with_avahi_group
 897 fi
 898 AC_SUBST(AVAHI_GROUP)
 899 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 900
 901 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 902 if test -z "$with_avahi_priv_access_group" ; then
 903     AVAHI_PRIV_ACCESS_GROUP=netdev
 904 else
 905     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 906 fi
 907 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 908 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 909
 910 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autoipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 911 if test -z "$with_autoipd_user" ; then
 912     AVAHI_AUTOIPD_USER=avahi-autoipd
 913 else
 914     AVAHI_AUTOIPD_USER=$with_autoipd_user
 915 fi
 916 AC_SUBST(AVAHI_AUTOIPD_USER)
 917 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 918
 919 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 920 if test -z "$with_autoipd_group" ; then
 921     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 922 else
 923     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 924 fi
 925 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 926 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 927
 928 #
 929 # Avahi runtime dir
 930 #
 931 avahi_runtime_dir="${localstatedir}/run"
 932 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 933 AC_SUBST(avahi_runtime_dir)
 934 AC_SUBST(avahi_socket)
 935
 936 #
 937 # Avahi interfaces dir
 938 #
 939 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 940         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 941         AC_SUBST(interfacesdir)
 942 fi
 943
 944 #
 945 # Doxygen
 946 #
 947 DX_HTML_FEATURE(ON)
 948 DX_CHM_FEATURE(OFF)
 949 DX_CHI_FEATURE(OFF)
 950 DX_MAN_FEATURE(OFF)
 951 DX_RTF_FEATURE(OFF)
 952 DX_XML_FEATURE(ON)
 953 DX_PDF_FEATURE(OFF)
 954 DX_PS_FEATURE(OFF)
 955 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 956
 957 AC_ARG_ENABLE(core-docs,
 958         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 959 [case "${enableval}" in
 960   yes) ENABLE_CORE_DOCS=yes ;;
 961   no)  ENABLE_CORE_DOCS=no ;;
 962   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 963 esac],[ENABLE_CORE_DOCS=no])
 964
 965 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 966
 967 #
 968 # Build and Install man pages
 969 #
 970 AC_ARG_ENABLE(manpages,
 971         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 972 [case "${enableval}" in
 973   yes) manpages=yes ;;
 974   no)  manpages=no ;;
 975   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 976 esac],[manpages=yes])
 977
 978 if test x$manpages = xyes ; then
 979     #
 980     # XMLTOMAN manpage generation
 981     #
 982     AC_ARG_ENABLE(xmltoman,
 983     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 984     [case "${enableval}" in
 985       yes) xmltoman=yes ;;
 986       no)  xmltoman=no ;;
 987       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 988     esac],[xmltoman=yes])
 989
 990     if test x$xmltoman = xyes ; then
 991         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 992     fi
 993
 994     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 995         if ! test -e man/avahi-daemon.8 ; then
 996             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 997             exit 1
 998         fi
 999         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
1000         xmltoman=no
1001     fi
1002 fi
1003 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
1004 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1005
1006 #
1007 # Conditionally compile test and example programs
1008 #
1009 AC_ARG_ENABLE(tests,
1010         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
1011         [case "${enableval}" in
1012                 yes) ENABLE_TESTS=yes ;;
1013                 no)  ENABLE_TESTS=no ;;
1014                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
1015         esac],
1016         [ENABLE_TESTS=no])
1017
1018 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
1019
1020 #
1021 # Optionally enable libdns_sd compatibility support
1022 #
1023 AC_ARG_ENABLE(compat-libdns_sd,
1024         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
1025         [case "${enableval}" in
1026                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
1027                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
1028                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
1029         esac],
1030         [ENABLE_COMPAT_LIBDNS_SD=no])
1031
1032 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
1033
1034 #
1035 # Optionally enable HOWL compatibility support
1036 #
1037 AC_ARG_ENABLE(compat-howl,
1038         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
1039         [case "${enableval}" in
1040                 yes) ENABLE_COMPAT_HOWL=yes ;;
1041                 no)  ENABLE_COMPAT_HOWL=no ;;
1042                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
1043         esac],
1044         [ENABLE_COMPAT_HOWL=no])
1045
1046 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
1047
1048
1049 # ==========================================================================
1050 AC_CONFIG_FILES([
1051 Makefile
1052 avahi-common/Makefile
1053 avahi-core/Makefile
1054 avahi-glib/Makefile
1055 avahi-gobject/Makefile
1056 avahi-qt/Makefile
1057 avahi-daemon/Makefile
1058 avahi-daemon/avahi-dbus.conf
1059 avahi-discover-standalone/Makefile
1060 avahi-client/Makefile
1061 initscript/Makefile
1062 initscript/debian/Makefile
1063 initscript/gentoo/Makefile
1064 initscript/archlinux/Makefile
1065 initscript/suse/Makefile
1066 initscript/fedora/Makefile
1067 initscript/mandriva/Makefile
1068 initscript/darwin/Makefile
1069 initscript/freebsd/Makefile
1070 initscript/slackware/Makefile
1071 avahi-dnsconfd/Makefile
1072 avahi-utils/Makefile
1073 avahi-python/Makefile
1074 avahi-python/avahi/Makefile
1075 avahi-python/avahi-discover/Makefile
1076 examples/Makefile
1077 common/Makefile
1078 man/Makefile
1079 tests/Makefile
1080 service-type-database/Makefile
1081 avahi-sharp/Makefile
1082 avahi-ui-sharp/Makefile
1083 avahi-compat-libdns_sd/Makefile
1084 avahi-compat-howl/Makefile
1085 avahi-compat-howl/samples/Makefile
1086 avahi-autoipd/Makefile
1087 avahi-ui/Makefile
1088 po/Makefile.in
1089 ])
1090 AC_OUTPUT
1091
1092 # ==========================================================================
1093 echo "
1094  ---{ $PACKAGE_NAME $VERSION }---
1095
1096     prefix:                                    ${prefix}
1097     sysconfdir:                                ${sysconfdir}
1098     localstatedir:                             ${localstatedir}
1099     avahi socket:                              ${avahi_socket}
1100     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
1101     dbus-1 version:                            ${DBUS_VERSION}
1102     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1103     C Compiler:                                ${CC}
1104     CFLAGS:                                    ${CFLAGS}
1105     Enable GLIB:                               ${HAVE_GLIB}
1106     Enable GLIB GObject:                       ${HAVE_GOBJECT}
1107     Enable GTK:                                ${HAVE_GTK}
1108     Enable D-Bus:                              ${HAVE_DBUS}
1109     With XML:                                  ${with_xml}
1110     Enable GDBM:                               ${HAVE_GDBM}
1111     Enable DBM:                                ${HAVE_DBM}
1112     Enable libdaemon:                          ${HAVE_LIBDAEMON}
1113     Enable Python:                             ${HAVE_PYTHON}
1114     Enable pygtk:                              ${HAVE_PYGTK}
1115     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
1116     Enable QT3:                                ${HAVE_QT3}
1117     Enable QT4:                                ${HAVE_QT4}
1118     Enable Mono:                               ${HAVE_MONO}
1119     Enable Monodoc:                            ${HAVE_MONODOC}
1120     Distribution/OS:                           ${with_distro}
1121     User for avahi-daemon:                     ${AVAHI_USER}
1122     Group for avahi-daemon:                    ${AVAHI_GROUP}
1123     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
1124     User for avahi-autoipd:                    ${AVAHI_AUTOIPD_USER}
1125     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
1126     Enable chroot():                           ${enable_chroot}
1127     Enable Linux inotify:                      ${have_inotify}
1128     Enable stack-smashing protection:          ${enable_ssp}
1129 "
1130
1131 BUILD_DAEMON="no   (You need libdaemon and expat/bsdxml!)"
1132
1133 if test "x$HAVE_XML" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
1134     BUILD_DAEMON=yes
1135 fi
1136
1137 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
1138
1139 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
1140     BUILD_PYTHON=yes
1141 fi
1142
1143 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
1144
1145 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
1146     BUILD_CLIENT=yes
1147 fi
1148
1149 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1150    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
1151 fi
1152 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1153    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
1154 fi
1155 if test "x$ENABLE_AUTOIPD" = "xyes" -a "x$HAVE_LIBDAEMON" != "xyes" ; then
1156    ENABLE_AUTOIPD="no   (You need libdaemon!)"
1157 fi
1158
1159 BUILD_UI="no"
1160 if test "x$HAVE_GTK" = "xyes" -a "x$BUILD_CLIENT" = "xyes" ; then
1161    BUILD_UI="yes"
1162 fi
1163
1164 BUILD_GOBJECT="no"
1165 if test "x$BUILD_CLIENT" = "xyes" -a "x$HAVE_GOBJECT" = "xyes" ; then
1166    BUILD_GOBJECT="yes"
1167 fi
1168
1169 echo "\
1170     Building libavahi-core              yes
1171     Building avahi-daemon:              ${BUILD_DAEMON}
1172     Building avahi-dnsconfd:            ${BUILD_DAEMON}
1173     Building libavahi-client:           ${BUILD_CLIENT}
1174     Building avahi-utils:               ${BUILD_CLIENT}
1175     Building avahi-python:              ${BUILD_PYTHON}
1176     Building libavahi-glib:             ${HAVE_GLIB}
1177     Building libavahi-gobject:          ${BUILD_GOBJECT}
1178     Building avahi-discover-standalone: ${HAVE_GTK}
1179     Building libavahi-qt3:              ${HAVE_QT3}
1180     Building libavahi-qt4:              ${HAVE_QT4}
1181     Building avahi-sharp:               ${HAVE_MONO}
1182     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
1183     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
1184     Building tests:                     ${ENABLE_TESTS}
1185     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
1186     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
1187     Building libavahi-ui:               ${BUILD_UI}
1188 "