git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of catta.
   5 #
   6 # catta is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU Lesser General Public License as
   8 # published by the Free Software Foundation; either version 2 of the
   9 # License, or (at your option) any later version.
  10 #
  11 # catta is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  13 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  14 # License for more details.
  15 #
  16 # You should have received a copy of the GNU Lesser General Public
  17 # License along with catta; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  19 # USA.
  20
  21 AC_PREREQ(2.63)
  22 AC_INIT([catta],[0.1],[])
  23 AC_CONFIG_SRCDIR([src/server.c])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects])
  27
  28 AC_SUBST(PACKAGE_URL, [http://github.com/everbase/catta/])
  29
  30 AC_SUBST(LIBCATTA_VERSION_INFO, [0:0:0])
  31
  32 AC_CANONICAL_HOST
  33
  34 AM_SILENT_RULES([yes])
  35
  36 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  37
  38 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  39         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  40         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  41 ])
  42
  43 # Checks for programs.
  44 AC_PROG_CC
  45 AC_PROG_CC_C99
  46 AM_PROG_CC_C_O
  47 AC_USE_SYSTEM_EXTENSIONS
  48 AC_PROG_MKDIR_P
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AC_PROG_GCC_TRADITIONAL
  53
  54 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  55     AC_MSG_ERROR([C99 support is required])
  56 fi
  57
  58 # Windows stuff
  59 AC_CHECK_DECL(_WIN32)
  60 AM_CONDITIONAL([WINDOWS], [ test "x$ac_cv_have_decl__WIN32" = "xyes" ])
  61
  62 # -fstack-protector
  63 AC_ARG_ENABLE([stack-protector],
  64     [AS_HELP_STRING([--disable-stack-protector],
  65         [Disable GCC's/libc's stack-smashing protection])],
  66     [case "${enableval}" in
  67          yes) enable_ssp=yes ;;
  68           no) enable_ssp=no ;;
  69            *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;
  70      esac],
  71     [enable_ssp=yes])
  72
  73 if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then
  74     AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])
  75     enable_ssp=no
  76 fi
  77
  78 if test x"$enable_ssp" = x"yes"; then
  79     # Check for broken ssp in libc: http://www.avahi.org/ticket/105
  80     # libc's brokenness will get in the way regardless of whether -lssp is
  81     # provided, but provide it anyway (otherwise non-libc ssp would wrongly
  82     # break here)
  83
  84     # Get -lssp if it exists
  85     GCC_STACK_PROTECT_LIB
  86
  87     AC_MSG_CHECKING([whether stack-smashing protection is available])
  88     ssp_old_cflags="$CFLAGS"
  89     ssp_old_ldflags="$LDFLAGS"
  90     CFLAGS="$CFLAGS -Werror -fstack-protector-all -fPIC"
  91     LDFLAGS="$LDFLAGS -Wl,-z,defs"
  92     cat confdefs.h > conftest.c
  93     cat >>conftest.c <<_ACEOF
  94 void test_broken_ssp(c)
  95     const char *c;
  96 {
  97     char arr[[123]], *p; /* beware of possible double-braces if copying this */
  98     for (p = arr; *c; ++p) {
  99         *p = *c;
 100         ++c;
 101     }
 102 }
 103 _ACEOF
 104     rm -f conftest.o
 105
 106     if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then
 107         AC_MSG_RESULT([yes])
 108         AC_MSG_CHECKING([whether stack-smashing protection is buggy])
 109         if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then
 110             AC_MSG_RESULT([no])
 111         else
 112             AC_MSG_RESULT([yes])
 113             enable_ssp=no
 114         fi
 115     else
 116         AC_MSG_RESULT([no])
 117     fi
 118
 119     rm -f conftest.c conftest.o conftest.so
 120
 121     CFLAGS="$ssp_old_cflags"
 122     LDFLAGS="$ssp_old_ldflags"
 123 fi
 124
 125 if test x"$enable_ssp" = x"yes"; then
 126     # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice
 127     GCC_STACK_PROTECT_CC
 128
 129     AC_LANG_PUSH([C++])
 130     GCC_STACK_PROTECT_CXX
 131     AC_LANG_POP([C++])
 132     # XXX: Update the enable_ssp value now for output later?
 133 fi
 134
 135 # libtool stuff
 136 AC_PROG_LIBTOOL
 137
 138 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
 139
 140 #
 141 # Check for netlink.h
 142 #
 143 AC_CHECK_HEADER(linux/netlink.h,
 144 HAVE_NETLINK=yes
 145 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
 146 , [], [
 147 #include <sys/socket.h>
 148 #include <asm/types.h>
 149 ])
 150
 151 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
 152
 153 if test "x$HAVE_NETLINK" = "xyes" ; then
 154     # Test whether rtnetlink.h can be included when compiled with -std=c99
 155     # some distributions (e.g. archlinux) have broken headers that dont
 156     # define __u64 with -std=c99
 157     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 158     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 159         [AC_MSG_RESULT([yes])], [AC_MSG_ERROR([no])])
 160 fi
 161
 162 #
 163 # Check for net/route.h
 164 #
 165 AC_CHECK_HEADER(net/route.h,
 166 HAVE_PF_ROUTE=yes
 167 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
 168 , [], [
 169 #include <sys/types.h>
 170 #include <sys/socket.h>
 171 #include <net/if_dl.h>
 172 ])
 173
 174 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
 175
 176 #
 177 # Check for sys/filio.h; needed for FIONREAD on Solaris
 178 #
 179 AC_CHECK_HEADER(sys/filio.h,
 180 HAVE_SYS_FILIO_H=yes
 181 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 182 , [], [
 183 ])
 184
 185 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 186
 187 #
 188 # Check for sys/sysctl.h; not present on Solaris
 189 #
 190 AC_CHECK_HEADER(sys/sysctl.h,
 191 HAVE_SYS_SYSCTL=yes
 192 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 193 , [], [
 194 #include <sys/types.h>
 195 #include <sys/socket.h>
 196 #include <sys/param.h>
 197 ])
 198
 199 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 200
 201 #
 202 # Check for lifconf struct; only present on Solaris
 203 #
 204 AC_MSG_CHECKING(for struct lifconf)
 205 AC_CACHE_VAL(catta_cv_has_struct_lifconf,
 206 [AC_TRY_COMPILE(
 207 [#include <sys/socket.h>
 208 #include <net/if.h>
 209 ],[sizeof (struct lifconf);],
 210 catta_cv_has_struct_lifconf=yes,catta_cv_has_struct_lifconf=no)])
 211 AC_MSG_RESULT($catta_cv_has_struct_lifconf)
 212 if test $catta_cv_has_struct_lifconf = yes; then
 213     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 214 fi
 215
 216 #
 217 # Check for struct ip_mreqn
 218 #
 219 AC_MSG_CHECKING(for struct ip_mreqn)
 220 AC_TRY_COMPILE([#include <netinet/in.h>], [
 221         struct ip_mreqn mreq;
 222         mreq.imr_address.s_addr = 0;
 223 ], [
 224         # Yes, we have it...
 225         AC_MSG_RESULT(yes)
 226         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 227 ], [
 228         # We'll just have to try and use struct ip_mreq
 229         AC_MSG_RESULT(no)
 230         AC_MSG_CHECKING(for struct ip_mreq)
 231         AC_TRY_COMPILE([#include <netinet/in.h>], [
 232                 struct ip_mreq mreq;
 233                 mreq.imr_interface.s_addr = 0;
 234         ], [
 235                 # Yes, we have it...
 236                 AC_MSG_RESULT(yes)
 237                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 238         ], [
 239                 # No multicast support
 240                         AC_MSG_RESULT(no)
 241         ])
 242 ])
 243
 244 test_gcc_flag() {
 245     AC_LANG_CONFTEST([AC_LANG_SOURCE([[int main() {}]])])
 246     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 247     ret=$?
 248     rm -f conftest.o
 249     return $ret
 250 }
 251
 252 # If using GCC specify some additional parameters
 253 if test "x$GCC" = "xyes" ; then
 254
 255     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -fdiagnostics-show-option -Wno-cast-qual -fno-strict-aliasing"
 256
 257     for flag in $DESIRED_FLAGS ; do
 258         AC_MSG_CHECKING([whether $CC accepts $flag])
 259         if test_gcc_flag $flag ; then
 260            CFLAGS="$CFLAGS $flag"
 261            AC_MSG_RESULT([yes])
 262         else
 263            AC_MSG_RESULT([no])
 264         fi
 265     done
 266 fi
 267
 268 # Checks for header files.
 269 AC_CHECK_HEADERS([arpa/inet.h fcntl.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 270
 271  # Solaris stuff
 272  AC_SEARCH_LIBS([inet_ntop],[nsl])
 273  AC_SEARCH_LIBS([recv],[socket])
 274  AC_CHECK_DECL([CMSG_SPACE],,CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500 -D__EXTENSIONS__", [[#include <sys/socket.h>]])
 275
 276 # Checks for library functions.
 277 AC_FUNC_SELECT_ARGTYPES
 278 AC_CHECK_FUNCS([gethostname select socket uname strcasecmp gettimeofday strncasecmp strlcpy])
 279
 280 AC_FUNC_CHOWN
 281 AC_FUNC_STAT
 282 AC_TYPE_MODE_T
 283 AC_TYPE_PID_T
 284
 285 AC_CHECK_DECLS(environ)
 286
 287 # check if gcc's -fvisibility is supported
 288 CHECK_VISIBILITY_HIDDEN
 289
 290 # Check for pkg-config manually first, as if its not installed the
 291 # PKG_PROG_PKG_CONFIG macro won't be defined.
 292 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 293
 294 if test x"$have_pkg_config" = "xno"; then
 295     AC_MSG_ERROR(pkg-config is required to install this program)
 296 fi
 297
 298 PKG_PROG_PKG_CONFIG
 299
 300 #
 301 # Doxygen
 302 #
 303 DX_HTML_FEATURE(ON)
 304 DX_CHM_FEATURE(OFF)
 305 DX_CHI_FEATURE(OFF)
 306 DX_MAN_FEATURE(OFF)
 307 DX_RTF_FEATURE(OFF)
 308 DX_XML_FEATURE(ON)
 309 DX_PDF_FEATURE(OFF)
 310 DX_PS_FEATURE(OFF)
 311 DX_INIT_DOXYGEN(catta, doxygen.cfg, doxygen)
 312
 313 #
 314 # Conditionally compile test and example programs
 315 #
 316 AC_ARG_ENABLE(tests,
 317         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 318         [case "${enableval}" in
 319                 yes) ENABLE_TESTS=yes ;;
 320                 no)  ENABLE_TESTS=no ;;
 321                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 322         esac],
 323         [ENABLE_TESTS=no])
 324
 325 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 326
 327 # ==========================================================================
 328 AC_CONFIG_FILES([
 329 Makefile
 330 src/Makefile
 331 include/Makefile
 332 tests/Makefile
 333 examples/Makefile
 334 m4/Makefile
 335 ])
 336 AC_OUTPUT
 337
 338 # ==========================================================================
 339 echo "
 340  ---{ $PACKAGE_NAME $VERSION }---
 341
 342     prefix:                             ${prefix}
 343     sysconfdir:                         ${sysconfdir}
 344     localstatedir:                      ${localstatedir}
 345     C Compiler:                         ${CC}
 346     CFLAGS:                             ${CFLAGS}
 347     Enable stack-smashing protection:   ${enable_ssp}
 348     Building tests:                     ${ENABLE_TESTS}
 349 "