git.meshlink.io Git - catta/blob - avahi-daemon/introspect.xsl

   1 <?xml version="1.0" encoding="iso-8859-15"?>
   2 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/1999/xhtml">
   3
   4 <!--
   5   This file is part of avahi.
   6
   7   avahi is free software; you can redistribute it and/or modify it under
   8   the terms of the GNU General Public License as published by the Free
   9   Software Foundation; either version 2 of the License, or (at your
  10   option) any later version.
  11
  12   avahi is distributed in the hope that it will be useful, but WITHOUT
  13   ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14   FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
  15   for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with avahi; if not, write to the Free Software Foundation,
  19   Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  20 -->
  21
  22 <xsl:output method="xml" version="1.0" encoding="iso-8859-15" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd" indent="yes"/>
  23
  24 <xsl:template match="/">
  25   <html>
  26     <head>
  27       <title>DBUS Introspection data</title>
  28       <style type="text/css">
  29         body { color: black; background-color: white }
  30         h1 { font-family: sans-serif }
  31         ul { list-style-type: none; margin-bottom: 10px }
  32         li { font-family: sans-serif }
  33         .keyword { font-style: italic }
  34         .type { font-weight: bold }
  35         .symbol { font-family: monospace }
  36         .interface { padding: 10px; margin: 10px }
  37       </style>
  38     </head>
  39     <body>
  40       <xsl:for-each select="node/interface">
  41         <div class="interface">
  42           <h1>
  43             <span class="keyword">interface</span><xsl:text> </xsl:text>
  44             <span class="symbol"><xsl:value-of select="@name"/></span>
  45           </h1>
  46
  47           <ul>
  48
  49             <xsl:apply-templates select="annotation"/>
  50
  51             <xsl:for-each select="method|signal|property">
  52               <li>
  53                 <span class="keyword"><xsl:value-of select="name()"/></span>
  54                 <xsl:text> </xsl:text>
  55                 <span class="symbol"><xsl:value-of select="@name"/></span>
  56
  57                 <ul>
  58                   <xsl:apply-templates select="annotation"/>
  59                   <xsl:for-each select="arg">
  60                     <li>
  61                       <span class="keyword">
  62                         <xsl:choose>
  63                           <xsl:when test="@direction != &quot;&quot;">
  64                             <xsl:value-of select="@direction"/>
  65                           </xsl:when>
  66                           <xsl:when test="name(..) = &quot;signal&quot;">
  67                             out
  68                           </xsl:when>
  69                           <xsl:otherwise>
  70                             in
  71                           </xsl:otherwise>
  72                         </xsl:choose>
  73                       </span>
  74
  75                       <xsl:text> </xsl:text>
  76
  77                       <span class="type"><xsl:value-of select="@type"/></span><xsl:text> </xsl:text>
  78                       <span class="symbol"><xsl:value-of select="@name"/></span><xsl:text> </xsl:text>
  79                     </li>
  80                   </xsl:for-each>
  81                 </ul>
  82
  83               </li>
  84             </xsl:for-each>
  85
  86           </ul>
  87         </div>
  88       </xsl:for-each>
  89     </body>
  90   </html>
  91 </xsl:template>
  92
  93
  94 <xsl:template match="annotation">
  95   <li>
  96     <span class="keyword">annotation</span>
  97     <code><xsl:value-of select="@name"/></code><xsl:text> = </xsl:text>
  98     <code><xsl:value-of select="@value"/></code>
  99   </li>
 100 </xsl:template>
 101
 102 </xsl:stylesheet>