git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.1],[mzninuv (at) 0pointer (dot) de])
  25 AC_CONFIG_SRCDIR([avahi-core])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_PROG_CPP
  40 AC_PROG_INSTALL
  41 AC_PROG_LN_S
  42 AC_PROG_MAKE_SET
  43 AC_PROG_GCC_TRADITIONAL
  44
  45 # libtool stuff
  46 AC_PROG_LIBTOOL
  47
  48 # Checks for header files.
  49 AC_HEADER_STDC
  50 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_CONST
  54 AC_TYPE_SIZE_T
  55 AC_HEADER_TIME
  56 AC_HEADER_SYS_WAIT
  57
  58 # Checks for library functions.
  59 AC_FUNC_MEMCMP
  60 AC_FUNC_SELECT_ARGTYPES
  61 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid])
  62
  63 AC_FUNC_CHOWN
  64 AC_FUNC_STAT
  65 AC_TYPE_MODE_T
  66 AC_TYPE_PID_T
  67
  68 # Check for GLIB 2.0
  69 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
  70 AC_SUBST(GLIB20_CFLAGS)
  71 AC_SUBST(GLIB20_LIBS)
  72
  73 AC_ARG_ENABLE(gtk,
  74         AS_HELP_STRING(--enable-gtk,use GTK+ (default=yes)),
  75         [case "${enableval}" in
  76                 yes) ENABLE_GTK=yes ;;
  77                 no)  ENABLE_GTK=no ;;
  78                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
  79         esac],
  80         [ENABLE_GTK=yes]) dnl Default value
  81
  82 if test "x$ENABLE_GTK" = "xyes"; then
  83         # Check for GTK 2.0
  84         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
  85         AC_SUBST(GTK20_CFLAGS)
  86         AC_SUBST(GTK20_LIBS)
  87
  88         # Check for GLADE 2.0
  89         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
  90         AC_SUBST(GLADE20_CFLAGS)
  91         AC_SUBST(GLADE20_LIBS)
  92
  93         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
  94         AC_SUBST(interfacesdir)
  95
  96 fi
  97 AM_CONDITIONAL(ENABLE_GTK, test "x$ENABLE_GTK" = "xyes")
  98
  99 #
 100 # Doxygen
 101 #
 102 DX_HTML_FEATURE(ON)
 103 DX_CHM_FEATURE(OFF)
 104 DX_CHI_FEATURE(OFF)
 105 DX_MAN_FEATURE(OFF)
 106 DX_RTF_FEATURE(OFF)
 107 DX_XML_FEATURE(OFF)
 108 DX_PDF_FEATURE(OFF)
 109 DX_PS_FEATURE(OFF)
 110 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 111
 112 #
 113 # D-BUS
 114 #
 115 AC_ARG_ENABLE(dbus,
 116         AS_HELP_STRING(--enable-dbus,use DBus (default=yes)),
 117         [case "${enableval}" in
 118                 yes) ENABLE_DBUS=yes ;;
 119                 no)  ENABLE_DBUS=no ;;
 120                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 121         esac],
 122         [ENABLE_DBUS=yes]) dnl Default value
 123
 124
 125 if test "x$ENABLE_DBUS" = "xyes"; then
 126         AC_DEFINE(ENABLE_DBUS, 1, [Whether to use DBUS or not])
 127         PKG_CHECK_MODULES(DBUS, [ dbus-glib-1 >= 0.30])
 128
 129         AC_ARG_WITH(dbus-sys, [  --with-dbus-sys=<dir>   where D-BUS system.d directory is])
 130
 131         if ! test -z "$with_dbus_sys" ; then
 132            DBUS_SYS_DIR="$with_dbus_sys"
 133         else
 134            DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 135         fi
 136         AC_SUBST(DBUS_SYS_DIR)
 137
 138         AC_SUBST(DBUS_CFLAGS)
 139         AC_SUBST(DBUS_LIBS)
 140 fi
 141
 142 AM_CONDITIONAL(ENABLE_DBUS, test "x$ENABLE_DBUS" = "xyes")
 143
 144 #
 145 # Expat
 146 #
 147 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 148
 149 if ! $have_expat ; then
 150    AC_MSG_ERROR([*** libexpat not found ***])
 151 fi
 152
 153 #
 154 # LibDaemon
 155 #
 156 PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 157 AC_SUBST(LIBDAEMON_CFLAGS)
 158 AC_SUBST(LIBDAEMON_LIBS)
 159
 160 # If using GCC specify some additional parameters
 161 if test "x$GCC" = "xyes" ; then
 162    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
 163
 164    AC_LANG_CONFTEST([int main() {}])
 165    $CC -c conftest.c -std=c99 -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=c99 -Wno-unused-parameter"
 166    rm -f conftest.o
 167 fi
 168
 169 #
 170 # Detecting the linux distro for specific things like initscripts.
 171 #
 172 AC_ARG_WITH(distro, AS_HELP_STRING(--with-distro=DISTRO,Specify the Linux distribution to target: One of redhat, suse, gentoo, debian, or slackware))
 173 if test "z$with_distro" = "z"; then
 174    AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
 175    AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 176    AC_CHECK_FILE(/etc/fedora-release,with_distro="redhat")
 177    AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 178    AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 179    AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 180 fi
 181 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 182
 183 if test "z$with_distro" = "z"; then
 184    echo "Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO"
 185    exit 1
 186 else
 187 case $with_distro in
 188    debian|gentoo|suse)
 189      ;;
 190    *)
 191      echo "Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome)"
 192      ;;
 193 esac
 194
 195 fi
 196 AM_CONDITIONAL(TARGET_REDHAT, test x"$with_distro" = xredhat)
 197 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 198 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 199 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 200 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 201
 202 #
 203 # Defining Avahi User and Group.
 204 #
 205 AC_ARG_WITH(avahi_user,[  --with-avahi-user=<user>  User for running the Avahi daemon (avahi)])
 206 if test -z "$with_avahi_user" ; then
 207     AVAHI_USER=avahi
 208 else
 209     AVAHI_USER=$with_avahi_user
 210 fi
 211 AC_SUBST(AVAHI_USER)
 212 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 213
 214 AC_ARG_WITH(avahi_group,[  --with-avahi-group=<grp>  Group for Avahi (avahi)])
 215 if test -z "$with_avahi_group" ; then
 216     AVAHI_GROUP=avahi
 217 else
 218     AVAHI_GROUP=$with_avahi_group
 219 fi
 220 AC_SUBST(AVAHI_GROUP)
 221 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 222
 223 #
 224 # Avahi runtime dir
 225 #
 226 avahi_runtime_dir="${localstatedir}/run"
 227 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 228 AC_SUBST(avahi_runtime_dir)
 229 AC_SUBST(avahi_socket)
 230
 231 #
 232 # Python stuff
 233 #
 234 AM_PATH_PYTHON(2.4, [HAVE_PYTHON=yes], [HAVE_PYTHON=no])
 235 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = xyes ])
 236
 237 # ==========================================================================
 238 AC_CONFIG_FILES([
 239 Makefile
 240 avahi-core.pc
 241 avahi-common/Makefile
 242 avahi-core/Makefile
 243 avahi-daemon/Makefile
 244 avahi-daemon/avahi-dbus.conf
 245 avahi-discover-standalone/Makefile
 246 avahi-client/Makefile
 247 initscript/Makefile
 248 initscript/Debian/Makefile
 249 initscript/Gentoo/Makefile
 250 initscript/SUSE/Makefile
 251 avahi-dnsconfd/Makefile
 252 avahi-utils/Makefile
 253 avahi-utils/avahi/Makefile
 254 examples/Makefile
 255 common/Makefile
 256 ])
 257 AC_OUTPUT
 258
 259 # ==========================================================================
 260 echo "
 261  ---{ $PACKAGE_NAME $VERSION }---
 262
 263     prefix:                 ${prefix}
 264     sysconfdir:             ${sysconfdir}
 265     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 266     dbus-1 version:         `pkg-config dbus-1 --modversion`
 267     compiler:               ${CC}
 268     cflags:                 ${CFLAGS}
 269     Enable Gtk:             ${ENABLE_GTK}
 270     Enable DBUS:            ${ENABLE_DBUS}
 271     Have Python:            ${HAVE_PYTHON}
 272     Linux Distro:           ${with_distro}
 273     User for Avahi:         ${AVAHI_USER}
 274     Group for Avahi:        ${AVAHI_GROUP}
 275
 276  NOTE: Remember to create user ${AVAHI_USER} and group ${AVAHI_GROUP} before make install
 277 "