git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.1],[mzninuv (at) 0pointer (dot) de])
  25 AC_CONFIG_SRCDIR([avahi-core])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_PROG_CPP
  40 AC_PROG_INSTALL
  41 AC_PROG_LN_S
  42 AC_PROG_MAKE_SET
  43 AC_PROG_GCC_TRADITIONAL
  44
  45 # libtool stuff
  46 AC_PROG_LIBTOOL
  47
  48 # Checks for header files.
  49 AC_HEADER_STDC
  50 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_CONST
  54 AC_TYPE_SIZE_T
  55 AC_HEADER_TIME
  56 AC_HEADER_SYS_WAIT
  57
  58 # Checks for library functions.
  59 AC_FUNC_MEMCMP
  60 AC_FUNC_SELECT_ARGTYPES
  61 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid])
  62
  63 AC_FUNC_CHOWN
  64 AC_FUNC_STAT
  65 AC_TYPE_MODE_T
  66 AC_TYPE_PID_T
  67
  68 # Check for GLIB 2.0
  69 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
  70 AC_SUBST(GLIB20_CFLAGS)
  71 AC_SUBST(GLIB20_LIBS)
  72
  73 AC_ARG_ENABLE(gtk,
  74         AC_HELP_STRING([--enable-gtk],[use GTK+ (default=yes)]),
  75         [case "${enableval}" in
  76                 yes) ENABLE_GTK=yes ;;
  77                 no)  ENABLE_GTK=no ;;
  78                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
  79         esac],
  80         [ENABLE_GTK=yes]) dnl Default value
  81
  82 if test "x$ENABLE_GTK" = "xyes"; then
  83         # Check for GTK 2.0
  84         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
  85         AC_SUBST(GTK20_CFLAGS)
  86         AC_SUBST(GTK20_LIBS)
  87
  88         # Check for GLADE 2.0
  89         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
  90         AC_SUBST(GLADE20_CFLAGS)
  91         AC_SUBST(GLADE20_LIBS)
  92
  93         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
  94         AC_SUBST(interfacesdir)
  95
  96 fi
  97 AM_CONDITIONAL(ENABLE_GTK, test "x$ENABLE_GTK" = "xyes")
  98
  99 DX_HTML_FEATURE(ON)
 100 DX_CHM_FEATURE(OFF)
 101 DX_CHI_FEATURE(OFF)
 102 DX_MAN_FEATURE(OFF)
 103 DX_RTF_FEATURE(OFF)
 104 DX_XML_FEATURE(OFF)
 105 DX_PDF_FEATURE(OFF)
 106 DX_PS_FEATURE(OFF)
 107 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 108
 109 AC_ARG_ENABLE(dbus,
 110         AC_HELP_STRING([--enable-dbus],[use DBus (default=yes)]),
 111         [case "${enableval}" in
 112                 yes) ENABLE_DBUS=yes ;;
 113                 no)  ENABLE_DBUS=no ;;
 114                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 115         esac],
 116         [ENABLE_DBUS=yes]) dnl Default value
 117
 118
 119 if test "x$ENABLE_DBUS" = "xyes"; then
 120         AC_DEFINE(ENABLE_DBUS, 1, [Whether to use DBUS or not])
 121         PKG_CHECK_MODULES(DBUS, [ dbus-glib-1 >= 0.30])
 122
 123         AC_ARG_WITH(dbus-sys, [  --with-dbus-sys=<dir>   where D-BUS system.d directory is])
 124
 125         if ! test -z "$with_dbus_sys" ; then
 126            DBUS_SYS_DIR="$with_dbus_sys"
 127         else
 128            DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 129         fi
 130         AC_SUBST(DBUS_SYS_DIR)
 131
 132         AC_SUBST(DBUS_CFLAGS)
 133         AC_SUBST(DBUS_LIBS)
 134 fi
 135
 136 AM_CONDITIONAL(ENABLE_DBUS, test "x$ENABLE_DBUS" = "xyes")
 137
 138 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 139
 140 if ! $have_expat ; then
 141    AC_MSG_ERROR([*** libexpat not found ***])
 142 fi
 143
 144 PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 145 AC_SUBST(LIBDAEMON_CFLAGS)
 146 AC_SUBST(LIBDAEMON_LIBS)
 147
 148 # If using GCC specify some additional parameters
 149 if test "x$GCC" = "xyes" ; then
 150    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
 151
 152    AC_LANG_CONFTEST([int main() {}])
 153    $CC -c conftest.c -std=c99 -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=c99 -Wno-unused-parameter"
 154    rm -f conftest.o
 155 fi
 156
 157 #
 158 # Detecting the linux distro for specific things like initscripts.
 159 #
 160 AC_ARG_WITH(distro, AC_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, suse, gentoo, debian, or slackware]))
 161 if test "z$with_distro" = "z"; then
 162    AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
 163    AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 164    AC_CHECK_FILE(/etc/fedora-release,with_distro="redhat")
 165    AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 166    AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 167    AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 168 fi
 169 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 170
 171 if test "z$with_distro" = "z"; then
 172    echo "Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO"
 173    exit 1
 174 else
 175 case $with_distro in
 176    debian|gentoo|suse)
 177      ;;
 178    *)
 179      echo "Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome)"
 180      ;;
 181 esac
 182
 183 fi
 184 AM_CONDITIONAL(TARGET_REDHAT, test x"$with_distro" = xredhat)
 185 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 186 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 187 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 188 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 189
 190 #
 191 # Defining Avahi User and Group.
 192 #
 193 AC_ARG_WITH(avahi_user,[  --with-avahi-user=<user>  User for running the Avahi daemon (avahi)])
 194 if test -z "$with_avahi_user" ; then
 195     AVAHI_USER=avahi
 196 else
 197     AVAHI_USER=$with_avahi_user
 198 fi
 199 AC_SUBST(AVAHI_USER)
 200 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 201
 202 AC_ARG_WITH(avahi_group,[  --with-avahi-group=<grp>  Group for Avahi (avahi)])
 203 if test -z "$with_avahi_group" ; then
 204     AVAHI_GROUP=avahi
 205 else
 206     AVAHI_GROUP=$with_avahi_group
 207 fi
 208 AC_SUBST(AVAHI_GROUP)
 209 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 210
 211 #
 212 # Avahi runtime dir
 213 #
 214 avahi_runtime_dir="${localstatedir}/run"
 215 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 216 AC_SUBST(avahi_runtime_dir)
 217 AC_SUBST(avahi_socket)
 218
 219 AM_PATH_PYTHON(2.4, [HAVE_PYTHON=yes], [HAVE_PYTHON=no])
 220 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = xyes ])
 221
 222 AC_CONFIG_FILES([
 223 Makefile
 224 avahi-core.pc
 225 avahi-common/Makefile
 226 avahi-core/Makefile
 227 avahi-daemon/Makefile
 228 avahi-daemon/avahi-dbus.conf
 229 avahi-discover/Makefile
 230 avahi-client/Makefile
 231 initscript/Makefile
 232 initscript/Debian/Makefile
 233 initscript/Gentoo/Makefile
 234 initscript/SUSE/Makefile
 235 avahi-dnsconfd/Makefile
 236 avahi-utils/Makefile
 237 avahi-utils/avahi/Makefile
 238 avahi-utils/avahi-dump-all
 239 avahi-utils/avahi-publish-service
 240 avahi-utils/avahi-publish-address
 241 avahi-utils/avahi-discover
 242 examples/Makefile
 243 ])
 244 AC_OUTPUT
 245
 246 dnl ==========================================================================
 247 echo "
 248  ---{ $PACKAGE_NAME $VERSION }---
 249
 250     prefix:                 ${prefix}
 251     sysconfdir:             ${sysconfdir}
 252     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 253     dbus-1 version:         `pkg-config dbus-1 --modversion`
 254     compiler:               ${CC}
 255     cflags:                 ${CFLAGS}
 256     Enable Gtk:             ${ENABLE_GTK}
 257     Enable DBUS:            ${ENABLE_DBUS}
 258     Have Python:            ${HAVE_PYTHON}
 259     Linux Distro:           ${with_distro}
 260     User for Avahi:         ${AVAHI_USER}
 261     Group for Avahi:        ${AVAHI_GROUP}
 262
 263  NOTE: Remember to create user ${AVAHI_USER} and group ${AVAHI_GROUP} before make install
 264 "