git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.2],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 AC_GNU_SOURCE
  40 AC_PROG_CPP
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AC_PROG_GCC_TRADITIONAL
  45
  46 # libtool stuff
  47 AC_PROG_LIBTOOL
  48
  49 #
  50 # Detecting the linux distribution for specific things like init scripts.
  51 #
  52 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
  53 if test "z$with_distro" = "z"; then
  54     #AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  55     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  56     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
  57     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  58 fi
  59 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
  60
  61 if test "z$with_distro" = "z"; then
  62     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO])
  63     exit 1
  64 else
  65 case $with_distro in
  66     debian|gentoo|archlinux)
  67      ;;
  68     *)
  69      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome)])
  70      ;;
  71 esac
  72 fi
  73
  74 #AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
  75 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
  76 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
  77 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
  78
  79 test_gcc_flag() {
  80     AC_LANG_CONFTEST([int main() {}])
  81     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  82     ret=$?
  83     rm -f conftest.o
  84     return $ret
  85 }
  86
  87 # If using GCC specify some additional parameters
  88 if test "x$GCC" = "xyes" ; then
  89
  90     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     # Test whether rtnetlink.h can be included when compiled with -std=c99
  93     # some distributions (e.g. archlinux) have broken headers that dont
  94     # define __u64 with -std=c99
  95     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
  96     OLDCFLAGS="$CFLAGS"
  97     CFLAGS="-std=c99"
  98     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
  99         use_stdc99=yes, use_stdc99=no)
 100
 101     if test x"$use_stdc99" = xyes; then
 102         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 103         AC_MSG_RESULT([yes])
 104     else
 105         AC_MSG_RESULT([no])
 106     fi
 107
 108     CFLAGS="$OLDCFLAGS"
 109
 110     for flag in $DESIRED_FLAGS ; do
 111         AC_MSG_CHECKING([whether $CC accepts $flag])
 112         if test_gcc_flag $flag ; then
 113            CFLAGS="$CFLAGS $flag"
 114            AC_MSG_RESULT([yes])
 115         else
 116            AC_MSG_RESULT([no])
 117         fi
 118     done
 119 fi
 120
 121 # Checks for header files.
 122 AC_HEADER_STDC
 123 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 124
 125 # Checks for typedefs, structures, and compiler characteristics.
 126 AC_C_CONST
 127 AC_TYPE_SIZE_T
 128 AC_HEADER_TIME
 129 AC_HEADER_SYS_WAIT
 130
 131 # Checks for library functions.
 132 AC_FUNC_MEMCMP
 133 AC_FUNC_SELECT_ARGTYPES
 134 AC_FUNC_MALLOC
 135 AC_FUNC_REALLOC
 136 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv])
 137
 138 AC_FUNC_CHOWN
 139 AC_FUNC_STAT
 140 AC_TYPE_MODE_T
 141 AC_TYPE_PID_T
 142
 143 PKG_PROG_PKG_CONFIG
 144
 145 #
 146 # Check for GLIB 2.0
 147 #
 148 AC_ARG_ENABLE(glib,
 149         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 150         [case "${enableval}" in
 151                 yes) HAVE_GLIB=yes ;;
 152                 no)  HAVE_GLIB=no ;;
 153                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 154         esac],
 155         [HAVE_GLIB=yes])
 156
 157 if test "x$HAVE_GLIB" = "xyes" ; then
 158         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 159         AC_SUBST(GLIB20_CFLAGS)
 160         AC_SUBST(GLIB20_LIBS)
 161 fi
 162 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 163
 164 #
 165 # Check for GTK+
 166 #
 167 AC_ARG_ENABLE(gtk,
 168         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 169         [case "${enableval}" in
 170                 yes) HAVE_GTK=yes ;;
 171                 no)  HAVE_GTK=no ;;
 172                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 173         esac],
 174         [HAVE_GTK=yes])
 175
 176 if test "x$HAVE_GTK" = "xyes" ; then
 177         # Check for GTK 2.0
 178         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 179         AC_SUBST(GTK20_CFLAGS)
 180         AC_SUBST(GTK20_LIBS)
 181
 182         # Check for GLADE 2.0
 183         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 184         AC_SUBST(GLADE20_CFLAGS)
 185         AC_SUBST(GLADE20_LIBS)
 186
 187         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 188         AC_SUBST(interfacesdir)
 189 fi
 190 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 191
 192 #
 193 # D-BUS
 194 #
 195 AC_ARG_ENABLE(dbus,
 196         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 197         [case "${enableval}" in
 198                 yes) HAVE_DBUS=yes ;;
 199                 no)  HAVE_DBUS=no ;;
 200                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 201         esac],
 202         [HAVE_DBUS=yes])
 203
 204 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 205 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 206
 207 if test "x$HAVE_DBUS" = "xyes" ; then
 208     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 209
 210     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.30 ])
 211     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 212     AC_SUBST(DBUS_CFLAGS)
 213     AC_SUBST(DBUS_LIBS)
 214
 215     if ! test -z "$with_dbus_sys" ; then
 216         DBUS_SYS_DIR="$with_dbus_sys"
 217     else
 218         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 219     fi
 220     AC_SUBST(DBUS_SYS_DIR)
 221
 222     if ! test -z "$with_dbus_system_address" ; then
 223         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 224     else
 225         # Note this default path is hardcoded in D-BUS and should
 226         # not use $localstatedir
 227         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 228     fi
 229     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 230
 231 fi
 232 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 233
 234 #
 235 # Expat
 236 #
 237 AC_ARG_ENABLE(expat,
 238         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 239         [case "${enableval}" in
 240                 yes) HAVE_EXPAT=yes ;;
 241                 no)  HAVE_EXPAT=no ;;
 242                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 243         esac],
 244         [HAVE_EXPAT=yes])
 245
 246 if test "x$HAVE_EXPAT" = "xyes" ; then
 247     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 248
 249     if ! $have_expat ; then
 250         AC_MSG_ERROR([*** libexpat not found ***])
 251     fi
 252 fi
 253 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 254
 255 #
 256 # libdaemon
 257 #
 258 AC_ARG_ENABLE(libdaemon,
 259         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 260         [case "${enableval}" in
 261                 yes) HAVE_LIBDAEMON=yes ;;
 262                 no)  HAVE_LIBDAEMON=no ;;
 263                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 264         esac],
 265         [HAVE_LIBDAEMON=yes])
 266
 267 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 268     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 269     AC_SUBST(LIBDAEMON_CFLAGS)
 270     AC_SUBST(LIBDAEMON_LIBS)
 271 fi
 272 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 273
 274 #
 275 # Python stuff
 276 #
 277 AC_ARG_ENABLE(python,
 278     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 279     [case "${enableval}" in
 280           yes) HAVE_PYTHON=yes ;;
 281           no)  HAVE_PYTHON=no ;;
 282           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 283     esac],[HAVE_PYTHON=yes])
 284
 285 if test "x$HAVE_PYTHON" = "xyes" ; then
 286     AM_PATH_PYTHON([2.4])
 287     AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module pygtk)])
 288     AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 289 fi
 290 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 291
 292 #
 293 # Defining Avahi User and Group.
 294 #
 295 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 296 if test -z "$with_avahi_user" ; then
 297     AVAHI_USER=avahi
 298 else
 299     AVAHI_USER=$with_avahi_user
 300 fi
 301 AC_SUBST(AVAHI_USER)
 302 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 303
 304 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 305 if test -z "$with_avahi_group" ; then
 306     AVAHI_GROUP=avahi
 307 else
 308     AVAHI_GROUP=$with_avahi_group
 309 fi
 310 AC_SUBST(AVAHI_GROUP)
 311 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 312
 313 #
 314 # Avahi runtime dir
 315 #
 316 avahi_runtime_dir="${localstatedir}/run"
 317 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 318 AC_SUBST(avahi_runtime_dir)
 319 AC_SUBST(avahi_socket)
 320
 321
 322 #
 323 # Doxygen
 324 #
 325 DX_HTML_FEATURE(ON)
 326 DX_CHM_FEATURE(OFF)
 327 DX_CHI_FEATURE(OFF)
 328 DX_MAN_FEATURE(OFF)
 329 DX_RTF_FEATURE(OFF)
 330 DX_XML_FEATURE(OFF)
 331 DX_PDF_FEATURE(OFF)
 332 DX_PS_FEATURE(OFF)
 333 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 334
 335 #
 336 # XMLTOMAN manpage generation
 337 #
 338 AC_ARG_ENABLE(xmltoman,
 339         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 340 [case "${enableval}" in
 341   yes) xmltoman=yes ;;
 342   no)  xmltoman=no ;;
 343   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 344 esac],[xmltoman=yes])
 345
 346 if test x$xmltoman = xyes ; then
 347     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 348
 349     if test x$have_xmltoman = xno ; then
 350         if ! test -e man/avahi-daemon.8 ; then
 351             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 352             exit 1
 353         fi
 354         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 355         xmltoman=no
 356     fi
 357 fi
 358
 359 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 360
 361 # ==========================================================================
 362 AC_CONFIG_FILES([
 363 Makefile
 364 avahi-common/Makefile
 365 avahi-core/Makefile
 366 avahi-glib/Makefile
 367 avahi-daemon/Makefile
 368 avahi-daemon/avahi-dbus.conf
 369 avahi-discover-standalone/Makefile
 370 avahi-client/Makefile
 371 initscript/Makefile
 372 initscript/debian/Makefile
 373 initscript/gentoo/Makefile
 374 initscript/archlinux/Makefile
 375 avahi-dnsconfd/Makefile
 376 avahi-utils/Makefile
 377 avahi-utils/avahi/Makefile
 378 examples/Makefile
 379 common/Makefile
 380 man/Makefile
 381 tests/Makefile
 382 ])
 383 AC_OUTPUT
 384
 385 # ==========================================================================
 386 echo "
 387  ---{ $PACKAGE_NAME $VERSION }---
 388
 389     prefix:                 ${prefix}
 390     sysconfdir:             ${sysconfdir}
 391     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 392     dbus-1 version:         `pkg-config dbus-1 --modversion`
 393     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 394     compiler:               ${CC}
 395     cflags:                 ${CFLAGS}
 396     Enable GLIB:            ${HAVE_GLIB}
 397     Enable GTK:             ${HAVE_GTK}
 398     Enable D-BUS:           ${HAVE_DBUS}
 399     Enable Expat:           ${HAVE_EXPAT}
 400     Enable libdaemon:       ${HAVE_LIBDAEMON}
 401     Have Python:            ${HAVE_PYTHON}
 402     Linux Distro:           ${with_distro}
 403     User for Avahi:         ${AVAHI_USER}
 404     Group for Avahi:        ${AVAHI_GROUP}
 405 "
 406
 407 BUILD_DAEMON="no (!)"
 408
 409 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 410     BUILD_DAEMON=yes
 411 fi
 412
 413 BUILD_UTILS="no (!)"
 414
 415 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" ; then
 416     BUILD_UTILS=yes
 417 fi
 418
 419 BUILD_CLIENT="no (!)"
 420
 421 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 422     BUILD_CLIENT=yes
 423 fi
 424
 425
 426 echo "
 427     Building libavahi-core              yes
 428     Building avahi-daemon:              ${BUILD_DAEMON}
 429     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 430     Building avahi-utils:               ${BUILD_UTILS}
 431     Building libavahi-glib:             ${HAVE_GLIB}
 432     Building libavahi-client:           ${BUILD_CLIENT}
 433     Building avahi-discover-standalone: ${HAVE_GTK}
 434 "