git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.2],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 AC_GNU_SOURCE
  40 AC_PROG_CPP
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AC_PROG_GCC_TRADITIONAL
  45
  46 # libtool stuff
  47 AC_PROG_LIBTOOL
  48
  49 #
  50 # Detecting the linux distro for specific things like initscripts.
  51 #
  52 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
  53 if test "z$with_distro" = "z"; then
  54    #AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  55    AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  56    AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
  57    AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  58 fi
  59 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
  60
  61 if test "z$with_distro" = "z"; then
  62    echo "Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO"
  63    exit 1
  64 else
  65 case $with_distro in
  66    debian|gentoo|archlinux)
  67      ;;
  68    *)
  69      echo "Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome)"
  70      ;;
  71 esac
  72 fi
  73
  74 #AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
  75 #AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
  76 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
  77 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
  78
  79
  80 test_gcc_flag() {
  81    AC_LANG_CONFTEST([int main() {}])
  82    $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  83    ret=$?
  84    rm -f conftest.o
  85    return $ret
  86 }
  87
  88 # If using GCC specify some additional parameters
  89 if test "x$GCC" = "xyes" ; then
  90
  91    DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  92
  93    # Work around a kernel header bug in arch linux where rtnetlink.h
  94    # can't be included with -std=c99
  95    if test x"$with_distro" != xarchlinux ; then
  96        DESIRED_FLAGS="$DESIRED_FLAGS -std=c99"
  97    fi
  98
  99    for flag in $DESIRED_FLAGS ; do
 100        AC_MSG_CHECKING([whether $CC accepts $flag])
 101        if test_gcc_flag $flag ; then
 102           CFLAGS="$CFLAGS $flag"
 103           AC_MSG_RESULT([yes])
 104        else
 105           AC_MSG_RESULT([no])
 106        fi
 107    done
 108 fi
 109
 110 # Checks for header files.
 111 AC_HEADER_STDC
 112 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 113
 114 # Checks for typedefs, structures, and compiler characteristics.
 115 AC_C_CONST
 116 AC_TYPE_SIZE_T
 117 AC_HEADER_TIME
 118 AC_HEADER_SYS_WAIT
 119
 120 # Checks for library functions.
 121 AC_FUNC_MEMCMP
 122 AC_FUNC_SELECT_ARGTYPES
 123 AC_FUNC_MALLOC
 124 AC_FUNC_REALLOC
 125 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv])
 126
 127 AC_FUNC_CHOWN
 128 AC_FUNC_STAT
 129 AC_TYPE_MODE_T
 130 AC_TYPE_PID_T
 131
 132 PKG_PROG_PKG_CONFIG
 133
 134 #
 135 # Check for GLIB 2.0
 136 #
 137 AC_ARG_ENABLE(glib,
 138         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 139         [case "${enableval}" in
 140                 yes) HAVE_GLIB=yes ;;
 141                 no)  HAVE_GLIB=no ;;
 142                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 143         esac],
 144         [HAVE_GLIB=yes])
 145
 146 if test "x$HAVE_GLIB" = "xyes" ; then
 147         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 148         AC_SUBST(GLIB20_CFLAGS)
 149         AC_SUBST(GLIB20_LIBS)
 150 fi
 151 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 152
 153 #
 154 # Check for GTK+
 155 #
 156 AC_ARG_ENABLE(gtk,
 157         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 158         [case "${enableval}" in
 159                 yes) HAVE_GTK=yes ;;
 160                 no)  HAVE_GTK=no ;;
 161                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 162         esac],
 163         [HAVE_GTK=yes])
 164
 165 if test "x$HAVE_GTK" = "xyes" ; then
 166         # Check for GTK 2.0
 167         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 168         AC_SUBST(GTK20_CFLAGS)
 169         AC_SUBST(GTK20_LIBS)
 170
 171         # Check for GLADE 2.0
 172         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 173         AC_SUBST(GLADE20_CFLAGS)
 174         AC_SUBST(GLADE20_LIBS)
 175
 176             interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 177             AC_SUBST(interfacesdir)
 178 fi
 179 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 180
 181 #
 182 # D-BUS
 183 #
 184 AC_ARG_ENABLE(dbus,
 185         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 186         [case "${enableval}" in
 187                 yes) HAVE_DBUS=yes ;;
 188                 no)  HAVE_DBUS=no ;;
 189                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 190         esac],
 191         [HAVE_DBUS=yes])
 192
 193 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 194
 195 if test "x$HAVE_DBUS" = "xyes" ; then
 196         AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 197
 198     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.30 ])
 199     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 200     AC_SUBST(DBUS_CFLAGS)
 201         AC_SUBST(DBUS_LIBS)
 202
 203         if ! test -z "$with_dbus_sys" ; then
 204            DBUS_SYS_DIR="$with_dbus_sys"
 205         else
 206                DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 207         fi
 208         AC_SUBST(DBUS_SYS_DIR)
 209
 210 fi
 211 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 212
 213 #
 214 # Expat
 215 #
 216 AC_ARG_ENABLE(expat,
 217         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 218         [case "${enableval}" in
 219                 yes) HAVE_EXPAT=yes ;;
 220                 no)  HAVE_EXPAT=no ;;
 221                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 222         esac],
 223         [HAVE_EXPAT=yes])
 224
 225 if test "x$HAVE_EXPAT" = "xyes" ; then
 226    AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 227
 228    if ! $have_expat ; then
 229       AC_MSG_ERROR([*** libexpat not found ***])
 230    fi
 231 fi
 232 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 233
 234 #
 235 # libdaemon
 236 #
 237 AC_ARG_ENABLE(libdaemon,
 238         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 239         [case "${enableval}" in
 240                 yes) HAVE_LIBDAEMON=yes ;;
 241                 no)  HAVE_LIBDAEMON=no ;;
 242                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 243         esac],
 244         [HAVE_LIBDAEMON=yes])
 245
 246 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 247    PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 248    AC_SUBST(LIBDAEMON_CFLAGS)
 249    AC_SUBST(LIBDAEMON_LIBS)
 250 fi
 251 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 252
 253 #
 254 # Python stuff
 255 #
 256 AC_ARG_ENABLE(python,
 257         AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 258         [case "${enableval}" in
 259               yes) HAVE_PYTHON=yes ;;
 260               no)  HAVE_PYTHON=no ;;
 261               *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 262         esac],[HAVE_PYTHON=yes])
 263
 264 if test "x$HAVE_PYTHON" = "xyes" ; then
 265    AM_PATH_PYTHON([2.4])
 266    AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module pygtk)])
 267    AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 268 fi
 269 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 270
 271 #
 272 # Defining Avahi User and Group.
 273 #
 274 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 275 if test -z "$with_avahi_user" ; then
 276     AVAHI_USER=avahi
 277 else
 278     AVAHI_USER=$with_avahi_user
 279 fi
 280 AC_SUBST(AVAHI_USER)
 281 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 282
 283 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 284 if test -z "$with_avahi_group" ; then
 285     AVAHI_GROUP=avahi
 286 else
 287     AVAHI_GROUP=$with_avahi_group
 288 fi
 289 AC_SUBST(AVAHI_GROUP)
 290 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 291
 292 #
 293 # Avahi runtime dir
 294 #
 295 avahi_runtime_dir="${localstatedir}/run"
 296 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 297 AC_SUBST(avahi_runtime_dir)
 298 AC_SUBST(avahi_socket)
 299
 300
 301 #
 302 # Doxygen
 303 #
 304 DX_HTML_FEATURE(ON)
 305 DX_CHM_FEATURE(OFF)
 306 DX_CHI_FEATURE(OFF)
 307 DX_MAN_FEATURE(OFF)
 308 DX_RTF_FEATURE(OFF)
 309 DX_XML_FEATURE(OFF)
 310 DX_PDF_FEATURE(OFF)
 311 DX_PS_FEATURE(OFF)
 312 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 313
 314 #
 315 # XMLTOMAN manpage generation
 316 #
 317 AC_ARG_ENABLE(xmltoman,
 318         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 319 [case "${enableval}" in
 320   yes) xmltoman=yes ;;
 321   no)  xmltoman=no ;;
 322   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 323 esac],[xmltoman=yes])
 324
 325 if test x$xmltoman = xyes ; then
 326    AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 327
 328    if test x$have_xmltoman = xno ; then
 329      if ! test -e man/avahi-daemon.8 ; then
 330         AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 331         exit 1
 332      fi
 333      AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 334      xmltoman=no
 335    fi
 336 fi
 337
 338 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 339
 340 # ==========================================================================
 341 AC_CONFIG_FILES([
 342 Makefile
 343 avahi-common/Makefile
 344 avahi-core/Makefile
 345 avahi-glib/Makefile
 346 avahi-daemon/Makefile
 347 avahi-daemon/avahi-dbus.conf
 348 avahi-discover-standalone/Makefile
 349 avahi-client/Makefile
 350 initscript/Makefile
 351 initscript/debian/Makefile
 352 initscript/gentoo/Makefile
 353 initscript/archlinux/Makefile
 354 avahi-dnsconfd/Makefile
 355 avahi-utils/Makefile
 356 avahi-utils/avahi/Makefile
 357 examples/Makefile
 358 common/Makefile
 359 man/Makefile
 360 tests/Makefile
 361 ])
 362 AC_OUTPUT
 363
 364 # ==========================================================================
 365 echo "
 366  ---{ $PACKAGE_NAME $VERSION }---
 367
 368     prefix:                 ${prefix}
 369     sysconfdir:             ${sysconfdir}
 370     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 371     dbus-1 version:         `pkg-config dbus-1 --modversion`
 372     compiler:               ${CC}
 373     cflags:                 ${CFLAGS}
 374     Enable GLIB:            ${HAVE_GLIB}
 375     Enable GTK:             ${HAVE_GTK}
 376     Enable D-BUS:           ${HAVE_DBUS}
 377     Enable Expat:           ${HAVE_EXPAT}
 378     Enable libdaemon:       ${HAVE_LIBDAEMON}
 379     Have Python:            ${HAVE_PYTHON}
 380     Linux Distro:           ${with_distro}
 381     User for Avahi:         ${AVAHI_USER}
 382     Group for Avahi:        ${AVAHI_GROUP}
 383 "
 384
 385 BUILD_DAEMON="no (!)"
 386
 387 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 388    BUILD_DAEMON=yes
 389 fi
 390
 391 BUILD_UTILS="no (!)"
 392
 393 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" ; then
 394    BUILD_UTILS=yes
 395 fi
 396
 397 BUILD_CLIENT="no (!)"
 398
 399 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 400    BUILD_CLIENT=yes
 401 fi
 402
 403
 404 echo "
 405     Building libavahi-core              yes
 406     Building avahi-daemon:              ${BUILD_DAEMON}
 407     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 408     Building avahi-utils:               ${BUILD_UTILS}
 409     Building libavahi-glib:             ${HAVE_GLIB}
 410     Building libavahi-client:           ${BUILD_CLIENT}
 411     Building avahi-discover-standalone: ${HAVE_GTK}
 412 "