git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38
  39 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  40     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  41     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  42 fi
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AC_PROG_CXX
  47 AC_GNU_SOURCE
  48 AC_PROG_CPP
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AC_PROG_GCC_TRADITIONAL
  53
  54 # libtool stuff
  55 AC_PROG_LIBTOOL
  56
  57 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  58
  59 #
  60 # Host specific stuffs
  61 #
  62 case "$host" in
  63   *-netbsd* | *-knetbsd*-gnu)
  64     AC_DEFINE([NETBSD],[],[ Support for NetBSD])
  65     avahi_platform=netbsd
  66     ;;
  67   *-openbsd*)
  68     AC_DEFINE([OPENBSD],[],[ Support for OpenBSD])
  69     avahi_platform=openbsd
  70     ;;
  71   *-solaris*)
  72     AC_DEFINE([SOLARIS],[],[ Support for Sun Solaris])
  73     avahi_platform=solaris
  74     ;;
  75   *-linux*)
  76     AC_DEFINE([LINUX],[],[ Support for GNU/Linux])
  77     avahi_platform=linux
  78     ;;
  79   *-freebsd* | *-kfreebsd*-gnu)
  80     AC_DEFINE([FREEBSD],[],[ Support for FreeBSD])
  81     avahi_platform=freebsd
  82     ;;
  83   *-apple-darwin*)
  84     AC_DEFINE([DARWIN],[],[ Support for AppleDarwin])
  85     avahi_platform=darwin
  86     ;;
  87 esac
  88
  89 AC_CHECK_HEADER(linux/netlink.h,
  90 HAVE_NETLINK=yes
  91 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  92 , [], [
  93 #include <sys/socket.h>
  94 #include <asm/types.h>
  95 ])
  96
  97 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  98
  99 #
 100 # Detecting the linux distribution for specific things like init scripts.
 101 #
 102 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
 103 if test "z$with_distro" = "z"; then
 104     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 105     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 106     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 107     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 108 fi
 109 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 110
 111 if test "z$with_distro" = "z"; then
 112     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 113     exit 1
 114 else
 115 case $with_distro in
 116     debian|gentoo|archlinux|suse|none)
 117      ;;
 118     *)
 119      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 120      ;;
 121 esac
 122 fi
 123
 124 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 125 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 126 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 127 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 128
 129 test_gcc_flag() {
 130     AC_LANG_CONFTEST([int main() {}])
 131     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 132     ret=$?
 133     rm -f conftest.o
 134     return $ret
 135 }
 136
 137 # If using GCC specify some additional parameters
 138 if test "x$GCC" = "xyes" ; then
 139
 140     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
 141
 142     # Test whether rtnetlink.h can be included when compiled with -std=c99
 143     # some distributions (e.g. archlinux) have broken headers that dont
 144     # define __u64 with -std=c99
 145     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 146     OLDCFLAGS="$CFLAGS"
 147     CFLAGS="-std=c99"
 148     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 149         use_stdc99=yes, use_stdc99=no)
 150
 151     if test x"$use_stdc99" = xyes; then
 152         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 153         AC_MSG_RESULT([yes])
 154     else
 155         AC_MSG_RESULT([no])
 156     fi
 157
 158     CFLAGS="$OLDCFLAGS"
 159
 160     for flag in $DESIRED_FLAGS ; do
 161         AC_MSG_CHECKING([whether $CC accepts $flag])
 162         if test_gcc_flag $flag ; then
 163            CFLAGS="$CFLAGS $flag"
 164            AC_MSG_RESULT([yes])
 165         else
 166            AC_MSG_RESULT([no])
 167         fi
 168     done
 169 fi
 170
 171 # Checks for header files.
 172 AC_HEADER_STDC
 173 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 174
 175 # Checks for typedefs, structures, and compiler characteristics.
 176 AC_C_CONST
 177 AC_TYPE_SIZE_T
 178 AC_HEADER_TIME
 179 AC_HEADER_SYS_WAIT
 180
 181 # Checks for library functions.
 182 AC_FUNC_MEMCMP
 183 AC_FUNC_SELECT_ARGTYPES
 184 AC_FUNC_MALLOC
 185 AC_FUNC_REALLOC
 186 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp])
 187
 188 AC_FUNC_CHOWN
 189 AC_FUNC_STAT
 190 AC_TYPE_MODE_T
 191 AC_TYPE_PID_T
 192
 193 # Check for pkg-config manually first, as if its not installed the
 194 # PKG_PROG_PKG_CONFIG macro won't be defined.
 195 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 196
 197 if test x"$have_pkg_config" == xno; then
 198     AC_MSG_ERROR(pkg-config is required to install this program)
 199 fi
 200
 201 PKG_PROG_PKG_CONFIG
 202
 203 #
 204 # Check for GLIB 2.0
 205 #
 206 AC_ARG_ENABLE(glib,
 207         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 208         [case "${enableval}" in
 209                 yes) HAVE_GLIB=yes ;;
 210                 no)  HAVE_GLIB=no ;;
 211                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 212         esac],
 213         [HAVE_GLIB=yes])
 214
 215 if test "x$HAVE_GLIB" = "xyes" ; then
 216         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 217         AC_SUBST(GLIB20_CFLAGS)
 218         AC_SUBST(GLIB20_LIBS)
 219 fi
 220 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 221
 222 #
 223 # Check for Qt 3
 224 #
 225 AC_ARG_ENABLE(qt3,
 226         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 227         [case "${enableval}" in
 228                 yes) HAVE_QT3=yes ;;
 229                 no)  HAVE_QT3=no ;;
 230                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 231         esac],
 232         [HAVE_QT3=yes])
 233
 234 if test "x$HAVE_QT3" = "xyes" ; then
 235         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 236         AC_SUBST(QT3_CFLAGS)
 237         AC_SUBST(QT3_LIBS)
 238             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 239         MOC_QT3="no"
 240             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 241                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 242                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 243         AC_SUBST(MOC_QT3)
 244 fi
 245 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 246
 247 #
 248 # Check for Qt 4
 249 #
 250 AC_ARG_ENABLE(qt4,
 251         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 252         [case "${enableval}" in
 253                 yes) HAVE_QT4=yes ;;
 254                 no)  HAVE_QT4=no ;;
 255                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 256         esac],
 257         [HAVE_QT4=yes])
 258
 259 if test "x$HAVE_QT4" = "xyes" ; then
 260         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 261         AC_SUBST(QT4_CFLAGS)
 262         AC_SUBST(QT4_LIBS)
 263             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 264         MOC_QT4="no"
 265             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 266                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 267                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 268         AC_SUBST(MOC_QT4)
 269 fi
 270 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 271
 272 #
 273 # Check for GTK+
 274 #
 275 AC_ARG_ENABLE(gtk,
 276         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 277         [case "${enableval}" in
 278                 yes) HAVE_GTK=yes ;;
 279                 no)  HAVE_GTK=no ;;
 280                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 281         esac],
 282         [HAVE_GTK=yes])
 283
 284 if test "x$HAVE_GTK" = "xyes" ; then
 285         # Check for GTK 2.0
 286         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 287         AC_SUBST(GTK20_CFLAGS)
 288         AC_SUBST(GTK20_LIBS)
 289
 290         # Check for GLADE 2.0
 291         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 292         AC_SUBST(GLADE20_CFLAGS)
 293         AC_SUBST(GLADE20_LIBS)
 294 fi
 295 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 296
 297
 298
 299 #
 300 # D-BUS
 301 #
 302 AC_ARG_ENABLE(dbus,
 303         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 304         [case "${enableval}" in
 305                 yes) HAVE_DBUS=yes ;;
 306                 no)  HAVE_DBUS=no ;;
 307                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 308         esac],
 309         [HAVE_DBUS=yes])
 310
 311 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 312 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 313
 314 if test "x$HAVE_DBUS" = "xyes" ; then
 315     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 316
 317     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 318     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 319     AC_SUBST(DBUS_CFLAGS)
 320     AC_SUBST(DBUS_LIBS)
 321
 322     if ! test -z "$with_dbus_sys" ; then
 323         DBUS_SYS_DIR="$with_dbus_sys"
 324     else
 325         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 326     fi
 327     AC_SUBST(DBUS_SYS_DIR)
 328
 329     if ! test -z "$with_dbus_system_address" ; then
 330         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 331     else
 332         # This is ugly, but D-BUS doesn't export this address for us
 333         # so we have to guess, pretty much all setups i've seen have
 334         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 335         # /var/run upstream so we will try guess first then default
 336         # to /var/run/dbus
 337
 338         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 339         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket"
 340         for sock in $TRY_SOCKETS; do
 341             if test -S $sock; then
 342                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 343             fi
 344         done
 345     fi
 346     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 347
 348 fi
 349 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 350
 351 #
 352 # Expat
 353 #
 354 AC_ARG_ENABLE(expat,
 355         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 356         [case "${enableval}" in
 357                 yes) HAVE_EXPAT=yes ;;
 358                 no)  HAVE_EXPAT=no ;;
 359                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 360         esac],
 361         [HAVE_EXPAT=yes])
 362
 363 if test "x$HAVE_EXPAT" = "xyes" ; then
 364     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 365
 366     if ! $have_expat ; then
 367         AC_MSG_ERROR([*** libexpat not found ***])
 368     fi
 369 fi
 370 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 371
 372 #
 373 # libdaemon
 374 #
 375 AC_ARG_ENABLE(libdaemon,
 376         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 377         [case "${enableval}" in
 378                 yes) HAVE_LIBDAEMON=yes ;;
 379                 no)  HAVE_LIBDAEMON=no ;;
 380                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 381         esac],
 382         [HAVE_LIBDAEMON=yes])
 383
 384 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 385     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 386     AC_SUBST(LIBDAEMON_CFLAGS)
 387     AC_SUBST(LIBDAEMON_LIBS)
 388 fi
 389 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 390
 391 #
 392 # Python stuff
 393 #
 394 AC_ARG_ENABLE(python,
 395     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 396     [case "${enableval}" in
 397           yes) HAVE_PYTHON=yes ;;
 398           no)  HAVE_PYTHON=no ;;
 399           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 400     esac],[HAVE_PYTHON=yes])
 401
 402 HAVE_PYTHON_DBUS=no
 403 HAVE_PYGTK=no
 404
 405 if test "x$HAVE_PYTHON" = "xyes" ; then
 406     AM_PATH_PYTHON([2.4])
 407
 408     AC_ARG_ENABLE(pygtk,
 409         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 410         [case "${enableval}" in
 411                 yes) HAVE_PYGTK=yes ;;
 412                 no)  HAVE_PYGTK=no ;;
 413                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 414         esac],
 415         [HAVE_PYGTK=yes])
 416
 417     if test "x$HAVE_PYGTK" = "xyes" ; then
 418         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 419     fi
 420
 421
 422     AC_ARG_ENABLE(python-dbus,
 423         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 424         [case "${enableval}" in
 425                 yes) HAVE_PYTHON_DBUS=yes ;;
 426                 no)  HAVE_PYTHON_DBUS=no ;;
 427                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 428         esac],
 429         [HAVE_PYTHON_DBUS=yes])
 430
 431     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 432         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 433     fi
 434
 435     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 436     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 437 fi
 438 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 439 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 440 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 441
 442 #
 443 # Check for mono stuff
 444 #
 445 AC_ARG_ENABLE(mono,
 446         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 447         [case "${enableval}" in
 448                 yes) HAVE_MONO=yes ;;
 449                 no)  HAVE_MONO=no ;;
 450                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 451         esac],
 452         [HAVE_MONO=yes])
 453
 454 AC_ARG_ENABLE(monodoc,
 455         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 456         [case "${enableval}" in
 457                 yes) HAVE_MONODOC=yes ;;
 458                 no)  HAVE_MONODOC=no ;;
 459                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 460         esac],
 461         [HAVE_MONODOC=yes])
 462
 463 if test "x$HAVE_MONO" = "xyes" ; then
 464         AC_PATH_PROG(MCS, mcs)
 465         if test "x$MCS" = "x" ; then
 466                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 467         fi
 468
 469         AC_PATH_PROG(GACUTIL, gacutil)
 470         if test "x$GACUTIL" = "x" ; then
 471                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 472         fi
 473
 474         AC_SUBST(MCS)
 475         AC_SUBST(GACUTIL)
 476 fi
 477 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 478
 479 #
 480 # Check for monodoc stuff
 481 #
 482 if test "x$HAVE_MONODOC" = "xyes" ; then
 483         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 484         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 485
 486         AC_PATH_PROG(MONODOCER, monodocer)
 487         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 488
 489         AC_SUBST(MONODOC_DIR)
 490         AC_SUBST(MONODOCER)
 491         AC_SUBST(MDASSEMBLER)
 492 fi
 493 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 494
 495 #
 496 # Defining Avahi User and Group.
 497 #
 498 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 499 if test -z "$with_avahi_user" ; then
 500     AVAHI_USER=avahi
 501 else
 502     AVAHI_USER=$with_avahi_user
 503 fi
 504 AC_SUBST(AVAHI_USER)
 505 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 506
 507 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 508 if test -z "$with_avahi_group" ; then
 509     AVAHI_GROUP=avahi
 510 else
 511     AVAHI_GROUP=$with_avahi_group
 512 fi
 513 AC_SUBST(AVAHI_GROUP)
 514 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 515
 516 #
 517 # Avahi runtime dir
 518 #
 519 avahi_runtime_dir="${localstatedir}/run"
 520 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 521 AC_SUBST(avahi_runtime_dir)
 522 AC_SUBST(avahi_socket)
 523
 524
 525 #
 526 # Avahi interfaces dir
 527 #
 528 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 529         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 530         AC_SUBST(interfacesdir)
 531 fi
 532
 533
 534 #
 535 # Doxygen
 536 #
 537 DX_HTML_FEATURE(ON)
 538 DX_CHM_FEATURE(OFF)
 539 DX_CHI_FEATURE(OFF)
 540 DX_MAN_FEATURE(OFF)
 541 DX_RTF_FEATURE(OFF)
 542 DX_XML_FEATURE(OFF)
 543 DX_PDF_FEATURE(OFF)
 544 DX_PS_FEATURE(OFF)
 545 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 546
 547 #
 548 # XMLTOMAN manpage generation
 549 #
 550 AC_ARG_ENABLE(xmltoman,
 551         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 552 [case "${enableval}" in
 553   yes) xmltoman=yes ;;
 554   no)  xmltoman=no ;;
 555   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 556 esac],[xmltoman=yes])
 557
 558 if test x$xmltoman = xyes ; then
 559     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 560
 561     if test x$have_xmltoman = xno ; then
 562         if ! test -e man/avahi-daemon.8 ; then
 563             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 564             exit 1
 565         fi
 566         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 567         xmltoman=no
 568     fi
 569 fi
 570
 571 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 572
 573 # ==========================================================================
 574 AC_CONFIG_FILES([
 575 Makefile
 576 avahi-common/Makefile
 577 avahi-core/Makefile
 578 avahi-glib/Makefile
 579 avahi-qt/Makefile
 580 avahi-daemon/Makefile
 581 avahi-daemon/avahi-dbus.conf
 582 avahi-discover-standalone/Makefile
 583 avahi-client/Makefile
 584 initscript/Makefile
 585 initscript/debian/Makefile
 586 initscript/gentoo/Makefile
 587 initscript/archlinux/Makefile
 588 initscript/suse/Makefile
 589 avahi-dnsconfd/Makefile
 590 avahi-utils/Makefile
 591 avahi-utils/avahi/Makefile
 592 examples/Makefile
 593 common/Makefile
 594 man/Makefile
 595 tests/Makefile
 596 service-type-database/Makefile
 597 avahi-sharp/Makefile
 598 avahi-compat-libdns_sd/Makefile
 599 ])
 600 AC_OUTPUT
 601
 602 # ==========================================================================
 603 echo "
 604  ---{ $PACKAGE_NAME $VERSION }---
 605
 606     prefix:                 ${prefix}
 607     sysconfdir:             ${sysconfdir}
 608     localstatedir:          ${localstatedir}
 609     avahi socket:           ${avahi_socket}
 610     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 611     dbus-1 version:         `pkg-config dbus-1 --modversion`
 612     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 613     compiler:               ${CC}
 614     cflags:                 ${CFLAGS}
 615     Enable GLIB:            ${HAVE_GLIB}
 616     Enable GTK:             ${HAVE_GTK}
 617     Enable D-BUS:           ${HAVE_DBUS}
 618     Enable Expat:           ${HAVE_EXPAT}
 619     Enable libdaemon:       ${HAVE_LIBDAEMON}
 620     Enable Python:          ${HAVE_PYTHON}
 621     Enable pygtk:           ${HAVE_PYGTK}
 622     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 623     Enable QT3:             ${HAVE_QT3}
 624     Enable QT4:             ${HAVE_QT4}
 625     Enable Mono:            ${HAVE_MONO}
 626     Linux Distro:           ${with_distro}
 627     User for Avahi:         ${AVAHI_USER}
 628     Group for Avahi:        ${AVAHI_GROUP}
 629 "
 630
 631 BUILD_DAEMON="no (!)"
 632
 633 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 634     BUILD_DAEMON=yes
 635 fi
 636
 637 BUILD_UTILS="no (!)"
 638
 639 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 640     BUILD_UTILS=yes
 641 fi
 642
 643 BUILD_CLIENT="no (!)"
 644
 645 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 646     BUILD_CLIENT=yes
 647 fi
 648
 649 echo "
 650     Building libavahi-core              yes
 651     Building avahi-daemon:              ${BUILD_DAEMON}
 652     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 653     Building avahi-utils:               ${BUILD_UTILS}
 654     Building libavahi-glib:             ${HAVE_GLIB}
 655     Building libavahi-client:           ${BUILD_CLIENT}
 656     Building avahi-discover-standalone: ${HAVE_GTK}
 657     Building libavahi-qt3:              ${HAVE_QT3}
 658     Building libavahi-qt4:              ${HAVE_QT4}
 659     Building avahi-sharp:               ${HAVE_MONO}
 660     Building avahi-compat-libdns_sd:    ${BUILD_CLIENT}
 661 "