git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.1],[mzninuv (at) 0pointer (dot) de])
  25 AC_CONFIG_SRCDIR([avahi-core])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_CPP
  39 AC_PROG_INSTALL
  40 AC_PROG_LN_S
  41 AC_PROG_MAKE_SET
  42
  43 # libtool stuff
  44 AC_PROG_LIBTOOL
  45
  46 # Checks for header files.
  47 AC_HEADER_STDC
  48 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
  49
  50 # Checks for typedefs, structures, and compiler characteristics.
  51 AC_C_CONST
  52 AC_TYPE_SIZE_T
  53 AC_HEADER_TIME
  54
  55 # Checks for library functions.
  56 AC_FUNC_MEMCMP
  57 AC_FUNC_SELECT_ARGTYPES
  58 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strerror strrchr strstr uname setresuid setreuid])
  59
  60 AC_FUNC_CHOWN
  61 AC_FUNC_STAT
  62 AC_TYPE_MODE_T
  63 AC_TYPE_PID_T
  64
  65 # Check for GLIB 2.0
  66 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
  67 AC_SUBST(GLIB20_CFLAGS)
  68 AC_SUBST(GLIB20_LIBS)
  69
  70 AC_ARG_ENABLE(gtk,
  71         AC_HELP_STRING([--enable-gtk],[use GTK+ (default=yes)]),
  72         [case "${enableval}" in
  73                 yes) ENABLE_GTK=yes ;;
  74                 no)  ENABLE_GTK=no ;;
  75                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
  76         esac],
  77         [ENABLE_GTK=yes]) dnl Default value
  78
  79 if test "x$ENABLE_GTK" = "xyes"; then
  80         # Check for GTK 2.0
  81         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
  82         AC_SUBST(GTK20_CFLAGS)
  83         AC_SUBST(GTK20_LIBS)
  84
  85         # Check for GLADE 2.0
  86         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
  87         AC_SUBST(GLADE20_CFLAGS)
  88         AC_SUBST(GLADE20_LIBS)
  89
  90         DATADIRNAME=share
  91         if test "x${prefix}" = "xNONE"; then
  92            AC_DEFINE_UNQUOTED(INTERFACES_DIR, "${ac_default_prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/", [path where glade files will be installed])
  93            interfacesdir="${ac_default_prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/"
  94            AC_SUBST(interfacesdir)
  95         else
  96            AC_DEFINE_UNQUOTED(INTERFACES_DIR, "${prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/", [path where glade files will be installed])
  97            interfacesdir="${prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/"
  98            AC_SUBST(interfacesdir)
  99         fi
 100
 101 fi
 102 AM_CONDITIONAL(ENABLE_GTK, test "x$ENABLE_GTK" = "xyes")
 103
 104 AC_ARG_ENABLE(doxygen,
 105         AC_HELP_STRING([--enable-doxygen],[use doxygen to generate API docs (default=yes)]),
 106         [case "${enableval}" in
 107                 yes) ENABLE_DOXYGEN=yes ;;
 108                 no)  ENABLE_DOXYGEN=no ;;
 109                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 110         esac],
 111         [ENABLE_DOXYGEN=yes]) dnl Default value
 112
 113 AM_CONDITIONAL(ENABLE_DOXYGEN, test "x$ENABLE_DOXYGEN" = "xyes")
 114
 115 AC_ARG_ENABLE(dbus,
 116         AC_HELP_STRING([--enable-dbus],[use DBus (default=yes)]),
 117         [case "${enableval}" in
 118                 yes) ENABLE_DBUS=yes ;;
 119                 no)  ENABLE_DBUS=no ;;
 120                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 121         esac],
 122         [ENABLE_DBUS=yes]) dnl Default value
 123
 124
 125 if test "x$ENABLE_DBUS" = "xyes"; then
 126         AC_DEFINE(ENABLE_DBUS, 1, [Whether to use DBUS or not])
 127         PKG_CHECK_MODULES(DBUS, [ dbus-glib-1 >= 0.23])
 128
 129         AC_ARG_WITH(dbus-sys, [  --with-dbus-sys=<dir>   where D-BUS system.d directory is])
 130
 131         if ! test -z "$with_dbus_sys" ; then
 132            DBUS_SYS_DIR="$with_dbus_sys"
 133         else
 134            DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 135         fi
 136         AC_SUBST(DBUS_SYS_DIR)
 137         AC_DEFINE_UNQUOTED(DBUS_SYSTEMD_DIR, "$DBUS_SYS_DIR", [Where system.d dir for DBUS is])
 138
 139         if pkg-config dbus-1 --atleast-version=0.30 ; then
 140            AC_DEFINE(DBUS_USE_NEW_API, 1, [Whether to use the new API for DBUS 0.30])
 141         fi
 142
 143         AC_SUBST(DBUS_CFLAGS)
 144         AC_SUBST(DBUS_LIBS)
 145 fi
 146
 147 AM_CONDITIONAL(ENABLE_DBUS, test "x$ENABLE_DBUS" = "xyes")
 148
 149 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 150
 151 if ! $have_expat ; then
 152    AC_MSG_ERROR([*** libexpat not found ***])
 153 fi
 154
 155 PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 156 AC_SUBST(LIBDAEMON_CFLAGS)
 157 AC_SUBST(LIBDAEMON_LIBS)
 158
 159 # If using GCC specify some additional parameters
 160 if test "x$GCC" = "xyes" ; then
 161    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
 162
 163    AC_LANG_CONFTEST([int main() {}])
 164    $CC -c conftest.c -std=c99 -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=c99 -Wno-unused-parameter"
 165    rm -f conftest.o
 166 fi
 167
 168 #
 169 # Detecting the linux distro for specific things like initscripts.
 170 #
 171 AC_ARG_WITH(distro, AC_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, suse, gentoo, debian, or slackware]))
 172 if test "z$with_distro" = "z"; then
 173    AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
 174    AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 175    AC_CHECK_FILE(/etc/fedora-release,with_distro="redhat")
 176    AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 177    AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 178    AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 179 fi
 180 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 181
 182 if test "z$with_distro" = "z"; then
 183    echo "Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO"
 184    exit 1
 185 else
 186 case $with_distro in
 187    debian)
 188      ;;
 189    *)
 190      echo "Your distribution (${with_distro}) is not yet supported!  (patches welcome)"
 191      exit 1
 192      ;;
 193 esac
 194
 195 fi
 196 AM_CONDITIONAL(TARGET_REDHAT, test x"$with_distro" = xredhat)
 197 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 198 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 199 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 200 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 201
 202 #
 203 # Defining Avahi User and Group.
 204 #
 205 AC_ARG_WITH(avahi_user,[  --with-avahi-user=<user>  User for running the Avahi daemon (avahi)])
 206 if test -z "$with_avahi_user" ; then
 207     AVAHI_USER=avahi
 208 else
 209     AVAHI_USER=$with_avahi_user
 210 fi
 211 AC_SUBST(AVAHI_USER)
 212 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 213
 214 AC_ARG_WITH(avahi_group,[  --with-avahi-group=<grp>  Group for Avahi (avahi)])
 215 if test -z "$with_avahi_group" ; then
 216     AVAHI_GROUP=avahi
 217 else
 218     AVAHI_GROUP=$with_avahi_group
 219 fi
 220 AC_SUBST(AVAHI_GROUP)
 221 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 222
 223 AC_CONFIG_FILES([
 224 Makefile
 225 avahi-core.pc
 226 doxygen/Makefile
 227 doxygen/doxygen.conf
 228 avahi-common/Makefile
 229 avahi-core/Makefile
 230 avahi-daemon/Makefile
 231 avahi-daemon/avahi-dbus.conf
 232 avahi-discover/Makefile
 233 avahi-client/Makefile
 234 initscript/Makefile
 235 initscript/Debian/Makefile
 236 initscript/Debian/15avahi
 237 ])
 238 AC_OUTPUT
 239
 240 dnl ==========================================================================
 241 echo "
 242                    $PACKAGE_NAME $VERSION
 243                   ============
 244
 245         prefix:                   ${prefix}
 246         sysconfdir:               ${sysconfdir}
 247         dbus-1 system.d dir:      ${DBUS_SYS_DIR}
 248         dbus-1 version:           `pkg-config dbus-1 --modversion`
 249         compiler:                 ${CC}
 250         cflags:                   ${CFLAGS}
 251         Linux Distro:             ${with_distro}
 252         User for Avahi:           ${AVAHI_USER}
 253         Group for Avahi:          ${AVAHI_GROUP}
 254 "
 255
 256 echo "NOTE: Remember to create user ${AVAHI_USER} and group ${AVAHI_GROUP} before make install"
 257 echo