git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.4],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [1:0:1])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [0:2:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [1:0:0])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37
  38 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  39     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  40     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  41 fi
  42
  43 # Checks for programs.
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AC_GNU_SOURCE
  47 AC_PROG_CPP
  48 AC_PROG_INSTALL
  49 AC_PROG_LN_S
  50 AC_PROG_MAKE_SET
  51 AC_PROG_GCC_TRADITIONAL
  52
  53 # libtool stuff
  54 AC_PROG_LIBTOOL
  55
  56 #
  57 # Detecting the linux distribution for specific things like init scripts.
  58 #
  59 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
  60 if test "z$with_distro" = "z"; then
  61     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  62     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  63     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
  64     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  65 fi
  66 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
  67
  68 if test "z$with_distro" = "z"; then
  69     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
  70     exit 1
  71 else
  72 case $with_distro in
  73     debian|gentoo|archlinux|suse|none)
  74      ;;
  75     *)
  76      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
  77      ;;
  78 esac
  79 fi
  80
  81 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
  82 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
  83 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
  84 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
  85
  86 test_gcc_flag() {
  87     AC_LANG_CONFTEST([int main() {}])
  88     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  89     ret=$?
  90     rm -f conftest.o
  91     return $ret
  92 }
  93
  94 # If using GCC specify some additional parameters
  95 if test "x$GCC" = "xyes" ; then
  96
  97     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  98
  99     # Test whether rtnetlink.h can be included when compiled with -std=c99
 100     # some distributions (e.g. archlinux) have broken headers that dont
 101     # define __u64 with -std=c99
 102     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 103     OLDCFLAGS="$CFLAGS"
 104     CFLAGS="-std=c99"
 105     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 106         use_stdc99=yes, use_stdc99=no)
 107
 108     if test x"$use_stdc99" = xyes; then
 109         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 110         AC_MSG_RESULT([yes])
 111     else
 112         AC_MSG_RESULT([no])
 113     fi
 114
 115     CFLAGS="$OLDCFLAGS"
 116
 117     for flag in $DESIRED_FLAGS ; do
 118         AC_MSG_CHECKING([whether $CC accepts $flag])
 119         if test_gcc_flag $flag ; then
 120            CFLAGS="$CFLAGS $flag"
 121            AC_MSG_RESULT([yes])
 122         else
 123            AC_MSG_RESULT([no])
 124         fi
 125     done
 126 fi
 127
 128 # Checks for header files.
 129 AC_HEADER_STDC
 130 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
 131
 132 # Checks for typedefs, structures, and compiler characteristics.
 133 AC_C_CONST
 134 AC_TYPE_SIZE_T
 135 AC_HEADER_TIME
 136 AC_HEADER_SYS_WAIT
 137
 138 # Checks for library functions.
 139 AC_FUNC_MEMCMP
 140 AC_FUNC_SELECT_ARGTYPES
 141 AC_FUNC_MALLOC
 142 AC_FUNC_REALLOC
 143 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp])
 144
 145 AC_FUNC_CHOWN
 146 AC_FUNC_STAT
 147 AC_TYPE_MODE_T
 148 AC_TYPE_PID_T
 149
 150 # Check for pkg-config manually first, as if its not installed the
 151 # PKG_PROG_PKG_CONFIG macro won't be defined.
 152 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 153
 154 if test x"$have_pkg_config" == xno; then
 155     AC_MSG_ERROR(pkg-config is required to install this program)
 156 fi
 157
 158 PKG_PROG_PKG_CONFIG
 159
 160 #
 161 # Check for GLIB 2.0
 162 #
 163 AC_ARG_ENABLE(glib,
 164         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 165         [case "${enableval}" in
 166                 yes) HAVE_GLIB=yes ;;
 167                 no)  HAVE_GLIB=no ;;
 168                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 169         esac],
 170         [HAVE_GLIB=yes])
 171
 172 if test "x$HAVE_GLIB" = "xyes" ; then
 173         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 174         AC_SUBST(GLIB20_CFLAGS)
 175         AC_SUBST(GLIB20_LIBS)
 176 fi
 177 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 178
 179 #
 180 # Check for Qt 3
 181 #
 182 AC_ARG_ENABLE(qt3,
 183         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 184         [case "${enableval}" in
 185                 yes) HAVE_QT3=yes ;;
 186                 no)  HAVE_QT3=no ;;
 187                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 188         esac],
 189         [HAVE_QT3=yes])
 190
 191 if test "x$HAVE_QT3" = "xyes" ; then
 192         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 193         AC_SUBST(QT3_CFLAGS)
 194         AC_SUBST(QT3_LIBS)
 195             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 196         MOC_QT3="no"
 197             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 198                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 199                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 200         AC_SUBST(MOC_QT3)
 201 fi
 202 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 203
 204 #
 205 # Check for Qt 4
 206 #
 207 AC_ARG_ENABLE(qt4,
 208         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 209         [case "${enableval}" in
 210                 yes) HAVE_QT4=yes ;;
 211                 no)  HAVE_QT4=no ;;
 212                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 213         esac],
 214         [HAVE_QT4=yes])
 215
 216 if test "x$HAVE_QT4" = "xyes" ; then
 217         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 218         AC_SUBST(QT4_CFLAGS)
 219         AC_SUBST(QT4_LIBS)
 220             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 221         MOC_QT4="no"
 222             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 223                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 224                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 225         AC_SUBST(MOC_QT4)
 226 fi
 227 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 228
 229 #
 230 # Check for GTK+
 231 #
 232 AC_ARG_ENABLE(gtk,
 233         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 234         [case "${enableval}" in
 235                 yes) HAVE_GTK=yes ;;
 236                 no)  HAVE_GTK=no ;;
 237                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 238         esac],
 239         [HAVE_GTK=yes])
 240
 241 if test "x$HAVE_GTK" = "xyes" ; then
 242         # Check for GTK 2.0
 243         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 244         AC_SUBST(GTK20_CFLAGS)
 245         AC_SUBST(GTK20_LIBS)
 246
 247         # Check for GLADE 2.0
 248         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 249         AC_SUBST(GLADE20_CFLAGS)
 250         AC_SUBST(GLADE20_LIBS)
 251 fi
 252 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 253
 254 #
 255 # D-BUS
 256 #
 257 AC_ARG_ENABLE(dbus,
 258         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 259         [case "${enableval}" in
 260                 yes) HAVE_DBUS=yes ;;
 261                 no)  HAVE_DBUS=no ;;
 262                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 263         esac],
 264         [HAVE_DBUS=yes])
 265
 266 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 267 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 268
 269 if test "x$HAVE_DBUS" = "xyes" ; then
 270     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 271
 272     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 273     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 274     AC_SUBST(DBUS_CFLAGS)
 275     AC_SUBST(DBUS_LIBS)
 276
 277     if ! test -z "$with_dbus_sys" ; then
 278         DBUS_SYS_DIR="$with_dbus_sys"
 279     else
 280         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 281     fi
 282     AC_SUBST(DBUS_SYS_DIR)
 283
 284     if ! test -z "$with_dbus_system_address" ; then
 285         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 286     else
 287         # Note this default path is hardcoded in D-BUS and should
 288         # not use $localstatedir
 289         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 290     fi
 291     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 292
 293 fi
 294 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 295
 296 #
 297 # Expat
 298 #
 299 AC_ARG_ENABLE(expat,
 300         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 301         [case "${enableval}" in
 302                 yes) HAVE_EXPAT=yes ;;
 303                 no)  HAVE_EXPAT=no ;;
 304                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 305         esac],
 306         [HAVE_EXPAT=yes])
 307
 308 if test "x$HAVE_EXPAT" = "xyes" ; then
 309     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 310
 311     if ! $have_expat ; then
 312         AC_MSG_ERROR([*** libexpat not found ***])
 313     fi
 314 fi
 315 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 316
 317 #
 318 # libdaemon
 319 #
 320 AC_ARG_ENABLE(libdaemon,
 321         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 322         [case "${enableval}" in
 323                 yes) HAVE_LIBDAEMON=yes ;;
 324                 no)  HAVE_LIBDAEMON=no ;;
 325                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 326         esac],
 327         [HAVE_LIBDAEMON=yes])
 328
 329 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 330     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 331     AC_SUBST(LIBDAEMON_CFLAGS)
 332     AC_SUBST(LIBDAEMON_LIBS)
 333 fi
 334 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 335
 336 #
 337 # Python stuff
 338 #
 339 AC_ARG_ENABLE(python,
 340     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 341     [case "${enableval}" in
 342           yes) HAVE_PYTHON=yes ;;
 343           no)  HAVE_PYTHON=no ;;
 344           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 345     esac],[HAVE_PYTHON=yes])
 346
 347 HAVE_PYTHON_DBUS=no
 348 HAVE_PYGTK=no
 349
 350 if test "x$HAVE_PYTHON" = "xyes" ; then
 351     AM_PATH_PYTHON([2.4])
 352
 353     AC_ARG_ENABLE(pygtk,
 354         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 355         [case "${enableval}" in
 356                 yes) HAVE_PYGTK=yes ;;
 357                 no)  HAVE_PYGTK=no ;;
 358                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 359         esac],
 360         [HAVE_PYGTK=yes])
 361
 362     if test "x$HAVE_PYGTK" = "xyes" ; then
 363         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 364     fi
 365
 366
 367     AC_ARG_ENABLE(python-dbus,
 368         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 369         [case "${enableval}" in
 370                 yes) HAVE_PYTHON_DBUS=yes ;;
 371                 no)  HAVE_PYTHON_DBUS=no ;;
 372                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 373         esac],
 374         [HAVE_PYTHON_DBUS=yes])
 375
 376     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 377         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 378     fi
 379
 380     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 381     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 382 fi
 383 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 384 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 385 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 386
 387 #
 388 # Defining Avahi User and Group.
 389 #
 390 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 391 if test -z "$with_avahi_user" ; then
 392     AVAHI_USER=avahi
 393 else
 394     AVAHI_USER=$with_avahi_user
 395 fi
 396 AC_SUBST(AVAHI_USER)
 397 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 398
 399 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 400 if test -z "$with_avahi_group" ; then
 401     AVAHI_GROUP=avahi
 402 else
 403     AVAHI_GROUP=$with_avahi_group
 404 fi
 405 AC_SUBST(AVAHI_GROUP)
 406 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 407
 408 #
 409 # Avahi runtime dir
 410 #
 411 avahi_runtime_dir="${localstatedir}/run"
 412 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 413 AC_SUBST(avahi_runtime_dir)
 414 AC_SUBST(avahi_socket)
 415
 416
 417 #
 418 # Doxygen
 419 #
 420 DX_HTML_FEATURE(ON)
 421 DX_CHM_FEATURE(OFF)
 422 DX_CHI_FEATURE(OFF)
 423 DX_MAN_FEATURE(OFF)
 424 DX_RTF_FEATURE(OFF)
 425 DX_XML_FEATURE(OFF)
 426 DX_PDF_FEATURE(OFF)
 427 DX_PS_FEATURE(OFF)
 428 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 429
 430 #
 431 # XMLTOMAN manpage generation
 432 #
 433 AC_ARG_ENABLE(xmltoman,
 434         AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 435 [case "${enableval}" in
 436   yes) xmltoman=yes ;;
 437   no)  xmltoman=no ;;
 438   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 439 esac],[xmltoman=yes])
 440
 441 if test x$xmltoman = xyes ; then
 442     AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 443
 444     if test x$have_xmltoman = xno ; then
 445         if ! test -e man/avahi-daemon.8 ; then
 446             AC_MSG_ERROR([*** xmltoman was not found, it is required to build the manpages and they have not been pre-built])
 447             exit 1
 448         fi
 449         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 450         xmltoman=no
 451     fi
 452 fi
 453
 454 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 455
 456 # ==========================================================================
 457 AC_CONFIG_FILES([
 458 Makefile
 459 avahi-common/Makefile
 460 avahi-core/Makefile
 461 avahi-glib/Makefile
 462 avahi-qt/Makefile
 463 avahi-daemon/Makefile
 464 avahi-daemon/avahi-dbus.conf
 465 avahi-discover-standalone/Makefile
 466 avahi-client/Makefile
 467 initscript/Makefile
 468 initscript/debian/Makefile
 469 initscript/gentoo/Makefile
 470 initscript/archlinux/Makefile
 471 initscript/suse/Makefile
 472 avahi-dnsconfd/Makefile
 473 avahi-utils/Makefile
 474 avahi-utils/avahi/Makefile
 475 examples/Makefile
 476 common/Makefile
 477 man/Makefile
 478 tests/Makefile
 479 service-type-database/Makefile
 480 ])
 481 AC_OUTPUT
 482
 483 # ==========================================================================
 484 echo "
 485  ---{ $PACKAGE_NAME $VERSION }---
 486
 487     prefix:                 ${prefix}
 488     sysconfdir:             ${sysconfdir}
 489     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 490     dbus-1 version:         `pkg-config dbus-1 --modversion`
 491     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 492     compiler:               ${CC}
 493     cflags:                 ${CFLAGS}
 494     Enable GLIB:            ${HAVE_GLIB}
 495     Enable GTK:             ${HAVE_GTK}
 496     Enable D-BUS:           ${HAVE_DBUS}
 497     Enable Expat:           ${HAVE_EXPAT}
 498     Enable libdaemon:       ${HAVE_LIBDAEMON}
 499     Enable Python:          ${HAVE_PYTHON}
 500     Enable pygtk:           ${HAVE_PYGTK}
 501     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 502     Enable QT3:             ${HAVE_QT3}
 503     Enable QT4:             ${HAVE_QT4}
 504     Linux Distro:           ${with_distro}
 505     User for Avahi:         ${AVAHI_USER}
 506     Group for Avahi:        ${AVAHI_GROUP}
 507 "
 508
 509 BUILD_DAEMON="no (!)"
 510
 511 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 512     BUILD_DAEMON=yes
 513 fi
 514
 515 BUILD_UTILS="no (!)"
 516
 517 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 518     BUILD_UTILS=yes
 519 fi
 520
 521 BUILD_CLIENT="no (!)"
 522
 523 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 524     BUILD_CLIENT=yes
 525 fi
 526
 527 echo "
 528     Building libavahi-core              yes
 529     Building avahi-daemon:              ${BUILD_DAEMON}
 530     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 531     Building avahi-utils:               ${BUILD_UTILS}
 532     Building libavahi-glib:             ${HAVE_GLIB}
 533     Building libavahi-client:           ${BUILD_CLIENT}
 534     Building avahi-discover-standalone: ${HAVE_GTK}
 535     Building libavahi-qt3:              ${HAVE_QT3}
 536     Building libavahi-qt4:              ${HAVE_QT4}
 537 "