git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.1],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_PROG_CPP
  40 AC_PROG_INSTALL
  41 AC_PROG_LN_S
  42 AC_PROG_MAKE_SET
  43 AC_PROG_GCC_TRADITIONAL
  44
  45 # libtool stuff
  46 AC_PROG_LIBTOOL
  47
  48 # Checks for header files.
  49 AC_HEADER_STDC
  50 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_CONST
  54 AC_TYPE_SIZE_T
  55 AC_HEADER_TIME
  56 AC_HEADER_SYS_WAIT
  57
  58 # Checks for library functions.
  59 AC_FUNC_MEMCMP
  60 AC_FUNC_SELECT_ARGTYPES
  61 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid])
  62
  63 AC_FUNC_CHOWN
  64 AC_FUNC_STAT
  65 AC_TYPE_MODE_T
  66 AC_TYPE_PID_T
  67
  68 # Check for GLIB 2.0
  69 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
  70 AC_SUBST(GLIB20_CFLAGS)
  71 AC_SUBST(GLIB20_LIBS)
  72
  73 AC_ARG_ENABLE(gtk,
  74         AS_HELP_STRING(--enable-gtk,use GTK+ (default=yes)),
  75         [case "${enableval}" in
  76                 yes) ENABLE_GTK=yes ;;
  77                 no)  ENABLE_GTK=no ;;
  78                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
  79         esac],
  80         [ENABLE_GTK=yes]) dnl Default value
  81
  82 if test "x$ENABLE_GTK" = "xyes"; then
  83         # Check for GTK 2.0
  84         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
  85         AC_SUBST(GTK20_CFLAGS)
  86         AC_SUBST(GTK20_LIBS)
  87
  88         # Check for GLADE 2.0
  89         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
  90         AC_SUBST(GLADE20_CFLAGS)
  91         AC_SUBST(GLADE20_LIBS)
  92
  93         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
  94         AC_SUBST(interfacesdir)
  95
  96 fi
  97 AM_CONDITIONAL(ENABLE_GTK, test "x$ENABLE_GTK" = "xyes")
  98
  99 #
 100 # Doxygen
 101 #
 102 DX_HTML_FEATURE(ON)
 103 DX_CHM_FEATURE(OFF)
 104 DX_CHI_FEATURE(OFF)
 105 DX_MAN_FEATURE(OFF)
 106 DX_RTF_FEATURE(OFF)
 107 DX_XML_FEATURE(OFF)
 108 DX_PDF_FEATURE(OFF)
 109 DX_PS_FEATURE(OFF)
 110 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 111
 112 #
 113 # XMLTOMAN manpage generation
 114 #
 115 AC_ARG_ENABLE(xmltoman,
 116         AS_HELP_STRING(--disable-xmltoman,Disable rebuilding of man pages with xmltoman),
 117 [case "${enableval}" in
 118   yes) xmltoman=yes ;;
 119   no)  xmltoman=no ;;
 120   *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 121 esac],[xmltoman=yes])
 122
 123 if test x$xmltoman = xyes ; then
 124    AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 125
 126    if test x$have_xmltoman = xno ; then
 127      AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 128      xmltoman=no
 129    fi
 130 fi
 131
 132 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 133
 134 #
 135 # D-BUS
 136 #
 137 AC_ARG_ENABLE(dbus,
 138         AS_HELP_STRING(--enable-dbus,use DBus (default=yes)),
 139         [case "${enableval}" in
 140                 yes) ENABLE_DBUS=yes ;;
 141                 no)  ENABLE_DBUS=no ;;
 142                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 143         esac],
 144         [ENABLE_DBUS=yes]) dnl Default value
 145
 146
 147 if test "x$ENABLE_DBUS" = "xyes"; then
 148         AC_DEFINE(ENABLE_DBUS, 1, [Whether to use DBUS or not])
 149         PKG_CHECK_MODULES(DBUS, [ dbus-glib-1 >= 0.30])
 150
 151         AC_ARG_WITH(dbus-sys, [  --with-dbus-sys=<dir>   where D-BUS system.d directory is])
 152
 153         if ! test -z "$with_dbus_sys" ; then
 154            DBUS_SYS_DIR="$with_dbus_sys"
 155         else
 156            DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 157         fi
 158         AC_SUBST(DBUS_SYS_DIR)
 159
 160         AC_SUBST(DBUS_CFLAGS)
 161         AC_SUBST(DBUS_LIBS)
 162 fi
 163
 164 AM_CONDITIONAL(ENABLE_DBUS, test "x$ENABLE_DBUS" = "xyes")
 165
 166 #
 167 # Expat
 168 #
 169 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 170
 171 if ! $have_expat ; then
 172    AC_MSG_ERROR([*** libexpat not found ***])
 173 fi
 174
 175 #
 176 # LibDaemon
 177 #
 178 PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 179 AC_SUBST(LIBDAEMON_CFLAGS)
 180 AC_SUBST(LIBDAEMON_LIBS)
 181
 182 # If using GCC specify some additional parameters
 183 if test "x$GCC" = "xyes" ; then
 184    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
 185
 186    AC_LANG_CONFTEST([int main() {}])
 187    $CC -c conftest.c -std=c99 -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=c99 -Wno-unused-parameter"
 188    rm -f conftest.o
 189 fi
 190
 191 #
 192 # Detecting the linux distro for specific things like initscripts.
 193 #
 194 AC_ARG_WITH(distro, AS_HELP_STRING(--with-distro=DISTRO,Specify the Linux distribution to target: One of redhat, suse, gentoo, debian, or slackware))
 195 if test "z$with_distro" = "z"; then
 196    AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
 197    AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 198    AC_CHECK_FILE(/etc/fedora-release,with_distro="redhat")
 199    AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 200    AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 201    AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 202 fi
 203 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 204
 205 if test "z$with_distro" = "z"; then
 206    echo "Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO"
 207    exit 1
 208 else
 209 case $with_distro in
 210    debian|gentoo|suse)
 211      ;;
 212    *)
 213      echo "Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome)"
 214      ;;
 215 esac
 216
 217 fi
 218 AM_CONDITIONAL(TARGET_REDHAT, test x"$with_distro" = xredhat)
 219 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 220 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 221 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 222 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 223
 224 #
 225 # Defining Avahi User and Group.
 226 #
 227 AC_ARG_WITH(avahi_user,[  --with-avahi-user=<user>  User for running the Avahi daemon (avahi)])
 228 if test -z "$with_avahi_user" ; then
 229     AVAHI_USER=avahi
 230 else
 231     AVAHI_USER=$with_avahi_user
 232 fi
 233 AC_SUBST(AVAHI_USER)
 234 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 235
 236 AC_ARG_WITH(avahi_group,[  --with-avahi-group=<grp>  Group for Avahi (avahi)])
 237 if test -z "$with_avahi_group" ; then
 238     AVAHI_GROUP=avahi
 239 else
 240     AVAHI_GROUP=$with_avahi_group
 241 fi
 242 AC_SUBST(AVAHI_GROUP)
 243 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 244
 245 #
 246 # Avahi runtime dir
 247 #
 248 avahi_runtime_dir="${localstatedir}/run"
 249 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 250 AC_SUBST(avahi_runtime_dir)
 251 AC_SUBST(avahi_socket)
 252
 253 #
 254 # Python stuff
 255 #
 256 dnl AC_ARG_ENABLE(python,
 257 dnl        AS_HELP_STRING(--disable-python, Disable scripts that depends on python),
 258 dnl [case "${enableval}" in
 259 dnl   yes) use_python=yes ;;
 260 dnl   no)  use_python=no ;;
 261 dnl   *) AC_MSG_ERROR([bad value ${enableval} for --disable-python]) ;;
 262 dnl esac],[use_python=yes])
 263
 264 dnl HAVE_PYTHON=no
 265 dnl if test "x$use_python" = xyes ; then
 266    AM_PATH_PYTHON(2.4, [HAVE_PYTHON=yes], [HAVE_PYTHON=no])
 267
 268    if  test "x$HAVE_PYTHON" = xyes ; then
 269        AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(could not find pygtk module)])
 270        AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(could not find python dbus module)])
 271    fi
 272 dnl fi
 273
 274 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = xyes ])
 275
 276 # ==========================================================================
 277 AC_CONFIG_FILES([
 278 Makefile
 279 avahi-core.pc
 280 avahi-common/Makefile
 281 avahi-core/Makefile
 282 avahi-daemon/Makefile
 283 avahi-daemon/avahi-dbus.conf
 284 avahi-discover-standalone/Makefile
 285 avahi-client/Makefile
 286 initscript/Makefile
 287 initscript/Debian/Makefile
 288 initscript/Gentoo/Makefile
 289 initscript/SUSE/Makefile
 290 avahi-dnsconfd/Makefile
 291 avahi-utils/Makefile
 292 avahi-utils/avahi/Makefile
 293 examples/Makefile
 294 common/Makefile
 295 man/Makefile
 296 ])
 297 AC_OUTPUT
 298
 299 # ==========================================================================
 300 echo "
 301  ---{ $PACKAGE_NAME $VERSION }---
 302
 303     prefix:                 ${prefix}
 304     sysconfdir:             ${sysconfdir}
 305     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 306     dbus-1 version:         `pkg-config dbus-1 --modversion`
 307     compiler:               ${CC}
 308     cflags:                 ${CFLAGS}
 309     Enable Gtk:             ${ENABLE_GTK}
 310     Enable DBUS:            ${ENABLE_DBUS}
 311     Have Python:            ${HAVE_PYTHON}
 312     Linux Distro:           ${with_distro}
 313     User for Avahi:         ${AVAHI_USER}
 314     Group for Avahi:        ${AVAHI_GROUP}
 315
 316  NOTE: Remember to create user ${AVAHI_USER} and group ${AVAHI_GROUP} before make install
 317 "