git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([MeshLink], [0.1])
   5 DX_PS_FEATURE(OFF)
   6 DX_INIT_DOXYGEN([MeshLink], [$(top_srcdir)/Doxyfile])
   7 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AM_SILENT_RULES([yes])
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_GNU_SOURCE
  16 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  17
  18 dnl Checks for programs.
  19 AM_PROG_CC_C_O
  20 AM_PROG_AR
  21 AC_PROG_CC_C99
  22 AC_PROG_CXX
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_LN_S
  26 AC_PROG_LIBTOOL
  27 AX_PTHREAD
  28
  29 dnl Check and set OS
  30
  31 AC_CANONICAL_HOST
  32
  33 case $host_os in
  34   *linux*)
  35     linux=true
  36     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  37   ;;
  38   *mingw*)
  39     mingw=true
  40     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  41     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  42   ;;
  43 esac
  44
  45 AM_CONDITIONAL(LINUX, test "$linux" = true)
  46 AM_CONDITIONAL(MINGW, test "$mingw" = true)
  47
  48 AC_CACHE_SAVE
  49
  50 if test -d /sw/include ; then
  51   CPPFLAGS="$CPPFLAGS -I/sw/include"
  52 fi
  53 if test -d /sw/lib ; then
  54   LIBS="$LIBS -L/sw/lib"
  55 fi
  56
  57 dnl Compiler hardening flags
  58 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
  59
  60 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
  61 AS_IF([test "x$enable_hardening" != "xno"],
  62   [CPPFLAGS="$CPPFLAGS -Wall -W -pedantic"
  63    AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
  64    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
  65      [AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])]
  66    )
  67    case $host_os in
  68      *mingw*)
  69        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
  70        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
  71        ;;
  72      *)
  73        AX_CHECK_COMPILE_FLAG([-fPIC], [CPPFLAGS="$CPPFLAGS -fPIC"])
  74        ;;
  75    esac
  76    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
  77    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
  78   ]
  79 );
  80
  81 dnl Allow building without Catta
  82 AC_ARG_ENABLE([catta], AS_HELP_STRING([--disable-catta], [disable linking with the Catta library]))
  83 AS_IF([test "x$enable_catta" != "xno"],
  84   AC_DEFINE(HAVE_CATTA, 1, [Link with Catta])
  85   AC_CONFIG_SUBDIRS([catta])
  86 )
  87 AM_CONDITIONAL(CATTA, test "x$enable_catta" != "xno")
  88
  89 dnl UTCP debug flags
  90 AC_ARG_ENABLE([utcp_debug], AS_HELP_STRING([--enable-utcp-debug], [compile utcp with debug output]))
  91 AS_IF([test "x$enable_utcp_debug" = "xyes"],
  92   [AX_CHECK_COMPILE_FLAG([-DUTCP_DEBUG], [CPPFLAGS="$CPPFLAGS -DUTCP_DEBUG"])
  93   ]
  94 );
  95
  96 dnl Blackbox test suite
  97 PKG_CHECK_MODULES([CMOCKA], [cmocka >= 1.1.0], [cmocka=true], [cmocka=false])
  98 PKG_CHECK_MODULES([LXC], [lxc >= 2.0.0], [lxc=true], [lxc=false])
  99 AM_CONDITIONAL(BLACKBOX_TESTS, test "$cmocka" = true -a "$lxc" = true)
 100
 101
 102 dnl Additional example code
 103 PKG_CHECK_MODULES([NCURSES], [ncurses >= 5], [curses=true], [curses=false])
 104 AC_ARG_ENABLE([monitor_code],
 105         [AS_HELP_STRING([--enable-monitor-code], [Add monitor example code to the build])],
 106   [AS_IF([test "x$enable_monitor_code" = "xyes"], [monitor_code=true], [monitor_code=false])],
 107   [monitor_code=false]
 108 )
 109 AM_CONDITIONAL(MONITOR, test "$monitor_code" = true)
 110
 111 dnl Install test binaries
 112 AC_ARG_ENABLE([install_tests],
 113   [AS_HELP_STRING([--enable-install-tests], [include test binaries in installation])],
 114   [AS_IF([test "x$enable_install_tests" = "xyes"], [install_tests=true], [install_tests=false])],
 115   [install_tests=false]
 116 )
 117
 118 AM_CONDITIONAL(INSTALL_TESTS, test "$install_tests" = true)
 119
 120 dnl Checks for header files.
 121 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 122
 123 AC_CHECK_HEADERS([syslog.h sys/file.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h curses.h ifaddrs.h])
 124
 125 dnl Checks for typedefs, structures, and compiler characteristics.
 126 MeshLink_ATTRIBUTE(__malloc__)
 127 MeshLink_ATTRIBUTE(__warn_unused_result__)
 128
 129 dnl Checks for library functions.
 130 AC_TYPE_SIGNAL
 131 AC_CHECK_FUNCS([asprintf fchmod fork gettimeofday random pselect select setns strdup usleep getifaddrs freeifaddrs],
 132   [], [], [#include "$srcdir/src/have.h"]
 133 )
 134
 135 dnl Support for SunOS
 136
 137 AC_CHECK_FUNC(socket, [], [
 138   AC_CHECK_LIB(socket, connect)
 139 ])
 140
 141 AC_CACHE_SAVE
 142
 143 AC_CONFIG_FILES([
 144          Makefile
 145          src/Makefile
 146          test/Makefile
 147          test/blackbox/Makefile
 148          test/blackbox/run_blackbox_tests/Makefile
 149          test/blackbox/test_case_channel_conn_01/Makefile
 150          test/blackbox/test_case_channel_conn_02/Makefile
 151          test/blackbox/test_case_channel_conn_03/Makefile
 152          test/blackbox/test_case_channel_conn_04/Makefile
 153          test/blackbox/test_case_channel_conn_05/Makefile
 154          test/blackbox/test_case_channel_conn_06/Makefile
 155          test/blackbox/test_case_channel_conn_07/Makefile
 156          test/blackbox/test_case_channel_conn_08/Makefile
 157          test/blackbox/test_case_meta_conn_01/Makefile
 158          test/blackbox/test_case_meta_conn_02/Makefile
 159          test/blackbox/test_case_meta_conn_03/Makefile
 160          test/blackbox/test_case_meta_conn_04/Makefile
 161          test/blackbox/test_case_meta_conn_05/Makefile
 162          test/blackbox/test_cases_submesh01/Makefile
 163          test/blackbox/test_cases_submesh02/Makefile
 164          test/blackbox/test_cases_submesh03/Makefile
 165          test/blackbox/test_cases_submesh04/Makefile
 166          examples/Makefile
 167 ])
 168
 169 AC_OUTPUT