git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([MeshLink], [0.1])
   5 AC_CONFIG_SRCDIR([src/libmeshlink.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([check-news std-options subdir-objects -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21 AC_PROG_LIBTOOL
  22
  23 AM_PROG_CC_C_O
  24
  25 dnl Check and set OS
  26
  27 AC_CANONICAL_HOST
  28
  29 case $host_os in
  30   *linux*)
  31     linux=true
  32     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  33   ;;
  34   *freebsd*)
  35     bsd=true
  36     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  37   ;;
  38   *darwin*)
  39     bsd=true
  40     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  41   ;;
  42   *solaris*)
  43     solaris=true
  44     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  45   ;;
  46   *openbsd*)
  47     bsd=true
  48     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  49   ;;
  50   *netbsd*)
  51     bsd=true
  52     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  53   ;;
  54   *dragonfly*)
  55     bsd=true
  56     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  57   ;;
  58   *bsd*)
  59     bsd=true
  60     AC_MSG_WARN("Unknown BSD variant, MeshLink might not compile or work!")
  61     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  62   ;;
  63   *cygwin*)
  64     cygwin=true
  65     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  71   ;;
  72   *)
  73     AC_MSG_ERROR("Unknown operating system.")
  74   ;;
  75 esac
  76
  77 AC_ARG_WITH(windows2000,
  78   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
  79   [ AS_IF([test "x$with_windows2000" = "xyes"],
  80       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
  81   ]
  82 )
  83
  84 AM_CONDITIONAL(LINUX, test "$linux" = true)
  85 AM_CONDITIONAL(BSD, test "$bsd" = true)
  86 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
  87 AM_CONDITIONAL(MINGW, test "$mingw" = true)
  88 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
  89 AM_CONDITIONAL(UML, test "$uml" = true)
  90 AM_CONDITIONAL(VDE, test "$vde" = true)
  91 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
  92
  93 AC_CACHE_SAVE
  94
  95 if test -d /sw/include ; then
  96   CPPFLAGS="$CPPFLAGS -I/sw/include"
  97 fi
  98 if test -d /sw/lib ; then
  99   LIBS="$LIBS -L/sw/lib"
 100 fi
 101
 102 dnl Compiler hardening flags
 103 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 104
 105 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 106 AS_IF([test "x$enable_hardening" != "xno"],
 107   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
 108    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
 109    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
 110    case $host_os in
 111      *mingw*)
 112        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 113        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 114        ;;
 115      *)
 116        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 117        AX_CHECK_COMPILE_FLAG([-fPIC], [CPPFLAGS="$CPPFLAGS -fPIC"])
 118        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 119        ;;
 120    esac
 121    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 122    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 123   ]
 124 );
 125
 126 dnl Checks for header files.
 127 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 128
 129 AC_HEADER_STDC
 130 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 131 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 132   [], [], [#include "src/have.h"]
 133 )
 134 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 135   [], [], [#include "src/have.h"]
 136 )
 137 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 138   [], [], [#include "src/have.h"]
 139 )
 140
 141 dnl Checks for typedefs, structures, and compiler characteristics.
 142 AC_C_CONST
 143 AC_C_VOLATILE
 144 AC_TYPE_PID_T
 145 AC_TYPE_SIZE_T
 146 AC_HEADER_TIME
 147 AC_STRUCT_TM
 148
 149 MeshLink_ATTRIBUTE(__malloc__)
 150 MeshLink_ATTRIBUTE(__warn_unused_result__)
 151
 152 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 153   [#include "src/have.h"]
 154 )
 155
 156 dnl Checks for library functions.
 157 AC_TYPE_SIGNAL
 158 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 159   [], [], [#include "src/have.h"]
 160 )
 161
 162 dnl Support for SunOS
 163
 164 AC_CHECK_FUNC(socket, [], [
 165   AC_CHECK_LIB(socket, connect)
 166 ])
 167 AC_CHECK_FUNC(gethostbyname, [], [
 168   AC_CHECK_LIB(nsl, gethostbyname)
 169 ])
 170
 171 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 172   [], [], [#include "src/have.h"]
 173 )
 174
 175 AC_CACHE_SAVE
 176
 177 dnl These are defined in files in m4/
 178
 179 MeshLink_ZLIB
 180
 181 MeshLink_OPENSSL
 182
 183 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile test/Makefile])
 184
 185 AC_OUTPUT