git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.1pre9])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([check-news std-options subdir-objects -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21 AC_PROG_RANLIB
  22
  23 AM_PROG_CC_C_O
  24
  25 dnl Check and set OS
  26
  27 AC_CANONICAL_HOST
  28
  29 case $host_os in
  30   *linux*)
  31     linux=true
  32     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  33   ;;
  34   *freebsd*)
  35     bsd=true
  36     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  37   ;;
  38   *darwin*)
  39     bsd=true
  40     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  41   ;;
  42   *solaris*)
  43     solaris=true
  44     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  45   ;;
  46   *openbsd*)
  47     bsd=true
  48     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  49   ;;
  50   *netbsd*)
  51     bsd=true
  52     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  53   ;;
  54   *dragonfly*)
  55     bsd=true
  56     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  57   ;;
  58   *bsd*)
  59     bsd=true
  60     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  61     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  62   ;;
  63   *cygwin*)
  64     cygwin=true
  65     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  71   ;;
  72   *)
  73     AC_MSG_ERROR("Unknown operating system.")
  74   ;;
  75 esac
  76
  77 AC_ARG_ENABLE(uml,
  78   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  79   [ AS_IF([test "x$enable_uml" = "xyes"],
  80       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  81         uml=true
  82       ],
  83       [uml=false])
  84   ],
  85   [uml=false]
  86 )
  87
  88 AC_ARG_ENABLE(vde,
  89   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  90   [ AS_IF([test "x$enable_vde" = "xyes"],
  91       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  92         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  93         vde=true
  94       ],
  95       [vde=false])
  96   ],
  97   [vde=false]
  98 )
  99
 100 AC_ARG_ENABLE(tunemu,
 101   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 102   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 103       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 104         tunemu=true
 105       ],
 106       [tunemu=false])
 107   ],
 108   [tunemu=false]
 109 )
 110
 111 AC_ARG_WITH(windows2000,
 112   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 113   [ AS_IF([test "x$with_windows2000" = "xyes"],
 114       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 115   ]
 116 )
 117
 118 AM_CONDITIONAL(LINUX, test "$linux" = true)
 119 AM_CONDITIONAL(BSD, test "$bsd" = true)
 120 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 121 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 122 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 123 AM_CONDITIONAL(UML, test "$uml" = true)
 124 AM_CONDITIONAL(VDE, test "$vde" = true)
 125 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 126
 127 AC_CACHE_SAVE
 128
 129 if test -d /sw/include ; then
 130   CPPFLAGS="$CPPFLAGS -I/sw/include"
 131 fi
 132 if test -d /sw/lib ; then
 133   LIBS="$LIBS -L/sw/lib"
 134 fi
 135
 136 dnl Compiler hardening flags
 137 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 138
 139 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 140 AS_IF([test "x$enable_hardening" != "xno"],
 141   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
 142    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
 143    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
 144    case $host_os in
 145      *mingw*)
 146        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 147        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 148        ;;
 149      *)
 150        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 151        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 152        ;;
 153    esac
 154    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 155    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 156   ]
 157 );
 158
 159 dnl Checks for header files.
 160 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 161
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 164 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 165   [], [], [#include "src/have.h"]
 166 )
 167 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 168   [], [], [#include "src/have.h"]
 169 )
 170 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 171   [], [], [#include "src/have.h"]
 172 )
 173
 174 dnl Checks for typedefs, structures, and compiler characteristics.
 175 AC_C_CONST
 176 AC_C_VOLATILE
 177 AC_TYPE_PID_T
 178 AC_TYPE_SIZE_T
 179 AC_HEADER_TIME
 180 AC_STRUCT_TM
 181
 182 tinc_ATTRIBUTE(__malloc__)
 183 tinc_ATTRIBUTE(__warn_unused_result__)
 184
 185 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 186   [#include "src/have.h"]
 187 )
 188
 189 dnl Checks for library functions.
 190 AC_TYPE_SIGNAL
 191 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 192   [], [], [#include "src/have.h"]
 193 )
 194
 195 dnl Support for SunOS
 196
 197 AC_CHECK_FUNC(socket, [], [
 198   AC_CHECK_LIB(socket, connect)
 199 ])
 200 AC_CHECK_FUNC(gethostbyname, [], [
 201   AC_CHECK_LIB(nsl, gethostbyname)
 202 ])
 203
 204 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 205   [], [], [#include "src/have.h"]
 206 )
 207
 208 AC_CACHE_SAVE
 209
 210 dnl These are defined in files in m4/
 211
 212 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 213
 214 tinc_CURSES
 215 tinc_READLINE
 216 tinc_ZLIB
 217 tinc_LZO
 218
 219 if test -n "$with_libgcrypt"; then
 220         gcrypt=true
 221         tinc_LIBGCRYPT
 222 else
 223         openssl=true
 224         tinc_OPENSSL
 225 fi
 226
 227 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 228 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 229
 230 dnl Check if support for jumbograms is requested
 231 AC_ARG_ENABLE(jumbograms,
 232   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 233   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 234       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 235   ]
 236 )
 237
 238 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile gui/Makefile test/Makefile])
 239
 240 AC_OUTPUT