git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([MeshLink], [0.1])
   5 AC_CONFIG_SRCDIR([src/libmeshlink.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([check-news std-options subdir-objects -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22 AC_PROG_LIBTOOL
  23
  24 AM_PROG_CC_C_O
  25
  26 dnl Check and set OS
  27
  28 AC_CANONICAL_HOST
  29
  30 case $host_os in
  31   *linux*)
  32     linux=true
  33     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  34   ;;
  35   *freebsd*)
  36     bsd=true
  37     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  38   ;;
  39   *darwin*)
  40     bsd=true
  41     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  42   ;;
  43   *solaris*)
  44     solaris=true
  45     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  46   ;;
  47   *openbsd*)
  48     bsd=true
  49     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  50   ;;
  51   *netbsd*)
  52     bsd=true
  53     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  54   ;;
  55   *dragonfly*)
  56     bsd=true
  57     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  58   ;;
  59   *bsd*)
  60     bsd=true
  61     AC_MSG_WARN("Unknown BSD variant, MeshLink might not compile or work!")
  62     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  63   ;;
  64   *cygwin*)
  65     cygwin=true
  66     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  67   ;;
  68   *mingw*)
  69     mingw=true
  70     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  71     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  72   ;;
  73   *)
  74     AC_MSG_ERROR("Unknown operating system.")
  75   ;;
  76 esac
  77
  78 AC_ARG_WITH(windows2000,
  79   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
  80   [ AS_IF([test "x$with_windows2000" = "xyes"],
  81       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
  82   ]
  83 )
  84
  85 AM_CONDITIONAL(LINUX, test "$linux" = true)
  86 AM_CONDITIONAL(BSD, test "$bsd" = true)
  87 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
  88 AM_CONDITIONAL(MINGW, test "$mingw" = true)
  89 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
  90 AM_CONDITIONAL(UML, test "$uml" = true)
  91 AM_CONDITIONAL(VDE, test "$vde" = true)
  92 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
  93
  94 AC_CACHE_SAVE
  95
  96 if test -d /sw/include ; then
  97   CPPFLAGS="$CPPFLAGS -I/sw/include"
  98 fi
  99 if test -d /sw/lib ; then
 100   LIBS="$LIBS -L/sw/lib"
 101 fi
 102
 103 dnl Compiler hardening flags
 104 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 105
 106 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 107 AS_IF([test "x$enable_hardening" != "xno"],
 108   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
 109    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
 110    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
 111    case $host_os in
 112      *mingw*)
 113        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 114        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 115        ;;
 116      *)
 117        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 118        AX_CHECK_COMPILE_FLAG([-fPIC], [CPPFLAGS="$CPPFLAGS -fPIC"])
 119        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 120        ;;
 121    esac
 122    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 123    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 124   ]
 125 );
 126
 127 dnl Checks for header files.
 128 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 129
 130 AC_HEADER_STDC
 131 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 132 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 133   [], [], [#include "src/have.h"]
 134 )
 135 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 136   [], [], [#include "src/have.h"]
 137 )
 138 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 139   [], [], [#include "src/have.h"]
 140 )
 141
 142 dnl Checks for typedefs, structures, and compiler characteristics.
 143 AC_C_CONST
 144 AC_C_VOLATILE
 145 AC_TYPE_PID_T
 146 AC_TYPE_SIZE_T
 147 AC_HEADER_TIME
 148 AC_STRUCT_TM
 149
 150 MeshLink_ATTRIBUTE(__malloc__)
 151 MeshLink_ATTRIBUTE(__warn_unused_result__)
 152
 153 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 154   [#include "src/have.h"]
 155 )
 156
 157 dnl Checks for library functions.
 158 AC_TYPE_SIGNAL
 159 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 160   [], [], [#include "src/have.h"]
 161 )
 162
 163 dnl Support for SunOS
 164
 165 AC_CHECK_FUNC(socket, [], [
 166   AC_CHECK_LIB(socket, connect)
 167 ])
 168 AC_CHECK_FUNC(gethostbyname, [], [
 169   AC_CHECK_LIB(nsl, gethostbyname)
 170 ])
 171
 172 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 173   [], [], [#include "src/have.h"]
 174 )
 175
 176 AC_CACHE_SAVE
 177
 178 dnl These are defined in files in m4/
 179
 180 MeshLink_ZLIB
 181
 182 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile test/Makefile])
 183
 184 AC_OUTPUT