git.meshlink.io Git - meshlink/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.1pre7])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([check-news dist-xz no-dist-gzip std-options subdir-objects -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21 AC_PROG_RANLIB
  22
  23 AM_PROG_CC_C_O
  24
  25 dnl Check and set OS
  26
  27 AC_CANONICAL_HOST
  28
  29 case $host_os in
  30   *linux*)
  31     linux=true
  32     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  33   ;;
  34   *freebsd*)
  35     bsd=true
  36     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  37   ;;
  38   *darwin*)
  39     bsd=true
  40     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  41   ;;
  42   *solaris*)
  43     solaris=true
  44     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  45   ;;
  46   *openbsd*)
  47     bsd=true
  48     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  49   ;;
  50   *netbsd*)
  51     bsd=true
  52     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  53   ;;
  54   *dragonfly*)
  55     bsd=true
  56     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  57   ;;
  58   *bsd*)
  59     bsd=true
  60     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  61     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  62   ;;
  63   *cygwin*)
  64     cygwin=true
  65     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  71   ;;
  72   *)
  73     AC_MSG_ERROR("Unknown operating system.")
  74   ;;
  75 esac
  76
  77 AC_ARG_ENABLE(uml,
  78   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  79   [ AS_IF([test "x$enable_uml" = "xyes"],
  80       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  81         uml=true
  82       ],
  83       [uml=false])
  84   ],
  85   [uml=false]
  86 )
  87
  88 AC_ARG_ENABLE(vde,
  89   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  90   [ AS_IF([test "x$enable_vde" = "xyes"],
  91       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  92         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  93         vde=true
  94       ],
  95       [vde=false])
  96   ],
  97   [vde=false]
  98 )
  99
 100 AC_ARG_ENABLE(tunemu,
 101   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 102   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 103       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 104         tunemu=true
 105       ],
 106       [tunemu=false])
 107   ],
 108   [tunemu=false]
 109 )
 110
 111 AC_ARG_WITH(windows2000,
 112   AS_HELP_STRING([--without-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 113   [ AS_IF([test "x$with_windows2000" = "xyes"],
 114       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 115   ]
 116 )
 117
 118 AM_CONDITIONAL(LINUX, test "$linux" = true)
 119 AM_CONDITIONAL(BSD, test "$bsd" = true)
 120 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 121 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 122 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 123 AM_CONDITIONAL(UML, test "$uml" = true)
 124 AM_CONDITIONAL(VDE, test "$vde" = true)
 125 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 126
 127 AC_CACHE_SAVE
 128
 129 if test -d /sw/include ; then
 130   CPPFLAGS="$CPPFLAGS -I/sw/include"
 131 fi
 132 if test -d /sw/lib ; then
 133   LIBS="$LIBS -L/sw/lib"
 134 fi
 135
 136 dnl Checks for header files.
 137 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 138
 139 AC_HEADER_STDC
 140 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 141 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 142   [], [], [#include "src/have.h"]
 143 )
 144 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 145   [], [], [#include "src/have.h"]
 146 )
 147 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 148   [], [], [#include "src/have.h"]
 149 )
 150
 151 dnl Checks for typedefs, structures, and compiler characteristics.
 152 AC_C_CONST
 153 AC_C_VOLATILE
 154 AC_TYPE_PID_T
 155 AC_TYPE_SIZE_T
 156 AC_HEADER_TIME
 157 AC_STRUCT_TM
 158
 159 tinc_ATTRIBUTE(__malloc__)
 160 tinc_ATTRIBUTE(__warn_unused_result__)
 161
 162 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 163   [#include "src/have.h"]
 164 )
 165
 166 dnl Checks for library functions.
 167 AC_TYPE_SIGNAL
 168 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 169   [], [], [#include "src/have.h"]
 170 )
 171
 172 dnl Support for SunOS
 173
 174 AC_CHECK_FUNC(socket, [], [
 175   AC_CHECK_LIB(socket, connect)
 176 ])
 177 AC_CHECK_FUNC(gethostbyname, [], [
 178   AC_CHECK_LIB(nsl, gethostbyname)
 179 ])
 180
 181 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 182   [], [], [#include "src/have.h"]
 183 )
 184
 185 AC_CACHE_SAVE
 186
 187 dnl These are defined in files in m4/
 188
 189 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 190
 191 tinc_CURSES
 192 tinc_READLINE
 193 tinc_ZLIB
 194 tinc_LZO
 195
 196 if test "$with_libgcrypt" = yes; then
 197         gcrypt=true
 198         AM_PATH_LIBGCRYPT([1.4.0], [], [])
 199 else
 200         openssl=true
 201         tinc_OPENSSL
 202 fi
 203
 204 AM_CONDITIONAL(OPENSSL, test "$openssl" = true)
 205 AM_CONDITIONAL(GCRYPT, test "$grypt" = true)
 206
 207 dnl Check if support for jumbograms is requested
 208 AC_ARG_ENABLE(jumbograms,
 209   AS_HELP_STRING([--disable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 210   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 211       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 212   ]
 213 )
 214
 215 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile gui/Makefile])
 216
 217 AC_OUTPUT