git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.16],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [7:3:4])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [4:5:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:1:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:1:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:1:0])
  37
  38 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  39 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  40 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  41 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  42
  43 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  44     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  45     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  46 fi
  47
  48 # Checks for programs.
  49 AC_PROG_CC
  50 AC_PROG_CXX
  51 AC_GNU_SOURCE
  52 AC_PROG_CPP
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55 AC_PROG_MAKE_SET
  56 AC_PROG_GCC_TRADITIONAL
  57
  58 # libtool stuff
  59 AC_PROG_LIBTOOL
  60
  61 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  62
  63 #
  64 # Check for netlink.h
  65 #
  66 AC_CHECK_HEADER(linux/netlink.h,
  67 HAVE_NETLINK=yes
  68 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  69 , [], [
  70 #include <sys/socket.h>
  71 #include <asm/types.h>
  72 ])
  73
  74 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  75
  76 #
  77 # Check for net/route.h
  78 #
  79 AC_CHECK_HEADER(net/route.h,
  80 HAVE_PF_ROUTE=yes
  81 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  82 , [], [
  83 #include <sys/types.h>
  84 #include <sys/socket.h>
  85 ])
  86
  87 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  88
  89 #
  90 # Check for sys/filio.h; needed for FIONREAD on Solaris
  91 #
  92 AC_CHECK_HEADER(sys/filio.h,
  93 HAVE_SYS_FILIO_H=yes
  94 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
  95 , [], [
  96 ])
  97
  98 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
  99
 100 #
 101 # Check for sys/sysctl.h; not present on Solaris
 102 #
 103 AC_CHECK_HEADER(sys/sysctl.h,
 104 HAVE_SYS_SYSCTL=yes
 105 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 106 , [], [
 107 #include <sys/types.h>
 108 #include <sys/socket.h>
 109 #include <sys/param.h>
 110 ])
 111
 112 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 113
 114 #
 115 # Check for lifconf struct; only present on Solaris
 116 #
 117 AC_MSG_CHECKING(for struct lifconf)
 118 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 119 [AC_TRY_COMPILE(
 120 [#include <sys/socket.h>
 121 #include <net/if.h>
 122 ],[sizeof (struct lifconf);],
 123 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 124 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 125 if test $avahi_cv_has_struct_lifconf = yes; then
 126     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 127 fi
 128
 129 #
 130 # Check for struct ip_mreqn
 131 #
 132 AC_MSG_CHECKING(for struct ip_mreqn)
 133 AC_TRY_COMPILE([#include <netinet/in.h>], [
 134         struct ip_mreqn mreq;
 135         mreq.imr_address.s_addr = 0;
 136 ], [
 137         # Yes, we have it...
 138         AC_MSG_RESULT(yes)
 139         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 140 ], [
 141         # We'll just have to try and use struct ip_mreq
 142         AC_MSG_RESULT(no)
 143         AC_MSG_CHECKING(for struct ip_mreq)
 144         AC_TRY_COMPILE([#include <netinet/in.h>], [
 145                 struct ip_mreq mreq;
 146                 mreq.imr_interface.s_addr = 0;
 147         ], [
 148                 # Yes, we have it...
 149                 AC_MSG_RESULT(yes)
 150                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 151         ], [
 152                 # No multicast support
 153                         AC_MSG_RESULT(no)
 154         ])
 155 ])
 156
 157 #
 158 # Detecting the linux distribution for specific things like init scripts.
 159 #
 160 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 161 if test "z$with_distro" = "z"; then
 162     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 163     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 164     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 165     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 166     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 167     AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 168     AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 169     if test "z$with_distro" = "z"; then
 170         with_distro=`uname -s`
 171     fi
 172 fi
 173 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 174
 175 case $with_distro in
 176     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 177      ;;
 178     netbsd)
 179      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 180      ;;
 181     linux)
 182      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 183      ;;
 184     *)
 185      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 186      ;;
 187 esac
 188
 189 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 190 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 191 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 192 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 193 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 194 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 195 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 196 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 197 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 198 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 199
 200 test_gcc_flag() {
 201     AC_LANG_CONFTEST([int main() {}])
 202     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 203     ret=$?
 204     rm -f conftest.o
 205     return $ret
 206 }
 207
 208 # If using GCC specify some additional parameters
 209 if test "x$GCC" = "xyes" ; then
 210
 211     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 212
 213     if test "x$HAVE_NETLINK" = "xyes" ; then
 214         # Test whether rtnetlink.h can be included when compiled with -std=c99
 215         # some distributions (e.g. archlinux) have broken headers that dont
 216         # define __u64 with -std=c99
 217         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 218         OLDCFLAGS="$CFLAGS"
 219         CFLAGS="-std=c99"
 220         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 221             use_stdc99=yes, use_stdc99=no)
 222
 223         if test x"$use_stdc99" = xyes; then
 224             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 225             AC_MSG_RESULT([yes])
 226         else
 227             AC_MSG_RESULT([no])
 228         fi
 229
 230         CFLAGS="$OLDCFLAGS"
 231     else
 232         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 233     fi
 234
 235     for flag in $DESIRED_FLAGS ; do
 236         AC_MSG_CHECKING([whether $CC accepts $flag])
 237         if test_gcc_flag $flag ; then
 238            CFLAGS="$CFLAGS $flag"
 239            AC_MSG_RESULT([yes])
 240         else
 241            AC_MSG_RESULT([no])
 242         fi
 243     done
 244 fi
 245
 246 # Checks for header files.
 247 AC_HEADER_STDC
 248 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 249 AC_HEADER_STDBOOL
 250
 251 # Checks for typedefs, structures, and compiler characteristics.
 252 AC_C_CONST
 253 AC_TYPE_SIZE_T
 254 AC_HEADER_TIME
 255 AC_HEADER_SYS_WAIT
 256
 257 # Checks for library functions.
 258 AC_FUNC_MEMCMP
 259 AC_FUNC_SELECT_ARGTYPES
 260 AC_FUNC_MALLOC
 261 AC_FUNC_REALLOC
 262 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 263
 264 AC_FUNC_CHOWN
 265 AC_FUNC_STAT
 266 AC_TYPE_MODE_T
 267 AC_TYPE_PID_T
 268
 269 AC_CHECK_DECLS(environ)
 270
 271 enable_chroot=yes
 272 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 273 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 274 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 275
 276 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 277
 278 if test "x$enable_chroot" = "xyes" ; then
 279    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 280 fi
 281
 282 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 283 if test "x$HAVE_DLOPEN" = "xyes" ; then
 284     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 285 fi
 286 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 287
 288 # Check for pkg-config manually first, as if its not installed the
 289 # PKG_PROG_PKG_CONFIG macro won't be defined.
 290 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 291
 292 if test x"$have_pkg_config" = "xno"; then
 293     AC_MSG_ERROR(pkg-config is required to install this program)
 294 fi
 295
 296 PKG_PROG_PKG_CONFIG
 297
 298 #
 299 # Check for GLIB 2.0
 300 #
 301 AC_ARG_ENABLE(glib,
 302         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 303         [case "${enableval}" in
 304                 yes) HAVE_GLIB=yes ;;
 305                 no)  HAVE_GLIB=no ;;
 306                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 307         esac],
 308         [HAVE_GLIB=yes])
 309
 310 if test "x$HAVE_GLIB" = "xyes" ; then
 311         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 312         AC_SUBST(GLIB20_CFLAGS)
 313         AC_SUBST(GLIB20_LIBS)
 314 fi
 315 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 316
 317 #
 318 # Check for Qt 3
 319 #
 320 AC_ARG_ENABLE(qt3,
 321         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 322         [case "${enableval}" in
 323                 yes) HAVE_QT3=yes ;;
 324                 no)  HAVE_QT3=no ;;
 325                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 326         esac],
 327         [HAVE_QT3=yes])
 328
 329 if test "x$HAVE_QT3" = "xyes" ; then
 330         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 331         AC_SUBST(QT3_CFLAGS)
 332         AC_SUBST(QT3_LIBS)
 333             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 334         MOC_QT3="no"
 335             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 336                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 337                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 338         AC_SUBST(MOC_QT3)
 339 fi
 340 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 341
 342 #
 343 # Check for Qt 4
 344 #
 345 AC_ARG_ENABLE(qt4,
 346         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 347         [case "${enableval}" in
 348                 yes) HAVE_QT4=yes ;;
 349                 no)  HAVE_QT4=no ;;
 350                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 351         esac],
 352         [HAVE_QT4=yes])
 353
 354 if test "x$HAVE_QT4" = "xyes" ; then
 355         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 356         AC_SUBST(QT4_CFLAGS)
 357         AC_SUBST(QT4_LIBS)
 358             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 359         MOC_QT4="no"
 360             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 361                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 362                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 363         AC_SUBST(MOC_QT4)
 364 fi
 365 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 366
 367 #
 368 # Check for GTK+
 369 #
 370 AC_ARG_ENABLE(gtk,
 371         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 372         [case "${enableval}" in
 373                 yes) HAVE_GTK=yes ;;
 374                 no)  HAVE_GTK=no ;;
 375                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 376         esac],
 377         [HAVE_GTK=yes])
 378
 379 if test "x$HAVE_GTK" = "xyes" ; then
 380         # Check for GTK 2.0
 381         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 382         AC_SUBST(GTK20_CFLAGS)
 383         AC_SUBST(GTK20_LIBS)
 384
 385         # Check for GLADE 2.0
 386         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 387         AC_SUBST(GLADE20_CFLAGS)
 388         AC_SUBST(GLADE20_LIBS)
 389 fi
 390 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 391
 392 #
 393 # D-Bus
 394 #
 395 AC_ARG_ENABLE(dbus,
 396         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 397         [case "${enableval}" in
 398                 yes) HAVE_DBUS=yes ;;
 399                 no)  HAVE_DBUS=no ;;
 400                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 401         esac],
 402         [HAVE_DBUS=yes])
 403
 404 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 405 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 406
 407 DBUS_VERSION="Disabled"
 408 DBUS_SYS_DIR="Disabled"
 409 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 410 if test "x$HAVE_DBUS" = "xyes" ; then
 411     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 412
 413     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 414
 415     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 416     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 417     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 418     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 419     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 420         DBUS_VERSION_MAJOR="0"
 421     fi
 422     if test "z$DBUS_VERSION_MINOR" = "z"; then
 423         DBUS_VERSION_MINOR="0"
 424     fi
 425     if test "z$DBUS_VERSION_MICRO" = "z"; then
 426         DBUS_VERSION_MICRO="0"
 427     fi
 428
 429     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 430         echo "Error: Couldn't determine the version of your D-Bus package."
 431         echo "  This is probably an error in this script, please report it"
 432         echo "  along with the following information:"
 433         echo "      Base D-Buss version ='$DBUS_VERSION'"
 434         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 435         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 436         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 437         exit 1
 438     else
 439         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 440         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 441         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 442         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 443     fi
 444
 445     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 446     AC_SUBST(DBUS_CFLAGS)
 447     AC_SUBST(DBUS_LIBS)
 448
 449     if ! test -z "$with_dbus_sys" ; then
 450         DBUS_SYS_DIR="$with_dbus_sys"
 451     else
 452         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 453     fi
 454     AC_SUBST(DBUS_SYS_DIR)
 455
 456     if ! test -z "$with_dbus_system_address" ; then
 457         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 458     else
 459         # This is ugly, but D-Bus doesn't export this address for us
 460         # so we have to guess, pretty much all setups i've seen have
 461         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 462         # /var/run upstream so we will try guess first then default
 463         # to /var/run/dbus.
 464
 465         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 466         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 467         for sock in $TRY_SOCKETS; do
 468             if test -S $sock; then
 469                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 470             fi
 471         done
 472     fi
 473     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 474
 475     SAVED_LIBS="$LIBS"
 476     LIBS="$LIBS $DBUS_LIBS"
 477     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 478     LIBS="$SAVED_LIBS"
 479 fi
 480 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 481
 482 #
 483 # Expat
 484 #
 485 AC_ARG_ENABLE(expat,
 486         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 487         [case "${enableval}" in
 488                 yes) HAVE_EXPAT=yes ;;
 489                 no)  HAVE_EXPAT=no ;;
 490                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 491         esac],
 492         [HAVE_EXPAT=yes])
 493
 494 if test "x$HAVE_EXPAT" = "xyes" ; then
 495     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 496
 497     if ! $have_expat ; then
 498         AC_MSG_ERROR([*** libexpat not found ***])
 499     fi
 500 fi
 501 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 502
 503 #
 504 # GDBM
 505 #
 506 #
 507 # Check for dbm
 508 #
 509 AC_ARG_ENABLE(dbm,
 510         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 511         [case "${enableval}" in
 512                 yes) HAVE_DBM=yes ;;
 513                 no)  HAVE_DBM=no ;;
 514                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 515         esac],
 516         [HAVE_DBM=no])
 517
 518 AC_ARG_ENABLE(gdbm,
 519         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 520         [case "${enableval}" in
 521                 yes) HAVE_GDBM=yes ;;
 522                 no)  HAVE_GDBM=no ;;
 523                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 524         esac],
 525         [HAVE_GDBM=yes])
 526
 527 if test "x$HAVE_GDBM" = "xyes" ; then
 528     if test "x$HAVE_DBM" = "xyes" ; then
 529         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 530     fi
 531     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 532
 533     if ! $have_gdbm ; then
 534         AC_MSG_ERROR([*** libgdbm not found ***])
 535     fi
 536     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 537 else
 538     if test "x$HAVE_DBM" = "xyes" ; then
 539         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 540
 541         if ! $have_dbm ; then
 542             AC_MSG_ERROR([*** dbm not found ***])
 543         fi
 544         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 545     fi
 546 fi
 547 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 548 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 549
 550 #
 551 # libdaemon
 552 #
 553 AC_ARG_ENABLE(libdaemon,
 554         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 555         [case "${enableval}" in
 556                 yes) HAVE_LIBDAEMON=yes ;;
 557                 no)  HAVE_LIBDAEMON=no ;;
 558                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 559         esac],
 560         [HAVE_LIBDAEMON=yes])
 561
 562 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 563     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 564     AC_SUBST(LIBDAEMON_CFLAGS)
 565     AC_SUBST(LIBDAEMON_LIBS)
 566 fi
 567 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 568
 569 #
 570 # Python stuff
 571 #
 572 AC_ARG_ENABLE(python,
 573     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 574     [case "${enableval}" in
 575           yes) HAVE_PYTHON=yes ;;
 576           no)  HAVE_PYTHON=no ;;
 577           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 578     esac],[HAVE_PYTHON=yes])
 579
 580 HAVE_PYTHON_DBUS=no
 581 HAVE_PYGTK=no
 582
 583 if test "x$HAVE_PYTHON" = "xyes" ; then
 584     AM_PATH_PYTHON([2.4])
 585
 586     AC_ARG_ENABLE(pygtk,
 587         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 588         [case "${enableval}" in
 589                 yes) HAVE_PYGTK=yes ;;
 590                 no)  HAVE_PYGTK=no ;;
 591                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 592         esac],
 593         [HAVE_PYGTK=yes])
 594
 595     if test "x$HAVE_PYGTK" = "xyes" ; then
 596         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 597     fi
 598
 599
 600     if test "x$HAVE_DBUS" = "xyes" ; then
 601         AC_ARG_ENABLE(python-dbus,
 602             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 603             [case "${enableval}" in
 604                    yes) HAVE_PYTHON_DBUS=yes ;;
 605                    no)  HAVE_PYTHON_DBUS=no ;;
 606                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 607             esac],
 608             [HAVE_PYTHON_DBUS=yes])
 609
 610         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 611             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 612         fi
 613
 614         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 615         if test "x$HAVE_GDBM" = "xyes"; then
 616             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 617         fi
 618         if test "x$HAVE_DBM" = "xyes"; then
 619             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 620         fi
 621     fi
 622 fi
 623 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 624 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 625 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 626
 627 #
 628 # Check for mono stuff
 629 #
 630 HAVE_MONO=no
 631 if test "x$HAVE_DBUS" = "xyes" ; then
 632     AC_ARG_ENABLE(mono,
 633             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 634             [case "${enableval}" in
 635                     yes) HAVE_MONO=yes ;;
 636                     no)  HAVE_MONO=no ;;
 637                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 638             esac],
 639             [HAVE_MONO=yes])
 640
 641     if test "x$HAVE_MONO" = "xyes" ; then
 642         AC_PATH_PROG(MCS, mcs)
 643         if test "x$MCS" = "x" ; then
 644             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 645         fi
 646
 647         AC_PATH_PROG(GACUTIL, gacutil)
 648         if test "x$GACUTIL" = "x" ; then
 649             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 650         fi
 651
 652         AC_SUBST(MCS)
 653         AC_SUBST(GACUTIL)
 654     fi
 655 fi
 656 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 657
 658 #
 659 # Check for monodoc stuff
 660 #
 661 HAVE_MONODOC=no
 662 AC_ARG_ENABLE(monodoc,
 663         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 664         [case "${enableval}" in
 665                 yes) HAVE_MONODOC=yes ;;
 666                 no)  HAVE_MONODOC=no ;;
 667                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 668         esac],
 669         [HAVE_MONODOC=yes])
 670
 671 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 672         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 673         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 674
 675         AC_PATH_PROG(MONODOCER, monodocer)
 676         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 677
 678         AC_SUBST(MONODOC_DIR)
 679         AC_SUBST(MONODOCER)
 680         AC_SUBST(MDASSEMBLER)
 681 fi
 682 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 683
 684 #
 685 # Build autoipd?
 686 #
 687 AC_ARG_ENABLE(autoipd,
 688         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 689         [case "${enableval}" in
 690                 yes) ENABLE_AUTOIPD=yes ;;
 691                 no)  ENABLE_AUTOIPD=no ;;
 692                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 693         esac],
 694         [ENABLE_AUTOIPD=yes])
 695
 696 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 697
 698 #
 699 # Defining users and groups
 700 #
 701 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 702 if test -z "$with_avahi_user" ; then
 703     AVAHI_USER=avahi
 704 else
 705     AVAHI_USER=$with_avahi_user
 706 fi
 707 AC_SUBST(AVAHI_USER)
 708 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 709
 710 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 711 if test -z "$with_avahi_group" ; then
 712     AVAHI_GROUP=avahi
 713 else
 714     AVAHI_GROUP=$with_avahi_group
 715 fi
 716 AC_SUBST(AVAHI_GROUP)
 717 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 718
 719 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 720 if test -z "$with_avahi_priv_access_group" ; then
 721     AVAHI_PRIV_ACCESS_GROUP=netdev
 722 else
 723     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 724 fi
 725 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 726 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 727
 728 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 729 if test -z "$with_autoipd_user" ; then
 730     AVAHI_AUTOIPD_USER=avahi-autoipd
 731 else
 732     AVAHI_AUTOIPD_USER=$with_autoipd_user
 733 fi
 734 AC_SUBST(AVAHI_AUTOIPD_USER)
 735 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 736
 737 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 738 if test -z "$with_autoipd_group" ; then
 739     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 740 else
 741     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 742 fi
 743 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 744 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 745
 746 #
 747 # Avahi runtime dir
 748 #
 749 avahi_runtime_dir="${localstatedir}/run"
 750 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 751 AC_SUBST(avahi_runtime_dir)
 752 AC_SUBST(avahi_socket)
 753
 754 #
 755 # Avahi interfaces dir
 756 #
 757 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 758         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 759         AC_SUBST(interfacesdir)
 760 fi
 761
 762 #
 763 # Doxygen
 764 #
 765 DX_HTML_FEATURE(ON)
 766 DX_CHM_FEATURE(OFF)
 767 DX_CHI_FEATURE(OFF)
 768 DX_MAN_FEATURE(OFF)
 769 DX_RTF_FEATURE(OFF)
 770 DX_XML_FEATURE(OFF)
 771 DX_PDF_FEATURE(OFF)
 772 DX_PS_FEATURE(OFF)
 773 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 774
 775 AC_ARG_ENABLE(core-docs,
 776         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 777 [case "${enableval}" in
 778   yes) ENABLE_CORE_DOCS=yes ;;
 779   no)  ENABLE_CORE_DOCS=no ;;
 780   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 781 esac],[ENABLE_CORE_DOCS=no])
 782
 783 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 784
 785 #
 786 # Build and Install man pages
 787 #
 788 AC_ARG_ENABLE(manpages,
 789         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 790 [case "${enableval}" in
 791   yes) manpages=yes ;;
 792   no)  manpages=no ;;
 793   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 794 esac],[manpages=yes])
 795
 796 if test x$manpages = xyes ; then
 797     #
 798     # XMLTOMAN manpage generation
 799     #
 800     AC_ARG_ENABLE(xmltoman,
 801     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 802     [case "${enableval}" in
 803       yes) xmltoman=yes ;;
 804       no)  xmltoman=no ;;
 805       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 806     esac],[xmltoman=yes])
 807
 808     if test x$xmltoman = xyes ; then
 809         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 810     fi
 811
 812     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 813         if ! test -e man/avahi-daemon.8 ; then
 814             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 815             exit 1
 816         fi
 817         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 818         xmltoman=no
 819     fi
 820 fi
 821 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 822 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 823
 824 #
 825 # Conditionally compile test and example programs
 826 #
 827 AC_ARG_ENABLE(tests,
 828         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 829         [case "${enableval}" in
 830                 yes) ENABLE_TESTS=yes ;;
 831                 no)  ENABLE_TESTS=no ;;
 832                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 833         esac],
 834         [ENABLE_TESTS=no])
 835
 836 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 837
 838 #
 839 # Optionally enable libdns_sd compatibility support
 840 #
 841 AC_ARG_ENABLE(compat-libdns_sd,
 842         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 843         [case "${enableval}" in
 844                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 845                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 846                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 847         esac],
 848         [ENABLE_COMPAT_LIBDNS_SD=no])
 849
 850 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 851
 852 #
 853 # Optionally enable HOWL compatibility support
 854 #
 855 AC_ARG_ENABLE(compat-howl,
 856         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 857         [case "${enableval}" in
 858                 yes) ENABLE_COMPAT_HOWL=yes ;;
 859                 no)  ENABLE_COMPAT_HOWL=no ;;
 860                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 861         esac],
 862         [ENABLE_COMPAT_HOWL=no])
 863
 864 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 865
 866
 867 # ==========================================================================
 868 AC_CONFIG_FILES([
 869 Makefile
 870 avahi-common/Makefile
 871 avahi-core/Makefile
 872 avahi-glib/Makefile
 873 avahi-qt/Makefile
 874 avahi-daemon/Makefile
 875 avahi-daemon/avahi-dbus.conf
 876 avahi-discover-standalone/Makefile
 877 avahi-client/Makefile
 878 initscript/Makefile
 879 initscript/debian/Makefile
 880 initscript/gentoo/Makefile
 881 initscript/archlinux/Makefile
 882 initscript/suse/Makefile
 883 initscript/fedora/Makefile
 884 initscript/mandriva/Makefile
 885 initscript/darwin/Makefile
 886 initscript/freebsd/Makefile
 887 initscript/slackware/Makefile
 888 avahi-dnsconfd/Makefile
 889 avahi-utils/Makefile
 890 avahi-python/Makefile
 891 avahi-python/avahi/Makefile
 892 examples/Makefile
 893 common/Makefile
 894 man/Makefile
 895 tests/Makefile
 896 service-type-database/Makefile
 897 avahi-sharp/Makefile
 898 avahi-compat-libdns_sd/Makefile
 899 avahi-compat-howl/Makefile
 900 avahi-compat-howl/samples/Makefile
 901 avahi-autoipd/Makefile
 902 ])
 903 AC_OUTPUT
 904
 905 # ==========================================================================
 906 echo "
 907  ---{ $PACKAGE_NAME $VERSION }---
 908
 909     prefix:                                    ${prefix}
 910     sysconfdir:                                ${sysconfdir}
 911     localstatedir:                             ${localstatedir}
 912     avahi socket:                              ${avahi_socket}
 913     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
 914     dbus-1 version:                            ${DBUS_VERSION}
 915     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 916     C Compiler:                                ${CC}
 917     CFLAGS:                                    ${CFLAGS}
 918     Enable GLIB:                               ${HAVE_GLIB}
 919     Enable GTK:                                ${HAVE_GTK}
 920     Enable D-Bus:                              ${HAVE_DBUS}
 921     Enable Expat:                              ${HAVE_EXPAT}
 922     Enable GDBM:                               ${HAVE_GDBM}
 923     Enable DBM:                                ${HAVE_DBM}
 924     Enable libdaemon:                          ${HAVE_LIBDAEMON}
 925     Enable Python:                             ${HAVE_PYTHON}
 926     Enable pygtk:                              ${HAVE_PYGTK}
 927     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
 928     Enable QT3:                                ${HAVE_QT3}
 929     Enable QT4:                                ${HAVE_QT4}
 930     Enable Mono:                               ${HAVE_MONO}
 931     Enable Monodoc:                            ${HAVE_MONODOC}
 932     Distribution/OS:                           ${with_distro}
 933     User for avahi-daemon:                     ${AVAHI_USER}
 934     Group for avahi-daemon:                    ${AVAHI_GROUP}
 935     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
 936     User for avahi-autopid:                    ${AVAHI_AUTOIPD_USER}
 937     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
 938     Enable chroot():                           ${enable_chroot}
 939 "
 940
 941 BUILD_DAEMON="no   (You need libdaemon and expat!)"
 942
 943 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 944     BUILD_DAEMON=yes
 945 fi
 946
 947 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
 948
 949 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 950     BUILD_PYTHON=yes
 951 fi
 952
 953 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
 954
 955 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 956     BUILD_CLIENT=yes
 957 fi
 958
 959 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 960    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
 961 fi
 962 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 963    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
 964 fi
 965
 966
 967 echo "\
 968     Building libavahi-core              yes
 969     Building avahi-daemon:              ${BUILD_DAEMON}
 970     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 971     Building libavahi-client:           ${BUILD_CLIENT}
 972     Building avahi-utils:               ${BUILD_CLIENT}
 973     Building avahi-python:              ${BUILD_PYTHON}
 974     Building libavahi-glib:             ${HAVE_GLIB}
 975     Building avahi-discover-standalone: ${HAVE_GTK}
 976     Building libavahi-qt3:              ${HAVE_QT3}
 977     Building libavahi-qt4:              ${HAVE_QT4}
 978     Building avahi-sharp:               ${HAVE_MONO}
 979     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 980     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 981     Building tests:                     ${ENABLE_TESTS}
 982     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
 983     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
 984 "