git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [2:0:2])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [2:0:1])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [2:0:1])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [0:1:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the Linux distribution to target: One of debian, gentoo, archlinux or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125 fi
 126 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 127
 128 if test "z$with_distro" = "z"; then
 129     AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 130     exit 1
 131 else
 132 case $with_distro in
 133     debian|gentoo|archlinux|suse|fedora|none)
 134      ;;
 135     *)
 136      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 137      ;;
 138 esac
 139 fi
 140
 141 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 142 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 143 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 144 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 145 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 146
 147 test_gcc_flag() {
 148     AC_LANG_CONFTEST([int main() {}])
 149     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 150     ret=$?
 151     rm -f conftest.o
 152     return $ret
 153 }
 154
 155 # If using GCC specify some additional parameters
 156 if test "x$GCC" = "xyes" ; then
 157
 158     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wlarger-than-4000 -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
 159
 160     # Test whether rtnetlink.h can be included when compiled with -std=c99
 161     # some distributions (e.g. archlinux) have broken headers that dont
 162     # define __u64 with -std=c99
 163     AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 164     OLDCFLAGS="$CFLAGS"
 165     CFLAGS="-std=c99"
 166     AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 167         use_stdc99=yes, use_stdc99=no)
 168
 169     if test x"$use_stdc99" = xyes; then
 170         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 171         AC_MSG_RESULT([yes])
 172     else
 173         AC_MSG_RESULT([no])
 174     fi
 175
 176     CFLAGS="$OLDCFLAGS"
 177
 178     for flag in $DESIRED_FLAGS ; do
 179         AC_MSG_CHECKING([whether $CC accepts $flag])
 180         if test_gcc_flag $flag ; then
 181            CFLAGS="$CFLAGS $flag"
 182            AC_MSG_RESULT([yes])
 183         else
 184            AC_MSG_RESULT([no])
 185         fi
 186     done
 187 fi
 188
 189 # Checks for header files.
 190 AC_HEADER_STDC
 191 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 192 AC_HEADER_STDBOOL
 193
 194 # Checks for typedefs, structures, and compiler characteristics.
 195 AC_C_CONST
 196 AC_TYPE_SIZE_T
 197 AC_HEADER_TIME
 198 AC_HEADER_SYS_WAIT
 199
 200 # Checks for library functions.
 201 AC_FUNC_MEMCMP
 202 AC_FUNC_SELECT_ARGTYPES
 203 AC_FUNC_MALLOC
 204 AC_FUNC_REALLOC
 205 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname])
 206
 207 AC_FUNC_CHOWN
 208 AC_FUNC_STAT
 209 AC_TYPE_MODE_T
 210 AC_TYPE_PID_T
 211
 212 AC_CHECK_DECLS(environ)
 213
 214 # Check for pkg-config manually first, as if its not installed the
 215 # PKG_PROG_PKG_CONFIG macro won't be defined.
 216 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 217
 218 if test x"$have_pkg_config" = "xno"; then
 219     AC_MSG_ERROR(pkg-config is required to install this program)
 220 fi
 221
 222 PKG_PROG_PKG_CONFIG
 223
 224 #
 225 # Check for GLIB 2.0
 226 #
 227 AC_ARG_ENABLE(glib,
 228         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 229         [case "${enableval}" in
 230                 yes) HAVE_GLIB=yes ;;
 231                 no)  HAVE_GLIB=no ;;
 232                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 233         esac],
 234         [HAVE_GLIB=yes])
 235
 236 if test "x$HAVE_GLIB" = "xyes" ; then
 237         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 238         AC_SUBST(GLIB20_CFLAGS)
 239         AC_SUBST(GLIB20_LIBS)
 240 fi
 241 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 242
 243 #
 244 # Check for Qt 3
 245 #
 246 AC_ARG_ENABLE(qt3,
 247         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 248         [case "${enableval}" in
 249                 yes) HAVE_QT3=yes ;;
 250                 no)  HAVE_QT3=no ;;
 251                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 252         esac],
 253         [HAVE_QT3=yes])
 254
 255 if test "x$HAVE_QT3" = "xyes" ; then
 256         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 257         AC_SUBST(QT3_CFLAGS)
 258         AC_SUBST(QT3_LIBS)
 259             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 260         MOC_QT3="no"
 261             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 262                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 263                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 264         AC_SUBST(MOC_QT3)
 265 fi
 266 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 267
 268 #
 269 # Check for Qt 4
 270 #
 271 AC_ARG_ENABLE(qt4,
 272         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 273         [case "${enableval}" in
 274                 yes) HAVE_QT4=yes ;;
 275                 no)  HAVE_QT4=no ;;
 276                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 277         esac],
 278         [HAVE_QT4=yes])
 279
 280 if test "x$HAVE_QT4" = "xyes" ; then
 281         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 282         AC_SUBST(QT4_CFLAGS)
 283         AC_SUBST(QT4_LIBS)
 284             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 285         MOC_QT4="no"
 286             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 287                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 288                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 289         AC_SUBST(MOC_QT4)
 290 fi
 291 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 292
 293 #
 294 # Check for GTK+
 295 #
 296 AC_ARG_ENABLE(gtk,
 297         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 298         [case "${enableval}" in
 299                 yes) HAVE_GTK=yes ;;
 300                 no)  HAVE_GTK=no ;;
 301                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 302         esac],
 303         [HAVE_GTK=yes])
 304
 305 if test "x$HAVE_GTK" = "xyes" ; then
 306         # Check for GTK 2.0
 307         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 308         AC_SUBST(GTK20_CFLAGS)
 309         AC_SUBST(GTK20_LIBS)
 310
 311         # Check for GLADE 2.0
 312         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 313         AC_SUBST(GLADE20_CFLAGS)
 314         AC_SUBST(GLADE20_LIBS)
 315 fi
 316 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 317
 318 #
 319 # D-BUS
 320 #
 321 AC_ARG_ENABLE(dbus,
 322         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 323         [case "${enableval}" in
 324                 yes) HAVE_DBUS=yes ;;
 325                 no)  HAVE_DBUS=no ;;
 326                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 327         esac],
 328         [HAVE_DBUS=yes])
 329
 330 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 331 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 332
 333 if test "x$HAVE_DBUS" = "xyes" ; then
 334     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 335
 336     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 337     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 338     AC_SUBST(DBUS_CFLAGS)
 339     AC_SUBST(DBUS_LIBS)
 340
 341     if ! test -z "$with_dbus_sys" ; then
 342         DBUS_SYS_DIR="$with_dbus_sys"
 343     else
 344         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 345     fi
 346     AC_SUBST(DBUS_SYS_DIR)
 347
 348     if ! test -z "$with_dbus_system_address" ; then
 349         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 350     else
 351         # This is ugly, but D-BUS doesn't export this address for us
 352         # so we have to guess, pretty much all setups i've seen have
 353         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 354         # /var/run upstream so we will try guess first then default
 355         # to /var/run/dbus
 356
 357         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 358         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket"
 359         for sock in $TRY_SOCKETS; do
 360             if test -S $sock; then
 361                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 362             fi
 363         done
 364     fi
 365     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 366
 367 fi
 368 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 369
 370 #
 371 # Expat
 372 #
 373 AC_ARG_ENABLE(expat,
 374         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 375         [case "${enableval}" in
 376                 yes) HAVE_EXPAT=yes ;;
 377                 no)  HAVE_EXPAT=no ;;
 378                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 379         esac],
 380         [HAVE_EXPAT=yes])
 381
 382 if test "x$HAVE_EXPAT" = "xyes" ; then
 383     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 384
 385     if ! $have_expat ; then
 386         AC_MSG_ERROR([*** libexpat not found ***])
 387     fi
 388 fi
 389 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 390
 391 #
 392 # libdaemon
 393 #
 394 AC_ARG_ENABLE(libdaemon,
 395         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 396         [case "${enableval}" in
 397                 yes) HAVE_LIBDAEMON=yes ;;
 398                 no)  HAVE_LIBDAEMON=no ;;
 399                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 400         esac],
 401         [HAVE_LIBDAEMON=yes])
 402
 403 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 404     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 405     AC_SUBST(LIBDAEMON_CFLAGS)
 406     AC_SUBST(LIBDAEMON_LIBS)
 407 fi
 408 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 409
 410 #
 411 # Python stuff
 412 #
 413 AC_ARG_ENABLE(python,
 414     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 415     [case "${enableval}" in
 416           yes) HAVE_PYTHON=yes ;;
 417           no)  HAVE_PYTHON=no ;;
 418           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 419     esac],[HAVE_PYTHON=yes])
 420
 421 HAVE_PYTHON_DBUS=no
 422 HAVE_PYGTK=no
 423
 424 if test "x$HAVE_PYTHON" = "xyes" ; then
 425     AM_PATH_PYTHON([2.4])
 426
 427     AC_ARG_ENABLE(pygtk,
 428         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 429         [case "${enableval}" in
 430                 yes) HAVE_PYGTK=yes ;;
 431                 no)  HAVE_PYGTK=no ;;
 432                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 433         esac],
 434         [HAVE_PYGTK=yes])
 435
 436     if test "x$HAVE_PYGTK" = "xyes" ; then
 437         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 438     fi
 439
 440
 441     AC_ARG_ENABLE(python-dbus,
 442         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 443         [case "${enableval}" in
 444                 yes) HAVE_PYTHON_DBUS=yes ;;
 445                 no)  HAVE_PYTHON_DBUS=no ;;
 446                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 447         esac],
 448         [HAVE_PYTHON_DBUS=yes])
 449
 450     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 451         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 452     fi
 453
 454     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 455     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 456 fi
 457 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 458 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 459 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 460
 461 #
 462 # Check for mono stuff
 463 #
 464 AC_ARG_ENABLE(mono,
 465         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 466         [case "${enableval}" in
 467                 yes) HAVE_MONO=yes ;;
 468                 no)  HAVE_MONO=no ;;
 469                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 470         esac],
 471         [HAVE_MONO=yes])
 472
 473 AC_ARG_ENABLE(monodoc,
 474         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 475         [case "${enableval}" in
 476                 yes) HAVE_MONODOC=yes ;;
 477                 no)  HAVE_MONODOC=no ;;
 478                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 479         esac],
 480         [HAVE_MONODOC=yes])
 481
 482 if test "x$HAVE_MONO" = "xyes" ; then
 483         AC_PATH_PROG(MCS, mcs)
 484         if test "x$MCS" = "x" ; then
 485                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 486         fi
 487
 488         AC_PATH_PROG(GACUTIL, gacutil)
 489         if test "x$GACUTIL" = "x" ; then
 490                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 491         fi
 492
 493         AC_SUBST(MCS)
 494         AC_SUBST(GACUTIL)
 495 fi
 496 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 497
 498 #
 499 # Check for monodoc stuff
 500 #
 501 if test "x$HAVE_MONODOC" = "xyes" ; then
 502         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 503         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 504
 505         AC_PATH_PROG(MONODOCER, monodocer)
 506         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 507
 508         AC_SUBST(MONODOC_DIR)
 509         AC_SUBST(MONODOCER)
 510         AC_SUBST(MDASSEMBLER)
 511 fi
 512 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 513
 514 #
 515 # Defining Avahi User and Group.
 516 #
 517 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 518 if test -z "$with_avahi_user" ; then
 519     AVAHI_USER=avahi
 520 else
 521     AVAHI_USER=$with_avahi_user
 522 fi
 523 AC_SUBST(AVAHI_USER)
 524 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 525
 526 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 527 if test -z "$with_avahi_group" ; then
 528     AVAHI_GROUP=avahi
 529 else
 530     AVAHI_GROUP=$with_avahi_group
 531 fi
 532 AC_SUBST(AVAHI_GROUP)
 533 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 534
 535 #
 536 # Avahi runtime dir
 537 #
 538 avahi_runtime_dir="${localstatedir}/run"
 539 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 540 AC_SUBST(avahi_runtime_dir)
 541 AC_SUBST(avahi_socket)
 542
 543 #
 544 # Avahi interfaces dir
 545 #
 546 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 547         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 548         AC_SUBST(interfacesdir)
 549 fi
 550
 551 #
 552 # Doxygen
 553 #
 554 DX_HTML_FEATURE(ON)
 555 DX_CHM_FEATURE(OFF)
 556 DX_CHI_FEATURE(OFF)
 557 DX_MAN_FEATURE(OFF)
 558 DX_RTF_FEATURE(OFF)
 559 DX_XML_FEATURE(OFF)
 560 DX_PDF_FEATURE(OFF)
 561 DX_PS_FEATURE(OFF)
 562 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 563
 564 #
 565 # Build and Install man pages
 566 #
 567 AC_ARG_ENABLE(manpages,
 568         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 569 [case "${enableval}" in
 570   yes) manpages=yes ;;
 571   no)  manpages=no ;;
 572   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 573 esac],[manpages=yes])
 574
 575 if test x$manpages = xyes ; then
 576     #
 577     # XMLTOMAN manpage generation
 578     #
 579     AC_ARG_ENABLE(xmltoman,
 580     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 581     [case "${enableval}" in
 582       yes) xmltoman=yes ;;
 583       no)  xmltoman=no ;;
 584       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 585     esac],[xmltoman=yes])
 586
 587     if test x$xmltoman = xyes ; then
 588         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 589     fi
 590
 591     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 592         if ! test -e man/avahi-daemon.8 ; then
 593             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 594             exit 1
 595         fi
 596         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 597         xmltoman=no
 598     fi
 599 fi
 600 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 601 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 602
 603 #
 604 # Conditionally compile test and example programs
 605 #
 606 AC_ARG_ENABLE(tests,
 607         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 608         [case "${enableval}" in
 609                 yes) ENABLE_TESTS=yes ;;
 610                 no)  ENABLE_TESTS=no ;;
 611                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 612         esac],
 613         [ENABLE_TESTS=no])
 614
 615 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 616
 617 #
 618 # Optionally enable libdns_sd compatibility support
 619 #
 620 AC_ARG_ENABLE(compat-libdns_sd,
 621         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 622         [case "${enableval}" in
 623                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 624                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 625                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 626         esac],
 627         [ENABLE_COMPAT_LIBDNS_SD=no])
 628
 629 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 630
 631 #
 632 # Optionally enable HOWL compatibility support
 633 #
 634 AC_ARG_ENABLE(compat-howl,
 635         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 636         [case "${enableval}" in
 637                 yes) ENABLE_COMPAT_HOWL=yes ;;
 638                 no)  ENABLE_COMPAT_HOWL=no ;;
 639                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 640         esac],
 641         [ENABLE_COMPAT_HOWL=no])
 642
 643 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 644
 645
 646 # ==========================================================================
 647 AC_CONFIG_FILES([
 648 Makefile
 649 avahi-common/Makefile
 650 avahi-core/Makefile
 651 avahi-glib/Makefile
 652 avahi-qt/Makefile
 653 avahi-daemon/Makefile
 654 avahi-daemon/avahi-dbus.conf
 655 avahi-discover-standalone/Makefile
 656 avahi-client/Makefile
 657 initscript/Makefile
 658 initscript/debian/Makefile
 659 initscript/gentoo/Makefile
 660 initscript/archlinux/Makefile
 661 initscript/suse/Makefile
 662 initscript/fedora/Makefile
 663 avahi-dnsconfd/Makefile
 664 avahi-utils/Makefile
 665 avahi-utils/avahi/Makefile
 666 examples/Makefile
 667 common/Makefile
 668 man/Makefile
 669 tests/Makefile
 670 service-type-database/Makefile
 671 avahi-sharp/Makefile
 672 avahi-compat-libdns_sd/Makefile
 673 avahi-compat-howl/Makefile
 674 avahi-compat-howl/samples/Makefile
 675 ])
 676 AC_OUTPUT
 677
 678 # ==========================================================================
 679 echo "
 680  ---{ $PACKAGE_NAME $VERSION }---
 681
 682     prefix:                 ${prefix}
 683     sysconfdir:             ${sysconfdir}
 684     localstatedir:          ${localstatedir}
 685     avahi socket:           ${avahi_socket}
 686     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 687     dbus-1 version:         `pkg-config dbus-1 --modversion`
 688     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 689     compiler:               ${CC}
 690     cflags:                 ${CFLAGS}
 691     Enable GLIB:            ${HAVE_GLIB}
 692     Enable GTK:             ${HAVE_GTK}
 693     Enable D-BUS:           ${HAVE_DBUS}
 694     Enable Expat:           ${HAVE_EXPAT}
 695     Enable libdaemon:       ${HAVE_LIBDAEMON}
 696     Enable Python:          ${HAVE_PYTHON}
 697     Enable pygtk:           ${HAVE_PYGTK}
 698     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 699     Enable QT3:             ${HAVE_QT3}
 700     Enable QT4:             ${HAVE_QT4}
 701     Enable Mono:            ${HAVE_MONO}
 702     Linux Distro:           ${with_distro}
 703     User for Avahi:         ${AVAHI_USER}
 704     Group for Avahi:        ${AVAHI_GROUP}
 705 "
 706
 707 BUILD_DAEMON="no (!)"
 708
 709 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 710     BUILD_DAEMON=yes
 711 fi
 712
 713 BUILD_UTILS="no (!)"
 714
 715 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 716     BUILD_UTILS=yes
 717 fi
 718
 719 BUILD_CLIENT="no (!)"
 720
 721 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 722     BUILD_CLIENT=yes
 723 fi
 724
 725 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 726    AC_MSG_ERROR([building avahi-compat-libdns_sd without building libavahi-client doesn't work])
 727 fi
 728 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 729    AC_MSG_ERROR([building avahi-compat-howl without building libavahi-client doesn't work])
 730 fi
 731
 732
 733 echo "
 734     Building libavahi-core              yes
 735     Building avahi-daemon:              ${BUILD_DAEMON}
 736     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 737     Building avahi-utils:               ${BUILD_UTILS}
 738     Building libavahi-glib:             ${HAVE_GLIB}
 739     Building libavahi-client:           ${BUILD_CLIENT}
 740     Building avahi-discover-standalone: ${HAVE_GTK}
 741     Building libavahi-qt3:              ${HAVE_QT3}
 742     Building libavahi-qt4:              ${HAVE_QT4}
 743     Building avahi-sharp:               ${HAVE_MONO}
 744     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 745     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 746     Building tests:                     ${ENABLE_TESTS}
 747 "