git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6.23],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://avahi.org/])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [8:0:5])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [5:5:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [5:4:2])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:1:0])
  35 AC_SUBST(LIBAVAHI_GOBJECT_VERSION_INFO, [0:1:0])
  36 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:2:0])
  37 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:2:0])
  38 AC_SUBST(LIBAVAHI_UI_VERSION_INFO, [1:0:1])
  39
  40 # Do not touch these, since they we took this version-info from upstream HOWL/Bonjour
  41 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  42 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  43 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 # Checks for programs.
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AC_GNU_SOURCE
  54 AC_PROG_CPP
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_GCC_TRADITIONAL
  59
  60 AM_PROG_CC_C_O
  61
  62 # -fstack-protector
  63 AC_ARG_ENABLE([stack-protector],
  64     [AS_HELP_STRING([--disable-stack-protector],
  65         [Disable GCC's/libc's stack-smashing protection])],
  66     [case "${enableval}" in
  67          yes) enable_ssp=yes ;;
  68           no) enable_ssp=no ;;
  69            *) AC_MSG_ERROR([invalid value ${enableval} for --disable-stack-protector]) ;;
  70      esac],
  71     [enable_ssp=yes])
  72
  73 if test x"$enable_ssp" = x"yes" && test x"$GCC" != x"yes"; then
  74     AC_MSG_NOTICE([Disabling stack-smashing protection because compiler is not GCC])
  75     enable_ssp=no
  76 fi
  77
  78 if test x"$enable_ssp" = x"yes"; then
  79     # Check for broken ssp in libc: http://www.avahi.org/ticket/105
  80     # libc's brokenness will get in the way regardless of whether -lssp is
  81     # provided, but provide it anyway (otherwise non-libc ssp would wrongly
  82     # break here)
  83
  84     # Get -lssp if it exists
  85     GCC_STACK_PROTECT_LIB
  86
  87     AC_MSG_CHECKING([whether stack-smashing protection is available])
  88     ssp_old_cflags="$CFLAGS"
  89     ssp_old_ldflags="$LDFLAGS"
  90     CFLAGS="$CFLAGS -Werror -fstack-protector-all -fPIC"
  91     LDFLAGS="$LDFLAGS -Wl,-z,defs"
  92     cat confdefs.h > conftest.c
  93     cat >>conftest.c <<_ACEOF
  94 void test_broken_ssp(c)
  95     const char *c;
  96 {
  97     char arr[[123]], *p; /* beware of possible double-braces if copying this */
  98     for (p = arr; *c; ++p) {
  99         *p = *c;
 100         ++c;
 101     }
 102 }
 103 _ACEOF
 104     rm -f conftest.o
 105
 106     if $CC -c $CFLAGS $CPPFLAGS -o conftest.o conftest.c >/dev/null 2>&1; then
 107         AC_MSG_RESULT([yes])
 108         AC_MSG_CHECKING([whether stack-smashing protection is buggy])
 109         if $CC -o conftest.so $LDFLAGS -shared conftest.o $LIBS >/dev/null 2>&1; then
 110             AC_MSG_RESULT([no])
 111         else
 112             AC_MSG_RESULT([yes])
 113             enable_ssp=no
 114         fi
 115     else
 116         AC_MSG_RESULT([no])
 117     fi
 118
 119     rm -f conftest.c conftest.o conftest.so
 120
 121     CFLAGS="$ssp_old_cflags"
 122     LDFLAGS="$ssp_old_ldflags"
 123 fi
 124
 125 if test x"$enable_ssp" = x"yes"; then
 126     # Do this the long way so we don't call GCC_STACK_PROTECT_LIB twice
 127     GCC_STACK_PROTECT_CC
 128
 129     AC_LANG_PUSH([C++])
 130     GCC_STACK_PROTECT_CXX
 131     AC_LANG_POP([C++])
 132     # XXX: Update the enable_ssp value now for output later?
 133 fi
 134
 135 # libtool stuff
 136 AC_PROG_LIBTOOL
 137
 138 AC_CACHE_CHECK([whether the C++ compiler works], [avahi_cv_sys_cxx_works], [
 139     AC_LANG_PUSH([C++])
 140     AC_COMPILE_IFELSE([int main() { return 0; }], [avahi_cv_sys_cxx_works=yes],
 141         [avahi_cv_sys_cxx_works=no])
 142     AC_LANG_POP([C++])
 143     ])
 144 [ if [ "x$avahi_cv_sys_cxx_works" = "xno" ]; then ]
 145     AC_MSG_FAILURE([The C++ compiler does not work])
 146 [ fi ]
 147
 148 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
 149
 150 #
 151 # Check for netlink.h
 152 #
 153 AC_CHECK_HEADER(linux/netlink.h,
 154 HAVE_NETLINK=yes
 155 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
 156 , [], [
 157 #include <sys/socket.h>
 158 #include <asm/types.h>
 159 ])
 160
 161 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
 162
 163 #
 164 # Check for net/route.h
 165 #
 166 AC_CHECK_HEADER(net/route.h,
 167 HAVE_PF_ROUTE=yes
 168 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
 169 , [], [
 170 #include <sys/types.h>
 171 #include <sys/socket.h>
 172 ])
 173
 174 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
 175
 176 #
 177 # Check for sys/filio.h; needed for FIONREAD on Solaris
 178 #
 179 AC_CHECK_HEADER(sys/filio.h,
 180 HAVE_SYS_FILIO_H=yes
 181 AC_DEFINE([HAVE_SYS_FILIO_H],[],[Support for sys/filio.h])
 182 , [], [
 183 ])
 184
 185 AM_CONDITIONAL(HAVE_SYS_FILIO_H, [ test x"$HAVE_SYS_FILIO_H" = xyes ])
 186
 187 #
 188 # Check for sys/sysctl.h; not present on Solaris
 189 #
 190 AC_CHECK_HEADER(sys/sysctl.h,
 191 HAVE_SYS_SYSCTL=yes
 192 AC_DEFINE([HAVE_SYS_SYSCTL_H],[],[Support for sys/sysctl.h])
 193 , [], [
 194 #include <sys/types.h>
 195 #include <sys/socket.h>
 196 #include <sys/param.h>
 197 ])
 198
 199 AM_CONDITIONAL(HAVE_SYS_SYSCTL_H, [ test x"$HAVE_SYS_SYSCTL_H" = xyes ])
 200
 201 #
 202 # Check for lifconf struct; only present on Solaris
 203 #
 204 AC_MSG_CHECKING(for struct lifconf)
 205 AC_CACHE_VAL(avahi_cv_has_struct_lifconf,
 206 [AC_TRY_COMPILE(
 207 [#include <sys/socket.h>
 208 #include <net/if.h>
 209 ],[sizeof (struct lifconf);],
 210 avahi_cv_has_struct_lifconf=yes,avahi_cv_has_struct_lifconf=no)])
 211 AC_MSG_RESULT($avahi_cv_has_struct_lifconf)
 212 if test $avahi_cv_has_struct_lifconf = yes; then
 213     AC_DEFINE(HAVE_STRUCT_LIFCONF,1,[Define if there is a struct lifconf.])
 214 fi
 215
 216 #
 217 # Check for struct ip_mreqn
 218 #
 219 AC_MSG_CHECKING(for struct ip_mreqn)
 220 AC_TRY_COMPILE([#include <netinet/in.h>], [
 221         struct ip_mreqn mreq;
 222         mreq.imr_address.s_addr = 0;
 223 ], [
 224         # Yes, we have it...
 225         AC_MSG_RESULT(yes)
 226         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
 227 ], [
 228         # We'll just have to try and use struct ip_mreq
 229         AC_MSG_RESULT(no)
 230         AC_MSG_CHECKING(for struct ip_mreq)
 231         AC_TRY_COMPILE([#include <netinet/in.h>], [
 232                 struct ip_mreq mreq;
 233                 mreq.imr_interface.s_addr = 0;
 234         ], [
 235                 # Yes, we have it...
 236                 AC_MSG_RESULT(yes)
 237                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 238         ], [
 239                 # No multicast support
 240                         AC_MSG_RESULT(no)
 241         ])
 242 ])
 243
 244 #
 245 # Detecting the linux distribution for specific things like init scripts.
 246 #
 247 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, mandriva, darwin, netbsd, freebsd, slackware or none]))
 248 if test "z$with_distro" = "z"; then
 249     if test "$cross_compiling" = yes; then
 250         AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 251     else
 252         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 253         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 254         AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 255         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 256         AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 257         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
 258         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 259     fi
 260     if test "z$with_distro" = "z"; then
 261         with_distro=`uname -s`
 262     fi
 263 fi
 264 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 265
 266 case $with_distro in
 267     debian|gentoo|archlinux|suse|fedora|mandriva|darwin|freebsd|slackware|none)
 268      ;;
 269     netbsd)
 270      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 271      ;;
 272     linux)
 273      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 274      ;;
 275     *)
 276      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and D-Bus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 277      ;;
 278 esac
 279
 280 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 281 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 282 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 283 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 284 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 285 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 286 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 287 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 288 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 289 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 290
 291 test_gcc_flag() {
 292     AC_LANG_CONFTEST([int main() {}])
 293     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 294     ret=$?
 295     rm -f conftest.o
 296     return $ret
 297 }
 298
 299 # If using GCC specify some additional parameters
 300 if test "x$GCC" = "xyes" ; then
 301
 302     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -fPIC"
 303
 304     if test "x$HAVE_NETLINK" = "xyes" ; then
 305         # Test whether rtnetlink.h can be included when compiled with -std=c99
 306         # some distributions (e.g. archlinux) have broken headers that dont
 307         # define __u64 with -std=c99
 308         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 309         OLDCFLAGS="$CFLAGS"
 310         CFLAGS="-std=c99"
 311         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 312             use_stdc99=yes, use_stdc99=no)
 313
 314         if test x"$use_stdc99" = xyes; then
 315             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 316             AC_MSG_RESULT([yes])
 317         else
 318             AC_MSG_RESULT([no])
 319         fi
 320
 321         CFLAGS="$OLDCFLAGS"
 322     else
 323         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 324     fi
 325
 326     for flag in $DESIRED_FLAGS ; do
 327         AC_MSG_CHECKING([whether $CC accepts $flag])
 328         if test_gcc_flag $flag ; then
 329            CFLAGS="$CFLAGS $flag"
 330            AC_MSG_RESULT([yes])
 331         else
 332            AC_MSG_RESULT([no])
 333         fi
 334     done
 335 fi
 336
 337 # Checks for header files.
 338 AC_HEADER_STDC
 339 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 340 AC_HEADER_STDBOOL
 341
 342 # Checks for typedefs, structures, and compiler characteristics.
 343 AC_C_CONST
 344 AC_TYPE_SIZE_T
 345 AC_HEADER_TIME
 346 AC_HEADER_SYS_WAIT
 347
 348  # Solaris stuff
 349  AC_SEARCH_LIBS([inet_ntop],[nsl])
 350  AC_SEARCH_LIBS([recv],[socket])
 351  AC_CHECK_DECL([CMSG_SPACE],,CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500 -D__EXTENSIONS__")
 352
 353 # Checks for library functions.
 354 AC_FUNC_MEMCMP
 355 AC_FUNC_SELECT_ARGTYPES
 356 # avahi_malloc actually returns NULL for avahi_malloc(0), so it does not matter
 357 # whether libc's malloc does too. (Same for realloc.)
 358 #AC_FUNC_MALLOC
 359 #AC_FUNC_REALLOC
 360 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 361
 362 AC_FUNC_CHOWN
 363 AC_FUNC_STAT
 364 AC_TYPE_MODE_T
 365 AC_TYPE_PID_T
 366
 367 AC_CHECK_DECLS(environ)
 368
 369 # check if gcc's -fvisibility is supported
 370 CHECK_VISIBILITY_HIDDEN
 371
 372 enable_chroot=yes
 373 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 374 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 375 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 376
 377 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 378
 379 if test "x$enable_chroot" = "xyes" ; then
 380    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 381 fi
 382
 383 AC_CHECK_LIB(dl, dlopen, [ AC_CHECK_HEADERS(dlfcn.h, HAVE_DLOPEN=yes, HAVE_DLOPEN=no) ], HAVE_DLOPEN=no)
 384 if test "x$HAVE_DLOPEN" = "xyes" ; then
 385     AC_DEFINE([HAVE_DLOPEN],1,[Have dlopen()])
 386 fi
 387 AM_CONDITIONAL(HAVE_DLOPEN, test "x$HAVE_DLOPEN" = "xyes")
 388
 389 have_inotify=no
 390 AC_CHECK_HEADERS([linux/inotify.h], [have_inotify=yes])
 391 AC_CHECK_HEADERS([sys/inotify.h], [have_inotify=yes])
 392
 393 AM_CONDITIONAL(HAVE_INOTIFY, test "x$have_inotify" = "xyes")
 394
 395 if test "x$have_inotify" = "xyes" ; then
 396    AC_DEFINE([HAVE_INOTIFY], 1, [Enable Linux inotify() usage])
 397 fi
 398
 399 have_kqueue=yes
 400 AC_CHECK_FUNCS([kqueue],,have_kqueue=no)
 401
 402 AM_CONDITIONAL(HAVE_KQUEUE, test "x$have_kqueue" = "xyes")
 403
 404 if test "x$have_kqueue" = "xyes" ; then
 405     AC_DEFINE([HAVE_KQUEUE], 1, [Enable BSD kqueue() usage])
 406 fi
 407
 408 AM_GNU_GETTEXT([external])
 409
 410 IT_PROG_INTLTOOL([0.35.0])
 411 GETTEXT_PACKAGE=avahi
 412 AC_SUBST([GETTEXT_PACKAGE])
 413 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 414 AM_GLIB_GNU_GETTEXT
 415
 416 avahilocaledir='${prefix}/${DATADIRNAME}/locale'
 417 AC_SUBST(avahilocaledir)
 418
 419
 420 # Check for pkg-config manually first, as if its not installed the
 421 # PKG_PROG_PKG_CONFIG macro won't be defined.
 422 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 423
 424 if test x"$have_pkg_config" = "xno"; then
 425     AC_MSG_ERROR(pkg-config is required to install this program)
 426 fi
 427
 428 PKG_PROG_PKG_CONFIG
 429
 430 #
 431 # Check for GLIB 2.0
 432 #
 433 AC_ARG_ENABLE(glib,
 434         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 435         [case "${enableval}" in
 436                 yes) HAVE_GLIB=yes ;;
 437                 no)  HAVE_GLIB=no ;;
 438                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 439         esac],
 440         [HAVE_GLIB=yes])
 441
 442 if test "x$HAVE_GLIB" = "xyes" ; then
 443         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 444         AC_SUBST(GLIB20_CFLAGS)
 445         AC_SUBST(GLIB20_LIBS)
 446 fi
 447 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 448
 449 #
 450 # Check for GLIB's gobject 2.0
 451 #
 452 AC_ARG_ENABLE(gobject,
 453         AS_HELP_STRING([--disable-gobject],[Disable use of GLib GObject]),
 454         [case "${enableval}" in
 455                 yes) HAVE_GOBJECT=yes ;;
 456                 no)  HAVE_GOBJECT=no ;;
 457                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gobject) ;;
 458         esac],
 459         [HAVE_GOBJECT=yes])
 460
 461 if test "x$HAVE_GOBJECT" = "xyes" ; then
 462         PKG_CHECK_MODULES(GOBJECT, [ glib-2.0 >= 2.4.0 gobject-2.0 ])
 463         AC_SUBST(GOBJECT_CFLAGS)
 464         AC_SUBST(GOBJECT_LIBS)
 465 fi
 466 AM_CONDITIONAL(HAVE_GOBJECT, test "x$HAVE_GOBJECT" = "xyes")
 467
 468 #
 469 # Check for Qt 3
 470 #
 471 AC_ARG_ENABLE(qt3,
 472         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 473         [case "${enableval}" in
 474                 yes) HAVE_QT3=yes ;;
 475                 no)  HAVE_QT3=no ;;
 476                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 477         esac],
 478         [HAVE_QT3=yes])
 479
 480 if test "x$HAVE_QT3" = "xyes" ; then
 481         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 482         AC_SUBST(QT3_CFLAGS)
 483         AC_SUBST(QT3_LIBS)
 484             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 485         AC_PATH_PROGS(MOC_QT3, [moc-qt3 moc], no, [$QT3_PREFIX])
 486         if test "$MOC_QT3" = no; then
 487             AC_MSG_ERROR([Could not find QT3 moc])
 488         fi
 489         AC_SUBST(MOC_QT3)
 490 fi
 491 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 492
 493 #
 494 # Check for Qt 4
 495 #
 496 AC_ARG_ENABLE(qt4,
 497         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 498         [case "${enableval}" in
 499                 yes) HAVE_QT4=yes ;;
 500                 no)  HAVE_QT4=no ;;
 501                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 502         esac],
 503         [HAVE_QT4=yes])
 504
 505 if test "x$HAVE_QT4" = "xyes" ; then
 506         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 507         AC_SUBST(QT4_CFLAGS)
 508         AC_SUBST(QT4_LIBS)
 509             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 510         AC_PATH_PROGS(MOC_QT4, [moc-qt4 moc], no, [$QT4_PREFIX])
 511         if test "$MOC_QT4" = no; then
 512             AC_MSG_ERROR([Could not find QT4 moc])
 513         fi
 514         AC_SUBST(MOC_QT4)
 515 fi
 516 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 517
 518 #
 519 # Check for GTK+
 520 #
 521 AC_ARG_ENABLE(gtk,
 522         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 523         [case "${enableval}" in
 524                 yes) HAVE_GTK=yes ;;
 525                 no)  HAVE_GTK=no ;;
 526                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 527         esac],
 528         [HAVE_GTK=yes])
 529
 530 if test "x$HAVE_GTK" = "xyes" ; then
 531         # Check for GTK 2.0
 532         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 533         AC_SUBST(GTK20_CFLAGS)
 534         AC_SUBST(GTK20_LIBS)
 535
 536         # Check for GLADE 2.0
 537         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 538         AC_SUBST(GLADE20_CFLAGS)
 539         AC_SUBST(GLADE20_LIBS)
 540 fi
 541 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 542
 543 #
 544 # D-Bus
 545 #
 546 AC_ARG_ENABLE(dbus,
 547         AS_HELP_STRING([--disable-dbus],[Disable use of D-Bus]),
 548         [case "${enableval}" in
 549                 yes) HAVE_DBUS=yes ;;
 550                 no)  HAVE_DBUS=no ;;
 551                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 552         esac],
 553         [HAVE_DBUS=yes])
 554
 555 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [Path to D-Bus system.d directory]))
 556 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [Path to the D-Bus system socket, you probably want to put unix:path= at the start. Only needed for very old D-Bus releases]))
 557
 558 DBUS_VERSION="Disabled"
 559 DBUS_SYS_DIR="Disabled"
 560 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="Disabled"
 561 if test "x$HAVE_DBUS" = "xyes" ; then
 562     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 563
 564     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-Bus or not])
 565
 566     DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 567     DBUS_VERSION_MAJOR=`echo $DBUS_VERSION | awk -F. '{print $1}'`
 568     DBUS_VERSION_MINOR=`echo $DBUS_VERSION | awk -F. '{print $2}'`
 569     DBUS_VERSION_MICRO=`echo $DBUS_VERSION | awk -F. '{print $3}'`
 570     if test "z$DBUS_VERSION_MAJOR" = "z"; then
 571         DBUS_VERSION_MAJOR="0"
 572     fi
 573     if test "z$DBUS_VERSION_MINOR" = "z"; then
 574         DBUS_VERSION_MINOR="0"
 575     fi
 576     if test "z$DBUS_VERSION_MICRO" = "z"; then
 577         DBUS_VERSION_MICRO="0"
 578     fi
 579
 580     if test "z$DBUS_VERSION_MAJOR" = "z0" -a "z$DBUS_VERSION_MINOR" = "z0" -a "z$DBUS_VERSION_MICRO" = "z0"; then
 581         echo "Error: Couldn't determine the version of your D-Bus package."
 582         echo "  This is probably an error in this script, please report it"
 583         echo "  along with the following information:"
 584         echo "      Base D-Buss version ='$DBUS_VERSION'"
 585         echo "      DBUS_VERSION_MAJOR='$DBUS_VERSION_MAJOR'"
 586         echo "      DBUS_VERSION_MINOR='$DBUS_VERSION_MINOR'"
 587         echo "      DBUS_VERSION_MICRO='$DBUS_VERSION_MICRO'"
 588         exit 1
 589     else
 590         echo "Your D-Bus version is $DBUS_VERSION_MAJOR,$DBUS_VERSION_MINOR,$DBUS_VERSION_MICRO."
 591         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MAJOR=$DBUS_VERSION_MAJOR"
 592         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MINOR=$DBUS_VERSION_MINOR"
 593         DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_VERSION_MICRO=$DBUS_VERSION_MICRO"
 594     fi
 595
 596     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 597     AC_SUBST(DBUS_CFLAGS)
 598     AC_SUBST(DBUS_LIBS)
 599
 600     if ! test -z "$with_dbus_sys" ; then
 601         DBUS_SYS_DIR="$with_dbus_sys"
 602     else
 603         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 604     fi
 605     AC_SUBST(DBUS_SYS_DIR)
 606
 607     if ! test -z "$with_dbus_system_address" ; then
 608         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 609     else
 610         # This is ugly, but D-Bus doesn't export this address for us
 611         # so we have to guess, pretty much all setups i've seen have
 612         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 613         # /var/run upstream so we will try guess first then default
 614         # to /var/run/dbus.
 615
 616         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 617         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 618         for sock in $TRY_SOCKETS; do
 619             if test -S $sock; then
 620                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 621             fi
 622         done
 623     fi
 624     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 625
 626     SAVED_LIBS="$LIBS"
 627     LIBS="$LIBS $DBUS_LIBS"
 628     AC_CHECK_FUNCS([dbus_connection_close dbus_bus_get_private])
 629     LIBS="$SAVED_LIBS"
 630 fi
 631 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 632
 633 #
 634 # Expat
 635 #
 636 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[expat/bsdxml/none]],[XML library to use]))
 637 use_expat=false
 638 use_bsdxml=false
 639
 640 # See what we have
 641 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 642 AC_CHECK_LIB(bsdxml, XML_ParserCreate, [ AC_CHECK_HEADERS(bsdxml.h, have_bsdxml=true, have_bsdxml=false) ], have_bsdxml=false)
 643
 644 if test "x$with_xml" = "xnone"; then
 645         :
 646 elif test "x$with_xml" = "xexpat"; then
 647         use_expat=true
 648         if ! $have_expat ; then
 649                 AC_MSG_ERROR([*** libexpat requested, but not found ***])
 650         fi
 651 elif test "x$with_xml" = "xbsdxml"; then
 652         use_bsdxml=true
 653         if ! $have_bsdxml ; then
 654                 AC_MSG_ERROR([*** libbsdxml requested, but not found ***])
 655         fi
 656 elif test "x$with_xml" != "x"; then
 657         AC_MSG_ERROR([*** unknown with-xml option ***])
 658 else
 659         if $have_expat ; then
 660                 use_expat=true
 661         elif $have_bsdxml ; then
 662                 use_bsdxml=true
 663         else
 664                 AC_MSG_ERROR([*** neither libexpat not libbsdxml could be found ***])
 665         fi
 666 fi
 667
 668 if $use_expat; then
 669         with_xml=expat
 670         XML_CFLAGS=-DUSE_EXPAT_H
 671         XML_LIBS=-lexpat
 672 fi
 673 if $use_bsdxml; then
 674         with_xml=bsdxml
 675         XML_CFLAGS=-DUSE_BSDXML_H
 676         XML_LIBS=-lbsdxml
 677 fi
 678 AC_SUBST(XML_LIBS)
 679 AC_SUBST(XML_CFLAGS)
 680
 681 if $use_expat || $use_bsdxml; then
 682         HAVE_XML=yes
 683 fi
 684
 685 AM_CONDITIONAL(HAVE_XML, test "x$HAVE_XML" = "xyes")
 686
 687 #
 688 # GDBM
 689 #
 690 #
 691 # Check for dbm
 692 #
 693 AC_ARG_ENABLE(dbm,
 694         AS_HELP_STRING([--enable-dbm],[Enable use of DBM]),
 695         [case "${enableval}" in
 696                 yes) HAVE_DBM=yes ;;
 697                 no)  HAVE_DBM=no ;;
 698                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbm) ;;
 699         esac],
 700         [HAVE_DBM=no])
 701
 702 AC_ARG_ENABLE(gdbm,
 703         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 704         [case "${enableval}" in
 705                 yes) HAVE_GDBM=yes ;;
 706                 no)  HAVE_GDBM=no ;;
 707                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gdbm) ;;
 708         esac],
 709         [HAVE_GDBM=yes])
 710
 711 if test "x$HAVE_GDBM" = "xyes" ; then
 712     if test "x$HAVE_DBM" = "xyes" ; then
 713         AC_MSG_ERROR([*** --enable-gdbm and --enable-dbm both specified ***])
 714     fi
 715     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 716
 717     if ! $have_gdbm ; then
 718         AC_MSG_ERROR([*** libgdbm not found ***])
 719     fi
 720     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 721 else
 722     if test "x$HAVE_DBM" = "xyes" ; then
 723         AC_CHECK_HEADERS(ndbm.h, have_dbm=true, have_dbm=false)
 724
 725         if ! $have_dbm ; then
 726             AC_MSG_ERROR([*** dbm not found ***])
 727         fi
 728         AC_DEFINE([HAVE_DBM],[],[Support for DBM])
 729     fi
 730 fi
 731 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 732 AM_CONDITIONAL(HAVE_DBM, test "x$HAVE_DBM" = "xyes")
 733
 734 #
 735 # libdaemon
 736 #
 737 AC_ARG_ENABLE(libdaemon,
 738         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 739         [case "${enableval}" in
 740                 yes) HAVE_LIBDAEMON=yes ;;
 741                 no)  HAVE_LIBDAEMON=no ;;
 742                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 743         esac],
 744         [HAVE_LIBDAEMON=yes])
 745
 746 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 747     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.11 ])
 748     AC_SUBST(LIBDAEMON_CFLAGS)
 749     AC_SUBST(LIBDAEMON_LIBS)
 750 fi
 751 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 752
 753 #
 754 # Python stuff
 755 #
 756 AC_ARG_ENABLE(python,
 757     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 758     [case "${enableval}" in
 759           yes) HAVE_PYTHON=yes ;;
 760           no)  HAVE_PYTHON=no ;;
 761           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 762     esac],[HAVE_PYTHON=yes])
 763
 764 HAVE_PYTHON_DBUS=no
 765 HAVE_PYGTK=no
 766
 767 if test "x$HAVE_PYTHON" = "xyes" ; then
 768     AM_PATH_PYTHON([2.4])
 769
 770     AC_ARG_ENABLE(pygtk,
 771         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 772         [case "${enableval}" in
 773                 yes) HAVE_PYGTK=yes ;;
 774                 no)  HAVE_PYGTK=no ;;
 775                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 776         esac],
 777         [HAVE_PYGTK=yes])
 778
 779     if test "x$HAVE_PYGTK" = "xyes" ; then
 780         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 781     fi
 782
 783
 784     if test "x$HAVE_DBUS" = "xyes" ; then
 785         AC_ARG_ENABLE(python-dbus,
 786             AS_HELP_STRING([--disable-python-dbus],[Disable use of D-Bus in Python]),
 787             [case "${enableval}" in
 788                    yes) HAVE_PYTHON_DBUS=yes ;;
 789                    no)  HAVE_PYTHON_DBUS=no ;;
 790                    *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 791             esac],
 792             [HAVE_PYTHON_DBUS=yes])
 793
 794         if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 795             AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 796         fi
 797
 798         AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 799         if test "x$HAVE_GDBM" = "xyes"; then
 800             AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 801         fi
 802         if test "x$HAVE_DBM" = "xyes"; then
 803             AM_CHECK_PYMOD(dbm,,,[AC_MSG_ERROR(Could not find Python module dbm)])
 804         fi
 805     fi
 806 fi
 807 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 808 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 809 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 810
 811 #
 812 # Check for mono stuff
 813 #
 814 HAVE_MONO=no
 815 if test "x$HAVE_DBUS" = "xyes" ; then
 816     AC_ARG_ENABLE(mono,
 817             AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 818             [case "${enableval}" in
 819                     yes) HAVE_MONO=yes ;;
 820                     no)  HAVE_MONO=no ;;
 821                     *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 822             esac],
 823             [HAVE_MONO=yes])
 824
 825     if test "x$HAVE_MONO" = "xyes" ; then
 826         AC_PATH_PROG(MCS, mcs)
 827         if test "x$MCS" = "x" ; then
 828             AC_MSG_ERROR([Can not find "mcs" - The Mono C-Sharp Compiler) in your PATH])
 829         fi
 830
 831         AC_PATH_PROG(GACUTIL, gacutil)
 832         if test "x$GACUTIL" = "x" ; then
 833             AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 834         fi
 835
 836         AC_SUBST(MCS)
 837         AC_SUBST(GACUTIL)
 838     fi
 839 fi
 840 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 841
 842 #
 843 # Check for monodoc stuff
 844 #
 845 HAVE_MONODOC=no
 846 AC_ARG_ENABLE(monodoc,
 847         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 848         [case "${enableval}" in
 849                 yes) HAVE_MONODOC=yes ;;
 850                 no)  HAVE_MONODOC=no ;;
 851                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 852         esac],
 853         [HAVE_MONODOC=yes])
 854
 855 if test "x$HAVE_MONO" = "xyes" && test "x$HAVE_MONODOC" = "xyes" ; then
 856         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 857         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 858
 859         AC_PATH_PROG(MONODOCER, monodocer)
 860         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 861
 862         AC_SUBST(MONODOC_DIR)
 863         AC_SUBST(MONODOCER)
 864         AC_SUBST(MDASSEMBLER)
 865 fi
 866 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 867
 868 #
 869 # Build autoipd?
 870 #
 871 AC_ARG_ENABLE(autoipd,
 872         AS_HELP_STRING([--disable-autoipd],[Disable building of avahi-autoipd]),
 873         [case "${enableval}" in
 874                 yes) ENABLE_AUTOIPD=yes ;;
 875                 no)  ENABLE_AUTOIPD=no ;;
 876                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-autoipd) ;;
 877         esac],
 878         [ENABLE_AUTOIPD=yes])
 879
 880 AM_CONDITIONAL(ENABLE_AUTOIPD, test "x$ENABLE_AUTOIPD" = "xyes")
 881
 882 #
 883 # Defining users and groups
 884 #
 885 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running avahi-daemon (avahi)]))
 886 if test -z "$with_avahi_user" ; then
 887     AVAHI_USER=avahi
 888 else
 889     AVAHI_USER=$with_avahi_user
 890 fi
 891 AC_SUBST(AVAHI_USER)
 892 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 893
 894 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for running avahi-daemon (avahi)]))
 895 if test -z "$with_avahi_group" ; then
 896     AVAHI_GROUP=avahi
 897 else
 898     AVAHI_GROUP=$with_avahi_group
 899 fi
 900 AC_SUBST(AVAHI_GROUP)
 901 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 902
 903 AC_ARG_WITH(avahi_priv_access_group,AS_HELP_STRING([--with-avahi-priv-access-group=<group>],[Priviliged access group for Avahi clients (netdev)]))
 904 if test -z "$with_avahi_priv_access_group" ; then
 905     AVAHI_PRIV_ACCESS_GROUP=netdev
 906 else
 907     AVAHI_PRIV_ACCESS_GROUP=$with_avahi_priv_access_group
 908 fi
 909 AC_SUBST(AVAHI_PRIV_ACCESS_GROUP)
 910 AC_DEFINE_UNQUOTED(AVAHI_PRIV_ACCESS_GROUP,"$AVAHI_PRIV_ACCESS_GROUP", [Privileged access group for Avahi clients])
 911
 912 AC_ARG_WITH(autoipd_user, AS_HELP_STRING([--with-autoipd-user=<user>],[User for running the avahi-autoipd daemon (avahi-autoipd)]))
 913 if test -z "$with_autoipd_user" ; then
 914     AVAHI_AUTOIPD_USER=avahi-autoipd
 915 else
 916     AVAHI_AUTOIPD_USER=$with_autoipd_user
 917 fi
 918 AC_SUBST(AVAHI_AUTOIPD_USER)
 919 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_USER,"$AVAHI_AUTOIPD_USER", [User for running the avahi-autoipd daemon])
 920
 921 AC_ARG_WITH(autoipd_group,AS_HELP_STRING([--with-autoipd-group=<group>],[Group for running the avahi-autoipd daemon (avahi-autoipd)]))
 922 if test -z "$with_autoipd_group" ; then
 923     AVAHI_AUTOIPD_GROUP=avahi-autoipd
 924 else
 925     AVAHI_AUTOIPD_GROUP=$with_autoipd_group
 926 fi
 927 AC_SUBST(AVAHI_AUTOIPD_GROUP)
 928 AC_DEFINE_UNQUOTED(AVAHI_AUTOIPD_GROUP,"$AVAHI_AUTOIPD_GROUP", [Group for running the avahi-autoipd daemon])
 929
 930 #
 931 # Avahi runtime dir
 932 #
 933 avahi_runtime_dir="${localstatedir}/run"
 934 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 935 AC_SUBST(avahi_runtime_dir)
 936 AC_SUBST(avahi_socket)
 937
 938 #
 939 # Avahi interfaces dir
 940 #
 941 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 942         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 943         AC_SUBST(interfacesdir)
 944 fi
 945
 946 #
 947 # Doxygen
 948 #
 949 DX_HTML_FEATURE(ON)
 950 DX_CHM_FEATURE(OFF)
 951 DX_CHI_FEATURE(OFF)
 952 DX_MAN_FEATURE(OFF)
 953 DX_RTF_FEATURE(OFF)
 954 DX_XML_FEATURE(ON)
 955 DX_PDF_FEATURE(OFF)
 956 DX_PS_FEATURE(OFF)
 957 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 958
 959 AC_ARG_ENABLE(core-docs,
 960         AS_HELP_STRING([--enable-core-docs],[Enable building of documentation for avahi-core]),
 961 [case "${enableval}" in
 962   yes) ENABLE_CORE_DOCS=yes ;;
 963   no)  ENABLE_CORE_DOCS=no ;;
 964   *) AC_MSG_ERROR([bad value ${enableval} for --enable-core-docs]) ;;
 965 esac],[ENABLE_CORE_DOCS=no])
 966
 967 AM_CONDITIONAL([ENABLE_CORE_DOCS], [test "x$ENABLE_CORE_DOCS" = xyes])
 968
 969 #
 970 # Build and Install man pages
 971 #
 972 AC_ARG_ENABLE(manpages,
 973         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 974 [case "${enableval}" in
 975   yes) manpages=yes ;;
 976   no)  manpages=no ;;
 977   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 978 esac],[manpages=yes])
 979
 980 if test x$manpages = xyes ; then
 981     #
 982     # XMLTOMAN manpage generation
 983     #
 984     AC_ARG_ENABLE(xmltoman,
 985     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 986     [case "${enableval}" in
 987       yes) xmltoman=yes ;;
 988       no)  xmltoman=no ;;
 989       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 990     esac],[xmltoman=yes])
 991
 992     if test x$xmltoman = xyes ; then
 993         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 994     fi
 995
 996     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 997         if ! test -e man/avahi-daemon.8 ; then
 998             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 999             exit 1
1000         fi
1001         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
1002         xmltoman=no
1003     fi
1004 fi
1005 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
1006 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1007
1008 #
1009 # Conditionally compile test and example programs
1010 #
1011 AC_ARG_ENABLE(tests,
1012         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
1013         [case "${enableval}" in
1014                 yes) ENABLE_TESTS=yes ;;
1015                 no)  ENABLE_TESTS=no ;;
1016                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
1017         esac],
1018         [ENABLE_TESTS=no])
1019
1020 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
1021
1022 #
1023 # Optionally enable libdns_sd compatibility support
1024 #
1025 AC_ARG_ENABLE(compat-libdns_sd,
1026         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
1027         [case "${enableval}" in
1028                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
1029                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
1030                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
1031         esac],
1032         [ENABLE_COMPAT_LIBDNS_SD=no])
1033
1034 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
1035
1036 #
1037 # Optionally enable HOWL compatibility support
1038 #
1039 AC_ARG_ENABLE(compat-howl,
1040         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
1041         [case "${enableval}" in
1042                 yes) ENABLE_COMPAT_HOWL=yes ;;
1043                 no)  ENABLE_COMPAT_HOWL=no ;;
1044                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
1045         esac],
1046         [ENABLE_COMPAT_HOWL=no])
1047
1048 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
1049
1050
1051 # ==========================================================================
1052 AC_CONFIG_FILES([
1053 Makefile
1054 avahi-common/Makefile
1055 avahi-core/Makefile
1056 avahi-glib/Makefile
1057 avahi-gobject/Makefile
1058 avahi-qt/Makefile
1059 avahi-daemon/Makefile
1060 avahi-daemon/avahi-dbus.conf
1061 avahi-discover-standalone/Makefile
1062 avahi-client/Makefile
1063 initscript/Makefile
1064 initscript/debian/Makefile
1065 initscript/gentoo/Makefile
1066 initscript/archlinux/Makefile
1067 initscript/suse/Makefile
1068 initscript/fedora/Makefile
1069 initscript/mandriva/Makefile
1070 initscript/darwin/Makefile
1071 initscript/freebsd/Makefile
1072 initscript/slackware/Makefile
1073 avahi-dnsconfd/Makefile
1074 avahi-utils/Makefile
1075 avahi-python/Makefile
1076 avahi-python/avahi/Makefile
1077 avahi-python/avahi-discover/Makefile
1078 examples/Makefile
1079 common/Makefile
1080 man/Makefile
1081 tests/Makefile
1082 service-type-database/Makefile
1083 avahi-sharp/Makefile
1084 avahi-ui-sharp/Makefile
1085 avahi-compat-libdns_sd/Makefile
1086 avahi-compat-howl/Makefile
1087 avahi-compat-howl/samples/Makefile
1088 avahi-autoipd/Makefile
1089 avahi-ui/Makefile
1090 po/Makefile.in
1091 ])
1092 AC_OUTPUT
1093
1094 # ==========================================================================
1095 echo "
1096  ---{ $PACKAGE_NAME $VERSION }---
1097
1098     prefix:                                    ${prefix}
1099     sysconfdir:                                ${sysconfdir}
1100     localstatedir:                             ${localstatedir}
1101     avahi socket:                              ${avahi_socket}
1102     dbus-1 system.d dir:                       ${DBUS_SYS_DIR}
1103     dbus-1 version:                            ${DBUS_VERSION}
1104     dbus-1 system socket:                      ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1105     C Compiler:                                ${CC}
1106     CFLAGS:                                    ${CFLAGS}
1107     Enable GLIB:                               ${HAVE_GLIB}
1108     Enable GLIB GObject:                       ${HAVE_GOBJECT}
1109     Enable GTK:                                ${HAVE_GTK}
1110     Enable D-Bus:                              ${HAVE_DBUS}
1111     With XML:                                  ${with_xml}
1112     Enable GDBM:                               ${HAVE_GDBM}
1113     Enable DBM:                                ${HAVE_DBM}
1114     Enable libdaemon:                          ${HAVE_LIBDAEMON}
1115     Enable Python:                             ${HAVE_PYTHON}
1116     Enable pygtk:                              ${HAVE_PYGTK}
1117     Enable python-dbus:                        ${HAVE_PYTHON_DBUS}
1118     Enable QT3:                                ${HAVE_QT3}
1119     Enable QT4:                                ${HAVE_QT4}
1120     Enable Mono:                               ${HAVE_MONO}
1121     Enable Monodoc:                            ${HAVE_MONODOC}
1122     Distribution/OS:                           ${with_distro}
1123     User for avahi-daemon:                     ${AVAHI_USER}
1124     Group for avahi-daemon:                    ${AVAHI_GROUP}
1125     Priviliged access group for Avahi clients: ${AVAHI_PRIV_ACCESS_GROUP}
1126     User for avahi-autoipd:                    ${AVAHI_AUTOIPD_USER}
1127     Group for avahi-autoipd:                   ${AVAHI_AUTOIPD_GROUP}
1128     Enable chroot():                           ${enable_chroot}
1129     Enable Linux inotify:                      ${have_inotify}
1130     Enable stack-smashing protection:          ${enable_ssp}
1131 "
1132
1133 BUILD_DAEMON="no   (You need libdaemon and expat/bsdxml!)"
1134
1135 if test "x$HAVE_XML" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
1136     BUILD_DAEMON=yes
1137 fi
1138
1139 BUILD_PYTHON="no   (You need python, pygtk and python-dbus!)"
1140
1141 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
1142     BUILD_PYTHON=yes
1143 fi
1144
1145 BUILD_CLIENT="no   (You need avahi-daemon and D-Bus!)"
1146
1147 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
1148     BUILD_CLIENT=yes
1149 fi
1150
1151 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1152    ENABLE_COMPAT_LIBDNS_SD="no   (You need libavahi-client!)"
1153 fi
1154 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
1155    ENABLE_COMPAT_HOWL="no   (You need libavahi-client!)"
1156 fi
1157 if test "x$ENABLE_AUTOIPD" = "xyes" -a "x$HAVE_LIBDAEMON" != "xyes" ; then
1158    ENABLE_AUTOIPD="no   (You need libdaemon!)"
1159 fi
1160
1161 BUILD_UI="no"
1162 if test "x$HAVE_GTK" = "xyes" -a "x$BUILD_CLIENT" = "xyes" ; then
1163    BUILD_UI="yes"
1164 fi
1165
1166 BUILD_GOBJECT="no"
1167 if test "x$BUILD_CLIENT" = "xyes" -a "x$HAVE_GOBJECT" = "xyes" ; then
1168    BUILD_GOBJECT="yes"
1169 fi
1170
1171 echo "\
1172     Building libavahi-core              yes
1173     Building avahi-daemon:              ${BUILD_DAEMON}
1174     Building avahi-dnsconfd:            ${BUILD_DAEMON}
1175     Building libavahi-client:           ${BUILD_CLIENT}
1176     Building avahi-utils:               ${BUILD_CLIENT}
1177     Building avahi-python:              ${BUILD_PYTHON}
1178     Building libavahi-glib:             ${HAVE_GLIB}
1179     Building libavahi-gobject:          ${BUILD_GOBJECT}
1180     Building avahi-discover-standalone: ${HAVE_GTK}
1181     Building libavahi-qt3:              ${HAVE_QT3}
1182     Building libavahi-qt4:              ${HAVE_QT4}
1183     Building avahi-sharp:               ${HAVE_MONO}
1184     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
1185     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
1186     Building tests:                     ${ENABLE_TESTS}
1187     Building avahi-core documentation:  ${ENABLE_CORE_DOCS}
1188     Building avahi-autoipd:             ${ENABLE_AUTOIPD}
1189     Building libavahi-ui:               ${BUILD_UI}
1190 "