git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.6],[avahi (at) lists (dot) freedesktop (dot) org])
  25 AC_CONFIG_SRCDIR([avahi-core/server.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 AC_SUBST(LIBAVAHI_COMMON_VERSION_INFO, [3:0:0])
  32 AC_SUBST(LIBAVAHI_CORE_VERSION_INFO, [3:0:0])
  33 AC_SUBST(LIBAVAHI_CLIENT_VERSION_INFO, [3:0:0])
  34 AC_SUBST(LIBAVAHI_GLIB_VERSION_INFO, [1:0:0])
  35 AC_SUBST(LIBAVAHI_QT3_VERSION_INFO, [1:0:0])
  36 AC_SUBST(LIBAVAHI_QT4_VERSION_INFO, [1:0:0])
  37 AC_SUBST(LIBAVAHI_COMPAT_LIBDNS_SD_VERSION_INFO, [1:0:0])
  38 AC_SUBST(LIBAVAHI_COMPAT_HOWL_VERSION_INFO, [0:0:0])
  39 AC_SUBST(HOWL_COMPAT_VERSION, [0.9.8])
  40
  41 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  42     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 fi
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AC_GNU_SOURCE
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53 AC_PROG_MAKE_SET
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 # libtool stuff
  57 AC_PROG_LIBTOOL
  58
  59 ACX_PTHREAD(,AC_MSG_ERROR([Missing POSIX Threads support]))
  60
  61 #
  62 # Check for netlink.h
  63 #
  64 AC_CHECK_HEADER(linux/netlink.h,
  65 HAVE_NETLINK=yes
  66 AC_DEFINE([HAVE_NETLINK],[],[Support for Linux netlink])
  67 , [], [
  68 #include <sys/socket.h>
  69 #include <asm/types.h>
  70 ])
  71
  72 AM_CONDITIONAL(HAVE_NETLINK, [ test x"$HAVE_NETLINK" = xyes ])
  73
  74 #
  75 # Check for net/route.h
  76 #
  77 AC_CHECK_HEADER(net/route.h,
  78 HAVE_PF_ROUTE=yes
  79 AC_DEFINE([HAVE_PF_ROUTE],[],[Support for PF_ROUTE])
  80 , [], [
  81 #include <sys/types.h>
  82 #include <sys/socket.h>
  83 ])
  84
  85 AM_CONDITIONAL(HAVE_PF_ROUTE, [ test x"$HAVE_PF_ROUTE" = xyes ])
  86
  87 #
  88 # Check for struct ip_mreqn
  89 #
  90 AC_MSG_CHECKING(for struct ip_mreqn)
  91 AC_TRY_COMPILE([#include <netinet/in.h>], [
  92         struct ip_mreqn mreq;
  93         mreq.imr_address.s_addr = 0;
  94 ], [
  95         # Yes, we have it...
  96         AC_MSG_RESULT(yes)
  97         AC_DEFINE([HAVE_STRUCT_IP_MREQN],[],[Support for struct ip_mreqn])
  98 ], [
  99         # We'll just have to try and use struct ip_mreq
 100         AC_MSG_RESULT(no)
 101         AC_MSG_CHECKING(for struct ip_mreq)
 102         AC_TRY_COMPILE([#include <netinet/in.h>], [
 103                 struct ip_mreq mreq;
 104                 mreq.imr_interface.s_addr = 0;
 105         ], [
 106                 # Yes, we have it...
 107                 AC_MSG_RESULT(yes)
 108                 AC_DEFINE([HAVE_STRUCT_IP_MREQ],[],[Support for struct ip_mreq])
 109         ], [
 110                 # No multicast support
 111                         AC_MSG_RESULT(no)
 112         ])
 113 ])
 114
 115 #
 116 # Detecting the linux distribution for specific things like init scripts.
 117 #
 118 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of debian, gentoo, archlinux, fedora, darwin, netbsd, freebsd or none]))
 119 if test "z$with_distro" = "z"; then
 120     AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 121     AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 122     AC_CHECK_FILE(/etc/arch-release,with_distro="archlinux")
 123     AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 124     AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 125     if test "z$with_distro" = "z"; then
 126         with_distro=`uname -s`
 127     fi
 128 fi
 129 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 130
 131 case $with_distro in
 132     debian|gentoo|archlinux|suse|fedora|darwin|none)
 133      ;;
 134     netbsd|freebsd)
 135      AC_MSG_WARN([Your distribution (${with_distro}) is supported but no init script exist yet! (patches welcome)])
 136      ;;
 137     linux)
 138      AC_MSG_ERROR([Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO, set DISTRO to none if your distribution is not supported.])
 139      ;;
 140     *)
 141      AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, init scripts and dbus configuration will not be installed! (patches welcome), you can specify --with-distro=none to skip this check])
 142      ;;
 143 esac
 144
 145 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 146 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 147 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 148 AM_CONDITIONAL(TARGET_ARCHLINUX, test x"$with_distro" = xarchlinux)
 149 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 150 AM_CONDITIONAL(TARGET_DARWIN, test x"$with_distro" = xdarwin)
 151 AM_CONDITIONAL(TARGET_NETBSD, test x"$with_distro" = xnetbsd)
 152 AM_CONDITIONAL(TARGET_FREEBSD, test x"$with_distro" = xfreebsd)
 153
 154 test_gcc_flag() {
 155     AC_LANG_CONFTEST([int main() {}])
 156     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
 157     ret=$?
 158     rm -f conftest.o
 159     return $ret
 160 }
 161
 162 # If using GCC specify some additional parameters
 163 if test "x$GCC" = "xyes" ; then
 164
 165     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline"
 166
 167     if test "x$HAVE_NETLINK" = "xyes" ; then
 168         # Test whether rtnetlink.h can be included when compiled with -std=c99
 169         # some distributions (e.g. archlinux) have broken headers that dont
 170         # define __u64 with -std=c99
 171         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
 172         OLDCFLAGS="$CFLAGS"
 173         CFLAGS="-std=c99"
 174         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
 175             use_stdc99=yes, use_stdc99=no)
 176
 177         if test x"$use_stdc99" = xyes; then
 178             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 179             AC_MSG_RESULT([yes])
 180         else
 181             AC_MSG_RESULT([no])
 182         fi
 183
 184         CFLAGS="$OLDCFLAGS"
 185     else
 186         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
 187     fi
 188
 189     for flag in $DESIRED_FLAGS ; do
 190         AC_MSG_CHECKING([whether $CC accepts $flag])
 191         if test_gcc_flag $flag ; then
 192            CFLAGS="$CFLAGS $flag"
 193            AC_MSG_RESULT([yes])
 194         else
 195            AC_MSG_RESULT([no])
 196         fi
 197     done
 198 fi
 199
 200 # Checks for header files.
 201 AC_HEADER_STDC
 202 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h netdb.h syslog.h])
 203 AC_HEADER_STDBOOL
 204
 205 # Checks for typedefs, structures, and compiler characteristics.
 206 AC_C_CONST
 207 AC_TYPE_SIZE_T
 208 AC_HEADER_TIME
 209 AC_HEADER_SYS_WAIT
 210
 211 # Checks for library functions.
 212 AC_FUNC_MEMCMP
 213 AC_FUNC_SELECT_ARGTYPES
 214 AC_FUNC_MALLOC
 215 AC_FUNC_REALLOC
 216 AC_CHECK_FUNCS([gethostname memchr memmove memset mkdir select socket strchr strcspn strdup strerror strrchr strspn strstr uname setresuid setreuid setresgid setregid strcasecmp gettimeofday putenv strncasecmp strlcpy gethostbyname seteuid setegid setproctitle getprogname])
 217
 218 AC_FUNC_CHOWN
 219 AC_FUNC_STAT
 220 AC_TYPE_MODE_T
 221 AC_TYPE_PID_T
 222
 223 AC_CHECK_DECLS(environ)
 224
 225 enable_chroot=yes
 226 AC_CHECK_HEADERS([sys/capability.h],,enable_chroot=no)
 227 AC_CHECK_HEADERS([sys/prctl.h],,enable_chroot=no)
 228 AC_CHECK_FUNCS([chroot],,enable_chroot=no)
 229
 230 AM_CONDITIONAL(ENABLE_CHROOT, test "x$enable_chroot" = "xyes")
 231
 232 if test "x$enable_chroot" = "xyes" ; then
 233    AC_DEFINE([ENABLE_CHROOT], 1, [Enable chroot() usage])
 234 fi
 235
 236 # Check for pkg-config manually first, as if its not installed the
 237 # PKG_PROG_PKG_CONFIG macro won't be defined.
 238 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 239
 240 if test x"$have_pkg_config" = "xno"; then
 241     AC_MSG_ERROR(pkg-config is required to install this program)
 242 fi
 243
 244 PKG_PROG_PKG_CONFIG
 245
 246 #
 247 # Check for GLIB 2.0
 248 #
 249 AC_ARG_ENABLE(glib,
 250         AS_HELP_STRING([--disable-glib],[Disable use of GLib]),
 251         [case "${enableval}" in
 252                 yes) HAVE_GLIB=yes ;;
 253                 no)  HAVE_GLIB=no ;;
 254                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-glib) ;;
 255         esac],
 256         [HAVE_GLIB=yes])
 257
 258 if test "x$HAVE_GLIB" = "xyes" ; then
 259         PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
 260         AC_SUBST(GLIB20_CFLAGS)
 261         AC_SUBST(GLIB20_LIBS)
 262 fi
 263 AM_CONDITIONAL(HAVE_GLIB, test "x$HAVE_GLIB" = "xyes")
 264
 265 #
 266 # Check for Qt 3
 267 #
 268 AC_ARG_ENABLE(qt3,
 269         AS_HELP_STRING([--disable-qt3],[Disable building of Qt3 mainloop integration]),
 270         [case "${enableval}" in
 271                 yes) HAVE_QT3=yes ;;
 272                 no)  HAVE_QT3=no ;;
 273                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt3) ;;
 274         esac],
 275         [HAVE_QT3=yes])
 276
 277 if test "x$HAVE_QT3" = "xyes" ; then
 278         PKG_CHECK_MODULES( QT3, [ qt-mt >= 3.0.0 ])
 279         AC_SUBST(QT3_CFLAGS)
 280         AC_SUBST(QT3_LIBS)
 281             QT3_PREFIX="`$PKG_CONFIG --variable=prefix qt-mt`/bin"
 282         MOC_QT3="no"
 283             AC_CHECK_FILE( "$QT3_PREFIX/moc-qt3", [ MOC_QT3=$QT3_PREFIX/moc-qt3 ], [
 284                     AC_CHECK_FILE("$QT3_PREFIX/moc", [ MOC_QT3=$QT3_PREFIX/moc ], [
 285                 AC_MSG_ERROR([Couldn't find QT3 moc])])])
 286         AC_SUBST(MOC_QT3)
 287 fi
 288 AM_CONDITIONAL(HAVE_QT3, test "x$HAVE_QT3" = "xyes")
 289
 290 #
 291 # Check for Qt 4
 292 #
 293 AC_ARG_ENABLE(qt4,
 294         AS_HELP_STRING([--disable-qt4],[Disable building of Qt4Core mainloop integration]),
 295         [case "${enableval}" in
 296                 yes) HAVE_QT4=yes ;;
 297                 no)  HAVE_QT4=no ;;
 298                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-qt4) ;;
 299         esac],
 300         [HAVE_QT4=yes])
 301
 302 if test "x$HAVE_QT4" = "xyes" ; then
 303         PKG_CHECK_MODULES( QT4, [ QtCore >= 4.0.0 ])
 304         AC_SUBST(QT4_CFLAGS)
 305         AC_SUBST(QT4_LIBS)
 306             QT4_PREFIX="`$PKG_CONFIG --variable=prefix QtCore`/bin"
 307         MOC_QT4="no"
 308             AC_CHECK_FILE( "$QT4_PREFIX/moc-qt4", [ MOC_QT4=$QT4_PREFIX/moc-qt4 ], [
 309                AC_CHECK_FILE("$QT4_PREFIX/moc", [ MOC_QT4=$QT4_PREFIX/moc ], [
 310                AC_MSG_ERROR([Couldn't find QT4 moc])])])
 311         AC_SUBST(MOC_QT4)
 312 fi
 313 AM_CONDITIONAL(HAVE_QT4, test "x$HAVE_QT4" = "xyes")
 314
 315 #
 316 # Check for GTK+
 317 #
 318 AC_ARG_ENABLE(gtk,
 319         AS_HELP_STRING([--disable-gtk],[Disable use of GTK+]),
 320         [case "${enableval}" in
 321                 yes) HAVE_GTK=yes ;;
 322                 no)  HAVE_GTK=no ;;
 323                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 324         esac],
 325         [HAVE_GTK=yes])
 326
 327 if test "x$HAVE_GTK" = "xyes" ; then
 328         # Check for GTK 2.0
 329         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
 330         AC_SUBST(GTK20_CFLAGS)
 331         AC_SUBST(GTK20_LIBS)
 332
 333         # Check for GLADE 2.0
 334         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
 335         AC_SUBST(GLADE20_CFLAGS)
 336         AC_SUBST(GLADE20_LIBS)
 337 fi
 338 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 339
 340 #
 341 # D-BUS
 342 #
 343 AC_ARG_ENABLE(dbus,
 344         AS_HELP_STRING([--disable-dbus],[Disable use of D-BUS]),
 345         [case "${enableval}" in
 346                 yes) HAVE_DBUS=yes ;;
 347                 no)  HAVE_DBUS=no ;;
 348                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 349         esac],
 350         [HAVE_DBUS=yes])
 351
 352 AC_ARG_WITH(dbus-sys, AS_HELP_STRING([--with-dbus-sys=<dir>], [where D-BUS system.d directory is]))
 353 AC_ARG_WITH(dbus-system-socket, AS_HELP_STRING([--with-dbus-system-address=<address>], [where the dbus system socket is, you probably want to put unix:path= at the start]))
 354
 355 if test "x$HAVE_DBUS" = "xyes" ; then
 356     AC_DEFINE(HAVE_DBUS, 1, [Whether we have D-BUS or not])
 357
 358     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 0.34 ])
 359     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 360     AC_SUBST(DBUS_CFLAGS)
 361     AC_SUBST(DBUS_LIBS)
 362
 363     if ! test -z "$with_dbus_sys" ; then
 364         DBUS_SYS_DIR="$with_dbus_sys"
 365     else
 366         DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 367     fi
 368     AC_SUBST(DBUS_SYS_DIR)
 369
 370     if ! test -z "$with_dbus_system_address" ; then
 371         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="$with_dbus_system_address"
 372     else
 373         # This is ugly, but D-BUS doesn't export this address for us
 374         # so we have to guess, pretty much all setups i've seen have
 375         # it in /var/lib/dbus or /var/run/dbus, and its defaulted to
 376         # /var/run upstream so we will try guess first then default
 377         # to /var/run/dbus
 378
 379         DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=/var/run/dbus/system_bus_socket"
 380         TRY_SOCKETS="/var/lib/dbus/system_bus_socket /var/run/dbus/system_bus_socket ${localstatedir}/run/dbus/system_bus_socket ${prefix}/var/run/dbus/system_bus_socket"
 381         for sock in $TRY_SOCKETS; do
 382             if test -S $sock; then
 383                 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$sock"
 384             fi
 385         done
 386     fi
 387     AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
 388
 389 fi
 390 AM_CONDITIONAL(HAVE_DBUS, test "x$HAVE_DBUS" = "xyes")
 391
 392 #
 393 # Expat
 394 #
 395 AC_ARG_ENABLE(expat,
 396         AS_HELP_STRING([--disable-expat],[Disable use of Expat]),
 397         [case "${enableval}" in
 398                 yes) HAVE_EXPAT=yes ;;
 399                 no)  HAVE_EXPAT=no ;;
 400                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-expat) ;;
 401         esac],
 402         [HAVE_EXPAT=yes])
 403
 404 if test "x$HAVE_EXPAT" = "xyes" ; then
 405     AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 406
 407     if ! $have_expat ; then
 408         AC_MSG_ERROR([*** libexpat not found ***])
 409     fi
 410 fi
 411 AM_CONDITIONAL(HAVE_EXPAT, test "x$HAVE_EXPAT" = "xyes")
 412
 413 #
 414 # GDBM
 415 #
 416 AC_ARG_ENABLE(gdbm,
 417         AS_HELP_STRING([--disable-gdbm],[Disable use of GDBM]),
 418         [case "${enableval}" in
 419                 yes) HAVE_GDBM=yes ;;
 420                 no)  HAVE_GDBM=no ;;
 421                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbm) ;;
 422         esac],
 423         [HAVE_GDBM=yes])
 424
 425 if test "x$HAVE_GDBM" = "xyes" ; then
 426     AC_CHECK_LIB(gdbm, gdbm_open, [ AC_CHECK_HEADERS(gdbm.h, have_gdbm=true, have_gdbm=false) ], have_gdbm=false)
 427
 428     if ! $have_gdbm ; then
 429         AC_MSG_ERROR([*** libgdbm not found ***])
 430     fi
 431     AC_DEFINE([HAVE_GDBM],[],[Support for GDBM])
 432 fi
 433 AM_CONDITIONAL(HAVE_GDBM, test "x$HAVE_GDBM" = "xyes")
 434
 435 #
 436 # libdaemon
 437 #
 438 AC_ARG_ENABLE(libdaemon,
 439         AS_HELP_STRING([--disable-libdaemon],[Disable use of libdaemon]),
 440         [case "${enableval}" in
 441                 yes) HAVE_LIBDAEMON=yes ;;
 442                 no)  HAVE_LIBDAEMON=no ;;
 443                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdaemon) ;;
 444         esac],
 445         [HAVE_LIBDAEMON=yes])
 446
 447 if test "x$HAVE_LIBDAEMON" = "xyes" ; then
 448     PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 449     AC_SUBST(LIBDAEMON_CFLAGS)
 450     AC_SUBST(LIBDAEMON_LIBS)
 451 fi
 452 AM_CONDITIONAL(HAVE_LIBDAEMON, test "x$HAVE_LIBDAEMON" = "xyes")
 453
 454 #
 455 # Python stuff
 456 #
 457 AC_ARG_ENABLE(python,
 458     AS_HELP_STRING([--disable-python], [Disable scripts that depends on python]),
 459     [case "${enableval}" in
 460           yes) HAVE_PYTHON=yes ;;
 461           no)  HAVE_PYTHON=no ;;
 462           *) AC_MSG_ERROR([bad value ${enableval} for --enable-python]) ;;
 463     esac],[HAVE_PYTHON=yes])
 464
 465 HAVE_PYTHON_DBUS=no
 466 HAVE_PYGTK=no
 467
 468 if test "x$HAVE_PYTHON" = "xyes" ; then
 469     AM_PATH_PYTHON([2.4])
 470
 471     AC_ARG_ENABLE(pygtk,
 472         AS_HELP_STRING([--disable-pygtk],[Disable use of GTK in Python]),
 473         [case "${enableval}" in
 474                 yes) HAVE_PYGTK=yes ;;
 475                 no)  HAVE_PYGTK=no ;;
 476                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-pygtk) ;;
 477         esac],
 478         [HAVE_PYGTK=yes])
 479
 480     if test "x$HAVE_PYGTK" = "xyes" ; then
 481         AM_CHECK_PYMOD(gtk,,,[AC_MSG_ERROR(Could not find Python module gtk)])
 482     fi
 483
 484
 485     AC_ARG_ENABLE(python-dbus,
 486         AS_HELP_STRING([--disable-python-dbus],[Disable use of D-BUS in Python]),
 487         [case "${enableval}" in
 488                 yes) HAVE_PYTHON_DBUS=yes ;;
 489                 no)  HAVE_PYTHON_DBUS=no ;;
 490                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-python-dbus) ;;
 491         esac],
 492         [HAVE_PYTHON_DBUS=yes])
 493
 494     if test "x$HAVE_PYTHON_DBUS" = "xyes"; then
 495         AM_CHECK_PYMOD(dbus,,,[AC_MSG_ERROR(Could not find Python module dbus)])
 496     fi
 497
 498     AM_CHECK_PYMOD(socket,,,[AC_MSG_ERROR(Could not find Python module socket)])
 499     AM_CHECK_PYMOD(gdbm,,,[AC_MSG_ERROR(Could not find Python module gdbm)])
 500 fi
 501 AM_CONDITIONAL(HAVE_PYTHON, [test "x$HAVE_PYTHON" = "xyes" ])
 502 AM_CONDITIONAL(HAVE_PYGTK, test "x$HAVE_PYGTK" = "xyes")
 503 AM_CONDITIONAL(HAVE_PYTHON_DBUS, test "x$HAVE_PYTHON_DBUS" = "xyes")
 504
 505 #
 506 # Check for mono stuff
 507 #
 508 AC_ARG_ENABLE(mono,
 509         AS_HELP_STRING([--disable-mono],[Disable mono bindings]),
 510         [case "${enableval}" in
 511                 yes) HAVE_MONO=yes ;;
 512                 no)  HAVE_MONO=no ;;
 513                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-mono) ;;
 514         esac],
 515         [HAVE_MONO=yes])
 516
 517 AC_ARG_ENABLE(monodoc,
 518         AS_HELP_STRING([--disable-monodoc],[Disable documentation for mono bindings]),
 519         [case "${enableval}" in
 520                 yes) HAVE_MONODOC=yes ;;
 521                 no)  HAVE_MONODOC=no ;;
 522                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-monodoc) ;;
 523         esac],
 524         [HAVE_MONODOC=yes])
 525
 526 if test "x$HAVE_MONO" = "xyes" ; then
 527         AC_PATH_PROG(MCS, mcs)
 528         if test "x$MCS" = "x" ; then
 529                AC_MSG_ERROR([Can not find "mcs" in your PATH])
 530         fi
 531
 532         AC_PATH_PROG(GACUTIL, gacutil)
 533         if test "x$GACUTIL" = "x" ; then
 534                 AC_MSG_ERROR([Can not find "gacutil" in your PATH])
 535         fi
 536
 537         AC_SUBST(MCS)
 538         AC_SUBST(GACUTIL)
 539 fi
 540 AM_CONDITIONAL(HAVE_MONO, test "x$HAVE_MONO" = "xyes")
 541
 542 #
 543 # Check for monodoc stuff
 544 #
 545 if test "x$HAVE_MONODOC" = "xyes" ; then
 546         PKG_CHECK_MODULES(MONODOC, [monodoc >= 1.1.8])
 547         MONODOC_DIR=`$PKG_CONFIG --variable=sourcesdir monodoc`
 548
 549         AC_PATH_PROG(MONODOCER, monodocer)
 550         AC_PATH_PROG(MDASSEMBLER, mdassembler)
 551
 552         AC_SUBST(MONODOC_DIR)
 553         AC_SUBST(MONODOCER)
 554         AC_SUBST(MDASSEMBLER)
 555 fi
 556 AM_CONDITIONAL(HAVE_MONODOC, test "x$HAVE_MONODOC" = "xyes")
 557
 558 #
 559 # Defining Avahi User and Group.
 560 #
 561 AC_ARG_WITH(avahi_user, AS_HELP_STRING([--with-avahi-user=<user>],[User for running the Avahi daemon (avahi)]))
 562 if test -z "$with_avahi_user" ; then
 563     AVAHI_USER=avahi
 564 else
 565     AVAHI_USER=$with_avahi_user
 566 fi
 567 AC_SUBST(AVAHI_USER)
 568 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 569
 570 AC_ARG_WITH(avahi_group,AS_HELP_STRING([--with-avahi-group=<group>],[Group for Avahi (avahi)]))
 571 if test -z "$with_avahi_group" ; then
 572     AVAHI_GROUP=avahi
 573 else
 574     AVAHI_GROUP=$with_avahi_group
 575 fi
 576 AC_SUBST(AVAHI_GROUP)
 577 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 578
 579 #
 580 # Avahi runtime dir
 581 #
 582 avahi_runtime_dir="${localstatedir}/run"
 583 avahi_socket="${avahi_runtime_dir}/avahi-daemon/socket"
 584 AC_SUBST(avahi_runtime_dir)
 585 AC_SUBST(avahi_socket)
 586
 587 #
 588 # Avahi interfaces dir
 589 #
 590 if test "x$HAVE_PYTHON_DBUS" = "xyes" -o "x$HAVE_GTK" = "xyes"; then
 591         interfacesdir="${datadir}/${PACKAGE}/interfaces/"
 592         AC_SUBST(interfacesdir)
 593 fi
 594
 595 #
 596 # Doxygen
 597 #
 598 DX_HTML_FEATURE(ON)
 599 DX_CHM_FEATURE(OFF)
 600 DX_CHI_FEATURE(OFF)
 601 DX_MAN_FEATURE(OFF)
 602 DX_RTF_FEATURE(OFF)
 603 DX_XML_FEATURE(OFF)
 604 DX_PDF_FEATURE(OFF)
 605 DX_PS_FEATURE(OFF)
 606 DX_INIT_DOXYGEN(avahi, doxygen.cfg, doxygen)
 607
 608 #
 609 # Build and Install man pages
 610 #
 611 AC_ARG_ENABLE(manpages,
 612         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 613 [case "${enableval}" in
 614   yes) manpages=yes ;;
 615   no)  manpages=no ;;
 616   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 617 esac],[manpages=yes])
 618
 619 if test x$manpages = xyes ; then
 620     #
 621     # XMLTOMAN manpage generation
 622     #
 623     AC_ARG_ENABLE(xmltoman,
 624     AS_HELP_STRING([--disable-xmltoman],[Disable rebuilding of man pages with xmltoman]),
 625     [case "${enableval}" in
 626       yes) xmltoman=yes ;;
 627       no)  xmltoman=no ;;
 628       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 629     esac],[xmltoman=yes])
 630
 631     if test x$xmltoman = xyes ; then
 632         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 633     fi
 634
 635     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 636         if ! test -e man/avahi-daemon.8 ; then
 637             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 638             exit 1
 639         fi
 640         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 641         xmltoman=no
 642     fi
 643 fi
 644 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 645 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 646
 647 #
 648 # Conditionally compile test and example programs
 649 #
 650 AC_ARG_ENABLE(tests,
 651         AS_HELP_STRING([--enable-tests],[Enable building of tests and examples]),
 652         [case "${enableval}" in
 653                 yes) ENABLE_TESTS=yes ;;
 654                 no)  ENABLE_TESTS=no ;;
 655                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-tests) ;;
 656         esac],
 657         [ENABLE_TESTS=no])
 658
 659 AM_CONDITIONAL([ENABLE_TESTS], [test "x$ENABLE_TESTS" = "xyes"])
 660
 661 #
 662 # Optionally enable libdns_sd compatibility support
 663 #
 664 AC_ARG_ENABLE(compat-libdns_sd,
 665         AS_HELP_STRING([--enable-compat-libdns_sd],[Enable compatibility layer for libdns_sd]),
 666         [case "${enableval}" in
 667                 yes) ENABLE_COMPAT_LIBDNS_SD=yes ;;
 668                 no)  ENABLE_COMPAT_LIBDNS_SD=no ;;
 669                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libdns_sd) ;;
 670         esac],
 671         [ENABLE_COMPAT_LIBDNS_SD=no])
 672
 673 AM_CONDITIONAL([ENABLE_COMPAT_LIBDNS_SD], [test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes"])
 674
 675 #
 676 # Optionally enable HOWL compatibility support
 677 #
 678 AC_ARG_ENABLE(compat-howl,
 679         AS_HELP_STRING([--enable-compat-howl],[Enable compatibility layer for HOWL]),
 680         [case "${enableval}" in
 681                 yes) ENABLE_COMPAT_HOWL=yes ;;
 682                 no)  ENABLE_COMPAT_HOWL=no ;;
 683                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-howl) ;;
 684         esac],
 685         [ENABLE_COMPAT_HOWL=no])
 686
 687 AM_CONDITIONAL([ENABLE_COMPAT_HOWL], [test "x$ENABLE_COMPAT_HOWL" = "xyes"])
 688
 689
 690 # ==========================================================================
 691 AC_CONFIG_FILES([
 692 Makefile
 693 avahi-common/Makefile
 694 avahi-core/Makefile
 695 avahi-glib/Makefile
 696 avahi-qt/Makefile
 697 avahi-daemon/Makefile
 698 avahi-daemon/avahi-dbus.conf
 699 avahi-discover-standalone/Makefile
 700 avahi-client/Makefile
 701 initscript/Makefile
 702 initscript/debian/Makefile
 703 initscript/gentoo/Makefile
 704 initscript/archlinux/Makefile
 705 initscript/suse/Makefile
 706 initscript/fedora/Makefile
 707 initscript/darwin/Makefile
 708 avahi-dnsconfd/Makefile
 709 avahi-utils/Makefile
 710 avahi-python/Makefile
 711 avahi-python/avahi/Makefile
 712 examples/Makefile
 713 common/Makefile
 714 man/Makefile
 715 tests/Makefile
 716 service-type-database/Makefile
 717 avahi-sharp/Makefile
 718 avahi-compat-libdns_sd/Makefile
 719 avahi-compat-howl/Makefile
 720 avahi-compat-howl/samples/Makefile
 721 ])
 722 AC_OUTPUT
 723
 724 # ==========================================================================
 725 echo "
 726  ---{ $PACKAGE_NAME $VERSION }---
 727
 728     prefix:                 ${prefix}
 729     sysconfdir:             ${sysconfdir}
 730     localstatedir:          ${localstatedir}
 731     avahi socket:           ${avahi_socket}
 732     dbus-1 system.d dir:    ${DBUS_SYS_DIR}
 733     dbus-1 version:         `pkg-config dbus-1 --modversion`
 734     dbus-1 system socket    ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
 735     compiler:               ${CC}
 736     cflags:                 ${CFLAGS}
 737     Enable GLIB:            ${HAVE_GLIB}
 738     Enable GTK:             ${HAVE_GTK}
 739     Enable D-BUS:           ${HAVE_DBUS}
 740     Enable Expat:           ${HAVE_EXPAT}
 741     Enable GDBM:            ${HAVE_GDBM}
 742     Enable libdaemon:       ${HAVE_LIBDAEMON}
 743     Enable Python:          ${HAVE_PYTHON}
 744     Enable pygtk:           ${HAVE_PYGTK}
 745     Enable python-dbus:     ${HAVE_PYTHON_DBUS}
 746     Enable QT3:             ${HAVE_QT3}
 747     Enable QT4:             ${HAVE_QT4}
 748     Enable Mono:            ${HAVE_MONO}
 749     Distribution/OS:        ${with_distro}
 750     User for Avahi:         ${AVAHI_USER}
 751     Group for Avahi:        ${AVAHI_GROUP}
 752     Enable chroot():        ${enable_chroot}
 753 "
 754
 755 BUILD_DAEMON="no (!)"
 756
 757 if test "x$HAVE_EXPAT" = "xyes" -a "x$HAVE_LIBDAEMON" = "xyes" ; then
 758     BUILD_DAEMON=yes
 759 fi
 760
 761 BUILD_UTILS="no (!)"
 762
 763 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" -a "x$HAVE_PYTHON" = "xyes" -a "x$HAVE_PYTHON_DBUS" = "xyes" -a "x$HAVE_PYGTK" = "xyes" ; then
 764     BUILD_UTILS=yes
 765 fi
 766
 767 BUILD_CLIENT="no (!)"
 768
 769 if test "x$BUILD_DAEMON" = "xyes" -a "x$HAVE_DBUS" = "xyes" ; then
 770     BUILD_CLIENT=yes
 771 fi
 772
 773 if test "x$ENABLE_COMPAT_LIBDNS_SD" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 774    AC_MSG_ERROR([building avahi-compat-libdns_sd without building libavahi-client doesn't work])
 775 fi
 776 if test "x$ENABLE_COMPAT_HOWL" = "xyes" -a "x$BUILD_CLIENT" != "xyes" ; then
 777    AC_MSG_ERROR([building avahi-compat-howl without building libavahi-client doesn't work])
 778 fi
 779
 780
 781 echo "
 782     Building libavahi-core              yes
 783     Building avahi-daemon:              ${BUILD_DAEMON}
 784     Building avahi-dnsconfd:            ${BUILD_DAEMON}
 785     Building avahi-utils:               ${BUILD_UTILS}
 786     Building libavahi-glib:             ${HAVE_GLIB}
 787     Building libavahi-client:           ${BUILD_CLIENT}
 788     Building avahi-discover-standalone: ${HAVE_GTK}
 789     Building libavahi-qt3:              ${HAVE_QT3}
 790     Building libavahi-qt4:              ${HAVE_QT4}
 791     Building avahi-sharp:               ${HAVE_MONO}
 792     Building avahi-compat-libdns_sd:    ${ENABLE_COMPAT_LIBDNS_SD}
 793     Building avahi-compat-howl:         ${ENABLE_COMPAT_HOWL}
 794     Building tests:                     ${ENABLE_TESTS}
 795 "