git.meshlink.io Git - catta/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of avahi.
   7 #
   8 # avahi is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation; either version 2 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # avahi is distributed in the hope that it will be useful, but WITHOUT
  14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
  16 # License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with avahi; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  21 # USA.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([avahi],[0.1],[mzninuv (at) 0pointer (dot) de])
  25 AC_CONFIG_SRCDIR([avahi-core])
  26 AC_CONFIG_HEADERS([config.h])
  27 AM_INIT_AUTOMAKE([foreign -Wall])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/Software/Avahi])
  30
  31 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  32    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  33    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  34 fi
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_CPP
  39 AC_PROG_INSTALL
  40 AC_PROG_LN_S
  41 AC_PROG_MAKE_SET
  42
  43 # libtool stuff
  44 AC_PROG_LIBTOOL
  45
  46 # Checks for header files.
  47 AC_HEADER_STDC
  48 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h netinet/in.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h])
  49
  50 # Checks for typedefs, structures, and compiler characteristics.
  51 AC_C_CONST
  52 AC_TYPE_SIZE_T
  53 AC_HEADER_TIME
  54
  55 # Checks for library functions.
  56 AC_FUNC_MEMCMP
  57 AC_FUNC_SELECT_ARGTYPES
  58 AC_CHECK_FUNCS([gethostname memset select socket strchr strcspn strerror uname])
  59
  60 AC_CHECK_FUNCS(setresuid)
  61 AC_CHECK_FUNCS(setreuid)
  62
  63 # Check for GLIB 2.0
  64 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ])
  65 AC_SUBST(GLIB20_CFLAGS)
  66 AC_SUBST(GLIB20_LIBS)
  67
  68 AC_ARG_ENABLE(gtk,
  69         AC_HELP_STRING([--enable-gtk],[use GTK+ (default=yes)]),
  70         [case "${enableval}" in
  71                 yes) ENABLE_GTK=yes ;;
  72                 no)  ENABLE_GTK=no ;;
  73                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
  74         esac],
  75         [ENABLE_GTK=yes]) dnl Default value
  76
  77 if test "x$ENABLE_GTK" = "xyes"; then
  78         # Check for GTK 2.0
  79         PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ])
  80         AC_SUBST(GTK20_CFLAGS)
  81         AC_SUBST(GTK20_LIBS)
  82
  83         # Check for GLADE 2.0
  84         PKG_CHECK_MODULES(GLADE20, [ libglade-2.0 >= 2.4.0 ])
  85         AC_SUBST(GLADE20_CFLAGS)
  86         AC_SUBST(GLADE20_LIBS)
  87
  88         DATADIRNAME=share
  89         if test "x${prefix}" = "xNONE"; then
  90            AC_DEFINE_UNQUOTED(INTERFACES_DIR, "${ac_default_prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/", [path where glade files will be installed])
  91            interfacesdir="${ac_default_prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/"
  92            AC_SUBST(interfacesdir)
  93         else
  94            AC_DEFINE_UNQUOTED(INTERFACES_DIR, "${prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/", [path where glade files will be installed])
  95            interfacesdir="${prefix}/${DATADIRNAME}/${PACKAGE}/interfaces/"
  96            AC_SUBST(interfacesdir)
  97         fi
  98
  99 fi
 100 AM_CONDITIONAL(ENABLE_GTK, test "x$ENABLE_GTK" = "xyes")
 101
 102 AC_ARG_ENABLE(doxygen,
 103         AC_HELP_STRING([--enable-doxygen],[use doxygen to generate API docs (default=yes)]),
 104         [case "${enableval}" in
 105                 yes) ENABLE_DOXYGEN=yes ;;
 106                 no)  ENABLE_DOXYGEN=no ;;
 107                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk) ;;
 108         esac],
 109         [ENABLE_DOXYGEN=yes]) dnl Default value
 110
 111 AM_CONDITIONAL(ENABLE_DOXYGEN, test "x$ENABLE_DOXYGEN" = "xyes")
 112
 113 AC_ARG_ENABLE(dbus,
 114         AC_HELP_STRING([--enable-dbus],[use DBus (default=yes)]),
 115         [case "${enableval}" in
 116                 yes) ENABLE_DBUS=yes ;;
 117                 no)  ENABLE_DBUS=no ;;
 118                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-dbus) ;;
 119         esac],
 120         [ENABLE_DBUS=yes]) dnl Default value
 121
 122 AC_DEFINE(ENABLE_DBUS, 1, [Whether to use DBUS or not])
 123
 124 if test "x$ENABLE_DBUS" = "xyes"; then
 125         PKG_CHECK_MODULES(DBUS, [ dbus-glib-1 >= 0.23])
 126
 127         AC_ARG_WITH(dbus-sys, [  --with-dbus-sys=<dir>   where D-BUS system.d directory is])
 128
 129         if ! test -z "$with_dbus_sys" ; then
 130            DBUS_SYS_DIR="$with_dbus_sys"
 131         else
 132            DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 133         fi
 134         AC_SUBST(DBUS_SYS_DIR)
 135         AC_DEFINE_UNQUOTED(DBUS_SYSTEMD_DIR, "$DBUS_SYS_DIR", [Where system.d dir for DBUS is])
 136
 137         if pkg-config dbus-1 --atleast-version=0.30 ; then
 138            AC_DEFINE(DBUS_USE_NEW_API, 1, [Whether to use the new API for DBUS 0.30])
 139         fi
 140
 141         AC_SUBST(DBUS_CFLAGS)
 142         AC_SUBST(DBUS_LIBS)
 143
 144         if pkg-config dbus-1 --atleast-version=0.30 ; then
 145                 AC_DEFINE(DBUS_USE_NEW_API, 1, [Whether to use the new API for DBUS 0.30])
 146         fi
 147 fi
 148
 149 AM_CONDITIONAL(ENABLE_DBUS, test "x$ENABLE_DBUS" = "xyes")
 150
 151 AC_CHECK_LIB(expat, XML_ParserCreate, [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ], have_expat=false)
 152
 153 if ! $have_expat ; then
 154    AC_MSG_ERROR([*** libexpat not found ***])
 155 fi
 156
 157 PKG_CHECK_MODULES(LIBDAEMON, [ libdaemon >= 0.5 ])
 158 AC_SUBST(LIBDAEMON_CFLAGS)
 159 AC_SUBST(LIBDAEMON_LIBS)
 160
 161 # If using GCC specify some additional parameters
 162 if test "x$GCC" = "xyes" ; then
 163    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
 164
 165    AC_LANG_CONFTEST([int main() {}])
 166    $CC -c conftest.c -std=c99 -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=c99 -Wno-unused-parameter"
 167    rm -f conftest.o
 168 fi
 169
 170 #
 171 # Detecting the linux distro for specific things like initscripts.
 172 #
 173 AC_ARG_WITH(distro, AC_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, suse, gentoo, debian, or slackware]))
 174 if test "z$with_distro" = "z"; then
 175    AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
 176    AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 177    AC_CHECK_FILE(/etc/fedora-release,with_distro="redhat")
 178    AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 179    AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 180    AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 181 fi
 182 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 183
 184 if test "z$with_distro" = "z"; then
 185    echo "Linux distribution autodetection failed, you must specify the distribution to target using --with-distro=DISTRO"
 186    exit 1
 187 else
 188 case $with_distro in
 189    debian)
 190      ;;
 191    *)
 192      echo "Your distribution (${with_distro}) is not yet supported!  (patches welcome)"
 193      exit 1
 194      ;;
 195 esac
 196
 197 fi
 198 AM_CONDITIONAL(TARGET_REDHAT, test x"$with_distro" = xredhat)
 199 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 200 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 201 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 202 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 203
 204 #
 205 # Defining Avahi User and Group.
 206 #
 207 AC_ARG_WITH(avahi_user,[  --with-avahi-user=<user>  User for running the Avahi daemon (avahi)])
 208 if test -z "$with_avahi_user" ; then
 209     AVAHI_USER=avahi
 210 else
 211     AVAHI_USER=$with_avahi_user
 212 fi
 213 AC_SUBST(AVAHI_USER)
 214 AC_DEFINE_UNQUOTED(AVAHI_USER,"$AVAHI_USER", [User for running the Avahi daemon])
 215
 216 AC_ARG_WITH(avahi_group,[  --with-avahi-group=<grp>  Group for Avahi (avahi)])
 217 if test -z "$with_avahi_group" ; then
 218     AVAHI_GROUP=avahi
 219 else
 220     AVAHI_GROUP=$with_avahi_group
 221 fi
 222 AC_SUBST(AVAHI_GROUP)
 223 AC_DEFINE_UNQUOTED(AVAHI_GROUP,"$AVAHI_GROUP", [Group for Avahi])
 224
 225 AC_CONFIG_FILES([
 226 Makefile
 227 avahi-core.pc
 228 doxygen/Makefile
 229 doxygen/doxygen.conf
 230 avahi-common/Makefile
 231 avahi-core/Makefile
 232 avahi-daemon/Makefile
 233 avahi-daemon/avahi-dbus.conf
 234 avahi-discover/Makefile
 235 avahi-client/Makefile
 236 initscript/Makefile
 237 initscript/Debian/Makefile
 238 initscript/Debian/15avahi
 239 ])
 240 AC_OUTPUT
 241
 242 dnl ==========================================================================
 243 echo "
 244                    $PACKAGE_NAME $VERSION
 245                   ============
 246
 247         prefix:                   ${prefix}
 248         sysconfdir:               ${sysconfdir}
 249         dbus-1 system.d dir:      ${DBUS_SYS_DIR}
 250         dbus-1 version:           `pkg-config dbus-1 --modversion`
 251         compiler:                 ${CC}
 252         cflags:                   ${CFLAGS}
 253         Linux Distro:             ${with_distro}
 254         User for Avahi:           ${AVAHI_USER}
 255         Group for Avahi:          ${AVAHI_GROUP}
 256 "
 257
 258 echo "NOTE: Remember to create user ${AVAHI_USER} and group ${AVAHI_GROUP} before make install"
 259 echo